New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso.F90 @ 2399

Last change on this file since 2399 was 2399, checked in by gm, 13 years ago

v3.3beta: diaptr (poleward heat & salt transports) #759 : rewriting including dynamical allocation + DOCTOR names
  • Property svn:keywords set to Id
File size: 15.5 KB
Line 
1MODULE traldf_iso
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  OPA  !  1994-08  (G. Madec, M. Imbard)
7   !!            8.0  !  1997-05  (G. Madec)  split into traldf and trazdf
8   !!            NEMO !  2002-08  (G. Madec)  Free form, F90
9   !!            1.0  !  2005-11  (G. Madec)  merge traldf and trazdf :-)
10   !!            3.3  !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!----------------------------------------------------------------------
12#if   defined key_ldfslp   ||   defined key_esopa
13   !!----------------------------------------------------------------------
14   !!   'key_ldfslp'               slope of the lateral diffusive direction
15   !!----------------------------------------------------------------------
16   !!   tra_ldf_iso  : update the tracer trend with the horizontal
17   !!                  component of a iso-neutral laplacian operator
18   !!                  and with the vertical part of
19   !!                  the isopycnal or geopotential s-coord. operator
20   !!----------------------------------------------------------------------
21   USE oce             ! ocean dynamics and active tracers
22   USE dom_oce         ! ocean space and time domain
23   USE ldftra_oce      ! ocean active tracers: lateral physics
24   USE zdf_oce         ! ocean vertical physics
25   USE in_out_manager  ! I/O manager
26   USE iom             !
27   USE ldfslp          ! iso-neutral slopes
28   USE diaptr          ! poleward transport diagnostics
29   USE trc_oce         ! share passive tracers/Ocean variables
30#if defined key_diaar5
31   USE phycst          ! physical constants
32   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
33#endif
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   tra_ldf_iso   ! routine called by step.F90
39
40   !! * Substitutions
41#  include "domzgr_substitute.h90"
42#  include "ldftra_substitute.h90"
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE tra_ldf_iso( kt, cdtype, pgu, pgv,              &
52      &                                ptb, pta, kjpt, pahtb0 )
53      !!----------------------------------------------------------------------
54      !!                  ***  ROUTINE tra_ldf_iso  ***
55      !!
56      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
57      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
58      !!      add it to the general trend of tracer equation.
59      !!
60      !! ** Method  :   The horizontal component of the lateral diffusive trends
61      !!      is provided by a 2nd order operator rotated along neural or geopo-
62      !!      tential surfaces to which an eddy induced advection can be added
63      !!      It is computed using before fields (forward in time) and isopyc-
64      !!      nal or geopotential slopes computed in routine ldfslp.
65      !!
66      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
67      !!      ========    with partial cell update if ln_zps=T.
68      !!
69      !!      2nd part :  horizontal fluxes of the lateral mixing operator
70      !!      ========   
71      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
72      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
73      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
74      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
75      !!      take the horizontal divergence of the fluxes:
76      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
77      !!      Add this trend to the general trend (ta,sa):
78      !!         ta = ta + difft
79      !!
80      !!      3rd part: vertical trends of the lateral mixing operator
81      !!      ========  (excluding the vertical flux proportional to dk[t] )
82      !!      vertical fluxes associated with the rotated lateral mixing:
83      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
84      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
85      !!      take the horizontal divergence of the fluxes:
86      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
87      !!      Add this trend to the general trend (ta,sa):
88      !!         pta = pta + difft
89      !!
90      !! ** Action :   Update pta arrays with the before rotated diffusion
91      !!----------------------------------------------------------------------
92      USE oce         , zftu => ua   ! use ua as workspace
93      USE oce         , zftv => va   ! use va as workspace
94      !!
95      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
96      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
97      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
98      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
99      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
100      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
101      REAL(wp)                             , INTENT(in   ) ::   pahtb0     ! background diffusion coef
102      !!
103      INTEGER  ::  ji, jj, jk,jn   ! dummy loop indices
104      INTEGER  ::  iku, ikv        ! temporary integer
105      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! local scalars
106      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !   -      -
107      REAL(wp) ::  zcoef0, zbtr, ztra            !   -      -
108      REAL(wp), DIMENSION(jpi,jpj)     ::   zdkt, zdk1t         ! 2D workspace
109      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdit, zdjt, ztfw    ! 3D workspace
110#if defined key_diaar5
111      REAL(wp), DIMENSION(jpi,jpj)     ::   z2d                 ! 2D workspace
112      REAL(wp)                         ::   zztmp               ! local scalar
113#endif
114      !!----------------------------------------------------------------------
115
116      IF( kt == nit000 )  THEN
117         IF(lwp) WRITE(numout,*)
118         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype
119         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
120      ENDIF
121      !
122      !                                                          ! ===========
123      DO jn = 1, kjpt                                            ! tracer loop
124         !                                                       ! ===========
125         !                                               
126         !!----------------------------------------------------------------------
127         !!   I - masked horizontal derivative
128         !!----------------------------------------------------------------------
129         !!bug ajout.... why?   ( 1,jpj,:) and (jpi,1,:) should be sufficient....
130         zdit (1,:,:) = 0.e0     ;     zdit (jpi,:,:) = 0.e0
131         zdjt (1,:,:) = 0.e0     ;     zdjt (jpi,:,:) = 0.e0
132         !!end
133
134         ! Horizontal tracer gradient
135         DO jk = 1, jpkm1
136            DO jj = 1, jpjm1
137               DO ji = 1, fs_jpim1   ! vector opt.
138                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
139                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
140               END DO
141            END DO
142         END DO
143         IF( ln_zps ) THEN      ! partial steps correction at the last level
144            DO jj = 1, jpjm1
145               DO ji = 1, fs_jpim1   ! vector opt.
146                  ! last level
147                  iku = MIN( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1
148                  ikv = MIN( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1
149                  zdit(ji,jj,iku) = pgu(ji,jj,jn)         
150                  zdjt(ji,jj,ikv) = pgv(ji,jj,jn)     
151               END DO
152            END DO
153         ENDIF
154
155         !!----------------------------------------------------------------------
156         !!   II - horizontal trend  (full)
157         !!----------------------------------------------------------------------
158!CDIR PARALLEL DO PRIVATE( zdk1t )
159         !                                                ! ===============
160         DO jk = 1, jpkm1                                 ! Horizontal slab
161            !                                             ! ===============
162            ! 1. Vertical tracer gradient at level jk and jk+1
163            ! ------------------------------------------------
164            ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
165            zdk1t(:,:) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
166            !
167            IF( jk == 1 ) THEN   ;   zdkt(:,:) = zdk1t(:,:)
168            ELSE                 ;   zdkt(:,:) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask(:,:,jk)
169            ENDIF
170
171            ! 2. Horizontal fluxes
172            ! --------------------   
173            DO jj = 1 , jpjm1
174               DO ji = 1, fs_jpim1   ! vector opt.
175                  zabe1 = ( fsahtu(ji,jj,jk) + pahtb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
176                  zabe2 = ( fsahtv(ji,jj,jk) + pahtb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
177                  !
178                  zmsku = 1. / MAX(  tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
179                     &             + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
180                  !
181                  zmskv = 1. / MAX(  tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
182                     &             + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
183                  !
184                  zcof1 = - fsahtu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
185                  zcof2 = - fsahtv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
186                  !
187                  zftu(ji,jj,jk ) = (  zabe1 * zdit(ji,jj,jk)   &
188                     &              + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
189                     &                         + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  ) * umask(ji,jj,jk)
190                  zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
191                     &              + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
192                     &                         + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  ) * vmask(ji,jj,jk)                 
193               END DO
194            END DO
195
196            ! II.4 Second derivative (divergence) and add to the general trend
197            ! ----------------------------------------------------------------
198            DO jj = 2 , jpjm1
199               DO ji = fs_2, fs_jpim1   ! vector opt.
200                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
201                  ztra = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
202                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
203               END DO
204            END DO
205            !                                          ! ===============
206         END DO                                        !   End of slab 
207         !                                             ! ===============
208         !
209         ! "Poleward" diffusive heat or salt transports (T-S case only)
210         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
211            IF( jn == jp_tem)   htr_ldf(:) = ptr_vj( zftv(:,:,:) )
212            IF( jn == jp_sal)   str_ldf(:) = ptr_vj( zftv(:,:,:) )
213         ENDIF
214 
215#if defined key_diaar5
216         IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
217            zztmp = 0.5 * rau0 * rcp 
218            z2d(:,:) = 0.e0 
219            DO jk = 1, jpkm1
220               DO jj = 2, jpjm1
221                  DO ji = fs_2, fs_jpim1   ! vector opt.
222                     z2d(ji,jj) = z2d(ji,jj) + zztmp * zftu(ji,jj,jk)       &
223                        &       * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) * e1u(ji,jj) * fse3u(ji,jj,jk) 
224                  END DO
225               END DO
226            END DO
227            CALL lbc_lnk( z2d, 'U', -1. )
228            CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
229            z2d(:,:) = 0.e0 
230            DO jk = 1, jpkm1
231               DO jj = 2, jpjm1
232                  DO ji = fs_2, fs_jpim1   ! vector opt.
233                     z2d(ji,jj) = z2d(ji,jj) + zztmp * zftv(ji,jj,jk)       &
234                        &       * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) * e2v(ji,jj) * fse3v(ji,jj,jk) 
235                  END DO
236               END DO
237            END DO
238            CALL lbc_lnk( z2d, 'V', -1. )
239            CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
240         END IF
241#endif
242
243         !!----------------------------------------------------------------------
244         !!   III - vertical trend of T & S (extra diagonal terms only)
245         !!----------------------------------------------------------------------
246         
247         ! Local constant initialization
248         ! -----------------------------
249         ztfw(1,:,:) = 0.e0     ;     ztfw(jpi,:,:) = 0.e0
250         
251         ! Vertical fluxes
252         ! ---------------
253         
254         ! Surface and bottom vertical fluxes set to zero
255         ztfw(:,:, 1 ) = 0.e0      ;      ztfw(:,:,jpk) = 0.e0
256         
257         ! interior (2=<jk=<jpk-1)
258         DO jk = 2, jpkm1
259            DO jj = 2, jpjm1
260               DO ji = fs_2, fs_jpim1   ! vector opt.
261                  zcoef0 = - fsahtw(ji,jj,jk) * tmask(ji,jj,jk)
262                  !
263                  zmsku = 1./MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)      &
264                     &            + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk), 1.  )
265                  zmskv = 1./MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)      &
266                     &            + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk), 1.  )
267                  !
268                  zcoef3 = zcoef0 * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk)
269                  zcoef4 = zcoef0 * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk)
270                  !
271                  ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
272                     &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
273                     &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
274                     &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
275               END DO
276            END DO
277         END DO
278         
279         
280         ! I.5 Divergence of vertical fluxes added to the general tracer trend
281         ! -------------------------------------------------------------------
282         DO jk = 1, jpkm1
283            DO jj = 2, jpjm1
284               DO ji = fs_2, fs_jpim1   ! vector opt.
285                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
286                  ztra = (  ztfw(ji,jj,jk) - ztfw(ji,jj,jk+1)  ) * zbtr
287                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
288               END DO
289            END DO
290         END DO
291         !
292      END DO
293      !
294   END SUBROUTINE tra_ldf_iso
295
296#else
297   !!----------------------------------------------------------------------
298   !!   default option :   Dummy code   NO rotation of the diffusive tensor
299   !!----------------------------------------------------------------------
300CONTAINS
301   SUBROUTINE tra_ldf_iso( kt )               ! Empty routine
302      WRITE(*,*) 'tra_ldf_iso: You should not have seen this print! error?', kt
303   END SUBROUTINE tra_ldf_iso
304#endif
305
306   !!==============================================================================
307END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.