source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/OBS/mpp_map.F90 @ 2287

MODULE mpp_map
   !!======================================================================
   !!                       ***  MODULE mpp_mpa  ***
   !! NEMOVAR: MPP global grid point mapping to processors
   !!======================================================================

   !!----------------------------------------------------------------------
   !! mppmap      : Global array which maps i,j to area number.
   !! mppmap_init : Initialize mppmap.
   !!----------------------------------------------------------------------
   !! * Modules used   
   USE par_kind, ONLY : &   ! Precision variables
      & wp
   USE par_oce, ONLY : &    ! Ocean parameters
      & jpi,   &
      & jpj
   USE dom_oce, ONLY : &    ! Ocean space and time domain variables
      & mig,   &
      & mjg,   &  
      & nldi,  &
      & nlei,  &
      & nldj,  &
      & nlej,  &
      & narea 
#if defined key_mpp_mpi
   USE lib_mpp, ONLY : &    ! MPP library
      & mpi_comm_opa
#endif
   USE in_out_manager

   IMPLICIT NONE

   !! * Routine accessibility
   PRIVATE

   PUBLIC &
      & mppmap_init,        &
      & mppmap

   !! * Module variables

   INTEGER, DIMENSION(:,:), ALLOCATABLE :: &
      & mppmap

   !!----------------------------------------------------------------------
   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
   !! $Id$
   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
   !!----------------------------------------------------------------------

CONTAINS

   SUBROUTINE mppmap_init
      !!----------------------------------------------------------------------
      !!               ***  ROUTINE mppmap_init ***
      !!          
      !! ** Purpose : Setup a global map of processor rank for all gridpoints
      !!
      !! ** Method  : MPI all reduce.
      !!
      !! ** Action  : This does only work for MPI. 
      !!              It does not work for SHMEM.
      !!
      !! References : http://www.mpi-forum.org
      !!
      !! History :
      !!        !  07-08  (K. Mogensen)  Original code
      !!----------------------------------------------------------------------

      !! * Arguments
      INTEGER, DIMENSION(:,:), ALLOCATABLE :: imppmap
#if defined key_mpp_mpi
      !! * Local declarations
      INTEGER :: ierr
INCLUDE 'mpif.h'
#endif

      ALLOCATE( &
         & mppmap(jpiglo,jpjglo) &
         & )

      ! Initialize local imppmap

      ALLOCATE( &
         & imppmap(jpiglo,jpjglo) &
         & )
      imppmap(:,:) = 0

      ! Setup local grid points
      imppmap(mig(nldi):mig(nlei),mjg(nldj):mjg(nlej)) = narea 
      
      ! Get global data

#if defined key_mpp_mpi

      ! Call the MPI library to find the max across processors

      CALL mpi_allreduce( imppmap, mppmap, jpiglo*jpjglo, mpi_integer, &
         &                mpi_max, mpi_comm_opa, ierr )
#elif defined key_mpp_shmem
#error "Only MPI support for MPP in NEMOVAR"
#else      
      
      ! Just copy the data

      mppmap(:,:) = imppmap(:,:)

#endif

   END SUBROUTINE mppmap_init

END MODULE mpp_map