New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_tvd.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_tvd.F90 @ 2287

Last change on this file since 2287 was 2287, checked in by smasson, 13 years ago

update licence of all NEMO files...

  • Property svn:keywords set to Id
File size: 17.2 KB
Line 
1MODULE traadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  OPA  !  1995-12  (L. Mortier)  Original code
7   !!                 !  2000-01  (H. Loukos)  adapted to ORCA
8   !!                 !  2000-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  2000-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  2001-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
12   !!    NEMO    1.0  !  2004-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
13   !!            2.0  !  2008-04  (S. Cravatte) add the i-, j- & k- trends computation
14   !!             -   !  2009-11  (V. Garnier) Surface pressure gradient organization
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   tra_adv_tvd  : update the tracer trend with the horizontal
20   !!                  and vertical advection trends using a TVD scheme
21   !!   nonosc       : compute monotonic tracer fluxes by a nonoscillatory
22   !!                  algorithm
23   !!----------------------------------------------------------------------
24   USE oce             ! ocean dynamics and active tracers
25   USE dom_oce         ! ocean space and time domain
26   USE trdmod_oce      ! tracers trends
27   USE trdtra      ! tracers trends
28   USE in_out_manager  ! I/O manager
29   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
30   USE lib_mpp
31   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
32   USE diaptr          ! poleward transport diagnostics
33   USE trc_oce         ! share passive tracers/Ocean variables
34
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   tra_adv_tvd    ! routine called by step.F90
40
41   LOGICAL  :: l_trd       ! flag to compute trends
42
43   !! * Substitutions
44#  include "domzgr_substitute.h90"
45#  include "vectopt_loop_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
48   !! $Id$
49   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51
52CONTAINS
53
54   SUBROUTINE tra_adv_tvd ( kt, cdtype, p2dt, pun, pvn, pwn,   &
55      &                                       ptb, ptn, pta, kjpt   )
56      !!----------------------------------------------------------------------
57      !!                  ***  ROUTINE tra_adv_tvd  ***
58      !!
59      !! **  Purpose :   Compute the now trend due to total advection of
60      !!       tracers and add it to the general trend of tracer equations
61      !!
62      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
63      !!       corrected flux (monotonic correction)
64      !!       note: - this advection scheme needs a leap-frog time scheme
65      !!
66      !! ** Action : - update (pta) with the now advective tracer trends
67      !!             - save the trends
68      !!----------------------------------------------------------------------
69      USE oce         , zwx => ua   ! use ua as workspace
70      USE oce         , zwy => va   ! use va as workspace
71      !!
72      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
73      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
74      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
75      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
76      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
77      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
78      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
79      !!
80      INTEGER  ::   ji, jj, jk, jn           ! dummy loop indices 
81      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
82      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
83      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
84      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zwi, zwz   ! 3D workspace
85      REAL(wp), DIMENSION (:,:,:), ALLOCATABLE ::   ztrdx, ztrdy, ztrdz
86      !!----------------------------------------------------------------------
87
88      IF( kt == nit000 )  THEN
89         WRITE(numout,*)
90         WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme on ', cdtype
91         WRITE(numout,*) '~~~~~~~~~~~'
92         !
93         l_trd = .FALSE.
94         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
95      ENDIF
96      !
97      IF( l_trd )  THEN
98        ALLOCATE( ztrdx(jpi,jpj,jpk) )      ;      ztrdx(:,:,:) = 0.e0
99        ALLOCATE( ztrdy(jpi,jpj,jpk) )      ;      ztrdy(:,:,:) = 0.e0
100        ALLOCATE( ztrdz(jpi,jpj,jpk) )      ;      ztrdz(:,:,:) = 0.e0
101      END IF
102      !
103      zwi(:,:,:) = 0.e0
104      !
105      !                                                          ! ===========
106      DO jn = 1, kjpt                                            ! tracer loop
107         !                                                       ! ===========
108         ! 1. Bottom value : flux set to zero
109         ! ----------------------------------
110         zwx(:,:,jpk) = 0.e0    ;    zwz(:,:,jpk) = 0.e0
111         zwy(:,:,jpk) = 0.e0    ;    zwi(:,:,jpk) = 0.e0
112
113         ! 2. upstream advection with initial mass fluxes & intermediate update
114         ! --------------------------------------------------------------------
115         ! upstream tracer flux in the i and j direction
116         DO jk = 1, jpkm1
117            DO jj = 1, jpjm1
118               DO ji = 1, fs_jpim1   ! vector opt.
119                  ! upstream scheme
120                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
121                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
122                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
123                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
124                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
125                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
126               END DO
127            END DO
128         END DO
129
130         ! upstream tracer flux in the k direction
131         ! Surface value
132         IF( lk_vvl ) THEN   ;   zwz(:,:, 1 ) = 0.e0                         ! volume variable
133         ELSE                ;   zwz(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
134         ENDIF
135         ! Interior value
136         DO jk = 2, jpkm1
137            DO jj = 1, jpj
138               DO ji = 1, jpi
139                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
140                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
141                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
142               END DO
143            END DO
144         END DO
145
146         ! total advective trend
147         DO jk = 1, jpkm1
148            z2dtt = p2dt(jk)
149            DO jj = 2, jpjm1
150               DO ji = fs_2, fs_jpim1   ! vector opt.
151                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
152                  ! total intermediate advective trends
153                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
154                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
155                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
156                  ! update and guess with monotonic sheme
157                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
158                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
159               END DO
160            END DO
161         END DO
162         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
163         CALL lbc_lnk( zwi, 'T', 1. ) 
164
165         !                                 ! trend diagnostics (contribution of upstream fluxes)
166         IF( l_trd )  THEN 
167            ! store intermediate advective trends
168            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
169         END IF
170         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
171         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN 
172           IF( jn == jp_tem )  pht_adv(:) = ptr_vj( zwy(:,:,:) )
173           IF( jn == jp_sal )  pst_adv(:) = ptr_vj( zwy(:,:,:) )
174         ENDIF
175
176         ! 3. antidiffusive flux : high order minus low order
177         ! --------------------------------------------------
178         ! antidiffusive flux on i and j
179         DO jk = 1, jpkm1
180            DO jj = 1, jpjm1
181               DO ji = 1, fs_jpim1   ! vector opt.
182                  zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
183                  zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
184               END DO
185            END DO
186         END DO
187     
188         ! antidiffusive flux on k
189         zwz(:,:,1) = 0.e0         ! Surface value
190         !
191         DO jk = 2, jpkm1          ! Interior value
192            DO jj = 1, jpj
193               DO ji = 1, jpi
194                  zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk)
195               END DO
196            END DO
197         END DO
198         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
199         CALL lbc_lnk( zwz, 'W',  1. )
200
201         ! 4. monotonicity algorithm
202         ! -------------------------
203         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
204
205
206         ! 5. final trend with corrected fluxes
207         ! ------------------------------------
208         DO jk = 1, jpkm1
209            DO jj = 2, jpjm1
210               DO ji = fs_2, fs_jpim1   ! vector opt. 
211                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
212                  ! total advective trends
213                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
214                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
215                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
216                  ! add them to the general tracer trends
217                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
218               END DO
219            END DO
220         END DO
221
222         !                                 ! trend diagnostics (contribution of upstream fluxes)
223         IF( l_trd )  THEN
224            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
225            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
226            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
227           
228            CALL trd_tra( kt, cdtype, jn, jptra_trd_xad, ztrdx, pun, ptn(:,:,:,jn) )   
229            CALL trd_tra( kt, cdtype, jn, jptra_trd_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
230            CALL trd_tra( kt, cdtype, jn, jptra_trd_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
231         END IF
232         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
233         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN 
234           IF( jn == jp_tem )  pht_adv(:) = ptr_vj( zwy(:,:,:) ) + pht_adv(:)
235           IF( jn == jp_sal )  pst_adv(:) = ptr_vj( zwy(:,:,:) ) + pst_adv(:)
236         ENDIF
237         !
238      ENDDO
239      !
240      IF( l_trd )  THEN
241        DEALLOCATE( ztrdx )     ;     DEALLOCATE( ztrdy )     ;      DEALLOCATE( ztrdz ) 
242      END IF
243      !
244   END SUBROUTINE tra_adv_tvd
245
246
247   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
248      !!---------------------------------------------------------------------
249      !!                    ***  ROUTINE nonosc  ***
250      !!     
251      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
252      !!       scheme and the before field by a nonoscillatory algorithm
253      !!
254      !! **  Method  :   ... ???
255      !!       warning : pbef and paft must be masked, but the boundaries
256      !!       conditions on the fluxes are not necessary zalezak (1979)
257      !!       drange (1995) multi-dimensional forward-in-time and upstream-
258      !!       in-space based differencing for fluid
259      !!----------------------------------------------------------------------
260      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
261      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
262      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
263      !!
264      INTEGER ::   ji, jj, jk               ! dummy loop indices
265      INTEGER ::   ikm1
266      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zbetup, zbetdo
267      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zbup, zbdo
268      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt
269      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv
270      REAL(wp) ::   zup, zdo
271      !!----------------------------------------------------------------------
272
273      zbig = 1.e+40
274      zrtrn = 1.e-15
275      zbetup(:,:,jpk) = 0.e0   ;   zbetdo(:,:,jpk) = 0.e0
276
277
278      ! Search local extrema
279      ! --------------------
280      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
281      zbup = MAX( pbef * tmask - zbig * ( 1.e0 - tmask ),   &
282         &        paft * tmask - zbig * ( 1.e0 - tmask )  )
283      zbdo = MIN( pbef * tmask + zbig * ( 1.e0 - tmask ),   &
284         &        paft * tmask + zbig * ( 1.e0 - tmask )  )
285
286      DO jk = 1, jpkm1
287         ikm1 = MAX(jk-1,1)
288         z2dtt = p2dt(jk)
289         DO jj = 2, jpjm1
290            DO ji = fs_2, fs_jpim1   ! vector opt.
291
292               ! search maximum in neighbourhood
293               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
294                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
295                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
296                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
297
298               ! search minimum in neighbourhood
299               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
300                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
301                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
302                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
303
304               ! positive part of the flux
305               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
306                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
307                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
308
309               ! negative part of the flux
310               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
311                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
312                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
313
314               ! up & down beta terms
315               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
316               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
317               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
318            END DO
319         END DO
320      END DO
321      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
322
323
324
325      ! 3. monotonic flux in the i & j direction (paa & pbb)
326      ! ----------------------------------------
327      DO jk = 1, jpkm1
328         DO jj = 2, jpjm1
329            DO ji = fs_2, fs_jpim1   ! vector opt.
330               zau = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
331               zbu = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
332               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
333               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1.e0 - zcu) * zbu )
334
335               zav = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
336               zbv = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
337               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
338               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1.e0 - zcv) * zbv )
339
340      ! monotonic flux in the k direction, i.e. pcc
341      ! -------------------------------------------
342               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
343               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
344               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
345               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1.e0 - zc) * zb )
346            END DO
347         END DO
348      END DO
349      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
350      !
351   END SUBROUTINE nonosc
352
353   !!======================================================================
354END MODULE traadv_tvd
Note: See TracBrowser for help on using the repository browser.