New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
ldftra_c2d.h90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/LDF – NEMO

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/LDF/ldftra_c2d.h90 @ 2281

Last change on this file since 2281 was 2281, checked in by smasson, 13 years ago

set proper svn properties to all files...

  • Property svn:keywords set to Id
File size: 7.1 KB
Line 
1   !!----------------------------------------------------------------------
2   !!                      ***  ldftra_c2d.h90  ***
3   !!----------------------------------------------------------------------
4
5   !!----------------------------------------------------------------------
6   !!   OPA 9.0 , LOCEAN-IPSL (2005)
7   !! $Id$
8   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
9   !!----------------------------------------------------------------------
10
11   SUBROUTINE ldf_tra_c2d( ld_print )
12      !!----------------------------------------------------------------------
13      !!                  ***  ROUTINE ldftra_c2d  ***
14      !!             
15      !! ** Purpose :   initializations of horizontally non uniform eddy
16      !!      diffusivity coefficients
17      !!
18      !! ** Method :
19      !!       biharmonic operator    : ahtt = defined at T-level
20      !!                                ahtu,ahtv,ahtw never used
21      !!       harmonic operator (ahtt never used)
22      !!           iso-model level   : ahtu, ahtv defined at u-, v-points
23      !!         isopycnal         : ahtu, ahtv, ahtw defined at u-, v-, w-pts
24      !!         or geopotential   
25      !!       eddy induced velocity
26      !!           always harmonic   : aeiu, aeiv, aeiw defined at u-, v-, w-pts
27      !!
28      !!----------------------------------------------------------------------
29      !! * Arguments
30      LOGICAL, INTENT (in) :: ld_print   ! If true, print arrays in numout
31
32      !! * Local variables
33      INTEGER ::   ji, jj                  ! dummy loop indices
34# if defined key_orca_r4
35      INTEGER :: i1, i2, j1, j2
36# endif
37      REAL(wp) ::   za00, zd_max, zeumax, zevmax, zetmax
38     
39      !!----------------------------------------------------------------------
40
41      IF( lk_traldf_eiv ) THEN
42         IF(lwp) WRITE(numout,*)
43         IF(lwp) WRITE(numout,*) ' ldf_tra_c2d : 2D eddy diffusivity and eddy'
44         IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~   --  induced velocity coefficients'
45         IF(lwp) WRITE(numout,*)
46      ELSE
47         IF(lwp) WRITE(numout,*)
48         IF(lwp) WRITE(numout,*) ' ldf_tra2d : 2D eddy diffusivity coefficient'
49         IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~   --'
50         IF(lwp) WRITE(numout,*)
51      ENDIF
52
53      zd_max = MAX( MAXVAL( e1t(:,:) ), MAXVAL( e2t(:,:) ) )
54      IF( lk_mpp ) CALL mpp_max( zd_max )   ! max over the global domain
55
56      ! harmonic operator : (U-, V-, W-points)
57      ! ==================
58      IF( ln_traldf_lap ) THEN
59 
60         za00 = aht0 / zd_max
61 
62         DO jj = 1, jpj
63            DO ji = 1, jpi
64               zeumax = MAX( e1u(ji,jj), e2u(ji,jj) )
65               zevmax = MAX( e1v(ji,jj), e2v(ji,jj) )
66               zetmax = MAX( e1t(ji,jj), e2t(ji,jj) )
67               ahtu(ji,jj) = za00 * zeumax ! set ahtu = ahtv at u- and v-points,
68               ahtv(ji,jj) = za00 * zevmax ! and ahtw at w-point (idem T-point)
69               ahtw(ji,jj) = za00 * zetmax !
70            END DO
71         END DO
72
73         CALL lbc_lnk( ahtu, 'U', 1. )   ! Lateral boundary conditions
74         CALL lbc_lnk( ahtv, 'V', 1. )   ! (no change of sign)
75         CALL lbc_lnk( ahtw, 'W', 1. )
76
77         ! Special case for ORCA R2 and R4 configurations (overwrite the value of ahtu ahtv ahtw)
78         ! ==============================================
79         IF( cp_cfg == "orca" .AND. ( jp_cfg == 2 .OR. jp_cfg == 4 ) )   THEN
80            ahtu(:,:) = aht0              ! set ahtu = ahtv at u- and v-points,
81            ahtv(:,:) = aht0              ! and ahtw at w-point
82            ahtw(:,:) = aht0              ! (here : no space variation)
83            IF(lwp) WRITE(numout,*) '               ORCA R2 or R4 case'
84            IF(lwp) WRITE(numout,*) '               Constant values used for eddy diffusivity coefficients'
85            IF(lwp) WRITE(numout,*) '               Variation lat/lon only for eddy induced velocity coefficients'
86         ENDIF
87
88         ! Control print
89         IF( lwp .AND. ld_print ) THEN
90            WRITE(numout,*)
91            WRITE(numout,*) 'inildf: ahtu array'
92            CALL prihre( ahtu, jpi, jpj, 1, jpi, 1,   &
93               &                         1, jpj, 1, 1.e-3, numout )
94            WRITE(numout,*)
95            WRITE(numout,*) 'inildf: ahtv array'
96            CALL prihre( ahtv, jpi, jpj, 1, jpi, 1,   &
97               &                         1, jpj, 1, 1.e-3, numout )
98            WRITE(numout,*)
99            WRITE(numout,*) 'inildf: ahtw array'
100            CALL prihre( ahtw, jpi, jpj, 1, jpi, 1,   &
101               &                         1, jpj, 1, 1.e-3, numout )
102         ENDIF
103      ENDIF
104     
105      ! biharmonic operator : (T-point)
106      ! ====================
107      IF( ln_traldf_bilap ) THEN
108         ! (USER: modify ahtt following your desiderata)
109         ! Here: ahm is proportional to the cube of the maximum of the gridspacing
110         !       in the to horizontal direction
111
112         zd_max = MAX( MAXVAL( e1t(:,:) ), MAXVAL( e2t(:,:) ) )
113         IF( lk_mpp )   CALL mpp_max( zd_max )   ! max over the global domain
114
115         za00 = aht0 / ( zd_max * zd_max * zd_max )
116         DO jj = 1, jpj
117            DO ji = 1, jpi
118               zetmax = MAX( e1t(ji,jj), e2t(ji,jj) )
119               ahtt(ji,jj) = za00 * zetmax * zetmax * zetmax      ! set ahtt at T-point
120            END DO
121         END DO
122
123         CALL lbc_lnk( ahtt, 'T', 1. )   ! Lateral boundary conditions on ( ahtt )
124
125         ! Control print
126         IF( lwp .AND. ld_print ) THEN
127            WRITE(numout,*)
128            WRITE(numout,*) 'inildf: 2D ahtt array'
129            CALL prihre( ahtt, jpi, jpj, 1, jpi, 1,   &
130               &                         1, jpj, 1, 1.e-3, numout )
131         ENDIF
132      ENDIF
133
134# if defined key_traldf_eiv
135      ! set aeiu = aeiv at u- and v-points, and aeiw at w-point (idem T-point)
136      ! (here no space variation)
137      aeiu(:,:) = aeiv0
138      aeiv(:,:) = aeiv0
139      aeiw(:,:) = aeiv0
140     
141      IF( cp_cfg == "orca" .AND. jp_cfg == 4 ) THEN
142         !                                 ! Cancel eiv in Gibraltar strait
143         aeiu( mi0(68):mi1(71) , mj0(50):mj1(53) ) = 0.e0
144         aeiv( mi0(68):mi1(71) , mj0(50):mj1(53) ) = 0.e0
145         aeiw( mi0(68):mi1(71) , mj0(50):mj1(53) ) = 0.e0
146         !                                 ! Cancel eiv in Mediterrannean sea
147         aeiu( mi0(70):mi1(90) , mj0(49):mj1(56) ) = 0.e0
148         aeiv( mi0(70):mi1(90) , mj0(49):mj1(56) ) = 0.e0
149         aeiw( mi0(70):mi1(90) , mj0(49):mj1(56) ) = 0.e0
150      ENDIF
151
152      ! Lateral boundary conditions on ( aeiu, aeiv, aeiw )
153      CALL lbc_lnk( aeiu, 'U', 1. )
154      CALL lbc_lnk( aeiv, 'V', 1. )
155      CALL lbc_lnk( aeiw, 'W', 1. )
156
157      ! Control print
158      IF( lwp .AND. ld_print ) THEN
159         WRITE(numout,*)
160         WRITE(numout,*) 'inildf: aeiu array'
161         CALL prihre(aeiu,jpi,jpj,1,jpi,1,1,jpj,1,1.e-3,numout)
162         WRITE(numout,*)
163         WRITE(numout,*) 'inildf: aeiv array'
164         CALL prihre(aeiv,jpi,jpj,1,jpi,1,1,jpj,1,1.e-3,numout)
165         WRITE(numout,*)
166         WRITE(numout,*) 'inildf: aeiw array'
167         CALL prihre(aeiw,jpi,jpj,1,jpi,1,1,jpj,1,1.e-3,numout)
168      ENDIF
169
170# endif
171
172   END SUBROUTINE ldf_tra_c2d
Note: See TracBrowser for help on using the repository browser.