| 1 | MODULE sbcice_lim |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcice_lim *** |
|---|
| 4 | !! Surface module : update the ocean surface boundary condition over ice |
|---|
| 5 | !! & covered area using LIM sea-ice model |
|---|
| 6 | !! Sea-Ice model : LIM 3.0 Sea ice model time-stepping |
|---|
| 7 | !!===================================================================== |
|---|
| 8 | !! History : 2.0 ! 2006-12 (M. Vancoppenolle) Original code |
|---|
| 9 | !! 3.0 ! 2008-02 (C. Talandier) Surface module from icestp.F90 |
|---|
| 10 | !! - ! 2008-04 (G. Madec) sltyle and lim_ctl routine |
|---|
| 11 | !! 3.3 ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | #if defined key_lim3 |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! 'key_lim3' : LIM 3.0 sea-ice model |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | !! sbc_ice_lim : sea-ice model time-stepping and update ocean sbc over ice-covered area |
|---|
| 18 | !! lim_ctl : alerts in case of ice model crash |
|---|
| 19 | !! lim_prt_state : ice control print at a given grid point |
|---|
| 20 | !!---------------------------------------------------------------------- |
|---|
| 21 | USE oce ! ocean dynamics and tracers |
|---|
| 22 | USE dom_oce ! ocean space and time domain |
|---|
| 23 | USE lib_mpp ! MPP library |
|---|
| 24 | USE par_ice ! sea-ice parameters |
|---|
| 25 | USE ice ! LIM-3: ice variables |
|---|
| 26 | USE iceini ! LIM-3: ice initialisation |
|---|
| 27 | USE dom_ice ! LIM-3: ice domain |
|---|
| 28 | |
|---|
| 29 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 30 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 31 | USE sbcblk_core ! Surface boundary condition: CORE bulk |
|---|
| 32 | USE sbcblk_clio ! Surface boundary condition: CLIO bulk |
|---|
| 33 | USE albedo ! ocean & ice albedo |
|---|
| 34 | |
|---|
| 35 | USE phycst ! Define parameters for the routines |
|---|
| 36 | USE eosbn2 ! equation of state |
|---|
| 37 | USE limdyn ! Ice dynamics |
|---|
| 38 | USE limtrp ! Ice transport |
|---|
| 39 | USE limthd ! Ice thermodynamics |
|---|
| 40 | USE limitd_th ! Thermodynamics on ice thickness distribution |
|---|
| 41 | USE limitd_me ! Mechanics on ice thickness distribution |
|---|
| 42 | USE limsbc ! sea surface boundary condition |
|---|
| 43 | USE limdia ! Ice diagnostics |
|---|
| 44 | USE limwri ! Ice outputs |
|---|
| 45 | USE limrst ! Ice restarts |
|---|
| 46 | USE limupdate ! update of global variables |
|---|
| 47 | USE limvar ! Ice variables switch |
|---|
| 48 | |
|---|
| 49 | USE c1d ! 1D vertical configuration |
|---|
| 50 | USE lbclnk ! lateral boundary condition - MPP link |
|---|
| 51 | USE iom ! I/O manager library |
|---|
| 52 | USE in_out_manager ! I/O manager |
|---|
| 53 | USE prtctl ! Print control |
|---|
| 54 | |
|---|
| 55 | IMPLICIT NONE |
|---|
| 56 | PRIVATE |
|---|
| 57 | |
|---|
| 58 | PUBLIC sbc_ice_lim ! routine called by sbcmod.F90 |
|---|
| 59 | |
|---|
| 60 | !! * Substitutions |
|---|
| 61 | # include "domzgr_substitute.h90" |
|---|
| 62 | # include "vectopt_loop_substitute.h90" |
|---|
| 63 | !!---------------------------------------------------------------------- |
|---|
| 64 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 65 | !! $Id$ |
|---|
| 66 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 67 | !!---------------------------------------------------------------------- |
|---|
| 68 | CONTAINS |
|---|
| 69 | |
|---|
| 70 | SUBROUTINE sbc_ice_lim( kt, kblk ) |
|---|
| 71 | !!--------------------------------------------------------------------- |
|---|
| 72 | !! *** ROUTINE sbc_ice_lim *** |
|---|
| 73 | !! |
|---|
| 74 | !! ** Purpose : update the ocean surface boundary condition via the |
|---|
| 75 | !! Louvain la Neuve Sea Ice Model time stepping |
|---|
| 76 | !! |
|---|
| 77 | !! ** Method : ice model time stepping |
|---|
| 78 | !! - call the ice dynamics routine |
|---|
| 79 | !! - call the ice advection/diffusion routine |
|---|
| 80 | !! - call the ice thermodynamics routine |
|---|
| 81 | !! - call the routine that computes mass and |
|---|
| 82 | !! heat fluxes at the ice/ocean interface |
|---|
| 83 | !! - save the outputs |
|---|
| 84 | !! - save the outputs for restart when necessary |
|---|
| 85 | !! |
|---|
| 86 | !! ** Action : - time evolution of the LIM sea-ice model |
|---|
| 87 | !! - update all sbc variables below sea-ice: |
|---|
| 88 | !! utau, vtau, taum, wndm, qns , qsr, emp , emps |
|---|
| 89 | !!--------------------------------------------------------------------- |
|---|
| 90 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 91 | INTEGER, INTENT(in) :: kblk ! type of bulk (=3 CLIO, =4 CORE) |
|---|
| 92 | !! |
|---|
| 93 | INTEGER :: jl ! loop index |
|---|
| 94 | REAL(wp) :: zcoef ! temporary scalar |
|---|
| 95 | REAL(wp), DIMENSION(jpi,jpj,jpl) :: alb_ice_os ! albedo of the ice under overcast sky |
|---|
| 96 | REAL(wp), DIMENSION(jpi,jpj,jpl) :: alb_ice_cs ! albedo of ice under clear sky |
|---|
| 97 | !!---------------------------------------------------------------------- |
|---|
| 98 | |
|---|
| 99 | IF( kt == nit000 ) THEN |
|---|
| 100 | IF(lwp) WRITE(numout,*) |
|---|
| 101 | IF(lwp) WRITE(numout,*) 'sbc_ice_lim : update ocean surface boudary condition' |
|---|
| 102 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ via Louvain la Neuve Ice Model (LIM-3) time stepping' |
|---|
| 103 | ! |
|---|
| 104 | CALL ice_init |
|---|
| 105 | ! |
|---|
| 106 | IF( ln_nicep ) THEN ! control print at a given point |
|---|
| 107 | jiindx = 44 ; jjindx = 140 |
|---|
| 108 | WRITE(numout,*) ' The debugging point is : jiindx : ',jiindx, ' jjindx : ',jjindx |
|---|
| 109 | ENDIF |
|---|
| 110 | ENDIF |
|---|
| 111 | |
|---|
| 112 | ! !----------------------! |
|---|
| 113 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN ! Ice time-step only ! |
|---|
| 114 | ! !----------------------! |
|---|
| 115 | ! ! Bulk Formulea ! |
|---|
| 116 | ! !----------------! |
|---|
| 117 | ! |
|---|
| 118 | u_oce(:,:) = ssu_m(:,:) ! mean surface ocean current at ice velocity point |
|---|
| 119 | v_oce(:,:) = ssv_m(:,:) ! (C-grid dynamics : U- & V-points as the ocean) |
|---|
| 120 | ! |
|---|
| 121 | t_bo(:,:) = tfreez( sss_m ) + rt0 ! masked sea surface freezing temperature [Kelvin] |
|---|
| 122 | ! ! (set to rt0 over land) |
|---|
| 123 | CALL albedo_ice( t_su, ht_i, ht_s, alb_ice_cs, alb_ice_os ) ! ... ice albedo |
|---|
| 124 | |
|---|
| 125 | DO jl = 1, jpl |
|---|
| 126 | t_su(:,:,jl) = t_su(:,:,jl) + rt0 * ( 1. - tmask(:,:,1) ) |
|---|
| 127 | END DO |
|---|
| 128 | ! Bulk formulea - provides the following fields: |
|---|
| 129 | ! utau_ice, vtau_ice : surface ice stress (U- & V-points) [N/m2] |
|---|
| 130 | ! qsr_ice , qns_ice : solar & non solar heat flux over ice (T-point) [W/m2] |
|---|
| 131 | ! qla_ice : latent heat flux over ice (T-point) [W/m2] |
|---|
| 132 | ! dqns_ice, dqla_ice : non solar & latent heat sensistivity (T-point) [W/m2] |
|---|
| 133 | ! tprecip , sprecip : total & solid precipitation (T-point) [Kg/m2/s] |
|---|
| 134 | ! fr1_i0 , fr2_i0 : 1sr & 2nd fraction of qsr penetration in ice [%] |
|---|
| 135 | ! |
|---|
| 136 | SELECT CASE( kblk ) |
|---|
| 137 | CASE( 3 ) ! CLIO bulk formulation |
|---|
| 138 | CALL blk_ice_clio( t_su , alb_ice_cs, alb_ice_os, & |
|---|
| 139 | & utau_ice , vtau_ice , qns_ice , qsr_ice , & |
|---|
| 140 | & qla_ice , dqns_ice , dqla_ice , & |
|---|
| 141 | & tprecip , sprecip , & |
|---|
| 142 | & fr1_i0 , fr2_i0 , cp_ice_msh, jpl ) |
|---|
| 143 | ! |
|---|
| 144 | CASE( 4 ) ! CORE bulk formulation |
|---|
| 145 | CALL blk_ice_core( t_su , u_ice , v_ice , alb_ice_cs, & |
|---|
| 146 | & utau_ice , vtau_ice , qns_ice , qsr_ice , & |
|---|
| 147 | & qla_ice , dqns_ice , dqla_ice , & |
|---|
| 148 | & tprecip , sprecip , & |
|---|
| 149 | & fr1_i0 , fr2_i0 , cp_ice_msh, jpl ) |
|---|
| 150 | END SELECT |
|---|
| 151 | |
|---|
| 152 | ! !----------------------! |
|---|
| 153 | ! ! LIM-3 time-stepping ! |
|---|
| 154 | ! !----------------------! |
|---|
| 155 | ! |
|---|
| 156 | numit = numit + nn_fsbc ! Ice model time step |
|---|
| 157 | ! |
|---|
| 158 | ! ! Store previous ice values |
|---|
| 159 | !!gm : remark old_... should becomes ...b as tn versus tb |
|---|
| 160 | old_a_i (:,:,:) = a_i (:,:,:) ! ice area |
|---|
| 161 | old_e_i (:,:,:,:) = e_i (:,:,:,:) ! ice thermal energy |
|---|
| 162 | old_v_i (:,:,:) = v_i (:,:,:) ! ice volume |
|---|
| 163 | old_v_s (:,:,:) = v_s (:,:,:) ! snow volume |
|---|
| 164 | old_e_s (:,:,:,:) = e_s (:,:,:,:) ! snow thermal energy |
|---|
| 165 | old_smv_i(:,:,:) = smv_i(:,:,:) ! salt content |
|---|
| 166 | old_oa_i (:,:,:) = oa_i (:,:,:) ! areal age content |
|---|
| 167 | |
|---|
| 168 | ! ! intialisation to zero !!gm is it truly necessary ??? |
|---|
| 169 | d_a_i_thd (:,:,:) = 0.e0 ; d_a_i_trp (:,:,:) = 0.e0 |
|---|
| 170 | d_v_i_thd (:,:,:) = 0.e0 ; d_v_i_trp (:,:,:) = 0.e0 |
|---|
| 171 | d_e_i_thd (:,:,:,:) = 0.e0 ; d_e_i_trp (:,:,:,:) = 0.e0 |
|---|
| 172 | d_v_s_thd (:,:,:) = 0.e0 ; d_v_s_trp (:,:,:) = 0.e0 |
|---|
| 173 | d_e_s_thd (:,:,:,:) = 0.e0 ; d_e_s_trp (:,:,:,:) = 0.e0 |
|---|
| 174 | d_smv_i_thd(:,:,:) = 0.e0 ; d_smv_i_trp(:,:,:) = 0.e0 |
|---|
| 175 | d_oa_i_thd (:,:,:) = 0.e0 ; d_oa_i_trp (:,:,:) = 0.e0 |
|---|
| 176 | ! |
|---|
| 177 | fseqv (:,:) = 0.e0 |
|---|
| 178 | fsbri (:,:) = 0.e0 ; fsalt_res(:,:) = 0.e0 |
|---|
| 179 | fsalt_rpo(:,:) = 0.e0 |
|---|
| 180 | fhmec (:,:) = 0.e0 ; fhbri (:,:) = 0.e0 |
|---|
| 181 | fmmec (:,:) = 0.e0 ; fheat_res(:,:) = 0.e0 |
|---|
| 182 | fheat_rpo(:,:) = 0.e0 ; focea2D (:,:) = 0.e0 |
|---|
| 183 | fsup2D (:,:) = 0.e0 |
|---|
| 184 | ! |
|---|
| 185 | diag_sni_gr(:,:) = 0.e0 ; diag_lat_gr(:,:) = 0.e0 |
|---|
| 186 | diag_bot_gr(:,:) = 0.e0 ; diag_dyn_gr(:,:) = 0.e0 |
|---|
| 187 | diag_bot_me(:,:) = 0.e0 ; diag_sur_me(:,:) = 0.e0 |
|---|
| 188 | ! dynamical invariants |
|---|
| 189 | delta_i(:,:) = 0.e0 ; divu_i(:,:) = 0.e0 ; shear_i(:,:) = 0.e0 |
|---|
| 190 | |
|---|
| 191 | CALL lim_rst_opn( kt ) ! Open Ice restart file |
|---|
| 192 | ! |
|---|
| 193 | IF( ln_nicep ) CALL lim_prt_state( jiindx, jjindx, 1, ' - Beginning the time step - ' ) ! control print |
|---|
| 194 | ! |
|---|
| 195 | IF( .NOT. lk_c1d ) THEN |
|---|
| 196 | ! Ice dynamics & transport (not in 1D case) |
|---|
| 197 | CALL lim_dyn( kt ) ! Ice dynamics ( rheology/dynamics ) |
|---|
| 198 | CALL lim_trp( kt ) ! Ice transport ( Advection/diffusion ) |
|---|
| 199 | CALL lim_var_agg(1) ! aggregate categories, requested |
|---|
| 200 | CALL lim_var_glo2eqv ! equivalent variables, requested for rafting |
|---|
| 201 | IF( ln_nicep ) CALL lim_prt_state( jiindx, jjindx,-1, ' - ice dyn & trp - ' ) ! control print |
|---|
| 202 | CALL lim_itd_me ! Mechanical redistribution ! (ridging/rafting) |
|---|
| 203 | ENDIF |
|---|
| 204 | ! ! Ice thermodynamics |
|---|
| 205 | CALL lim_var_glo2eqv ! equivalent variables |
|---|
| 206 | CALL lim_var_agg(1) ! aggregate ice categories |
|---|
| 207 | CALL lim_var_bv ! bulk brine volume (diag) |
|---|
| 208 | CALL lim_thd( kt ) ! Ice thermodynamics |
|---|
| 209 | zcoef = rdt_ice / 86400.e0 ! Ice natural aging |
|---|
| 210 | oa_i(:,:,:) = oa_i(:,:,:) + a_i(:,:,:) * zcoef |
|---|
| 211 | CALL lim_var_glo2eqv ! this CALL is maybe not necessary (Martin) |
|---|
| 212 | IF( ln_nicep ) CALL lim_prt_state( jiindx, jjindx, 1, ' - ice thermodyn. - ' ) ! control print |
|---|
| 213 | CALL lim_itd_th( kt ) ! Remap ice categories, lateral accretion ! |
|---|
| 214 | ! |
|---|
| 215 | ! ! Global variables update |
|---|
| 216 | CALL lim_var_agg( 1 ) ! requested by limupdate |
|---|
| 217 | CALL lim_update ! Global variables update |
|---|
| 218 | CALL lim_var_glo2eqv ! equivalent variables (outputs) |
|---|
| 219 | CALL lim_var_agg(2) ! aggregate ice thickness categories |
|---|
| 220 | IF( ln_nicep ) CALL lim_prt_state( jiindx, jjindx, 2, ' - Final state - ' ) ! control print |
|---|
| 221 | ! |
|---|
| 222 | CALL lim_sbc_flx( kt ) ! Update surface ocean mass, heat and salt fluxes |
|---|
| 223 | ! |
|---|
| 224 | IF( ln_nicep ) CALL lim_prt_state( jiindx, jjindx, 3, ' - Final state lim_sbc - ' ) ! control print |
|---|
| 225 | ! |
|---|
| 226 | ! ! Diagnostics and outputs |
|---|
| 227 | IF( ( MOD( kt+nn_fsbc-1, ninfo ) == 0 .OR. ntmoy == 1 ) .AND. .NOT. lk_mpp ) & |
|---|
| 228 | & CALL lim_dia |
|---|
| 229 | CALL lim_wri( 1 ) ! Ice outputs |
|---|
| 230 | IF( lrst_ice ) CALL lim_rst_write( kt ) ! Ice restart file |
|---|
| 231 | CALL lim_var_glo2eqv ! ??? |
|---|
| 232 | ! |
|---|
| 233 | IF( ln_nicep ) CALL lim_ctl ! alerts in case of model crash |
|---|
| 234 | ! |
|---|
| 235 | ENDIF ! End sea-ice time step only |
|---|
| 236 | |
|---|
| 237 | ! !--------------------------! |
|---|
| 238 | ! ! at all ocean time step ! |
|---|
| 239 | ! !--------------------------! |
|---|
| 240 | ! |
|---|
| 241 | ! ! Update surface ocean stresses (only in ice-dynamic case) |
|---|
| 242 | ! ! otherwise the atm.-ocean stresses are used everywhere |
|---|
| 243 | IF( ln_limdyn ) CALL lim_sbc_tau( kt, ub(:,:,1), vb(:,:,1) ) ! using before instantaneous surf. currents |
|---|
| 244 | |
|---|
| 245 | !!gm remark, the ocean-ice stress is not saved in ice diag call above ..... find a solution!!! |
|---|
| 246 | ! |
|---|
| 247 | END SUBROUTINE sbc_ice_lim |
|---|
| 248 | |
|---|
| 249 | |
|---|
| 250 | SUBROUTINE lim_ctl |
|---|
| 251 | !!----------------------------------------------------------------------- |
|---|
| 252 | !! *** ROUTINE lim_ctl *** |
|---|
| 253 | !! |
|---|
| 254 | !! ** Purpose : Alerts in case of model crash |
|---|
| 255 | !!------------------------------------------------------------------- |
|---|
| 256 | INTEGER :: ji, jj, jk, jl ! dummy loop indices |
|---|
| 257 | INTEGER :: inb_altests ! number of alert tests (max 20) |
|---|
| 258 | INTEGER :: ialert_id ! number of the current alert |
|---|
| 259 | REAL(wp) :: ztmelts ! ice layer melting point |
|---|
| 260 | CHARACTER (len=30), DIMENSION(20) :: cl_alname ! name of alert |
|---|
| 261 | INTEGER , DIMENSION(20) :: inb_alp ! number of alerts positive |
|---|
| 262 | !!------------------------------------------------------------------- |
|---|
| 263 | |
|---|
| 264 | inb_altests = 10 |
|---|
| 265 | inb_alp(:) = 0 |
|---|
| 266 | |
|---|
| 267 | ! Alert if incompatible volume and concentration |
|---|
| 268 | ialert_id = 2 ! reference number of this alert |
|---|
| 269 | cl_alname(ialert_id) = ' Incompat vol and con ' ! name of the alert |
|---|
| 270 | |
|---|
| 271 | DO jl = 1, jpl |
|---|
| 272 | DO jj = 1, jpj |
|---|
| 273 | DO ji = 1, jpi |
|---|
| 274 | IF( v_i(ji,jj,jl) /= 0.e0 .AND. a_i(ji,jj,jl) == 0.e0 ) THEN |
|---|
| 275 | WRITE(numout,*) ' ALERTE 2 : Incompatible volume and concentration ' |
|---|
| 276 | WRITE(numout,*) ' at_i ', at_i(ji,jj) |
|---|
| 277 | WRITE(numout,*) ' Point - category', ji, jj, jl |
|---|
| 278 | WRITE(numout,*) ' a_i *** a_i_old ', a_i (ji,jj,jl), old_a_i (ji,jj,jl) |
|---|
| 279 | WRITE(numout,*) ' v_i *** v_i_old ', v_i (ji,jj,jl), old_v_i (ji,jj,jl) |
|---|
| 280 | WRITE(numout,*) ' d_a_i_thd/trp ', d_a_i_thd(ji,jj,jl), d_a_i_trp(ji,jj,jl) |
|---|
| 281 | WRITE(numout,*) ' d_v_i_thd/trp ', d_v_i_thd(ji,jj,jl), d_v_i_trp(ji,jj,jl) |
|---|
| 282 | inb_alp(ialert_id) = inb_alp(ialert_id) + 1 |
|---|
| 283 | ENDIF |
|---|
| 284 | END DO |
|---|
| 285 | END DO |
|---|
| 286 | END DO |
|---|
| 287 | |
|---|
| 288 | ! Alerte if very thick ice |
|---|
| 289 | ialert_id = 3 ! reference number of this alert |
|---|
| 290 | cl_alname(ialert_id) = ' Very thick ice ' ! name of the alert |
|---|
| 291 | jl = jpl |
|---|
| 292 | DO jj = 1, jpj |
|---|
| 293 | DO ji = 1, jpi |
|---|
| 294 | IF( ht_i(ji,jj,jl) .GT. 50.0 ) THEN |
|---|
| 295 | CALL lim_prt_state( ji, jj, 2, ' ALERTE 3 : Very thick ice ' ) |
|---|
| 296 | inb_alp(ialert_id) = inb_alp(ialert_id) + 1 |
|---|
| 297 | ENDIF |
|---|
| 298 | END DO |
|---|
| 299 | END DO |
|---|
| 300 | |
|---|
| 301 | ! Alert if very fast ice |
|---|
| 302 | ialert_id = 4 ! reference number of this alert |
|---|
| 303 | cl_alname(ialert_id) = ' Very fast ice ' ! name of the alert |
|---|
| 304 | DO jj = 1, jpj |
|---|
| 305 | DO ji = 1, jpi |
|---|
| 306 | IF( MAX( ABS( u_ice(ji,jj) ), ABS( v_ice(ji,jj) ) ) .GT. 0.5 .AND. & |
|---|
| 307 | & at_i(ji,jj) .GT. 0.e0 ) THEN |
|---|
| 308 | CALL lim_prt_state( ji, jj, 1, ' ALERTE 4 : Very fast ice ' ) |
|---|
| 309 | WRITE(numout,*) ' ice strength : ', strength(ji,jj) |
|---|
| 310 | WRITE(numout,*) ' oceanic stress utau : ', utau(ji,jj) |
|---|
| 311 | WRITE(numout,*) ' oceanic stress vtau : ', vtau(ji,jj) |
|---|
| 312 | WRITE(numout,*) ' sea-ice stress utau_ice : ', utau_ice(ji,jj) |
|---|
| 313 | WRITE(numout,*) ' sea-ice stress vtau_ice : ', vtau_ice(ji,jj) |
|---|
| 314 | WRITE(numout,*) ' oceanic speed u : ', u_oce(ji,jj) |
|---|
| 315 | WRITE(numout,*) ' oceanic speed v : ', v_oce(ji,jj) |
|---|
| 316 | WRITE(numout,*) ' sst : ', sst_m(ji,jj) |
|---|
| 317 | WRITE(numout,*) ' sss : ', sss_m(ji,jj) |
|---|
| 318 | WRITE(numout,*) |
|---|
| 319 | inb_alp(ialert_id) = inb_alp(ialert_id) + 1 |
|---|
| 320 | ENDIF |
|---|
| 321 | END DO |
|---|
| 322 | END DO |
|---|
| 323 | |
|---|
| 324 | ! Alert if there is ice on continents |
|---|
| 325 | ialert_id = 6 ! reference number of this alert |
|---|
| 326 | cl_alname(ialert_id) = ' Ice on continents ' ! name of the alert |
|---|
| 327 | DO jj = 1, jpj |
|---|
| 328 | DO ji = 1, jpi |
|---|
| 329 | IF( tms(ji,jj) .LE. 0.0 .AND. at_i(ji,jj) .GT. 0.e0 ) THEN |
|---|
| 330 | CALL lim_prt_state( ji, jj, 1, ' ALERTE 6 : Ice on continents ' ) |
|---|
| 331 | WRITE(numout,*) ' masks s, u, v : ', tms(ji,jj), tmu(ji,jj), tmv(ji,jj) |
|---|
| 332 | WRITE(numout,*) ' sst : ', sst_m(ji,jj) |
|---|
| 333 | WRITE(numout,*) ' sss : ', sss_m(ji,jj) |
|---|
| 334 | WRITE(numout,*) ' at_i(ji,jj) : ', at_i(ji,jj) |
|---|
| 335 | WRITE(numout,*) ' v_ice(ji,jj) : ', v_ice(ji,jj) |
|---|
| 336 | WRITE(numout,*) ' v_ice(ji,jj-1) : ', v_ice(ji,jj-1) |
|---|
| 337 | WRITE(numout,*) ' u_ice(ji-1,jj) : ', u_ice(ji-1,jj) |
|---|
| 338 | WRITE(numout,*) ' u_ice(ji,jj) : ', v_ice(ji,jj) |
|---|
| 339 | ! |
|---|
| 340 | inb_alp(ialert_id) = inb_alp(ialert_id) + 1 |
|---|
| 341 | ENDIF |
|---|
| 342 | END DO |
|---|
| 343 | END DO |
|---|
| 344 | |
|---|
| 345 | ! |
|---|
| 346 | ! ! Alert if very fresh ice |
|---|
| 347 | ialert_id = 7 ! reference number of this alert |
|---|
| 348 | cl_alname(ialert_id) = ' Very fresh ice ' ! name of the alert |
|---|
| 349 | DO jl = 1, jpl |
|---|
| 350 | DO jj = 1, jpj |
|---|
| 351 | DO ji = 1, jpi |
|---|
| 352 | !!gm test twice sm_i ... ???? bug? |
|---|
| 353 | IF( ( ( ABS( sm_i(ji,jj,jl) ) .LT. 0.50) .OR. & |
|---|
| 354 | ( ABS( sm_i(ji,jj,jl) ) .LT. 0.50) ) .AND. & |
|---|
| 355 | ( a_i(ji,jj,jl) .GT. 0.e0 ) ) THEN |
|---|
| 356 | ! CALL lim_prt_state(ji,jj,1, ' ALERTE 7 : Very fresh ice ' ) |
|---|
| 357 | ! WRITE(numout,*) ' sst : ', sst_m(ji,jj) |
|---|
| 358 | ! WRITE(numout,*) ' sss : ', sss_m(ji,jj) |
|---|
| 359 | ! WRITE(numout,*) ' s_i_newice : ', s_i_newice(ji,jj,1:jpl) |
|---|
| 360 | ! WRITE(numout,*) |
|---|
| 361 | inb_alp(ialert_id) = inb_alp(ialert_id) + 1 |
|---|
| 362 | ENDIF |
|---|
| 363 | END DO |
|---|
| 364 | END DO |
|---|
| 365 | END DO |
|---|
| 366 | ! |
|---|
| 367 | |
|---|
| 368 | ! ! Alert if too old ice |
|---|
| 369 | ialert_id = 9 ! reference number of this alert |
|---|
| 370 | cl_alname(ialert_id) = ' Very old ice ' ! name of the alert |
|---|
| 371 | DO jl = 1, jpl |
|---|
| 372 | DO jj = 1, jpj |
|---|
| 373 | DO ji = 1, jpi |
|---|
| 374 | IF ( ( ( ABS( o_i(ji,jj,jl) ) .GT. rdt_ice ) .OR. & |
|---|
| 375 | ( ABS( o_i(ji,jj,jl) ) .LT. 0.00) ) .AND. & |
|---|
| 376 | ( a_i(ji,jj,jl) .GT. 0.0 ) ) THEN |
|---|
| 377 | CALL lim_prt_state( ji, jj, 1, ' ALERTE 9 : Wrong ice age ') |
|---|
| 378 | inb_alp(ialert_id) = inb_alp(ialert_id) + 1 |
|---|
| 379 | ENDIF |
|---|
| 380 | END DO |
|---|
| 381 | END DO |
|---|
| 382 | END DO |
|---|
| 383 | |
|---|
| 384 | ! Alert on salt flux |
|---|
| 385 | ialert_id = 5 ! reference number of this alert |
|---|
| 386 | cl_alname(ialert_id) = ' High salt flux ' ! name of the alert |
|---|
| 387 | DO jj = 1, jpj |
|---|
| 388 | DO ji = 1, jpi |
|---|
| 389 | IF( ABS( emps(ji,jj) ) .GT. 1.0e-2 ) THEN |
|---|
| 390 | CALL lim_prt_state( ji, jj, 3, ' ALERTE 5 : High salt flux ' ) |
|---|
| 391 | DO jl = 1, jpl |
|---|
| 392 | WRITE(numout,*) ' Category no: ', jl |
|---|
| 393 | WRITE(numout,*) ' a_i : ', a_i (ji,jj,jl) , ' old_a_i : ', old_a_i (ji,jj,jl) |
|---|
| 394 | WRITE(numout,*) ' d_a_i_trp : ', d_a_i_trp(ji,jj,jl) , ' d_a_i_thd : ', d_a_i_thd(ji,jj,jl) |
|---|
| 395 | WRITE(numout,*) ' v_i : ', v_i (ji,jj,jl) , ' old_v_i : ', old_v_i (ji,jj,jl) |
|---|
| 396 | WRITE(numout,*) ' d_v_i_trp : ', d_v_i_trp(ji,jj,jl) , ' d_v_i_thd : ', d_v_i_thd(ji,jj,jl) |
|---|
| 397 | WRITE(numout,*) ' ' |
|---|
| 398 | END DO |
|---|
| 399 | inb_alp(ialert_id) = inb_alp(ialert_id) + 1 |
|---|
| 400 | ENDIF |
|---|
| 401 | END DO |
|---|
| 402 | END DO |
|---|
| 403 | |
|---|
| 404 | ! Alert if qns very big |
|---|
| 405 | ialert_id = 8 ! reference number of this alert |
|---|
| 406 | cl_alname(ialert_id) = ' fnsolar very big ' ! name of the alert |
|---|
| 407 | DO jj = 1, jpj |
|---|
| 408 | DO ji = 1, jpi |
|---|
| 409 | IF( ABS( qns(ji,jj) ) .GT. 1500.0 .AND. ( at_i(ji,jj) .GT. 0.0 ) ) THEN |
|---|
| 410 | ! |
|---|
| 411 | WRITE(numout,*) ' ALERTE 8 : Very high non-solar heat flux' |
|---|
| 412 | WRITE(numout,*) ' ji, jj : ', ji, jj |
|---|
| 413 | WRITE(numout,*) ' qns : ', qns(ji,jj) |
|---|
| 414 | WRITE(numout,*) ' sst : ', sst_m(ji,jj) |
|---|
| 415 | WRITE(numout,*) ' sss : ', sss_m(ji,jj) |
|---|
| 416 | WRITE(numout,*) ' qcmif : ', qcmif(ji,jj) |
|---|
| 417 | WRITE(numout,*) ' qldif : ', qldif(ji,jj) |
|---|
| 418 | WRITE(numout,*) ' qcmif : ', qcmif(ji,jj) / rdt_ice |
|---|
| 419 | WRITE(numout,*) ' qldif : ', qldif(ji,jj) / rdt_ice |
|---|
| 420 | WRITE(numout,*) ' qfvbq : ', qfvbq(ji,jj) |
|---|
| 421 | WRITE(numout,*) ' qdtcn : ', qdtcn(ji,jj) |
|---|
| 422 | WRITE(numout,*) ' qfvbq / dt: ', qfvbq(ji,jj) / rdt_ice |
|---|
| 423 | WRITE(numout,*) ' qdtcn / dt: ', qdtcn(ji,jj) / rdt_ice |
|---|
| 424 | WRITE(numout,*) ' fdtcn : ', fdtcn(ji,jj) |
|---|
| 425 | WRITE(numout,*) ' fhmec : ', fhmec(ji,jj) |
|---|
| 426 | WRITE(numout,*) ' fheat_rpo : ', fheat_rpo(ji,jj) |
|---|
| 427 | WRITE(numout,*) ' fheat_res : ', fheat_res(ji,jj) |
|---|
| 428 | WRITE(numout,*) ' fhbri : ', fhbri(ji,jj) |
|---|
| 429 | ! |
|---|
| 430 | CALL lim_prt_state( ji, jj, 2, ' ') |
|---|
| 431 | inb_alp(ialert_id) = inb_alp(ialert_id) + 1 |
|---|
| 432 | ! |
|---|
| 433 | ENDIF |
|---|
| 434 | END DO |
|---|
| 435 | END DO |
|---|
| 436 | !+++++ |
|---|
| 437 | |
|---|
| 438 | ! Alert if very warm ice |
|---|
| 439 | ialert_id = 10 ! reference number of this alert |
|---|
| 440 | cl_alname(ialert_id) = ' Very warm ice ' ! name of the alert |
|---|
| 441 | inb_alp(ialert_id) = 0 |
|---|
| 442 | DO jl = 1, jpl |
|---|
| 443 | DO jk = 1, nlay_i |
|---|
| 444 | DO jj = 1, jpj |
|---|
| 445 | DO ji = 1, jpi |
|---|
| 446 | ztmelts = -tmut * s_i(ji,jj,jk,jl) + rtt |
|---|
| 447 | IF( t_i(ji,jj,jk,jl) .GE. ztmelts .AND. v_i(ji,jj,jl) .GT. 1.e-6 & |
|---|
| 448 | & .AND. a_i(ji,jj,jl) .GT. 0.e0 ) THEN |
|---|
| 449 | WRITE(numout,*) ' ALERTE 10 : Very warm ice' |
|---|
| 450 | WRITE(numout,*) ' ji, jj, jk, jl : ', ji, jj, jk, jl |
|---|
| 451 | WRITE(numout,*) ' t_i : ', t_i(ji,jj,jk,jl) |
|---|
| 452 | WRITE(numout,*) ' e_i : ', e_i(ji,jj,jk,jl) |
|---|
| 453 | WRITE(numout,*) ' s_i : ', s_i(ji,jj,jk,jl) |
|---|
| 454 | WRITE(numout,*) ' ztmelts : ', ztmelts |
|---|
| 455 | inb_alp(ialert_id) = inb_alp(ialert_id) + 1 |
|---|
| 456 | ENDIF |
|---|
| 457 | END DO |
|---|
| 458 | END DO |
|---|
| 459 | END DO |
|---|
| 460 | END DO |
|---|
| 461 | |
|---|
| 462 | ialert_id = 1 ! reference number of this alert |
|---|
| 463 | cl_alname(ialert_id) = ' NO alerte 1 ' ! name of the alert |
|---|
| 464 | WRITE(numout,*) |
|---|
| 465 | WRITE(numout,*) ' All alerts at the end of ice model ' |
|---|
| 466 | DO ialert_id = 1, inb_altests |
|---|
| 467 | WRITE(numout,*) ialert_id, cl_alname(ialert_id)//' : ', inb_alp(ialert_id), ' times ! ' |
|---|
| 468 | END DO |
|---|
| 469 | ! |
|---|
| 470 | END SUBROUTINE lim_ctl |
|---|
| 471 | |
|---|
| 472 | |
|---|
| 473 | SUBROUTINE lim_prt_state( ki, kj, kn, cd1 ) |
|---|
| 474 | !!----------------------------------------------------------------------- |
|---|
| 475 | !! *** ROUTINE lim_prt_state *** |
|---|
| 476 | !! |
|---|
| 477 | !! ** Purpose : Writes global ice state on the (i,j) point |
|---|
| 478 | !! in ocean.ouput |
|---|
| 479 | !! 3 possibilities exist |
|---|
| 480 | !! n = 1/-1 -> simple ice state (plus Mechanical Check if -1) |
|---|
| 481 | !! n = 2 -> exhaustive state |
|---|
| 482 | !! n = 3 -> ice/ocean salt fluxes |
|---|
| 483 | !! |
|---|
| 484 | !! ** input : point coordinates (i,j) |
|---|
| 485 | !! n : number of the option |
|---|
| 486 | !!------------------------------------------------------------------- |
|---|
| 487 | INTEGER , INTENT(in) :: ki, kj, kn ! ocean gridpoint indices |
|---|
| 488 | CHARACTER(len=*), INTENT(in) :: cd1 ! |
|---|
| 489 | !! |
|---|
| 490 | INTEGER :: jl |
|---|
| 491 | !!------------------------------------------------------------------- |
|---|
| 492 | |
|---|
| 493 | WRITE(numout,*) cd1 ! print title |
|---|
| 494 | |
|---|
| 495 | !---------------- |
|---|
| 496 | ! Simple state |
|---|
| 497 | !---------------- |
|---|
| 498 | |
|---|
| 499 | IF ( kn == 1 .OR. kn == -1 ) THEN |
|---|
| 500 | WRITE(numout,*) ' lim_prt_state - Point : ',ki,kj |
|---|
| 501 | WRITE(numout,*) ' ~~~~~~~~~~~~~~ ' |
|---|
| 502 | WRITE(numout,*) ' Simple state ' |
|---|
| 503 | WRITE(numout,*) ' masks s,u,v : ', tms(ki,kj), tmu(ki,kj), tmv(ki,kj) |
|---|
| 504 | WRITE(numout,*) ' lat - long : ', gphit(ki,kj), glamt(ki,kj) |
|---|
| 505 | WRITE(numout,*) ' Time step : ', numit |
|---|
| 506 | WRITE(numout,*) ' - Ice drift ' |
|---|
| 507 | WRITE(numout,*) ' ~~~~~~~~~~~ ' |
|---|
| 508 | WRITE(numout,*) ' u_ice(i-1,j) : ', u_ice(ki-1,kj) |
|---|
| 509 | WRITE(numout,*) ' u_ice(i ,j) : ', u_ice(ki,kj) |
|---|
| 510 | WRITE(numout,*) ' v_ice(i ,j-1): ', v_ice(ki,kj-1) |
|---|
| 511 | WRITE(numout,*) ' v_ice(i ,j) : ', v_ice(ki,kj) |
|---|
| 512 | WRITE(numout,*) ' strength : ', strength(ki,kj) |
|---|
| 513 | WRITE(numout,*) |
|---|
| 514 | WRITE(numout,*) ' - Cell values ' |
|---|
| 515 | WRITE(numout,*) ' ~~~~~~~~~~~ ' |
|---|
| 516 | WRITE(numout,*) ' cell area : ', area(ki,kj) |
|---|
| 517 | WRITE(numout,*) ' at_i : ', at_i(ki,kj) |
|---|
| 518 | WRITE(numout,*) ' vt_i : ', vt_i(ki,kj) |
|---|
| 519 | WRITE(numout,*) ' vt_s : ', vt_s(ki,kj) |
|---|
| 520 | DO jl = 1, jpl |
|---|
| 521 | WRITE(numout,*) ' - Category (', jl,')' |
|---|
| 522 | WRITE(numout,*) ' a_i : ', a_i(ki,kj,jl) |
|---|
| 523 | WRITE(numout,*) ' ht_i : ', ht_i(ki,kj,jl) |
|---|
| 524 | WRITE(numout,*) ' ht_s : ', ht_s(ki,kj,jl) |
|---|
| 525 | WRITE(numout,*) ' v_i : ', v_i(ki,kj,jl) |
|---|
| 526 | WRITE(numout,*) ' v_s : ', v_s(ki,kj,jl) |
|---|
| 527 | WRITE(numout,*) ' e_s : ', e_s(ki,kj,1,jl)/1.0e9 |
|---|
| 528 | WRITE(numout,*) ' e_i : ', e_i(ki,kj,1:nlay_i,jl)/1.0e9 |
|---|
| 529 | WRITE(numout,*) ' t_su : ', t_su(ki,kj,jl) |
|---|
| 530 | WRITE(numout,*) ' t_snow : ', t_s(ki,kj,1,jl) |
|---|
| 531 | WRITE(numout,*) ' t_i : ', t_i(ki,kj,1:nlay_i,jl) |
|---|
| 532 | WRITE(numout,*) ' sm_i : ', sm_i(ki,kj,jl) |
|---|
| 533 | WRITE(numout,*) ' smv_i : ', smv_i(ki,kj,jl) |
|---|
| 534 | WRITE(numout,*) |
|---|
| 535 | WRITE(numout,*) ' Pathological case : ', patho_case(ki,kj,jl) |
|---|
| 536 | END DO |
|---|
| 537 | ENDIF |
|---|
| 538 | IF( kn == -1 ) THEN |
|---|
| 539 | WRITE(numout,*) ' Mechanical Check ************** ' |
|---|
| 540 | WRITE(numout,*) ' Check what means ice divergence ' |
|---|
| 541 | WRITE(numout,*) ' Total ice concentration ', at_i (ki,kj) |
|---|
| 542 | WRITE(numout,*) ' Total lead fraction ', ato_i(ki,kj) |
|---|
| 543 | WRITE(numout,*) ' Sum of both ', ato_i(ki,kj) + at_i(ki,kj) |
|---|
| 544 | WRITE(numout,*) ' Sum of both minus 1 ', ato_i(ki,kj) + at_i(ki,kj) - 1.00 |
|---|
| 545 | ENDIF |
|---|
| 546 | |
|---|
| 547 | |
|---|
| 548 | !-------------------- |
|---|
| 549 | ! Exhaustive state |
|---|
| 550 | !-------------------- |
|---|
| 551 | |
|---|
| 552 | IF ( kn .EQ. 2 ) THEN |
|---|
| 553 | WRITE(numout,*) ' lim_prt_state - Point : ',ki,kj |
|---|
| 554 | WRITE(numout,*) ' ~~~~~~~~~~~~~~ ' |
|---|
| 555 | WRITE(numout,*) ' Exhaustive state ' |
|---|
| 556 | WRITE(numout,*) ' lat - long ', gphit(ki,kj), glamt(ki,kj) |
|---|
| 557 | WRITE(numout,*) ' Time step ', numit |
|---|
| 558 | WRITE(numout,*) |
|---|
| 559 | WRITE(numout,*) ' - Cell values ' |
|---|
| 560 | WRITE(numout,*) ' ~~~~~~~~~~~ ' |
|---|
| 561 | WRITE(numout,*) ' cell area : ', area(ki,kj) |
|---|
| 562 | WRITE(numout,*) ' at_i : ', at_i(ki,kj) |
|---|
| 563 | WRITE(numout,*) ' vt_i : ', vt_i(ki,kj) |
|---|
| 564 | WRITE(numout,*) ' vt_s : ', vt_s(ki,kj) |
|---|
| 565 | WRITE(numout,*) ' u_ice(i-1,j) : ', u_ice(ki-1,kj) |
|---|
| 566 | WRITE(numout,*) ' u_ice(i ,j) : ', u_ice(ki,kj) |
|---|
| 567 | WRITE(numout,*) ' v_ice(i ,j-1): ', v_ice(ki,kj-1) |
|---|
| 568 | WRITE(numout,*) ' v_ice(i ,j) : ', v_ice(ki,kj) |
|---|
| 569 | WRITE(numout,*) ' strength : ', strength(ki,kj) |
|---|
| 570 | WRITE(numout,*) ' d_u_ice_dyn : ', d_u_ice_dyn(ki,kj), ' d_v_ice_dyn : ', d_v_ice_dyn(ki,kj) |
|---|
| 571 | WRITE(numout,*) ' old_u_ice : ', old_u_ice(ki,kj) , ' old_v_ice : ', old_v_ice(ki,kj) |
|---|
| 572 | WRITE(numout,*) |
|---|
| 573 | |
|---|
| 574 | DO jl = 1, jpl |
|---|
| 575 | WRITE(numout,*) ' - Category (',jl,')' |
|---|
| 576 | WRITE(numout,*) ' ~~~~~~~~ ' |
|---|
| 577 | WRITE(numout,*) ' ht_i : ', ht_i(ki,kj,jl) , ' ht_s : ', ht_s(ki,kj,jl) |
|---|
| 578 | WRITE(numout,*) ' t_i : ', t_i(ki,kj,1:nlay_i,jl) |
|---|
| 579 | WRITE(numout,*) ' t_su : ', t_su(ki,kj,jl) , ' t_s : ', t_s(ki,kj,1,jl) |
|---|
| 580 | WRITE(numout,*) ' sm_i : ', sm_i(ki,kj,jl) , ' o_i : ', o_i(ki,kj,jl) |
|---|
| 581 | WRITE(numout,*) ' a_i : ', a_i(ki,kj,jl) , ' old_a_i : ', old_a_i(ki,kj,jl) |
|---|
| 582 | WRITE(numout,*) ' d_a_i_trp : ', d_a_i_trp(ki,kj,jl) , ' d_a_i_thd : ', d_a_i_thd(ki,kj,jl) |
|---|
| 583 | WRITE(numout,*) ' v_i : ', v_i(ki,kj,jl) , ' old_v_i : ', old_v_i(ki,kj,jl) |
|---|
| 584 | WRITE(numout,*) ' d_v_i_trp : ', d_v_i_trp(ki,kj,jl) , ' d_v_i_thd : ', d_v_i_thd(ki,kj,jl) |
|---|
| 585 | WRITE(numout,*) ' v_s : ', v_s(ki,kj,jl) , ' old_v_s : ', old_v_s(ki,kj,jl) |
|---|
| 586 | WRITE(numout,*) ' d_v_s_trp : ', d_v_s_trp(ki,kj,jl) , ' d_v_s_thd : ', d_v_s_thd(ki,kj,jl) |
|---|
| 587 | WRITE(numout,*) ' e_i1 : ', e_i(ki,kj,1,jl)/1.0e9 , ' old_ei1 : ', old_e_i(ki,kj,1,jl)/1.0e9 |
|---|
| 588 | WRITE(numout,*) ' de_i1_trp : ', d_e_i_trp(ki,kj,1,jl)/1.0e9, ' de_i1_thd : ', d_e_i_thd(ki,kj,1,jl)/1.0e9 |
|---|
| 589 | WRITE(numout,*) ' e_i2 : ', e_i(ki,kj,2,jl)/1.0e9 , ' old_ei2 : ', old_e_i(ki,kj,2,jl)/1.0e9 |
|---|
| 590 | WRITE(numout,*) ' de_i2_trp : ', d_e_i_trp(ki,kj,2,jl)/1.0e9, ' de_i2_thd : ', d_e_i_thd(ki,kj,2,jl)/1.0e9 |
|---|
| 591 | WRITE(numout,*) ' e_snow : ', e_s(ki,kj,1,jl) , ' old_e_snow : ', old_e_s(ki,kj,1,jl) |
|---|
| 592 | WRITE(numout,*) ' d_e_s_trp : ', d_e_s_trp(ki,kj,1,jl) , ' d_e_s_thd : ', d_e_s_thd(ki,kj,1,jl) |
|---|
| 593 | WRITE(numout,*) ' smv_i : ', smv_i(ki,kj,jl) , ' old_smv_i : ', old_smv_i(ki,kj,jl) |
|---|
| 594 | WRITE(numout,*) ' d_smv_i_trp: ', d_smv_i_trp(ki,kj,jl) , ' d_smv_i_thd: ', d_smv_i_thd(ki,kj,jl) |
|---|
| 595 | WRITE(numout,*) ' oa_i : ', oa_i(ki,kj,jl) , ' old_oa_i : ', old_oa_i(ki,kj,jl) |
|---|
| 596 | WRITE(numout,*) ' d_oa_i_trp : ', d_oa_i_trp(ki,kj,jl) , ' d_oa_i_thd : ', d_oa_i_thd(ki,kj,jl) |
|---|
| 597 | WRITE(numout,*) ' Path. case : ', patho_case(ki,kj,jl) |
|---|
| 598 | END DO !jl |
|---|
| 599 | |
|---|
| 600 | WRITE(numout,*) |
|---|
| 601 | WRITE(numout,*) ' - Heat / FW fluxes ' |
|---|
| 602 | WRITE(numout,*) ' ~~~~~~~~~~~~~~~~ ' |
|---|
| 603 | ! WRITE(numout,*) ' fsbri : ', fsbri(ki,kj) |
|---|
| 604 | ! WRITE(numout,*) ' fseqv : ', fseqv(ki,kj) |
|---|
| 605 | ! WRITE(numout,*) ' fsalt_res : ', fsalt_res(ki,kj) |
|---|
| 606 | WRITE(numout,*) ' fmmec : ', fmmec(ki,kj) |
|---|
| 607 | WRITE(numout,*) ' fhmec : ', fhmec(ki,kj) |
|---|
| 608 | WRITE(numout,*) ' fhbri : ', fhbri(ki,kj) |
|---|
| 609 | WRITE(numout,*) ' fheat_rpo : ', fheat_rpo(ki,kj) |
|---|
| 610 | WRITE(numout,*) |
|---|
| 611 | WRITE(numout,*) ' sst : ', sst_m(ki,kj) |
|---|
| 612 | WRITE(numout,*) ' sss : ', sss_m(ki,kj) |
|---|
| 613 | WRITE(numout,*) |
|---|
| 614 | WRITE(numout,*) ' - Stresses ' |
|---|
| 615 | WRITE(numout,*) ' ~~~~~~~~ ' |
|---|
| 616 | WRITE(numout,*) ' utau_ice : ', utau_ice(ki,kj) |
|---|
| 617 | WRITE(numout,*) ' vtau_ice : ', vtau_ice(ki,kj) |
|---|
| 618 | WRITE(numout,*) ' utau : ', utau(ki,kj) |
|---|
| 619 | WRITE(numout,*) ' vtau : ', vtau(ki,kj) |
|---|
| 620 | WRITE(numout,*) ' oc. vel. u : ', u_oce(ki,kj) |
|---|
| 621 | WRITE(numout,*) ' oc. vel. v : ', v_oce(ki,kj) |
|---|
| 622 | ENDIF |
|---|
| 623 | |
|---|
| 624 | !--------------------- |
|---|
| 625 | ! Salt / heat fluxes |
|---|
| 626 | !--------------------- |
|---|
| 627 | |
|---|
| 628 | IF ( kn .EQ. 3 ) THEN |
|---|
| 629 | WRITE(numout,*) ' lim_prt_state - Point : ',ki,kj |
|---|
| 630 | WRITE(numout,*) ' ~~~~~~~~~~~~~~ ' |
|---|
| 631 | WRITE(numout,*) ' - Salt / Heat Fluxes ' |
|---|
| 632 | WRITE(numout,*) ' ~~~~~~~~~~~~~~~~ ' |
|---|
| 633 | WRITE(numout,*) ' lat - long ', gphit(ki,kj), glamt(ki,kj) |
|---|
| 634 | WRITE(numout,*) ' Time step ', numit |
|---|
| 635 | WRITE(numout,*) |
|---|
| 636 | WRITE(numout,*) ' - Heat fluxes at bottom interface ***' |
|---|
| 637 | WRITE(numout,*) ' qsr : ', qsr(ki,kj) |
|---|
| 638 | WRITE(numout,*) ' qns : ', qns(ki,kj) |
|---|
| 639 | WRITE(numout,*) |
|---|
| 640 | WRITE(numout,*) ' - Salt fluxes at bottom interface ***' |
|---|
| 641 | WRITE(numout,*) ' emps : ', emps(ki,kj) |
|---|
| 642 | WRITE(numout,*) ' emp : ', emp(ki,kj) |
|---|
| 643 | WRITE(numout,*) ' fsbri : ', fsbri(ki,kj) |
|---|
| 644 | WRITE(numout,*) ' fseqv : ', fseqv(ki,kj) |
|---|
| 645 | WRITE(numout,*) ' fsalt_res : ', fsalt_res(ki,kj) |
|---|
| 646 | WRITE(numout,*) ' fsalt_rpo : ', fsalt_rpo(ki,kj) |
|---|
| 647 | WRITE(numout,*) ' - Heat fluxes at bottom interface ***' |
|---|
| 648 | WRITE(numout,*) ' fheat_res : ', fheat_res(ki,kj) |
|---|
| 649 | WRITE(numout,*) |
|---|
| 650 | WRITE(numout,*) ' - Momentum fluxes ' |
|---|
| 651 | WRITE(numout,*) ' utau : ', utau(ki,kj) |
|---|
| 652 | WRITE(numout,*) ' vtau : ', vtau(ki,kj) |
|---|
| 653 | ENDIF |
|---|
| 654 | WRITE(numout,*) ' ' |
|---|
| 655 | ! |
|---|
| 656 | END SUBROUTINE lim_prt_state |
|---|
| 657 | |
|---|
| 658 | #else |
|---|
| 659 | !!---------------------------------------------------------------------- |
|---|
| 660 | !! Default option Dummy module NO LIM 3.0 sea-ice model |
|---|
| 661 | !!---------------------------------------------------------------------- |
|---|
| 662 | CONTAINS |
|---|
| 663 | SUBROUTINE sbc_ice_lim ( kt, kblk ) ! Dummy routine |
|---|
| 664 | WRITE(*,*) 'sbc_ice_lim: You should not have seen this print! error?', kt, kblk |
|---|
| 665 | END SUBROUTINE sbc_ice_lim |
|---|
| 666 | #endif |
|---|
| 667 | |
|---|
| 668 | !!====================================================================== |
|---|
| 669 | END MODULE sbcice_lim |
|---|
