New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

sbcrnf.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

Context Navigation

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/SBC/sbcrnf.F90 @ 2350

Last change on this file since 2350 was 2350, checked in by rfurner, 13 years ago
correction to river scheme to restore conservation of heat and salt
Property svn:keywords set to `Id`
File size: 25.8 KB

Line
1	MODULE sbcrnf
2	!!======================================================================
3	!! * MODULE sbcrnf *
4	!! Ocean forcing: river runoff
5	!!=====================================================================
6	!! History : OPA ! 2000-11 (R. Hordoir, E. Durand) NetCDF FORMAT
7	!! NEMO 1.0 ! 2002-09 (G. Madec) F90: Free form and module
8	!! 3.0 ! 2006-07 (G. Madec) Surface module
9	!! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put
10	!!----------------------------------------------------------------------
11
12	!!----------------------------------------------------------------------
13	!! sbc_rnf : monthly runoffs read in a NetCDF file
14	!! sbc_rnf_init : runoffs initialisation
15	!! rnf_mouth : set river mouth mask
16	!!----------------------------------------------------------------------
17	USE dom_oce ! ocean space and time domain
18	USE phycst ! physical constants
19	USE sbc_oce ! surface boundary condition variables
20	USE fldread ! ???
21	USE in_out_manager ! I/O manager
22	USE iom ! I/O module
23	USE restart ! restart
24
25	IMPLICIT NONE
26	PRIVATE
27
28	PUBLIC sbc_rnf ! routine call in sbcmod module
29	PUBLIC sbc_rnf_div ! routine called in sshwzv module
30
31	! !!* namsbc_rnf namelist *
32	CHARACTER(len=100), PUBLIC :: cn_dir = './' !: Root directory for location of ssr files
33	LOGICAL , PUBLIC :: ln_rnf_depth = .false. !: depth river runoffs attribute specified in a file
34	LOGICAL , PUBLIC :: ln_rnf_tem = .false. !: temperature river runoffs attribute specified in a file
35	LOGICAL , PUBLIC :: ln_rnf_sal = .false. !: salinity river runoffs attribute specified in a file
36	LOGICAL , PUBLIC :: ln_rnf_emp = .false. !: runoffs into a file to be read or already into precipitation
37	TYPE(FLD_N) , PUBLIC :: sn_rnf !: information about the runoff file to be read
38	TYPE(FLD_N) , PUBLIC :: sn_cnf !: information about the runoff mouth file to be read
39	TYPE(FLD_N) :: sn_s_rnf !: information about the salinities of runoff file to be read
40	TYPE(FLD_N) :: sn_t_rnf !: information about the temperatures of runoff file to be read
41	TYPE(FLD_N) :: sn_dep_rnf !: information about the depth which river inflow affects
42	LOGICAL , PUBLIC :: ln_rnf_mouth = .false. !: specific treatment in mouths vicinity
43	REAL(wp) , PUBLIC :: rn_hrnf = 0.e0 !: runoffs, depth over which enhanced vertical mixing is used
44	REAL(wp) , PUBLIC :: rn_avt_rnf = 0.e0 !: runoffs, value of the additional vertical mixing coef. [m2/s]
45	REAL(wp) , PUBLIC :: rn_rfact = 1.e0 !: multiplicative factor for runoff
46
47	INTEGER , PUBLIC :: nkrnf = 0 !: number of levels over which Kz is increased at river mouths
48	REAL(wp), PUBLIC, DIMENSION(jpi,jpj) :: rnfmsk !: river mouth mask (hori.)
49	REAL(wp), PUBLIC, DIMENSION(jpk) :: rnfmsk_z !: river mouth mask (vert.)
50
51	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_rnf !: structure of input river runoff (file information, fields read)
52
53	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_s_rnf !: structure of input river runoff salinity (file information, fields read)
54	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_t_rnf !: structure of input river runoff temperature (file information, fields read)
55
56	REAL(wp), PUBLIC, DIMENSION(jpi,jpj) :: h_rnf !: depth of runoff in m
57	INTEGER, PUBLIC, DIMENSION(jpi,jpj) :: nk_rnf !: depth of runoff in model levels
58
59	REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpts) :: rnf_tsc_b, rnf_tsc !: before and now
60	! !: temp. & sal. content of river runoffs [K.m/s & PSU.m/s]
61
62	!! * Substitutions
63	# include "domzgr_substitute.h90"
64	!!----------------------------------------------------------------------
65	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
66	!! $Id$
67	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
68	!!----------------------------------------------------------------------
69
70	CONTAINS
71
72	SUBROUTINE sbc_rnf( kt )
73	!!----------------------------------------------------------------------
74	!! * ROUTINE sbc_rnf *
75	!!
76	!! ** Purpose : Introduce a climatological run off forcing
77	!!
78	!! ** Method : Set each river mouth with a monthly climatology
79	!! provided from different data.
80	!! CAUTION : upward water flux, runoff forced to be < 0
81	!!
82	!! ** Action : runoff updated runoff field at time-step kt
83	!!----------------------------------------------------------------------
84	INTEGER, INTENT(in) :: kt ! ocean time step
85	!!
86	INTEGER :: ji, jj ! dummy loop indices
87	REAL(wp) :: z1_rau0 ! local scalar
88	!!----------------------------------------------------------------------
89	!
90	IF( kt == nit000 ) CALL sbc_rnf_init ! Read namelist and allocate structures
91
92	! ! ---------------------------------------- !
93	IF( kt /= nit000 ) THEN ! Swap of forcing fields !
94	! ! ---------------------------------------- !
95	rnf_b (:,: ) = rnf (:,: ) ! Swap the ocean forcing fields except at nit000
96	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:) ! where before fields are set at the end of the routine
97	!
98	ENDIF
99
100	! !-------------------!
101	IF( .NOT. ln_rnf_emp ) THEN ! Update runoff !
102	! !-------------------!
103	!
104	CALL fld_read ( kt, nn_fsbc, sf_rnf ) ! Read Runoffs data and provide it at kt
105	IF( ln_rnf_tem ) CALL fld_read ( kt, nn_fsbc, sf_t_rnf ) ! idem for runoffs temperature if required
106	IF( ln_rnf_sal ) CALL fld_read ( kt, nn_fsbc, sf_s_rnf ) ! idem for runoffs salinity if required
107
108	! Runoff reduction only associated to the ORCA2_LIM configuration
109	! when reading the NetCDF file runoff_1m_nomask.nc
110	IF( cp_cfg == 'orca' .AND. jp_cfg == 2 ) THEN
111	DO jj = 1, jpj
112	DO ji = 1, jpi
113	IF( gphit(ji,jj) > 40 .AND. gphit(ji,jj) < 65 ) sf_rnf(1)%fnow(ji,jj,1) = 0.85 * sf_rnf(1)%fnow(ji,jj,1)
114	END DO
115	END DO
116	ENDIF
117
118	! C a u t i o n : runoff is negative and in kg/m2/s
119	IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
120	rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) )
121	!
122	z1_rau0 = 1.e0 / rau0
123	! ! set temperature & salinity content of runoffs
124	IF( ln_rnf_tem ) THEN ! use runoffs temperature data
125	rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * z1_rau0
126	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999 ) ! if missing data value use SST as runoffs temperature
127	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * z1_rau0
128	ENDWHERE
129	ELSE ! use SST as runoffs temperature
130	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * z1_rau0
131	ENDIF
132	! ! use runoffs salinity data
133	IF( ln_rnf_sal ) rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * z1_rau0
134	! ! else use S=0 for runoffs (done one for all in the init)
135	!
136	IF( ln_rnf_tem .OR. ln_rnf_sal ) THEN ! runoffs as outflow: use ocean SST and SSS
137	WHERE( rnf(:,:) < 0.e0 ) ! example baltic model when flow is out of domain
138	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * z1_rau0
139	rnf_tsc(:,:,jp_sal) = sss_m(:,:) * rnf(:,:) * z1_rau0
140	ENDWHERE
141	ENDIF
142	!
143	CALL iom_put( "runoffs", rnf ) ! output runoffs arrays
144	ENDIF
145	!
146	ENDIF
147	!
148	IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 !
149	! ! ---------------------------------------- !
150	IF( ln_rstart .AND. & !* Restart: read in restart file
151	& iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
152	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields red in the restart file'
153	CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b ) ! before runoff
154	CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) ) ! before heat content of runoff
155	CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) ) ! before salinity content of runoff
156	ELSE !* no restart: set from nit000 values
157	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields set to nit000'
158	rnf_b (:,: ) = rnf (:,: )
159	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
160	ENDIF
161	ENDIF
162	! ! ---------------------------------------- !
163	IF( lrst_oce ) THEN ! Write in the ocean restart file !
164	! ! ---------------------------------------- !
165	IF(lwp) WRITE(numout,*)
166	IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ', &
167	& 'at it= ', kt,' date= ', ndastp
168	IF(lwp) WRITE(numout,*) '~~~~'
169	CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf )
170	CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) )
171	CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) )
172	ENDIF
173
174	!
175	END SUBROUTINE sbc_rnf
176
177	SUBROUTINE sbc_rnf_div( phdivn )
178	!!----------------------------------------------------------------------
179	!! * ROUTINE sbc_rnf *
180	!!
181	!! ** Purpose : update the horizontal divergence with the runoff inflow
182	!!
183	!! ** Method :
184	!! CAUTION : rnf is positive (inflow) decreasing the
185	!! divergence and expressed in m/s
186	!!
187	!! ** Action : phdivn decreased by the runoff inflow
188	!!----------------------------------------------------------------------
189	REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) :: phdivn ! horizontal divergence
190	!!
191	INTEGER :: ji, jj, jk ! dummy loop indices
192	REAL(wp) :: z1_rau0 ! local scalar
193	REAL(wp) :: zfact ! local scalar
194	!!----------------------------------------------------------------------
195	!
196	zfact = 0.5e0
197	!
198	z1_rau0 = 1.e0 / rau0
199	IF( ln_rnf_depth ) THEN !== runoff distributed over several levels ==!
200	IF( lk_vvl ) THEN ! variable volume case
201	DO jj = 1, jpj ! update the depth over which runoffs are distributed
202	DO ji = 1, jpi
203	h_rnf(ji,jj) = 0.e0
204	DO jk = 1, nk_rnf(ji,jj) ! recalculates h_rnf to be the depth in metres
205	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk) ! to the bottom of the relevant grid box
206	END DO
207	! ! apply the runoff input flow
208	DO jk = 1, nk_rnf(ji,jj)
209	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * z1_rau0 / h_rnf(ji,jj)
210	END DO
211	END DO
212	END DO
213	ELSE ! constant volume case : just apply the runoff input flow
214	DO jj = 1, jpj
215	DO ji = 1, jpi
216	DO jk = 1, nk_rnf(ji,jj)
217	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * z1_rau0 / h_rnf(ji,jj)
218	END DO
219	END DO
220	END DO
221	ENDIF
222	ELSE !== runoff put only at the surface ==!
223	IF( lk_vvl ) THEN ! variable volume case
224	h_rnf(:,:) = fse3t(:,:,1) ! recalculate h_rnf to be depth of top box
225	ENDIF
226	phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * z1_rau0 / fse3t(:,:,1)
227	ENDIF
228	!
229	END SUBROUTINE sbc_rnf_div
230
231
232	SUBROUTINE sbc_rnf_init
233	!!----------------------------------------------------------------------
234	!! * ROUTINE sbc_rnf_init *
235	!!
236	!! ** Purpose : Initialisation of the runoffs if (ln_rnf=T)
237	!!
238	!! ** Method : - read the runoff namsbc_rnf namelist
239	!!
240	!! ** Action : - read parameters
241	!!----------------------------------------------------------------------
242	CHARACTER(len=32) :: rn_dep_file ! runoff file name
243	INTEGER :: ji, jj, jk ! dummy loop indices
244	INTEGER :: ierror, inum ! temporary integer
245	!!
246	NAMELIST/namsbc_rnf/ cn_dir, ln_rnf_emp, ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, &
247	& sn_rnf, sn_cnf , sn_s_rnf , sn_t_rnf , sn_dep_rnf, &
248	& ln_rnf_mouth , rn_hrnf , rn_avt_rnf, rn_rfact
249	!!----------------------------------------------------------------------
250
251	! ! ============
252	! ! Namelist
253	! ! ============
254	! (NB: frequency positive => hours, negative => months)
255	! ! file ! frequency ! variable ! time intep ! clim ! 'yearly' or ! weights ! rotation !
256	! ! name ! (hours) ! name ! (T/F) ! (T/F) ! 'monthly' ! filename ! pairs !
257	sn_rnf = FLD_N( 'runoffs', -1 , 'sorunoff' , .TRUE. , .true. , 'yearly' , '' , '' )
258	sn_cnf = FLD_N( 'runoffs', 0 , 'sorunoff' , .FALSE. , .true. , 'yearly' , '' , '' )
259
260	sn_s_rnf = FLD_N( 'runoffs', 24. , 'rosaline' , .TRUE. , .true. , 'yearly' , '' , '' )
261	sn_t_rnf = FLD_N( 'runoffs', 24. , 'rotemper' , .TRUE. , .true. , 'yearly' , '' , '' )
262	sn_dep_rnf = FLD_N( 'runoffs', 0. , 'rodepth' , .FALSE. , .true. , 'yearly' , '' , '' )
263	!
264	REWIND ( numnam ) ! Read Namelist namsbc_rnf
265	READ ( numnam, namsbc_rnf )
266
267	! ! Control print
268	IF(lwp) THEN
269	WRITE(numout,*)
270	WRITE(numout,*) 'sbc_rnf : runoff '
271	WRITE(numout,*) '~~~~~~~ '
272	WRITE(numout,*) ' Namelist namsbc_rnf'
273	WRITE(numout,*) ' runoff in a file to be read ln_rnf_emp = ', ln_rnf_emp
274	WRITE(numout,*) ' specific river mouths treatment ln_rnf_mouth = ', ln_rnf_mouth
275	WRITE(numout,*) ' river mouth additional Kz rn_avt_rnf = ', rn_avt_rnf
276	WRITE(numout,*) ' depth of river mouth additional mixing rn_hrnf = ', rn_hrnf
277	WRITE(numout,*) ' multiplicative factor for runoff rn_rfact = ', rn_rfact
278	ENDIF
279
280	! ! ==================
281	! ! Type of runoff
282	! ! ==================
283	!
284	IF( ln_rnf_emp ) THEN !== runoffs directly provided in the precipitations ==!
285	IF(lwp) WRITE(numout,*)
286	IF(lwp) WRITE(numout,*) ' runoffs directly provided in the precipitations'
287	IF( ln_rnf_depth .OR. ln_rnf_tem .OR. ln_rnf_sal ) THEN
288	CALL ctl_warn( 'runoffs already included in precipitations, so runoff (T,S, depth) attributes will not be used' )
289	ln_rnf_depth = .FALSE. ; ln_rnf_tem = .FALSE. ; ln_rnf_sal = .FALSE.
290	ENDIF
291	!
292	ELSE !== runoffs read in a file : set sf_rnf structure ==!
293	!
294	ALLOCATE( sf_rnf(1), STAT=ierror ) ! Create sf_rnf structure (runoff inflow)
295	IF(lwp) WRITE(numout,*)
296	IF(lwp) WRITE(numout,*) ' runoffs inflow read in a file'
297	IF( ierror > 0 ) THEN
298	CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' ) ; RETURN
299	ENDIF
300	ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1) )
301	IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
302	! ! fill sf_rnf with the namelist (sn_rnf) and control print
303	CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' )
304	!
305	IF( ln_rnf_tem ) THEN ! Create (if required) sf_t_rnf structure
306	IF(lwp) WRITE(numout,*)
307	IF(lwp) WRITE(numout,*) ' runoffs temperatures read in a file'
308	ALLOCATE( sf_t_rnf(1), STAT=ierror )
309	IF( ierror > 0 ) THEN
310	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' ) ; RETURN
311	ENDIF
312	ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1) )
313	IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
314	CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' )
315	ENDIF
316	!
317	IF( ln_rnf_sal ) THEN ! Create (if required) sf_s_rnf and sf_t_rnf structures
318	IF(lwp) WRITE(numout,*)
319	IF(lwp) WRITE(numout,*) ' runoffs salinities read in a file'
320	ALLOCATE( sf_s_rnf(1), STAT=ierror )
321	IF( ierror > 0 ) THEN
322	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' ) ; RETURN
323	ENDIF
324	ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1) )
325	IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
326	CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' )
327	ENDIF
328
329
330	IF ( ln_rnf_depth ) THEN ! depth of runoffs set from a file
331	IF(lwp) WRITE(numout,*)
332	IF(lwp) WRITE(numout,*) ' runoffs depth read in a file'
333	rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
334	CALL iom_open ( rn_dep_file, inum ) ! open file
335	CALL iom_get ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf ) ! read the river mouth array
336	CALL iom_close( inum ) ! close file
337
338	nk_rnf(:,:) = 0 ! set the number of level over which river runoffs are applied
339	DO jj = 1, jpj
340	DO ji = 1, jpi
341	IF ( h_rnf(ji,jj) > 0.e0 ) THEN
342	jk = 2
343	DO WHILE ( jk /= ( mbathy(ji,jj) - 1 ) .AND. fsdept(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1 ; ENDDO
344	nk_rnf(ji,jj) = jk
345	ELSE IF ( h_rnf(ji,jj) == -1 ) THEN ; nk_rnf(ji,jj) = 1
346	ELSE IF ( h_rnf(ji,jj) == -999 ) THEN ; nk_rnf(ji,jj) = mbathy(ji,jj) - 1
347	ELSE IF ( h_rnf(ji,jj) /= 0 ) THEN
348	CALL ctl_stop( 'runoff depth not positive, and not -999 or -1, rnf value in file fort.999' )
349	WRITE(999,*) 'ji, jj, rnf(ji,jj) :', ji, jj, rnf(ji,jj)
350	ENDIF
351	ENDDO
352	ENDDO
353	DO jj = 1, jpj ! set the associated depth
354	DO ji = 1, jpi
355	h_rnf(ji,jj) = 0.e0
356	DO jk = 1, nk_rnf(ji,jj)
357	h_rnf(ji,jj) = h_rnf(ji,jj)+fse3t(ji,jj,jk)
358	ENDDO
359	ENDDO
360	ENDDO
361	ELSE ! runoffs applied at the surface
362	nk_rnf(:,:) = 1
363	h_rnf(:,:) = fse3t(:,:,1)
364	ENDIF
365	!
366	ENDIF
367
368	rnf_tsc(:,:,:) = 0.e0 ! runoffs temperature & salinty contents initilisation
369	! ! ========================
370	! ! River mouth vicinity
371	! ! ========================
372	!
373	IF( ln_rnf_mouth ) THEN ! Specific treatment in vicinity of river mouths :
374	! ! - Increase Kz in surface layers ( rn_hrnf > 0 )
375	! ! - set to zero SSS damping (ln_ssr=T)
376	! ! - mixed upstream-centered (ln_traadv_cen2=T)
377	!
378	IF ( ln_rnf_depth ) CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already', &
379	& 'be spread through depth by ln_rnf_depth' )
380	!
381	nkrnf = 0 ! Number of level over which Kz increase
382	IF( rn_hrnf > 0.e0 ) THEN
383	nkrnf = 2
384	DO WHILE( nkrnf /= jpkm1 .AND. gdepw_0(nkrnf+1) < rn_hrnf ) ; nkrnf = nkrnf + 1 ; END DO
385	IF( ln_sco ) &
386	CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' )
387	ENDIF
388	IF(lwp) WRITE(numout,*)
389	IF(lwp) WRITE(numout,*) ' Specific treatment used in vicinity of river mouths :'
390	IF(lwp) WRITE(numout,*) ' - Increase Kz in surface layers (if rn_hrnf > 0 )'
391	IF(lwp) WRITE(numout,*) ' by ', rn_avt_rnf,' m2/s over ', nkrnf, ' w-levels'
392	IF(lwp) WRITE(numout,*) ' - set to zero SSS damping (if ln_ssr=T)'
393	IF(lwp) WRITE(numout,*) ' - mixed upstream-centered (if ln_traadv_cen2=T)'
394	!
395	CALL rnf_mouth ! set river mouth mask
396	!
397	ELSE ! No treatment at river mouths
398	IF(lwp) WRITE(numout,*)
399	IF(lwp) WRITE(numout,*) ' No specific treatment at river mouths'
400	rnfmsk (:,:) = 0.e0
401	rnfmsk_z(:) = 0.e0
402	nkrnf = 0
403	ENDIF
404
405	END SUBROUTINE sbc_rnf_init
406
407
408	SUBROUTINE rnf_mouth
409	!!----------------------------------------------------------------------
410	!! * ROUTINE rnf_mouth *
411	!!
412	!! ** Purpose : define the river mouths mask
413	!!
414	!! ** Method : read the river mouth mask (=0/1) in the river runoff
415	!! climatological file. Defined a given vertical structure.
416	!! CAUTION, the vertical structure is hard coded on the
417	!! first 5 levels.
418	!! This fields can be used to:
419	!! - set an upstream advection scheme
420	!! (ln_rnf_mouth=T and ln_traadv_cen2=T)
421	!! - increase vertical on the top nn_krnf vertical levels
422	!! at river runoff input grid point (nn_krnf>=2, see step.F90)
423	!! - set to zero SSS restoring flux at river mouth grid points
424	!!
425	!! ** Action : rnfmsk set to 1 at river runoff input, 0 elsewhere
426	!! rnfmsk_z vertical structure
427	!!----------------------------------------------------------------------
428	USE closea, ONLY : clo_rnf ! rnfmsk update routine
429	!
430	INTEGER :: inum ! temporary integers
431	CHARACTER(len=32) :: cl_rnfile ! runoff file name
432	!!----------------------------------------------------------------------
433	!
434	IF(lwp) WRITE(numout,*)
435	IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask'
436	IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
437
438	cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
439	IF( .NOT. sn_cnf%ln_clim ) THEN ; WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear ! add year
440	IF( sn_cnf%cltype == 'monthly' ) WRITE(cl_rnfile, '(a,"m",i2)' ) TRIM( cl_rnfile ), nmonth ! add month
441	ENDIF
442
443	! horizontal mask (read in NetCDF file)
444	CALL iom_open ( cl_rnfile, inum ) ! open file
445	CALL iom_get ( inum, jpdom_data, sn_cnf%clvar, rnfmsk ) ! read the river mouth array
446	CALL iom_close( inum ) ! close file
447
448	IF( nclosea == 1 ) CALL clo_rnf( rnfmsk ) ! closed sea inflow set as ruver mouth
449
450	rnfmsk_z(:) = 0.e0 ! vertical structure
451	rnfmsk_z(1) = 1.0
452	rnfmsk_z(2) = 1.0 ! **********
453	rnfmsk_z(3) = 0.5 ! HARD CODED on the 5 first levels
454	rnfmsk_z(4) = 0.25 ! **********
455	rnfmsk_z(5) = 0.125
456	!
457	END SUBROUTINE rnf_mouth
458
459	!!======================================================================
460	END MODULE sbcrnf

Note: See TracBrowser for help on using the repository browser.

Download in other formats: