New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso_grif.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso_grif.F90 @ 2399

Last change on this file since 2399 was 2399, checked in by gm, 13 years ago

v3.3beta: diaptr (poleward heat & salt transports) #759 : rewriting including dynamical allocation + DOCTOR names
  • Property svn:keywords set to Id
File size: 17.3 KB
Line 
1MODULE traldf_iso_grif
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso_grif  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History : 3.3  ! 2010-10  (G. Nurser, C. Harris, G. Madec) 
7   !!                !          Griffies operator version adapted from traldf_iso.F90
8   !!----------------------------------------------------------------------
9#if   defined key_ldfslp   ||   defined key_esopa
10   !!----------------------------------------------------------------------
11   !!   'key_ldfslp'               slope of the lateral diffusive direction
12   !!----------------------------------------------------------------------
13   !!   tra_ldf_iso_grif  : update the tracer trend with the horizontal
14   !!                       component of a iso-neutral laplacian operator
15   !!                       and with the vertical part of
16   !!                       the isopycnal or geopotential s-coord. operator
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and active tracers
19   USE dom_oce         ! ocean space and time domain
20   USE ldftra_oce      ! ocean active tracers: lateral physics
21   USE zdf_oce         ! ocean vertical physics
22   USE in_out_manager  ! I/O manager
23   USE iom             !
24   USE ldfslp          ! iso-neutral slopes
25   USE diaptr          ! poleward transport diagnostics
26   USE trc_oce         ! share passive tracers/Ocean variables
27#if defined key_diaar5
28   USE phycst          ! physical constants
29   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
30#endif
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC tra_ldf_iso_grif   ! routine called by traldf.F90
36
37   REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE ::   psix_eiv
38   REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE ::   psiy_eiv
39   REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE ::   ah_wslp2
40
41   !! * Substitutions
42#  include "domzgr_substitute.h90"
43#  include "ldftra_substitute.h90"
44#  include "vectopt_loop_substitute.h90"
45#  include "ldfeiv_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
48   !! $Id$
49   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53  SUBROUTINE tra_ldf_iso_grif( kt, cdtype, pgu, pgv,              &
54       &                                   ptb, pta, kjpt, pahtb0 )
55    !!----------------------------------------------------------------------
56    !!                  ***  ROUTINE tra_ldf_iso_grif  ***
57    !!
58    !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
59    !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
60    !!      add it to the general trend of tracer equation.
61    !!
62    !! ** Method  :   The horizontal component of the lateral diffusive trends
63    !!      is provided by a 2nd order operator rotated along neural or geopo-
64    !!      tential surfaces to which an eddy induced advection can be added
65    !!      It is computed using before fields (forward in time) and isopyc-
66    !!      nal or geopotential slopes computed in routine ldfslp.
67    !!
68    !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
69    !!      ========    with partial cell update if ln_zps=T.
70    !!
71    !!      2nd part :  horizontal fluxes of the lateral mixing operator
72    !!      ========   
73    !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
74    !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
75    !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
76    !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
77    !!      take the horizontal divergence of the fluxes:
78    !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
79    !!      Add this trend to the general trend (ta,sa):
80    !!         ta = ta + difft
81    !!
82    !!      3rd part: vertical trends of the lateral mixing operator
83    !!      ========  (excluding the vertical flux proportional to dk[t] )
84    !!      vertical fluxes associated with the rotated lateral mixing:
85    !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
86    !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
87    !!      take the horizontal divergence of the fluxes:
88    !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
89    !!      Add this trend to the general trend (ta,sa):
90    !!         pta = pta + difft
91    !!
92    !! ** Action :   Update pta arrays with the before rotated diffusion
93    !!----------------------------------------------------------------------
94    USE oce,   zftu => ua   ! use ua as workspace
95    USE oce,   zftv => va   ! use va as workspace
96    !!
97    INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
98    CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
99    INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
100    REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
101    REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
102    REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
103    REAL(wp)                             , INTENT(in   ) ::   pahtb0     ! background diffusion coef
104    !!
105    INTEGER  ::  ji, jj, jk,jn   ! dummy loop indices
106    INTEGER  ::  ip,jp,kp        ! dummy loop indices
107    INTEGER  ::  iku, ikv        ! temporary integer
108    INTEGER  ::  ierr            ! temporary integer
109    REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! local scalars
110    REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !   -      -
111    REAL(wp) ::  zcoef0, zbtr                  !   -      -
112    REAL(wp), DIMENSION(jpi,jpj,0:1) ::   zdkt               ! 2D+1 workspace
113    REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdit, zdjt, ztfw   ! 3D workspace
114      !
115    REAL(wp) ::   zslope_skew,zslope_iso,zslope2, zbu, zbv
116    REAL(wp) ::   ze1ur,zdxt,ze2vr,ze3wr,zdyt,zdzt
117    REAL(wp) ::   ah,zah_slp,zaei_slp
118#if defined key_diaar5
119    REAL(wp), DIMENSION(jpi,jpj)     ::   z2d                ! 2D workspace
120    REAL(wp)                         ::   zztmp              ! local scalar
121#endif
122      !!----------------------------------------------------------------------
123
124    IF( kt == nit000 )  THEN
125       IF(lwp) WRITE(numout,*)
126       IF(lwp) WRITE(numout,*) 'tra_ldf_iso_grif : rotated laplacian diffusion operator on ', cdtype
127       IF(lwp) WRITE(numout,*) '                   WARNING: STILL UNDER TEST, NOT RECOMMENDED. USE AT YOUR OWN PERIL'
128       IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
129       ALLOCATE( ah_wslp2(jpi,jpj,jpk) , STAT=ierr )
130       IF( ierr > 0 ) THEN
131          CALL ctl_stop( 'tra_ldf_iso_grif : unable to allocate Griffies operator ah_wslp2 ' )   ;   RETURN
132       ENDIF
133       IF( ln_traldf_gdia ) THEN
134          ALLOCATE( psix_eiv(jpi,jpj,jpk) , psiy_eiv(jpi,jpj,jpk) , STAT=ierr )
135          IF( ierr > 0 ) THEN
136             CALL ctl_stop( 'tra_ldf_iso_grif : unable to allocate Griffies operator diagnostics ' )   ;   RETURN
137          ENDIF
138       ENDIF
139    ENDIF
140
141      !                                               
142      !!----------------------------------------------------------------------
143      !!   0 - calculate  ah_wslp2, psix_eiv, psiy_eiv
144      !!----------------------------------------------------------------------
145
146!!gm Future development: consider using Ah defined at T-points and attached to the 4 t-point triads
147
148    ah_wslp2(:,:,:) = 0.0
149    IF( ln_traldf_gdia ) THEN
150       psix_eiv(:,:,:) = 0.0
151       psiy_eiv(:,:,:) = 0.0
152    ENDIF
153
154    DO ip=0,1
155       DO kp=0,1
156          DO jk=1,jpkm1
157             DO jj=1,jpjm1
158                DO ji=1,fs_jpim1
159                   ze3wr=1.0_wp/fse3w(ji+ip,jj,jk+kp)
160                   zbu = 0.25_wp*e1u(ji,jj)*e2u(ji,jj)*fse3u(ji,jj,jk)
161                   ah = fsahtu(ji,jj,jk)                                  !  fsaht(ji+ip,jj,jk)
162                   zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
163                   zslope2=(zslope_skew &
164                        & - umask(ji,jj,jk+kp)*(fsdept(ji+1,jj,jk) - fsdept(ji ,jj ,jk))*ze1ur &
165                        & )**2
166                   ah_wslp2(ji+ip,jj,jk+kp)=ah_wslp2(ji+ip,jj,jk+kp) + &
167                        & ah*((zbu*ze3wr)/(e1t(ji+ip,jj)*e2t(ji+ip,jj)))*zslope2
168                   IF( ln_traldf_gdia ) THEN
169                      zaei_slp = fsaeiw(ji+ip,jj,jk)*zslope_skew!fsaeit(ji+ip,jj,jk)*zslope_skew
170                      psix_eiv(ji,jj,jk+kp) = psix_eiv(ji,jj,jk+kp) + 0.25_wp*zaei_slp
171                   ENDIF
172                END DO
173             END DO
174          END DO
175       END DO
176    END DO
177
178    DO jp=0,1
179       DO kp=0,1
180          DO jk=1,jpkm1
181             DO jj=1,jpjm1
182                DO ji=1,fs_jpim1
183                   ze3wr=1.0_wp/fse3w(ji,jj+jp,jk+kp)
184                   zbv = 0.25_wp*e1v(ji,jj)*e2v(ji,jj)*fse3v(ji,jj,jk)
185                   ah = fsahtu(ji,jj,jk)!fsaht(ji,jj+jp,jk)
186                   zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
187                   zslope2=(zslope_skew - vmask(ji,jj,jk+kp)*(fsdept(ji,jj+1,jk) - fsdept(ji ,jj ,jk))*ze2vr &
188                        & )**2
189                   ah_wslp2(ji,jj+jp,jk+kp)=ah_wslp2(ji,jj+jp,jk+kp) + &
190                        & ah*((zbv*ze3wr)/(e1t(ji,jj+jp)*e2t(ji,jj+jp)))*zslope2
191                   IF( ln_traldf_gdia ) THEN
192                      zaei_slp = fsaeiw(ji,jj+jp,jk) * zslope_skew     !fsaeit(ji,jj+jp,jk)*zslope_skew
193                      psiy_eiv(ji,jj,jk+kp) = psiy_eiv(ji,jj,jk+kp) + 0.25_wp*zaei_slp
194                   ENDIF
195                END DO
196             END DO
197          END DO
198       END DO
199      END DO
200
201      !
202      !                                                          ! ===========
203      DO jn = 1, kjpt                                            ! tracer loop
204         !                                                       ! ===========
205         ! Zero fluxes for each tracer
206         ztfw(:,:,:) = 0._wp
207         zftu(:,:,:) = 0._wp
208         zftv(:,:,:) = 0._wp
209         !                                               
210         DO jk = 1, jpkm1                          !==  before lateral T & S gradients at T-level jk  ==!
211            DO jj = 1, jpjm1
212               DO ji = 1, fs_jpim1   ! vector opt.
213                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
214                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
215               END DO
216            END DO
217         END DO
218         IF( ln_zps ) THEN                               ! partial steps: correction at the last level
219# if defined key_vectopt_loop
220            DO jj = 1, 1
221               DO ji = 1, jpij-jpi   ! vector opt. (forced unrolling)
222# else
223            DO jj = 1, jpjm1
224               DO ji = 1, jpim1
225# endif
226                  iku = MIN( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1                ! last level
227                  ikv = MIN( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1
228                  zdit(ji,jj,iku) = pgu(ji,jj,jn)         
229                  zdjt(ji,jj,ikv) = pgv(ji,jj,jn)     
230               END DO
231            END DO
232         ENDIF
233
234         !!----------------------------------------------------------------------
235         !!   II - horizontal trend  (full)
236         !!----------------------------------------------------------------------
237         !
238         DO jk = 1, jpkm1
239            !
240            !                    !==  Vertical tracer gradient at level jk and jk+1
241            zdkt(:,:,1) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
242            !
243            !                          ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
244            IF( jk == 1 ) THEN   ;   zdkt(:,:,0) = zdkt(:,:,1)
245            ELSE                 ;   zdkt(:,:,0) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask(:,:,jk)
246            ENDIF
247
248            IF( .NOT. l_triad_iso ) THEN
249               triadi = triadi_g
250               triadj = triadj_g
251            ENDIF
252
253            DO ip=0,1              !==  Horizontal & vertical fluxes
254               DO kp=0,1
255                  DO jj=1,jpjm1
256                     DO ji=1,fs_jpim1
257                        ze1ur = 1._wp / e1u(ji,jj)
258                        zdxt = zdit(ji,jj,jk) * ze1ur
259                        ze3wr = 1._wp/fse3w(ji+ip,jj,jk+kp)
260                        zdzt  = zdkt(ji+ip,jj,kp) * ze3wr
261                        zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
262                        zslope_iso  = triadi(ji+ip,jj,jk,1-ip,kp)
263
264                        zbu = 0.25_wp * e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
265                        ah = fsahtu(ji,jj,jk)!*umask(ji,jj,jk+kp)         !fsaht(ji+ip,jj,jk)             ===>>  ????
266                        zah_slp = ah*zslope_iso
267                        zaei_slp = fsaeiw(ji+ip,jj,jk) * zslope_skew    !fsaeit(ji+ip,jj,jk)*zslope_skew
268                        zftu(ji,jj,jk)  = zftu(ji,jj,jk) - (ah*zdxt + (zah_slp - zaei_slp)*zdzt)*zbu*ze1ur
269                        ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp)*zdxt *zbu*ze3wr
270                     END DO
271                  END DO
272               END DO
273            END DO
274
275            DO jp=0,1
276               DO kp=0,1
277                  DO jj=1,jpjm1
278                     DO ji=1,fs_jpim1
279                        ze2vr = 1._wp/e2v(ji,jj)
280                        zdyt = zdjt(ji,jj,jk)*ze2vr
281                        ze3wr = 1._wp/fse3w(ji,jj+jp,jk+kp)
282                        zdzt = zdkt(ji,jj+jp,kp) * ze3wr
283                        zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
284                        zslope_iso = triadj(ji,jj+jp,jk,1-jp,kp)
285                        zbv = 0.25_wp * e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
286                        ah    = fsahtv(ji,jj,jk)!*vmask(ji,jj,jk+kp)         !fsaht(ji,jj+jp,jk)
287                        zah_slp = ah * zslope_iso
288                        zaei_slp = fsaeiw(ji,jj+jp,jk)*zslope_skew!fsaeit(ji,jj+jp,jk)*zslope_skew
289                        zftv(ji,jj,jk) = zftv(ji,jj,jk) - (ah*zdyt + (zah_slp - zaei_slp)*zdzt)*zbv*ze2vr
290                        ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp)*zdyt*zbv*ze3wr
291                     END DO
292                  END DO
293               END DO
294            END DO
295
296          !                        !==  divergence and add to the general trend  ==!
297          DO jj = 2 , jpjm1
298             DO ji = fs_2, fs_jpim1   ! vector opt.
299                zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
300                pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zbtr * (   zftu(ji-1,jj,jk) - zftu(ji,jj,jk)   &
301                  &                                            + zftv(ji,jj-1,jk) - zftv(ji,jj,jk)   )
302             END DO
303          END DO
304          !
305       END DO
306       !
307       DO jk = 1, jpkm1            !== Divergence of vertical fluxes added to the general tracer trend
308          DO jj = 2, jpjm1
309             DO ji = fs_2, fs_jpim1   ! vector opt.
310                pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + (  ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk)  )   &
311                  &                                 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
312             END DO
313          END DO
314       END DO
315       !
316       !                            ! "Poleward" diffusive heat or salt transports (T-S case only)
317       IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
318         IF( jn == jp_tem)   htr_ldf(:) = ptr_vj( zftv(:,:,:) )        ! 3.3  names
319         IF( jn == jp_sal)   str_ldf(:) = ptr_vj( zftv(:,:,:) )
320       ENDIF
321
322#if defined key_diaar5
323       IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
324          zztmp = 0.5 * rau0 * rcp 
325          z2d(:,:) = 0.e0 
326          DO jk = 1, jpkm1
327             DO jj = 2, jpjm1
328                DO ji = fs_2, fs_jpim1   ! vector opt.
329                   z2d(ji,jj) = z2d(ji,jj) + zztmp * zftu(ji,jj,jk)       &
330                        &       * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) * e1u(ji,jj) * fse3u(ji,jj,jk) 
331                END DO
332             END DO
333          END DO
334          CALL lbc_lnk( z2d, 'U', -1. )
335          CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
336          z2d(:,:) = 0.e0 
337          DO jk = 1, jpkm1
338             DO jj = 2, jpjm1
339                DO ji = fs_2, fs_jpim1   ! vector opt.
340                   z2d(ji,jj) = z2d(ji,jj) + zztmp * zftv(ji,jj,jk)       &
341                        &       * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) * e2v(ji,jj) * fse3v(ji,jj,jk) 
342                END DO
343             END DO
344          END DO
345          CALL lbc_lnk( z2d, 'V', -1. )
346          CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
347       END IF
348#endif
349       !
350    END DO
351    !
352  END SUBROUTINE tra_ldf_iso_grif
353
354#else
355   !!----------------------------------------------------------------------
356   !!   default option :   Dummy code   NO rotation of the diffusive tensor
357   !!----------------------------------------------------------------------
358CONTAINS
359   SUBROUTINE tra_ldf_iso_grif( kt )               ! Empty routine
360      WRITE(*,*) 'tra_ldf_iso: You should not have seen this print! error?', kt
361   END SUBROUTINE tra_ldf_iso_grif
362#endif
363
364   !!==============================================================================
365END MODULE traldf_iso_grif
Note: See TracBrowser for help on using the repository browser.