New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcfwb.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/SBC/sbcfwb.F90 @ 2287

Last change on this file since 2287 was 2287, checked in by smasson, 14 years ago

update licence of all NEMO files...
  • Property svn:keywords set to Id
File size: 10.1 KB
Line 
1MODULE sbcfwb
2   !!======================================================================
3   !!                       ***  MODULE  sbcfwb  ***
4   !! Ocean fluxes   : domain averaged freshwater budget
5   !!======================================================================
6   !! History :  8.2  !  01-02  (E. Durand)  Original code
7   !!            8.5  !  02-06  (G. Madec)  F90: Free form and module
8   !!            9.0  !  06-08  (G. Madec)  Surface module
9   !!            9.2  !  09-07  (C. Talandier) emp mean s spread over erp area
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   sbc_fwb      : freshwater budget for global ocean configurations
14   !!                  in free surface and forced mode
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and tracers
17   USE dom_oce         ! ocean space and time domain
18   USE sbc_oce         ! surface ocean boundary condition
19   USE phycst          ! physical constants
20   USE sbcrnf          ! ocean runoffs
21   USE sbcssr          ! SS damping terms
22   USE in_out_manager  ! I/O manager
23   USE lib_mpp         ! distribued memory computing library
24   USE lbclnk          ! ocean lateral boundary conditions
25   USE lib_fortran
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   sbc_fwb      ! routine called by step
31
32   REAL(wp) ::   a_fwb_b            ! annual domain averaged freshwater budget
33   REAL(wp) ::   a_fwb              ! for 2 year before (_b) and before year.
34   REAL(wp) ::   fwfold             ! fwfold to be suppressed
35   REAL(wp) ::   area               ! global mean ocean surface (interior domain)
36
37   REAL(wp), DIMENSION(jpi,jpj) ::   e1e2    ! area of the interior domain (e1t*e2t)
38
39   !! * Substitutions
40#  include "domzgr_substitute.h90"
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
44   !! $Id$
45   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc )
50      !!---------------------------------------------------------------------
51      !!                  ***  ROUTINE sbc_fwb  ***
52      !!
53      !! ** Purpose :   Control the mean sea surface drift
54      !!
55      !! ** Method  :   several ways  depending on kn_fwb
56      !!                =0 no control
57      !!                =1 global mean of emp set to zero at each nn_fsbc time step
58      !!                =2 annual global mean corrected from previous year
59      !!                =3 global mean of emp set to zero at each nn_fsbc time step
60      !!                   & spread out over erp area depending its sign
61      !!----------------------------------------------------------------------
62      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
63      INTEGER, INTENT( in ) ::   kn_fsbc  !
64      INTEGER, INTENT( in ) ::   kn_fwb   ! ocean time-step index
65      !!
66      INTEGER  ::   inum                  ! temporary logical unit
67      INTEGER  ::   ikty, iyear           !
68      REAL(wp) ::   z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp       ! temporary scalars
69      REAL(wp) ::   zsurf_neg, zsurf_pos, zsurf_tospread
70      REAL(wp), DIMENSION(jpi,jpj) ::   ztmsk_neg, ztmsk_pos, ztmsk_tospread
71      REAL(wp), DIMENSION(jpi,jpj) ::   z_wgt, zerp_cor
72      !!----------------------------------------------------------------------
73      !
74      IF( kt == nit000 ) THEN
75         !
76         IF(lwp) THEN
77            WRITE(numout,*)
78            WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction'
79            WRITE(numout,*) '~~~~~~~'
80            IF( kn_fwb == 1 )   WRITE(numout,*) '          instantaneously set to zero'
81            IF( kn_fwb == 2 )   WRITE(numout,*) '          adjusted from previous year budget'
82            IF( kn_fwb == 3 )   WRITE(numout,*) '          fwf set to zero and spread out over erp area'
83            !
84            IF( kn_fwb == 3 .AND. nn_sssr /= 2 )   &
85               &   CALL ctl_stop( 'The option nn_fwb = 3 must be associated to nn_sssr = 2 ' )
86           
87         ENDIF
88         !
89         e1e2(:,:) = e1t(:,:) * e2t(:,:) 
90         area = glob_sum( e1e2(:,:) )   ! sum over the global domain
91         !
92      ENDIF
93     
94
95      SELECT CASE ( kn_fwb )
96      !
97      CASE ( 0 )                               
98         WRITE(ctmp1,*)'sbc_fwb : nn_fwb = ', kn_fwb, ' is not yet associated to an option, choose either 1/2'
99         CALL ctl_stop( ctmp1 )
100         !
101         
102      !
103      CASE ( 1 )                               ! global mean fwf set to zero
104         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
105            z_fwf = glob_sum( e1e2(:,:) * ( emp(:,:) - rnf(:,:) ) ) / area   ! sum over the global domain
106            emp (:,:) = emp (:,:) - z_fwf 
107            emps(:,:) = emps(:,:) - z_fwf 
108         ENDIF
109         !
110      CASE ( 2 )                               ! fwf budget adjusted from the previous year
111         ! initialisation
112         IF( kt == nit000 ) THEN
113            ! Read the corrective factor on precipitations (fwfold)
114            CALL ctl_opn( inum, 'EMPave_old.dat', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE. )
115            READ ( inum, "(24X,I8,2ES24.16)" ) iyear, a_fwb_b, a_fwb
116            CLOSE( inum )
117            fwfold = a_fwb                  ! current year freshwater budget correction
118            !                               ! estimate from the previous year budget
119            IF(lwp)WRITE(numout,*)
120            IF(lwp)WRITE(numout,*)'sbc_fwb : year = ',iyear  , ' freshwater budget correction = ', fwfold
121            IF(lwp)WRITE(numout,*)'          year = ',iyear-1, ' freshwater budget read       = ', a_fwb
122            IF(lwp)WRITE(numout,*)'          year = ',iyear-2, ' freshwater budget read       = ', a_fwb_b
123         ENDIF   
124         !
125         ! Update fwfold if new year start
126         ikty = 365 * 86400 / rdttra(1)    !!bug  use of 365 days leap year or 360d year !!!!!!!
127         IF( MOD( kt, ikty ) == 0 ) THEN
128            a_fwb_b = a_fwb
129            a_fwb   = glob_sum( e1e2(:,:) * sshn(:,:) )   ! sum over the global domain
130            a_fwb   = a_fwb * 1.e+3 / ( area * 86400. * 365. )     ! convert in Kg/m3/s = mm/s
131!!gm        !                                                      !!bug 365d year
132            fwfold =  a_fwb                 ! current year freshwater budget correction
133            !                               ! estimate from the previous year budget
134         ENDIF
135         !
136         ! correct the freshwater fluxes
137         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
138            emp (:,:) = emp (:,:) + fwfold
139            emps(:,:) = emps(:,:) + fwfold
140         ENDIF
141         !
142         ! save fwfold value in a file
143         IF( kt == nitend .AND. lwp ) THEN
144            CALL ctl_opn( inum, 'EMPave.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea )
145            WRITE( inum, "(24X,I8,2ES24.16)" ) nyear, a_fwb_b, a_fwb
146            CLOSE( inum )
147         ENDIF
148         !
149      CASE ( 3 )                               ! global fwf set to zero and spread out over erp area
150         !
151         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
152            ! Select <0 and >0 area of erp
153            ztmsk_pos(:,:) = tmask_i(:,:)
154            WHERE( erp < 0.e0 ) ztmsk_pos = 0.e0
155            ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:)
156
157            ! Area filled by <0 and >0 erp
158            zsurf_neg = glob_sum( e1e2(:,:)*ztmsk_neg(:,:) )
159            zsurf_pos = glob_sum( e1e2(:,:)*ztmsk_pos(:,:) )
160       
161            ! fwf global mean
162            z_fwf = glob_sum( e1e2(:,:) * ( emp(:,:) - rnf(:,:) ) ) / area
163           
164            IF( z_fwf < 0.e0 ) THEN
165                ! to spread out over >0 erp area to increase evaporation damping process
166                zsurf_tospread = zsurf_pos
167                ztmsk_tospread(:,:) = ztmsk_pos(:,:)
168            ELSE
169                ! to spread out over <0 erp area to increase precipitation damping process
170                zsurf_tospread = zsurf_neg
171                ztmsk_tospread(:,:) = ztmsk_neg(:,:)
172            ENDIF
173
174            ! fwf global mean over <0 or >0 erp area
175            zsum_fwf = glob_sum( e1e2(:,:) * z_fwf )
176            z_fwf_nsrf =  zsum_fwf / ( zsurf_tospread + rsmall )
177            ! weight to respect erp field 2D structure
178            zsum_erp = glob_sum( ztmsk_tospread(:,:) * erp(:,:) * e1e2(:,:) )
179            z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall )
180
181            ! final correction term to apply
182            zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:)
183
184            CALL lbc_lnk( zerp_cor, 'T', 1. )
185
186            emp (:,:) = emp (:,:) + zerp_cor(:,:)
187            emps(:,:) = emps(:,:) + zerp_cor(:,:)
188            erp (:,:) = erp (:,:) + zerp_cor(:,:)
189           
190            IF( nprint == 1 .AND. lwp ) THEN
191               IF( z_fwf < 0.e0 ) THEN
192                  WRITE(numout,*)'       z_fwf < 0'
193                  WRITE(numout,*)'       SUM(erp+)        = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2(:,:) )*1.e-3,' m3.s-1'
194               ELSE
195                   WRITE(numout,*)'      z_fwf >= 0'
196                   WRITE(numout,*)'      SUM(erp-)        = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2(:,:) )*1.e-3,' m3.s-1'
197               ENDIF
198               WRITE(numout,*)'      SUM(empG)        = ', SUM( z_fwf*e1e2(:,:) )*1.e-3,' m3.s-1'
199               WRITE(numout,*)'      z_fwf            = ', z_fwf      ,' mm.s-1'
200               WRITE(numout,*)'      z_fwf_nsrf       = ', z_fwf_nsrf ,' mm.s-1'
201               WRITE(numout,*)'      MIN(zerp_cor)    = ', MINVAL(zerp_cor) 
202               WRITE(numout,*)'      MAX(zerp_cor)    = ', MAXVAL(zerp_cor) 
203            ENDIF
204            !
205         ENDIF
206         !
207      CASE DEFAULT    ! you should never be there
208         WRITE(ctmp1,*)'sbc_fwb : nn_fwb = ', kn_fwb, ' is not permitted for the FreshWater Budget correction, choose either 1/2'
209         CALL ctl_stop( ctmp1 )
210         !
211      END SELECT
212      !
213   END SUBROUTINE sbc_fwb
214
215   !!======================================================================
216END MODULE sbcfwb
Note: See TracBrowser for help on using the repository browser.