New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_muscl.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_muscl.F90 @ 2333

Last change on this file since 2333 was 2333, checked in by rblod, 14 years ago

Add missing lwp in some advection routines
  • Property svn:keywords set to Id
File size: 13.3 KB
Line 
1MODULE traadv_muscl
2   !!======================================================================
3   !!                       ***  MODULE  traadv_muscl  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   tra_adv_muscl : update the tracer trend with the horizontal
14   !!                   and vertical advection trends using MUSCL scheme
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and active tracers
17   USE dom_oce         ! ocean space and time domain
18   USE trdmod_oce      ! tracers trends
19   USE trdtra      ! tracers trends
20   USE in_out_manager  ! I/O manager
21   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
22   USE trabbl          ! tracers: bottom boundary layer
23   USE lib_mpp         ! distribued memory computing
24   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
25   USE diaptr          ! poleward transport diagnostics
26   USE trc_oce         ! share passive tracers/Ocean variables
27
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   tra_adv_muscl  ! routine called by step.F90
33
34   LOGICAL  :: l_trd       ! flag to compute trends
35
36   !! * Substitutions
37#  include "domzgr_substitute.h90"
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
41   !! $Id$
42   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44
45CONTAINS
46
47   SUBROUTINE tra_adv_muscl( kt, cdtype, p2dt, pun, pvn, pwn, &
48      &                                        ptb, pta, kjpt   )
49      !!----------------------------------------------------------------------
50      !!                    ***  ROUTINE tra_adv_muscl  ***
51      !!
52      !! ** Purpose :   Compute the now trend due to total advection of T and
53      !!      S using a MUSCL scheme (Monotone Upstream-centered Scheme for
54      !!      Conservation Laws) and add it to the general tracer trend.
55      !!
56      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
57      !!
58      !! ** Action  : - update (ta,sa) with the now advective tracer trends
59      !!              - save trends
60      !!
61      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
62      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
63      !!----------------------------------------------------------------------
64      USE oce         , zwx => ua   ! use ua as workspace
65      USE oce         , zwy => va   ! use va as workspace
66      !!
67      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
68      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
69      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
70      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
71      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
72      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb             ! before tracer field
73      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
74      !!
75      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
76      REAL(wp) ::   zu, z0u, zzwx    ! local scalar
77      REAL(wp) ::   zv, z0v, zzwy    !   -      -
78      REAL(wp) ::   zw, z0w          !   -      -
79      REAL(wp) ::   ztra, zbtr, zdt, zalpha
80      REAL(wp), DIMENSION (jpi,jpj,jpk) :: zslpx, zslpy   ! 3D workspace
81      !!----------------------------------------------------------------------
82
83      IF( kt == nit000 )  THEN
84         IF(lwp) WRITE(numout,*)
85         IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
86         IF(lwp) WRITE(numout,*) '~~~~~~~'
87         !
88         l_trd = .FALSE.
89         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
90      ENDIF
91
92      !                                                     ! ===========
93      DO jn = 1, kjpt                                       ! tracer loop
94         !                                                  ! ===========
95         ! I. Horizontal advective fluxes
96         ! ------------------------------
97         ! first guess of the slopes
98         zwx(:,:,jpk) = 0.e0   ;   zwy(:,:,jpk) = 0.e0        ! bottom values
99         ! interior values
100         DO jk = 1, jpkm1
101            DO jj = 1, jpjm1     
102               DO ji = 1, fs_jpim1   ! vector opt.
103                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
104                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
105               END DO
106           END DO
107         END DO
108         !
109         CALL lbc_lnk( zwx, 'U', -1. )                        ! lateral boundary conditions on zwx, zwy   (changed sign)
110         CALL lbc_lnk( zwy, 'V', -1. )
111         !                                             !-- Slopes of tracer
112         zslpx(:,:,jpk) = 0.e0   ;   zslpy(:,:,jpk) = 0.e0    ! bottom values
113         DO jk = 1, jpkm1                                     ! interior values
114            DO jj = 2, jpj
115               DO ji = fs_2, jpi   ! vector opt.
116                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
117                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
118                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
119                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
120               END DO
121            END DO
122         END DO
123         !
124         DO jk = 1, jpkm1                                     ! Slopes limitation
125            DO jj = 2, jpj
126               DO ji = fs_2, jpi   ! vector opt.
127                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
128                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
129                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
130                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
131                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
132                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
133               END DO
134           END DO
135         END DO             ! interior values
136
137         !                                             !-- MUSCL horizontal advective fluxes
138         DO jk = 1, jpkm1                                     ! interior values
139            zdt  = p2dt(jk)
140            DO jj = 2, jpjm1
141               DO ji = fs_2, fs_jpim1   ! vector opt.
142                  ! MUSCL fluxes
143                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
144                  zalpha = 0.5 - z0u
145                  zu  = z0u - 0.5 * pun(ji,jj,jk) * zdt / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) )
146                  zzwx = ptb(ji+1,jj,jk,jn) + zu * zslpx(ji+1,jj,jk)
147                  zzwy = ptb(ji  ,jj,jk,jn) + zu * zslpx(ji  ,jj,jk)
148                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
149                  !
150                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
151                  zalpha = 0.5 - z0v
152                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * zdt / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) )
153                  zzwx = ptb(ji,jj+1,jk,jn) + zv * zslpy(ji,jj+1,jk)
154                  zzwy = ptb(ji,jj  ,jk,jn) + zv * zslpy(ji,jj  ,jk) 
155                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
156               END DO
157            END DO
158         END DO
159         !                                                    ! lateral boundary conditions on zwx, zwy   (changed sign)
160         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )
161         !
162         ! Tracer flux divergence at t-point added to the general trend
163         DO jk = 1, jpkm1
164            DO jj = 2, jpjm1     
165               DO ji = fs_2, fs_jpim1   ! vector opt.
166                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
167                  ! horizontal advective trends
168                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
169                  &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )
170                  ! add it to the general tracer trends
171                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
172               END DO
173           END DO
174         END DO       
175         !                                 ! trend diagnostics (contribution of upstream fluxes)
176         IF( l_trd )  THEN
177            CALL trd_tra( kt, cdtype, jn, jptra_trd_xad, zwx, pun, ptb(:,:,:,jn) )
178            CALL trd_tra( kt, cdtype, jn, jptra_trd_yad, zwy, pvn, ptb(:,:,:,jn) )
179         END IF
180         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
181         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN 
182            IF( jn == jp_tem )  pht_adv(:) = ptr_vj( zwy(:,:,:) )
183            IF( jn == jp_sal )  pst_adv(:) = ptr_vj( zwy(:,:,:) )
184         ENDIF
185
186         ! II. Vertical advective fluxes
187         ! -----------------------------
188         !                                             !-- first guess of the slopes
189         zwx (:,:, 1 ) = 0.e0    ;    zwx (:,:,jpk) = 0.e0    ! surface & bottom boundary conditions
190         DO jk = 2, jpkm1                                     ! interior values
191            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
192         END DO
193
194         !                                             !-- Slopes of tracer
195         zslpx(:,:,1) = 0.e0                                  ! surface values
196         DO jk = 2, jpkm1                                     ! interior value
197            DO jj = 1, jpj
198               DO ji = 1, jpi
199                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )   &
200                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) ) )
201               END DO
202            END DO
203         END DO
204         !                                             !-- Slopes limitation
205         DO jk = 2, jpkm1                                     ! interior values
206            DO jj = 1, jpj
207               DO ji = 1, jpi
208                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
209                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
210                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
211               END DO
212            END DO
213         END DO
214         !                                             !-- vertical advective flux
215         !                                                    ! surface values  (bottom already set to zero)
216         IF( lk_vvl ) THEN    ;   zwx(:,:, 1 ) = 0.e0                      !  variable volume
217         ELSE                 ;   zwx(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
218         ENDIF 
219         !
220         DO jk = 1, jpkm1                                     ! interior values
221            zdt  = p2dt(jk)
222            DO jj = 2, jpjm1     
223               DO ji = fs_2, fs_jpim1   ! vector opt.
224                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk+1) )
225                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
226                  zalpha = 0.5 + z0w
227                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * zdt * zbtr 
228                  zzwx = ptb(ji,jj,jk+1,jn) + zw * zslpx(ji,jj,jk+1)
229                  zzwy = ptb(ji,jj,jk  ,jn) + zw * zslpx(ji,jj,jk  )
230                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
231               END DO
232            END DO
233         END DO
234
235         ! Compute & add the vertical advective trend
236         DO jk = 1, jpkm1
237            DO jj = 2, jpjm1     
238               DO ji = fs_2, fs_jpim1   ! vector opt.
239                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
240                  ! vertical advective trends
241                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) )
242                  ! add it to the general tracer trends
243                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) + ztra
244               END DO
245            END DO
246         END DO
247         !                                 ! Save the vertical advective trends for diagnostic
248         IF( l_trd ) CALL trd_tra( kt, cdtype, jn, jptra_trd_zad, zwx, pwn, ptb(:,:,:,jn) )
249         !
250      ENDDO
251      !
252   END SUBROUTINE tra_adv_muscl
253
254   !!======================================================================
255END MODULE traadv_muscl
Note: See TracBrowser for help on using the repository browser.