New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traqsr.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/TRA/traqsr.F90 @ 2326

Last change on this file since 2326 was 2326, checked in by cetlod, 13 years ago

correction of minor bugs on bio-optical retroaction when using PISCES

  • Property svn:keywords set to Id
File size: 26.5 KB
Line 
1MODULE traqsr
2   !!======================================================================
3   !!                       ***  MODULE  traqsr  ***
4   !! Ocean physics: solar radiation penetration in the top ocean levels
5   !!======================================================================
6   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
7   !!            7.0  !  1991-11  (G. Madec)
8   !!                 !  1996-01  (G. Madec)  s-coordinates
9   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
10   !!             -   !  2005-11  (G. Madec) zco, zps, sco coordinate
11   !!            3.2  !  2009-04  (G. Madec & NEMO team)
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_qsr      : trend due to the solar radiation penetration
16   !!   tra_qsr_init : solar radiation penetration initialization
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and active tracers
19   USE dom_oce         ! ocean space and time domain
20   USE sbc_oce         ! surface boundary condition: ocean
21   USE trc_oce         ! share SMS/Ocean variables
22   USE trdmod_oce      ! ocean variables trends
23   USE trdtra          ! ocean active tracers trends
24   USE in_out_manager  ! I/O manager
25   USE phycst          ! physical constants
26   USE prtctl          ! Print control
27   USE iom             ! I/O manager
28   USE fldread         ! read input fields
29   USE restart         ! ocean restart
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_qsr       ! routine called by step.F90 (ln_traqsr=T)
35   PUBLIC   tra_qsr_init  ! routine called by opa.F90
36
37   !                                           !!* Namelist namtra_qsr: penetrative solar radiation
38   LOGICAL , PUBLIC ::   ln_traqsr  = .TRUE.    !: light absorption (qsr) flag
39   LOGICAL , PUBLIC ::   ln_qsr_rgb = .FALSE.   !: Red-Green-Blue light absorption flag 
40   LOGICAL , PUBLIC ::   ln_qsr_2bd = .TRUE.    !: 2 band         light absorption flag
41   LOGICAL , PUBLIC ::   ln_qsr_bio = .FALSE.   !: bio-model      light absorption flag
42   INTEGER , PUBLIC ::   nn_chldta  = 0         !: use Chlorophyll data (=1) or not (=0)
43   REAL(wp), PUBLIC ::   rn_abs     = 0.58_wp   !: fraction absorbed in the very near surface (RGB & 2 bands)
44   REAL(wp), PUBLIC ::   rn_si0     = 0.35_wp   !: very near surface depth of extinction      (RGB & 2 bands)
45   REAL(wp), PUBLIC ::   rn_si1     = 23.0_wp   !: deepest depth of extinction (water type I)       (2 bands)
46   
47   ! Module variables
48   REAL(wp) ::   xsi0r                           !: inverse of rn_si0
49   REAL(wp) ::   xsi1r                           !: inverse of rn_si1
50!$AGRIF_DO_NOT_TREAT
51   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_chl   ! structure of input Chl (file informations, fields read)
52   INTEGER, PUBLIC ::   nksr              ! levels below which the light cannot penetrate ( depth larger than 391 m)
53   REAL(wp), DIMENSION(3,61) ::   rkrgb   !: tabulated attenuation coefficients for RGB absorption
54!$AGRIF_END_DO_NOT_TREAT
55
56   !! * Substitutions
57#  include "domzgr_substitute.h90"
58#  include "vectopt_loop_substitute.h90"
59   !!----------------------------------------------------------------------
60   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
61   !! $Id$
62   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
63   !!----------------------------------------------------------------------
64
65CONTAINS
66
67   SUBROUTINE tra_qsr( kt )
68      !!----------------------------------------------------------------------
69      !!                  ***  ROUTINE tra_qsr  ***
70      !!
71      !! ** Purpose :   Compute the temperature trend due to the solar radiation
72      !!      penetration and add it to the general temperature trend.
73      !!
74      !! ** Method  : The profile of the solar radiation within the ocean is defined
75      !!      through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs
76      !!      Considering the 2 wavebands case:
77      !!         I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) )
78      !!         The temperature trend associated with the solar radiation penetration
79      !!         is given by : zta = 1/e3t dk[ I ] / (rau0*Cp)
80      !!         At the bottom, boudary condition for the radiation is no flux :
81      !!      all heat which has not been absorbed in the above levels is put
82      !!      in the last ocean level.
83      !!         In z-coordinate case, the computation is only done down to the
84      !!      level where I(k) < 1.e-15 W/m2. In addition, the coefficients
85      !!      used for the computation are calculated one for once as they
86      !!      depends on k only.
87      !!
88      !! ** Action  : - update ta with the penetrative solar radiation trend
89      !!              - save the trend in ttrd ('key_trdtra')
90      !!
91      !! Reference  : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
92      !!              Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516.
93      !!----------------------------------------------------------------------
94      !!
95      INTEGER, INTENT(in) ::   kt     ! ocean time-step
96      !!
97      INTEGER  ::   ji, jj, jk           ! dummy loop indices
98      INTEGER  ::   irgb                 ! temporary integers
99      REAL(wp) ::   zchl, zcoef          ! temporary scalars
100      REAL(wp) ::   zc0, zc1, zc2, zc3   !    -         -
101      REAL(wp) ::   zz0, zz1             !    -         -
102      REAL(wp) ::   z1_e3t, zfact        !    -         -
103      REAL(wp), DIMENSION(jpi,jpj)     ::   zekb, zekg, zekr            ! 2D workspace
104      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ze0, ze1 , ze2, ze3, zea    ! 3D workspace
105      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::  ztrdt
106      !!----------------------------------------------------------------------
107
108      IF( kt == nit000 ) THEN
109         IF(lwp) WRITE(numout,*)
110         IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation'
111         IF(lwp) WRITE(numout,*) '~~~~~~~'
112         IF( .NOT.ln_traqsr )   RETURN
113      ENDIF
114
115      IF( l_trdtra ) THEN      ! Save ta and sa trends
116         ALLOCATE( ztrdt(jpi,jpj,jpk) )   ;    ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
117      ENDIF
118
119      !                                        Set before qsr tracer content field
120      !                                        ***********************************
121      IF( kt == nit000 ) THEN                     ! Set the forcing field at nit000 - 1
122         !                                        ! -----------------------------------
123         IF( ln_rstart .AND.    &                    ! Restart: read in restart file
124              & iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN
125            IF(lwp) WRITE(numout,*) '          nit000-1 qsr tracer content forcing field red in the restart file'
126            zfact = 0.5e0
127            CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b )   ! before heat content trend due to Qsr flux
128         ELSE                                           ! No restart or restart not found: Euler forward time stepping
129            zfact = 1.e0
130            qsr_hc_b(:,:,:) = 0.e0
131         ENDIF
132      ELSE                                        ! Swap of forcing field
133         !                                        ! ---------------------
134         zfact = 0.5e0
135         qsr_hc_b(:,:,:) = qsr_hc(:,:,:)
136      ENDIF
137      !                                        Compute now qsr tracer content field
138      !                                        ************************************
139     
140      !                                           ! ============================================== !
141      IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN      !  bio-model fluxes  : all vertical coordinates  !
142         !                                        ! ============================================== !
143         DO jk = 1, jpkm1
144            qsr_hc(:,:,jk) = ro0cpr * ( etot3(:,:,jk) - etot3(:,:,jk+1) )
145         END DO
146         !                                        Add to the general trend
147         DO jk = 1, jpkm1
148            DO jj = 2, jpjm1 
149               DO ji = fs_2, fs_jpim1   ! vector opt.
150                  z1_e3t = zfact / fse3t(ji,jj,jk)
151                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
152               END DO
153            END DO
154         END DO
155         CALL iom_put( 'qsr3d', etot3 )   ! Shortwave Radiation 3D distribution
156         !                                        ! ============================================== !
157      ELSE                                        !  Ocean alone :
158         !                                        ! ============================================== !
159         !
160         !                                                ! ------------------------- !
161         IF( ln_qsr_rgb) THEN                             !  R-G-B  light penetration !
162            !                                             ! ------------------------- !
163            ! Set chlorophyl concentration
164            IF( nn_chldta == 1 .OR. lk_vvl ) THEN            !*  Variable Chlorophyll or ocean volume
165               !
166               IF( nn_chldta == 1 ) THEN                             !*  Variable Chlorophyll
167                  !
168                  CALL fld_read( kt, 1, sf_chl )                         ! Read Chl data and provides it at the current time step
169                  !         
170!CDIR COLLAPSE
171!CDIR NOVERRCHK
172                  DO jj = 1, jpj                                         ! Separation in R-G-B depending of the surface Chl
173!CDIR NOVERRCHK
174                     DO ji = 1, jpi
175                        zchl = MIN( 10. , MAX( 0.03, sf_chl(1)%fnow(ji,jj,1) ) )
176                        irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
177                        zekb(ji,jj) = rkrgb(1,irgb)
178                        zekg(ji,jj) = rkrgb(2,irgb)
179                        zekr(ji,jj) = rkrgb(3,irgb)
180                     END DO
181                  END DO
182               ELSE                                            ! Variable ocean volume but constant chrlorophyll
183                  zchl = 0.05                                     ! constant chlorophyll
184                  irgb = NINT( 41 + 20.*LOG10( zchl ) + 1.e-15 )
185                  zekb(:,:) = rkrgb(1,irgb)                       ! Separation in R-G-B depending of the chlorophyll
186                  zekg(:,:) = rkrgb(2,irgb)
187                  zekr(:,:) = rkrgb(3,irgb)
188               ENDIF
189               !
190               zcoef  = ( 1. - rn_abs ) / 3.e0                        ! equi-partition in R-G-B
191               ze0(:,:,1) = rn_abs  * qsr(:,:)
192               ze1(:,:,1) = zcoef * qsr(:,:)
193               ze2(:,:,1) = zcoef * qsr(:,:)
194               ze3(:,:,1) = zcoef * qsr(:,:)
195               zea(:,:,1) =         qsr(:,:)
196               !
197               DO jk = 2, nksr+1
198!CDIR NOVERRCHK
199                  DO jj = 1, jpj
200!CDIR NOVERRCHK   
201                     DO ji = 1, jpi
202                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r     )
203                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) )
204                        zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) )
205                        zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) )
206                        ze0(ji,jj,jk) = zc0
207                        ze1(ji,jj,jk) = zc1
208                        ze2(ji,jj,jk) = zc2
209                        ze3(ji,jj,jk) = zc3
210                        zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
211                     END DO
212                  END DO
213               END DO
214               !
215               DO jk = 1, nksr                                        ! compute and add qsr trend to ta
216                  qsr_hc(:,:,jk) = ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) )
217               END DO
218               zea(:,:,nksr+1:jpk) = 0.e0     ! below 400m set to zero
219               CALL iom_put( 'qsr3d', zea )   ! Shortwave Radiation 3D distribution
220               !
221            ELSE                                                 !*  Constant Chlorophyll
222               DO jk = 1, nksr
223                  qsr_hc(:,:,jk) =  etot3(:,:,jk) * qsr(:,:)
224               END DO
225            ENDIF
226
227         ENDIF
228         !                                                ! ------------------------- !
229         IF( ln_qsr_2bd ) THEN                            !  2 band light penetration !
230            !                                             ! ------------------------- !
231            !
232            IF( lk_vvl ) THEN                                  !* variable volume
233               zz0   =        rn_abs   * ro0cpr
234               zz1   = ( 1. - rn_abs ) * ro0cpr
235               DO jk = 1, nksr                    ! solar heat absorbed at T-point in the top 400m
236                  DO jj = 2, jpjm1
237                     DO ji = 2, jpim1
238                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
239                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
240                        qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0*tmask(ji,jj,jk) - zc1*tmask(ji,jj,jk+1) ) 
241                     END DO
242                  END DO
243               END DO
244            ELSE                                               !* constant volume: coef. computed one for all
245               DO jk = 1, nksr
246                  DO jj = 2, jpjm1
247                     DO ji = fs_2, fs_jpim1   ! vector opt.
248                        qsr_hc(ji,jj,jk) =  etot3(ji,jj,jk) * qsr(ji,jj)
249                     END DO
250                  END DO
251               END DO
252               !
253            ENDIF
254            !
255         ENDIF
256         !
257         !                                        Add to the general trend
258         DO jk = 1, nksr
259            DO jj = 2, jpjm1 
260               DO ji = fs_2, fs_jpim1   ! vector opt.
261                  z1_e3t = zfact / fse3t(ji,jj,jk)
262                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
263               END DO
264            END DO
265         END DO
266         !
267      ENDIF
268      !
269      IF( lrst_oce ) THEN   !                  Write in the ocean restart file
270         !                                     *******************************
271         IF(lwp) WRITE(numout,*)
272         IF(lwp) WRITE(numout,*) 'qsr tracer content forcing field written in ocean restart file ',   &
273            &                    'at it= ', kt,' date= ', ndastp
274         IF(lwp) WRITE(numout,*) '~~~~'
275         CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b', qsr_hc )
276         !
277      ENDIF
278
279      IF( l_trdtra ) THEN     ! qsr tracers trends saved for diagnostics
280         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
281         CALL trd_tra( kt, 'TRA', jp_tem, jptra_trd_qsr, ztrdt )
282         DEALLOCATE( ztrdt )
283      ENDIF
284      !                       ! print mean trends (used for debugging)
285      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' qsr  - Ta: ', mask1=tmask, clinfo3='tra-ta' )
286      !
287   END SUBROUTINE tra_qsr
288
289
290   SUBROUTINE tra_qsr_init
291      !!----------------------------------------------------------------------
292      !!                  ***  ROUTINE tra_qsr_init  ***
293      !!
294      !! ** Purpose :   Initialization for the penetrative solar radiation
295      !!
296      !! ** Method  :   The profile of solar radiation within the ocean is set
297      !!      from two length scale of penetration (rn_si0,rn_si1) and a ratio
298      !!      (rn_abs). These parameters are read in the namtra_qsr namelist. The
299      !!      default values correspond to clear water (type I in Jerlov'
300      !!      (1968) classification.
301      !!         called by tra_qsr at the first timestep (nit000)
302      !!
303      !! ** Action  : - initialize rn_si0, rn_si1 and rn_abs
304      !!
305      !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
306      !!----------------------------------------------------------------------
307      INTEGER  ::   ji, jj, jk            ! dummy loop indices
308      INTEGER  ::   irgb, ierror          ! temporary integer
309      INTEGER  ::   ioptio, nqsr          ! temporary integer
310      REAL(wp) ::   zc0  , zc1, zcoef     ! temporary scalars
311      REAL(wp) ::   zc2  , zc3  , zchl    !    -         -
312      REAL(wp) ::   zz0  , zz1            !    -         -
313      REAL(wp), DIMENSION(jpi,jpj)     ::   zekb, zekg, zekr              ! 2D workspace
314      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ze0 , ze1 , ze2 , ze3 , zea   ! 3D workspace
315      !!
316      CHARACTER(len=100) ::   cn_dir   ! Root directory for location of ssr files
317      TYPE(FLD_N)        ::   sn_chl   ! informations about the chlorofyl field to be read
318      NAMELIST/namtra_qsr/  sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio,   &
319         &                  nn_chldta, rn_abs, rn_si0, rn_si1
320      !!----------------------------------------------------------------------
321
322      cn_dir = './'       ! directory in which the model is executed
323      ! ... default values (NB: frequency positive => hours, negative => months)
324      !            !     file       ! frequency !  variable  ! time interp !  clim   ! 'yearly' or ! weights  ! rotation   !
325      !            !     name       !  (hours)  !    name    !    (T/F)    !  (T/F)  ! 'monthly'   ! filename ! pairs      !
326      sn_chl = FLD_N( 'chlorophyll' ,    -1     ,  'CHLA'    ,  .true.     , .true.  ,   'yearly'  , ''       , ''         )
327      !
328      REWIND( numnam )            ! Read Namelist namtra_qsr : ratio and length of penetration
329      READ  ( numnam, namtra_qsr )
330      !
331      IF(lwp) THEN                ! control print
332         WRITE(numout,*)
333         WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation'
334         WRITE(numout,*) '~~~~~~~~~~~~'
335         WRITE(numout,*) '   Namelist namtra_qsr : set the parameter of penetration'
336         WRITE(numout,*) '      Light penetration (T) or not (F)         ln_traqsr  = ', ln_traqsr
337         WRITE(numout,*) '      RGB (Red-Green-Blue) light penetration   ln_qsr_rgb = ', ln_qsr_rgb
338         WRITE(numout,*) '      2 band               light penetration   ln_qsr_2bd = ', ln_qsr_2bd
339         WRITE(numout,*) '      bio-model            light penetration   ln_qsr_bio = ', ln_qsr_bio
340         WRITE(numout,*) '      RGB : Chl data (=1) or cst value (=0)    nn_chldta  = ', nn_chldta
341         WRITE(numout,*) '      RGB & 2 bands: fraction of light (rn_si1)    rn_abs = ', rn_abs
342         WRITE(numout,*) '      RGB & 2 bands: shortess depth of extinction  rn_si0 = ', rn_si0
343         WRITE(numout,*) '      2 bands: longest depth of extinction         rn_si1 = ', rn_si1
344      ENDIF
345
346      IF( ln_traqsr ) THEN     ! control consistency
347         !                     
348         IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio )   THEN
349            CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' )
350            ln_qsr_bio = .FALSE.
351         ENDIF
352         !
353         ioptio = 0                      ! Parameter control
354         IF( ln_qsr_rgb  )   ioptio = ioptio + 1
355         IF( ln_qsr_2bd  )   ioptio = ioptio + 1
356         IF( ln_qsr_bio  )   ioptio = ioptio + 1
357         !
358         IF( ioptio /= 1 ) &
359            CALL ctl_stop( '          Choose ONE type of light penetration in namelist namtra_qsr',  &
360            &              ' 2 bands, 3 RGB bands or bio-model light penetration' )
361         !
362         IF( ln_qsr_rgb .AND. nn_chldta == 0 )   nqsr =  1 
363         IF( ln_qsr_rgb .AND. nn_chldta == 1 )   nqsr =  2
364         IF( ln_qsr_2bd                      )   nqsr =  3
365         IF( ln_qsr_bio                      )   nqsr =  4
366         !
367         IF(lwp) THEN                   ! Print the choice
368            WRITE(numout,*)
369            IF( nqsr ==  1 )   WRITE(numout,*) '         R-G-B   light penetration - Constant Chlorophyll'
370            IF( nqsr ==  2 )   WRITE(numout,*) '         R-G-B   light penetration - Chl data '
371            IF( nqsr ==  3 )   WRITE(numout,*) '         2 bands light penetration'
372            IF( nqsr ==  4 )   WRITE(numout,*) '         bio-model light penetration'
373         ENDIF
374         !
375      ENDIF
376      !                          ! ===================================== !
377      IF( ln_traqsr  ) THEN      !  Initialisation of Light Penetration  ! 
378         !                       ! ===================================== !
379         !
380         xsi0r = 1.e0 / rn_si0
381         xsi1r = 1.e0 / rn_si1
382         !                                ! ---------------------------------- !
383         IF( ln_qsr_rgb ) THEN            !  Red-Green-Blue light penetration  !
384            !                             ! ---------------------------------- !
385            !
386            CALL trc_oce_rgb( rkrgb )           !* tabulated attenuation coef.
387            !
388            !                                   !* level of light extinction
389            IF(  ln_sco ) THEN   ;   nksr = jpkm1
390            ELSE                 ;   nksr = trc_oce_ext_lev( r_si2, 0.33e2 )
391            ENDIF
392
393            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m'
394            !
395            IF( nn_chldta == 1 ) THEN           !* Chl data : set sf_chl structure
396               IF(lwp) WRITE(numout,*)
397               IF(lwp) WRITE(numout,*) '        Chlorophyll read in a file'
398               ALLOCATE( sf_chl(1), STAT=ierror )
399               IF( ierror > 0 ) THEN
400                  CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' )   ;   RETURN
401               ENDIF
402               ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1)   )
403               IF( sn_chl%ln_tint )ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) )
404               !                                        ! fill sf_chl with sn_chl and control print
405               CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init',   &
406                  &                                         'Solar penetration function of read chlorophyll', 'namtra_qsr' )
407               !
408            ELSE                                !* constant Chl : compute once for all the distribution of light (etot3)
409               IF(lwp) WRITE(numout,*)
410               IF(lwp) WRITE(numout,*) '        Constant Chlorophyll concentration = 0.05'
411               IF( lk_vvl ) THEN                   ! variable volume
412                  IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
413               ELSE                                ! constant volume: computes one for all
414                  IF(lwp) WRITE(numout,*) '        fixed volume: light distribution computed one for all'
415                  !
416                  zchl = 0.05                                 ! constant chlorophyll
417                  irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
418                  zekb(:,:) = rkrgb(1,irgb)                   ! Separation in R-G-B depending of the chlorophyll
419                  zekg(:,:) = rkrgb(2,irgb)
420                  zekr(:,:) = rkrgb(3,irgb)
421                  !
422                  zcoef = ( 1. - rn_abs ) / 3.e0              ! equi-partition in R-G-B
423                  ze0(:,:,1) = rn_abs
424                  ze1(:,:,1) = zcoef
425                  ze2(:,:,1) = zcoef 
426                  ze3(:,:,1) = zcoef
427                  zea(:,:,1) = tmask(:,:,1)                   ! = ( ze0+ze1+z2+ze3 ) * tmask
428               
429                  DO jk = 2, nksr+1
430!CDIR NOVERRCHK
431                     DO jj = 1, jpj
432!CDIR NOVERRCHK   
433                        DO ji = 1, jpi
434                           zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * xsi0r     )
435                           zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekb(ji,jj) )
436                           zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekg(ji,jj) )
437                           zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekr(ji,jj) )
438                           ze0(ji,jj,jk) = zc0
439                           ze1(ji,jj,jk) = zc1
440                           ze2(ji,jj,jk) = zc2
441                           ze3(ji,jj,jk) = zc3
442                           zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
443                        END DO
444                     END DO
445                  END DO 
446                  !
447                  DO jk = 1, nksr
448                     etot3(:,:,jk) = ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) ) 
449                  END DO
450                  etot3(:,:,nksr+1:jpk) = 0.e0                ! below 400m set to zero
451               ENDIF
452            ENDIF
453            !
454         ENDIF
455            !                             ! ---------------------------------- !
456         IF( ln_qsr_2bd ) THEN            !    2 bands    light penetration    !
457            !                             ! ---------------------------------- !
458            !
459            !                                ! level of light extinction
460            nksr = trc_oce_ext_lev( rn_si1, 1.e2 )
461            IF(lwp) THEN
462               WRITE(numout,*)
463            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m'
464            ENDIF
465            !
466            IF( lk_vvl ) THEN                   ! variable volume
467               IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
468            ELSE                                ! constant volume: computes one for all
469               zz0 =        rn_abs   * ro0cpr
470               zz1 = ( 1. - rn_abs ) * ro0cpr
471               DO jk = 1, nksr                    !*  solar heat absorbed at T-point computed once for all
472                  DO jj = 1, jpj                              ! top 400 meters
473                     DO ji = 1, jpi
474                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
475                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
476                        etot3(ji,jj,jk) = (  zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1)  ) 
477                     END DO
478                  END DO
479               END DO
480               etot3(:,:,nksr+1:jpk) = 0.e0                   ! below 400m set to zero
481               !
482            ENDIF
483         ENDIF
484         !                       ! ===================================== !
485      ELSE                       !        No light penetration           !                   
486         !                       ! ===================================== !
487         IF(lwp) THEN
488            WRITE(numout,*)
489            WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration'
490            WRITE(numout,*) '~~~~~~~~~~~~'
491         ENDIF
492      ENDIF
493      !
494   END SUBROUTINE tra_qsr_init
495
496   !!======================================================================
497END MODULE traqsr
Note: See TracBrowser for help on using the repository browser.