source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/TRA/traadv.F90 @ 2287

Last change on this file since 2287 was 2287, checked in by smasson, 10 years ago

update licence of all NEMO files…

  • Property svn:keywords set to Id
File size: 11.2 KB
Line 
1MODULE traadv
2   !!==============================================================================
3   !!                       ***  MODULE  traadv  ***
4   !! Ocean active tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-09  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   tra_adv      : compute ocean tracer advection trend
12   !!   tra_adv_ctl  : control the different options of advection scheme
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and active tracers
15   USE dom_oce         ! ocean space and time domain
16   USE traadv_cen2     ! 2nd order centered scheme (tra_adv_cen2   routine)
17   USE traadv_tvd      ! TVD      scheme           (tra_adv_tvd    routine)
18   USE traadv_muscl    ! MUSCL    scheme           (tra_adv_muscl  routine)
19   USE traadv_muscl2   ! MUSCL2   scheme           (tra_adv_muscl2 routine)
20   USE traadv_ubs      ! UBS      scheme           (tra_adv_ubs    routine)
21   USE traadv_qck      ! QUICKEST scheme           (tra_adv_qck    routine)
22   USE traadv_eiv      ! eddy induced velocity     (tra_adv_eiv    routine)
23   USE ldftra_oce      ! lateral diffusion coefficient on tracers
24   USE in_out_manager  ! I/O manager
25   USE prtctl          ! Print control
26   USE iom
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   tra_adv         ! routine called by step module
32   PUBLIC   tra_adv_init    ! routine called by opa module
33 
34   !                                                   !!* Namelist namtra_adv *
35   LOGICAL ::   ln_traadv_cen2   = .TRUE.       ! 2nd order centered scheme flag
36   LOGICAL ::   ln_traadv_tvd    = .FALSE.      ! TVD scheme flag
37   LOGICAL ::   ln_traadv_muscl  = .FALSE.      ! MUSCL scheme flag
38   LOGICAL ::   ln_traadv_muscl2 = .FALSE.      ! MUSCL2 scheme flag
39   LOGICAL ::   ln_traadv_ubs    = .FALSE.      ! UBS scheme flag
40   LOGICAL ::   ln_traadv_qck    = .FALSE.      ! QUICKEST scheme flag
41
42   INTEGER ::   nadv   ! choice of the type of advection scheme
43
44   REAL(wp), DIMENSION(jpk) ::   r2dt  ! vertical profile time-step, = 2 rdttra
45      !                                ! except at nit000 (=rdttra) if neuler=0
46
47   !! * Substitutions
48#  include "domzgr_substitute.h90"
49#  include "vectopt_loop_substitute.h90"
50   !!----------------------------------------------------------------------
51   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
52   !! $Id$
53   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
54   !!----------------------------------------------------------------------
55
56CONTAINS
57
58   SUBROUTINE tra_adv( kt )
59      !!----------------------------------------------------------------------
60      !!                  ***  ROUTINE tra_adv  ***
61      !!
62      !! ** Purpose :   compute the ocean tracer advection trend.
63      !!
64      !! ** Method  : - Update (ua,va) with the advection term following nadv
65      !!----------------------------------------------------------------------
66      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
67      !!
68      INTEGER ::   jk   ! dummy loop index
69      REAL(wp), DIMENSION(jpi,jpj,jpk)   ::  zun, zvn, zwn   ! 3D workspace: effective transport
70      !!----------------------------------------------------------------------
71      !                                          ! set time step
72      IF( neuler == 0 .AND. kt == nit000 ) THEN     ! at nit000
73         r2dt(:) =  rdttra(:)                          ! = rdtra (restarting with Euler time stepping)
74      ELSEIF( kt <= nit000 + 1) THEN                ! at nit000 or nit000+1
75         r2dt(:) = 2. * rdttra(:)                      ! = 2 rdttra (leapfrog)
76      ENDIF
77      !                                               !==  effective transport  ==!
78      DO jk = 1, jpkm1
79         zun(:,:,jk) = e2u(:,:) * fse3u(:,:,jk) * un(:,:,jk)                  ! eulerian transport only
80         zvn(:,:,jk) = e1v(:,:) * fse3v(:,:,jk) * vn(:,:,jk)
81         zwn(:,:,jk) = e1t(:,:) * e2t(:,:)      * wn(:,:,jk)
82      END DO
83      zwn(:,:,jpk) = 0.e0                                                     ! no transport trough the bottom
84      !
85      IF( lk_traldf_eiv .AND. .NOT. ln_traldf_grif )   &
86         &                  CALL tra_adv_eiv( kt, zun, zvn, zwn, 'TRA' )      ! add the eiv transport (if necessary)
87      !
88      CALL iom_put( "uoce_eff", zun )                                         ! output effective transport     
89      CALL iom_put( "voce_eff", zvn )
90      CALL iom_put( "woce_eff", zwn )
91
92      SELECT CASE ( nadv )                            !==  compute advection trend and add it to general trend  ==!
93      CASE ( 1 )   ;    CALL tra_adv_cen2  ( kt, 'TRA',       zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  2nd order centered
94      CASE ( 2 )   ;    CALL tra_adv_tvd   ( kt, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  TVD
95      CASE ( 3 )   ;    CALL tra_adv_muscl ( kt, 'TRA', r2dt, zun, zvn, zwn, tsb,      tsa, jpts )   !  MUSCL
96      CASE ( 4 )   ;    CALL tra_adv_muscl2( kt, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  MUSCL2
97      CASE ( 5 )   ;    CALL tra_adv_ubs   ( kt, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  UBS
98      CASE ( 6 )   ;    CALL tra_adv_qck   ( kt, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  QUICKEST
99
100      !
101      CASE (-1 )                                      !==  esopa: test all possibility with control print  ==!
102         CALL tra_adv_cen2  ( kt, 'TRA',       zun, zvn, zwn, tsb, tsn, tsa, jpts )         
103         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv0 - Ta: ', mask1=tmask,               &
104            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
105         CALL tra_adv_tvd   ( kt, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
106         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv1 - Ta: ', mask1=tmask,               &
107            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
108         CALL tra_adv_muscl ( kt, 'TRA', r2dt, zun, zvn, zwn, tsb,      tsa, jpts )         
109         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv3 - Ta: ', mask1=tmask,               &
110            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
111         CALL tra_adv_muscl2( kt, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
112         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv4 - Ta: ', mask1=tmask,               &
113            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
114         CALL tra_adv_ubs   ( kt, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
115         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv5 - Ta: ', mask1=tmask,               &
116            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
117         CALL tra_adv_qck   ( kt, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
118         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv6 - Ta: ', mask1=tmask,               &
119            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
120         !
121      END SELECT
122
123      !                                              ! print mean trends (used for debugging)
124      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv  - Ta: ', mask1=tmask,               &
125         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
126      !
127   END SUBROUTINE tra_adv
128
129
130   SUBROUTINE tra_adv_init
131      !!---------------------------------------------------------------------
132      !!                  ***  ROUTINE tra_adv_init  ***
133      !!               
134      !! ** Purpose :   Control the consistency between namelist options for
135      !!              tracer advection schemes and set nadv
136      !!----------------------------------------------------------------------
137      INTEGER ::   ioptio
138      !!
139      NAMELIST/namtra_adv/ ln_traadv_cen2 , ln_traadv_tvd,    &
140         &                 ln_traadv_muscl, ln_traadv_muscl2, &
141         &                 ln_traadv_ubs  , ln_traadv_qck
142      !!----------------------------------------------------------------------
143
144      REWIND ( numnam )               ! Read Namelist namtra_adv : tracer advection scheme
145      READ   ( numnam, namtra_adv )
146
147      IF(lwp) THEN                    ! Namelist print
148         WRITE(numout,*)
149         WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
150         WRITE(numout,*) '~~~~~~~~~~~'
151         WRITE(numout,*) '   Namelist namtra_adv : chose a advection scheme for tracers'
152         WRITE(numout,*) '      2nd order advection scheme     ln_traadv_cen2   = ', ln_traadv_cen2
153         WRITE(numout,*) '      TVD advection scheme           ln_traadv_tvd    = ', ln_traadv_tvd
154         WRITE(numout,*) '      MUSCL  advection scheme        ln_traadv_muscl  = ', ln_traadv_muscl
155         WRITE(numout,*) '      MUSCL2 advection scheme        ln_traadv_muscl2 = ', ln_traadv_muscl2
156         WRITE(numout,*) '      UBS    advection scheme        ln_traadv_ubs    = ', ln_traadv_ubs
157         WRITE(numout,*) '      QUICKEST advection scheme      ln_traadv_qck    = ', ln_traadv_qck
158    ENDIF
159
160      ioptio = 0                      ! Parameter control
161      IF( ln_traadv_cen2   )   ioptio = ioptio + 1
162      IF( ln_traadv_tvd    )   ioptio = ioptio + 1
163      IF( ln_traadv_muscl  )   ioptio = ioptio + 1
164      IF( ln_traadv_muscl2 )   ioptio = ioptio + 1
165      IF( ln_traadv_ubs    )   ioptio = ioptio + 1
166      IF( ln_traadv_qck    )   ioptio = ioptio + 1
167      IF( lk_esopa         )   ioptio =          1
168
169      IF( ioptio /= 1 )   CALL ctl_stop( 'Choose ONE advection scheme in namelist namtra_adv' )
170
171      IF( n_cla == 1 .AND. .NOT. ln_traadv_cen2 )   &
172         &                CALL ctl_stop( 'cross-land advection only with 2nd order advection scheme' )
173
174      !                              ! Set nadv
175      IF( ln_traadv_cen2   )   nadv =  1
176      IF( ln_traadv_tvd    )   nadv =  2
177      IF( ln_traadv_muscl  )   nadv =  3
178      IF( ln_traadv_muscl2 )   nadv =  4
179      IF( ln_traadv_ubs    )   nadv =  5
180      IF( ln_traadv_qck    )   nadv =  6
181      IF( lk_esopa         )   nadv = -1
182
183      IF(lwp) THEN                   ! Print the choice
184         WRITE(numout,*)
185         IF( nadv ==  1 )   WRITE(numout,*) '         2nd order scheme is used'
186         IF( nadv ==  2 )   WRITE(numout,*) '         TVD       scheme is used'
187         IF( nadv ==  3 )   WRITE(numout,*) '         MUSCL     scheme is used'
188         IF( nadv ==  4 )   WRITE(numout,*) '         MUSCL2    scheme is used'
189         IF( nadv ==  5 )   WRITE(numout,*) '         UBS       scheme is used'
190         IF( nadv ==  6 )   WRITE(numout,*) '         QUICKEST  scheme is used'
191         IF( nadv == -1 )   WRITE(numout,*) '         esopa test: use all advection scheme'
192      ENDIF
193      !
194   END SUBROUTINE tra_adv_init
195
196  !!======================================================================
197END MODULE traadv
Note: See TracBrowser for help on using the repository browser.