New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_tvd.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_tvd.F90 @ 2399

Last change on this file since 2399 was 2399, checked in by gm, 13 years ago

v3.3beta: diaptr (poleward heat & salt transports) #759 : rewriting including dynamical allocation + DOCTOR names
  • Property svn:keywords set to Id
File size: 17.3 KB
Line 
1MODULE traadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  OPA  !  1995-12  (L. Mortier)  Original code
7   !!                 !  2000-01  (H. Loukos)  adapted to ORCA
8   !!                 !  2000-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  2000-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  2001-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
12   !!    NEMO    1.0  !  2004-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
13   !!            2.0  !  2008-04  (S. Cravatte) add the i-, j- & k- trends computation
14   !!             -   !  2009-11  (V. Garnier) Surface pressure gradient organization
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   tra_adv_tvd  : update the tracer trend with the horizontal
20   !!                  and vertical advection trends using a TVD scheme
21   !!   nonosc       : compute monotonic tracer fluxes by a nonoscillatory
22   !!                  algorithm
23   !!----------------------------------------------------------------------
24   USE oce             ! ocean dynamics and active tracers
25   USE dom_oce         ! ocean space and time domain
26   USE trdmod_oce      ! tracers trends
27   USE trdtra      ! tracers trends
28   USE in_out_manager  ! I/O manager
29   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
30   USE lib_mpp
31   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
32   USE diaptr          ! poleward transport diagnostics
33   USE trc_oce         ! share passive tracers/Ocean variables
34
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   tra_adv_tvd    ! routine called by step.F90
40
41   LOGICAL  :: l_trd       ! flag to compute trends
42
43   !! * Substitutions
44#  include "domzgr_substitute.h90"
45#  include "vectopt_loop_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
48   !! $Id$
49   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE tra_adv_tvd ( kt, cdtype, p2dt, pun, pvn, pwn,      &
54      &                                       ptb, ptn, pta, kjpt )
55      !!----------------------------------------------------------------------
56      !!                  ***  ROUTINE tra_adv_tvd  ***
57      !!
58      !! **  Purpose :   Compute the now trend due to total advection of
59      !!       tracers and add it to the general trend of tracer equations
60      !!
61      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
62      !!       corrected flux (monotonic correction)
63      !!       note: - this advection scheme needs a leap-frog time scheme
64      !!
65      !! ** Action : - update (pta) with the now advective tracer trends
66      !!             - save the trends
67      !!----------------------------------------------------------------------
68      USE oce         , zwx => ua   ! use ua as workspace
69      USE oce         , zwy => va   ! use va as workspace
70      !!
71      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
72      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
73      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
74      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
75      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
76      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
77      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
78      !!
79      INTEGER  ::   ji, jj, jk, jn           ! dummy loop indices 
80      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
81      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
82      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
83      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zwi, zwz   ! 3D workspace
84      REAL(wp), DIMENSION (:,:,:), ALLOCATABLE ::   ztrdx, ztrdy, ztrdz
85      !!----------------------------------------------------------------------
86
87      IF( kt == nit000 )  THEN
88         IF(lwp) WRITE(numout,*)
89         IF(lwp) WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme on ', cdtype
90         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
91         !
92         l_trd = .FALSE.
93         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
94      ENDIF
95      !
96      IF( l_trd )  THEN
97        ALLOCATE( ztrdx(jpi,jpj,jpk) )      ;      ztrdx(:,:,:) = 0.e0
98        ALLOCATE( ztrdy(jpi,jpj,jpk) )      ;      ztrdy(:,:,:) = 0.e0
99        ALLOCATE( ztrdz(jpi,jpj,jpk) )      ;      ztrdz(:,:,:) = 0.e0
100      END IF
101      !
102      zwi(:,:,:) = 0.e0
103      !
104      !                                                          ! ===========
105      DO jn = 1, kjpt                                            ! tracer loop
106         !                                                       ! ===========
107         ! 1. Bottom value : flux set to zero
108         ! ----------------------------------
109         zwx(:,:,jpk) = 0.e0    ;    zwz(:,:,jpk) = 0.e0
110         zwy(:,:,jpk) = 0.e0    ;    zwi(:,:,jpk) = 0.e0
111
112         ! 2. upstream advection with initial mass fluxes & intermediate update
113         ! --------------------------------------------------------------------
114         ! upstream tracer flux in the i and j direction
115         DO jk = 1, jpkm1
116            DO jj = 1, jpjm1
117               DO ji = 1, fs_jpim1   ! vector opt.
118                  ! upstream scheme
119                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
120                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
121                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
122                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
123                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
124                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
125               END DO
126            END DO
127         END DO
128
129         ! upstream tracer flux in the k direction
130         ! Surface value
131         IF( lk_vvl ) THEN   ;   zwz(:,:, 1 ) = 0.e0                         ! volume variable
132         ELSE                ;   zwz(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
133         ENDIF
134         ! Interior value
135         DO jk = 2, jpkm1
136            DO jj = 1, jpj
137               DO ji = 1, jpi
138                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
139                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
140                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
141               END DO
142            END DO
143         END DO
144
145         ! total advective trend
146         DO jk = 1, jpkm1
147            z2dtt = p2dt(jk)
148            DO jj = 2, jpjm1
149               DO ji = fs_2, fs_jpim1   ! vector opt.
150                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
151                  ! total intermediate advective trends
152                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
153                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
154                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
155                  ! update and guess with monotonic sheme
156                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
157                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
158               END DO
159            END DO
160         END DO
161         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
162         CALL lbc_lnk( zwi, 'T', 1. ) 
163
164         !                                 ! trend diagnostics (contribution of upstream fluxes)
165         IF( l_trd )  THEN 
166            ! store intermediate advective trends
167            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
168         END IF
169         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
170         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
171           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) )
172           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) )
173         ENDIF
174
175         ! 3. antidiffusive flux : high order minus low order
176         ! --------------------------------------------------
177         ! antidiffusive flux on i and j
178         DO jk = 1, jpkm1
179            DO jj = 1, jpjm1
180               DO ji = 1, fs_jpim1   ! vector opt.
181                  zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
182                  zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
183               END DO
184            END DO
185         END DO
186     
187         ! antidiffusive flux on k
188         zwz(:,:,1) = 0.e0         ! Surface value
189         !
190         DO jk = 2, jpkm1          ! Interior value
191            DO jj = 1, jpj
192               DO ji = 1, jpi
193                  zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk)
194               END DO
195            END DO
196         END DO
197         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
198         CALL lbc_lnk( zwz, 'W',  1. )
199
200         ! 4. monotonicity algorithm
201         ! -------------------------
202         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
203
204
205         ! 5. final trend with corrected fluxes
206         ! ------------------------------------
207         DO jk = 1, jpkm1
208            DO jj = 2, jpjm1
209               DO ji = fs_2, fs_jpim1   ! vector opt. 
210                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
211                  ! total advective trends
212                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
213                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
214                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
215                  ! add them to the general tracer trends
216                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
217               END DO
218            END DO
219         END DO
220
221         !                                 ! trend diagnostics (contribution of upstream fluxes)
222         IF( l_trd )  THEN
223            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
224            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
225            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
226           
227            CALL trd_tra( kt, cdtype, jn, jptra_trd_xad, ztrdx, pun, ptn(:,:,:,jn) )   
228            CALL trd_tra( kt, cdtype, jn, jptra_trd_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
229            CALL trd_tra( kt, cdtype, jn, jptra_trd_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
230         END IF
231         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
232         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
233           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) ) + htr_adv(:)
234           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) ) + str_adv(:)
235         ENDIF
236         !
237      ENDDO
238      !
239      IF( l_trd )  THEN
240        DEALLOCATE( ztrdx )     ;     DEALLOCATE( ztrdy )     ;      DEALLOCATE( ztrdz ) 
241      END IF
242      !
243   END SUBROUTINE tra_adv_tvd
244
245
246   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
247      !!---------------------------------------------------------------------
248      !!                    ***  ROUTINE nonosc  ***
249      !!     
250      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
251      !!       scheme and the before field by a nonoscillatory algorithm
252      !!
253      !! **  Method  :   ... ???
254      !!       warning : pbef and paft must be masked, but the boundaries
255      !!       conditions on the fluxes are not necessary zalezak (1979)
256      !!       drange (1995) multi-dimensional forward-in-time and upstream-
257      !!       in-space based differencing for fluid
258      !!----------------------------------------------------------------------
259      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
260      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
261      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
262      !!
263      INTEGER ::   ji, jj, jk               ! dummy loop indices
264      INTEGER ::   ikm1
265      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zbetup, zbetdo
266      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zbup, zbdo
267      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt
268      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv
269      REAL(wp) ::   zup, zdo
270      !!----------------------------------------------------------------------
271
272      zbig = 1.e+40
273      zrtrn = 1.e-15
274      zbetup(:,:,jpk) = 0.e0   ;   zbetdo(:,:,jpk) = 0.e0
275
276
277      ! Search local extrema
278      ! --------------------
279      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
280      zbup = MAX( pbef * tmask - zbig * ( 1.e0 - tmask ),   &
281         &        paft * tmask - zbig * ( 1.e0 - tmask )  )
282      zbdo = MIN( pbef * tmask + zbig * ( 1.e0 - tmask ),   &
283         &        paft * tmask + zbig * ( 1.e0 - tmask )  )
284
285      DO jk = 1, jpkm1
286         ikm1 = MAX(jk-1,1)
287         z2dtt = p2dt(jk)
288         DO jj = 2, jpjm1
289            DO ji = fs_2, fs_jpim1   ! vector opt.
290
291               ! search maximum in neighbourhood
292               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
293                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
294                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
295                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
296
297               ! search minimum in neighbourhood
298               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
299                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
300                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
301                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
302
303               ! positive part of the flux
304               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
305                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
306                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
307
308               ! negative part of the flux
309               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
310                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
311                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
312
313               ! up & down beta terms
314               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
315               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
316               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
317            END DO
318         END DO
319      END DO
320      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
321
322
323
324      ! 3. monotonic flux in the i & j direction (paa & pbb)
325      ! ----------------------------------------
326      DO jk = 1, jpkm1
327         DO jj = 2, jpjm1
328            DO ji = fs_2, fs_jpim1   ! vector opt.
329               zau = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
330               zbu = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
331               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
332               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1.e0 - zcu) * zbu )
333
334               zav = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
335               zbv = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
336               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
337               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1.e0 - zcv) * zbv )
338
339      ! monotonic flux in the k direction, i.e. pcc
340      ! -------------------------------------------
341               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
342               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
343               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
344               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1.e0 - zc) * zb )
345            END DO
346         END DO
347      END DO
348      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
349      !
350   END SUBROUTINE nonosc
351
352   !!======================================================================
353END MODULE traadv_tvd
Note: See TracBrowser for help on using the repository browser.