New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynzad.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/DYN/dynzad.F90 @ 2287

Last change on this file since 2287 was 2287, checked in by smasson, 13 years ago

update licence of all NEMO files...

  • Property svn:keywords set to Id
File size: 5.6 KB
Line 
1MODULE dynzad
2   !!======================================================================
3   !!                       ***  MODULE  dynzad  ***
4   !! Ocean dynamics : vertical advection trend
5   !!======================================================================
6   !! History :  6.0  !  91-01  (G. Madec) Original code
7   !!            7.0  !  91-11  (G. Madec)
8   !!            7.5  !  96-01  (G. Madec) statement function for e3
9   !!            8.5  !  02-07  (G. Madec) j-k-i case: Original code
10   !!            8.5  !  02-07  (G. Madec) Free form, F90
11   !!----------------------------------------------------------------------
12   
13   !!----------------------------------------------------------------------
14   !!   dyn_zad       : vertical advection momentum trend
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and tracers
17   USE dom_oce        ! ocean space and time domain
18   USE sbc_oce        ! surface boundary condition: ocean
19   USE trdmod_oce     ! ocean variables trends
20   USE trdmod         ! ocean dynamics trends
21   USE in_out_manager ! I/O manager
22   USE prtctl         ! Print control
23
24   IMPLICIT NONE
25   PRIVATE
26   
27   PUBLIC   dyn_zad   ! routine called by step.F90
28
29   !! * Substitutions
30#  include "domzgr_substitute.h90"
31#  include "vectopt_loop_substitute.h90"
32   !!----------------------------------------------------------------------
33   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
34   !! $Id$
35   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
36   !!----------------------------------------------------------------------
37
38CONTAINS
39
40   SUBROUTINE dyn_zad ( kt )
41      !!----------------------------------------------------------------------
42      !!                  ***  ROUTINE dynzad  ***
43      !!
44      !! ** Purpose :   Compute the now vertical momentum advection trend and
45      !!      add it to the general trend of momentum equation.
46      !!
47      !! ** Method  :   The now vertical advection of momentum is given by:
48      !!         w dz(u) = ua + 1/(e1u*e2u*e3u) mk+1[ mi(e1t*e2t*wn) dk(un) ]
49      !!         w dz(v) = va + 1/(e1v*e2v*e3v) mk+1[ mj(e1t*e2t*wn) dk(vn) ]
50      !!      Add this trend to the general trend (ua,va):
51      !!         (ua,va) = (ua,va) + w dz(u,v)
52      !!
53      !! ** Action  : - Update (ua,va) with the vert. momentum adv. trends
54      !!              - Save the trends in (ztrdu,ztrdv) ('key_trddyn')
55     !!----------------------------------------------------------------------
56      USE oce, ONLY:   zwuw => ta   ! use ta as 3D workspace
57      USE oce, ONLY:   zwvw => sa   ! use sa as 3D workspace
58      !!
59      INTEGER, INTENT(in) ::   kt   ! ocean time-step inedx
60      !!
61      INTEGER  ::   ji, jj, jk      ! dummy loop indices
62      REAL(wp) ::   zua, zva        ! temporary scalars
63      REAL(wp), DIMENSION(jpi,jpj)     ::   zww            ! 2D  workspace
64      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ztrdu, ztrdv   ! 3D workspace
65      !!----------------------------------------------------------------------
66     
67      IF( kt == nit000 ) THEN
68         IF(lwp)WRITE(numout,*)
69         IF(lwp)WRITE(numout,*) 'dyn_zad : arakawa advection scheme'
70      ENDIF
71
72      IF( l_trddyn )   THEN         ! Save ua and va trends
73         ztrdu(:,:,:) = ua(:,:,:) 
74         ztrdv(:,:,:) = va(:,:,:) 
75      ENDIF
76     
77      DO jk = 2, jpkm1              ! Vertical momentum advection at level w and u- and v- vertical
78         DO jj = 2, jpj                   ! vertical fluxes
79            DO ji = fs_2, jpi             ! vector opt.
80               zww(ji,jj) = 0.25 * e1t(ji,jj) * e2t(ji,jj) * wn(ji,jj,jk)
81            END DO
82         END DO
83         DO jj = 2, jpjm1                 ! vertical momentum advection at w-point
84            DO ji = fs_2, fs_jpim1        ! vector opt.
85               zwuw(ji,jj,jk) = ( zww(ji+1,jj  ) + zww(ji,jj) ) * ( un(ji,jj,jk-1)-un(ji,jj,jk) )
86               zwvw(ji,jj,jk) = ( zww(ji  ,jj+1) + zww(ji,jj) ) * ( vn(ji,jj,jk-1)-vn(ji,jj,jk) )
87            END DO 
88         END DO   
89      END DO
90      DO jj = 2, jpjm1              ! Surface and bottom values set to zero
91         DO ji = fs_2, fs_jpim1           ! vector opt.
92            zwuw(ji,jj, 1 ) = 0.e0
93            zwvw(ji,jj, 1 ) = 0.e0
94            zwuw(ji,jj,jpk) = 0.e0
95            zwvw(ji,jj,jpk) = 0.e0
96         END DO 
97      END DO
98
99      DO jk = 1, jpkm1              ! Vertical momentum advection at u- and v-points
100         DO jj = 2, jpjm1
101            DO ji = fs_2, fs_jpim1       ! vector opt.
102               !                         ! vertical momentum advective trends
103               zua = - ( zwuw(ji,jj,jk) + zwuw(ji,jj,jk+1) ) / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) )
104               zva = - ( zwvw(ji,jj,jk) + zwvw(ji,jj,jk+1) ) / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) )
105               !                         ! add the trends to the general momentum trends
106               ua(ji,jj,jk) = ua(ji,jj,jk) + zua
107               va(ji,jj,jk) = va(ji,jj,jk) + zva
108            END DO 
109         END DO 
110      END DO
111
112      IF( l_trddyn ) THEN           ! save the vertical advection trends for diagnostic
113         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
114         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
115         CALL trd_mod(ztrdu, ztrdv, jpdyn_trd_zad, 'DYN', kt)
116      ENDIF
117      !                             ! Control print
118      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' zad  - Ua: ', mask1=umask,   &
119         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
120      !
121   END SUBROUTINE dyn_zad
122
123   !!======================================================================
124END MODULE dynzad
Note: See TracBrowser for help on using the repository browser.