New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zpshde.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/TRA/zpshde.F90 @ 2281

Last change on this file since 2281 was 2281, checked in by smasson, 14 years ago

set proper svn properties to all files...
  • Property svn:keywords set to Id
File size: 11.7 KB
Line 
1MODULE zpshde
2   !!==============================================================================
3   !!                       ***  MODULE zpshde   ***
4   !! z-coordinate - partial step : Horizontal Derivative
5   !!==============================================================================
6   !! History :  OPA  !  2002-04  (A. Bozec)  Original code
7   !!            8.5  !  2002-08  (G. Madec E. Durand)  Optimization and Free form
8   !!   NEMO     1.0  !  2004-03  (C. Ethe)  adapted for passive tracers
9   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
10   !!==============================================================================
11   
12   !!----------------------------------------------------------------------
13   !!   zps_hde      :  Horizontal DErivative of T, S and rd at the last
14   !!                   ocean level (Z-coord. with Partial Steps)
15   !!----------------------------------------------------------------------
16   USE dom_oce         ! ocean space domain variables
17   USE oce             ! ocean dynamics and tracers variables
18   USE phycst          ! physical constants
19   USE in_out_manager  ! I/O manager
20   USE eosbn2          ! ocean equation of state
21   USE lbclnk          ! lateral boundary conditions (or mpp link)
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   zps_hde        ! routine called by step.F90
27   PUBLIC   zps_hde_init   ! routine called by opa.F90
28
29   INTEGER, DIMENSION(jpi,jpj) ::   mbatu, mbatv   ! bottom ocean level index at U- and V-points
30
31   !! * Substitutions
32#  include "domzgr_substitute.h90"
33#  include "vectopt_loop_substitute.h90"
34   !!----------------------------------------------------------------------
35   !! NEMO/OPA 3.3 , LOCEAN-IPSL (2010)
36   !! $Id$
37   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
38   !!----------------------------------------------------------------------
39CONTAINS
40
41   SUBROUTINE zps_hde( kt, kjpt, pta, pgtu, pgtv,   &
42                                 prd, pgru, pgrv    )
43      !!----------------------------------------------------------------------
44      !!                     ***  ROUTINE zps_hde  ***
45      !!                   
46      !! ** Purpose :   Compute the horizontal derivative of T, S and rd
47      !!      at u- and v-points with a linear interpolation for z-coordinate
48      !!      with partial steps.
49      !!
50      !! ** Method  :   In z-coord with partial steps, scale factors on last
51      !!      levels are different for each grid point, so that T, S and rd
52      !!      points are not at the same depth as in z-coord. To have horizontal
53      !!      gradients again, we interpolate T and S at the good depth :
54      !!      Linear interpolation of T, S   
55      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
56      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
57      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
58      !!         This formulation computes the two cases:
59      !!                 CASE 1                   CASE 2 
60      !!         k-1  ___ ___________   k-1   ___ ___________
61      !!                    Ti  T~                  T~  Ti+1
62      !!                  _____                        _____
63      !!         k        |   |Ti+1     k           Ti |   |
64      !!                  |   |____                ____|   |
65      !!              ___ |   |   |           ___  |   |   |
66      !!                 
67      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
68      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
69      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
70      !!          or
71      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
72      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
73      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
74      !!          Idem for di(s) and dj(s)         
75      !!
76      !!      For rho, we call eos_insitu_2d which will compute rd~(t~,s~) at
77      !!      the good depth zh from interpolated T and S for the different
78      !!      formulation of the equation of state (eos).
79      !!      Gradient formulation for rho :
80      !!          di(rho) = rd~ - rd(i,j,k) or rd (i+1,j,k) - rd~
81      !!
82      !! ** Action  : - pgtu, pgtv: horizontal gradient of tracer at U/V-points
83      !!              - pgru, pgrv: horizontal gradient of rd if present at U/V-points
84      !!                and rd at V-points
85      !!----------------------------------------------------------------------
86      INTEGER                              , INTENT(in   )           ::  kt          ! ocean time-step index
87      INTEGER                              , INTENT(in   )           ::  kjpt        ! number of tracers
88      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta         ! 4D tracers fields
89      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
90      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd         ! 3D density anomaly fields
91      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv  ! hor. grad. of prd at u- & v-pts
92      !!
93      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
94      INTEGER  ::   iku, ikv        ! partial step level at u- and v-points
95      REAL(wp), DIMENSION(jpi,jpj,kjpt) ::   zti, ztj     ! interpolated value of tracer
96      REAL(wp), DIMENSION(jpi,jpj)      ::   zri, zrj     ! interpolated value of rd
97      REAL(wp), DIMENSION(jpi,jpj)      ::   zhi, zhj     ! depth of interpolation for eos2d
98      REAL(wp) ::  ze3wu, ze3wv, zmaxu, zmaxv  ! temporary scalars
99      !!----------------------------------------------------------------------
100
101
102      ! Interpolation of tracers at the last ocean level
103      DO jn = 1, kjpt
104         !
105# if defined key_vectopt_loop
106         jj = 1
107         DO ji = 1, jpij-jpi   ! vector opt. (forced unrolled)
108# else
109         DO jj = 1, jpjm1
110            DO ji = 1, jpim1
111# endif
112               ! last level
113               iku = mbatu(ji,jj)
114               ikv = mbatv(ji,jj)
115               ze3wu  = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
116               ze3wv  = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
117
118               ! i- direction
119               IF( ze3wu >= 0. ) THEN      ! case 1
120                  zmaxu =  ze3wu / fse3w(ji+1,jj,iku)
121                  ! interpolated values of tracers
122                  zti(ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,iku-1,jn) - pta(ji+1,jj,iku,jn) )
123                  ! gradient of  tracers
124                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
125               ELSE                        ! case 2
126                  zmaxu = -ze3wu / fse3w(ji,jj,iku)
127                  ! interpolated values of tracers
128                  zti(ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,iku-1,jn) - pta(ji,jj,iku,jn) )
129                  ! gradient of tracers
130                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
131               ENDIF
132
133               ! j- direction
134               IF( ze3wv >= 0. ) THEN      ! case 1
135                  zmaxv =  ze3wv / fse3w(ji,jj+1,ikv)
136                  ! interpolated values of tracers
137                  ztj(ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikv-1,jn) - pta(ji,jj+1,ikv,jn) )
138                  ! gradient of tracers
139                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
140               ELSE                        ! case 2
141                  zmaxv =  -ze3wv / fse3w(ji,jj,ikv)
142                  ! interpolated values of tracers
143                  ztj(ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikv-1,jn) - pta(ji,jj,ikv,jn) )
144                  ! gradient of tracers
145                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
146               ENDIF
147# if ! defined key_vectopt_loop
148            END DO
149# endif
150         END DO
151         CALL lbc_lnk( pgtu(:,:,jn), 'U', -1. )   ;   CALL lbc_lnk( pgtv(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
152         !
153      END DO
154
155      ! horizontal derivative of density anomalies (rd)
156      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
157# if defined key_vectopt_loop
158         jj = 1
159         DO ji = 1, jpij-jpi   ! vector opt. (forced unrolled)
160# else
161         DO jj = 1, jpjm1
162            DO ji = 1, jpim1
163# endif
164               iku = mbatu(ji,jj)
165               ikv = mbatv(ji,jj)
166               ze3wu  = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
167               ze3wv  = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
168               IF( ze3wu >= 0. ) THEN   
169                  zhi(ji,jj) = fsdept(ji  ,jj,iku)
170               ELSE                   
171                  zhi(ji,jj) = fsdept(ji+1,jj,iku)
172               ENDIF
173               IF( ze3wv >= 0. ) THEN 
174                  zhj(ji,jj) = fsdept(ji,jj  ,ikv)
175               ELSE                   
176                  zhj(ji,jj) = fsdept(ji,jj+1,ikv)
177               ENDIF
178# if ! defined key_vectopt_loop
179            END DO
180# endif
181         END DO
182
183         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
184         ! step and store it in  zri, zrj for each  case
185         CALL eos( zti, zhi, zri )   ;   CALL eos( ztj, zhj, zrj )
186
187         ! Gradient of density at the last level
188# if defined key_vectopt_loop
189         jj = 1
190         DO ji = 1, jpij-jpi   ! vector opt. (forced unrolled)
191# else
192         DO jj = 1, jpjm1
193            DO ji = 1, jpim1
194# endif
195               iku = mbatu(ji,jj)
196               ikv = mbatv(ji,jj)
197               ze3wu  = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
198               ze3wv  = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
199               IF( ze3wu >= 0. ) THEN    ! i-direction: case 1
200                  pgru(ji,jj) = umask(ji,jj,1) * ( zri(ji,jj) - prd(ji,jj,iku) )
201               ELSE                      ! i-direction: case 2
202                  pgru(ji,jj) = umask(ji,jj,1) * ( prd(ji+1,jj,iku) - zri(ji,jj) )
203               ENDIF
204               IF( ze3wv >= 0. ) THEN    ! j-direction: case 1
205                  pgrv(ji,jj) = vmask(ji,jj,1) * ( zrj(ji,jj) - prd(ji,jj,ikv) )
206               ELSE                      ! j-direction: case 2
207                  pgrv(ji,jj) = vmask(ji,jj,1) * ( prd(ji,jj+1,ikv) - zrj(ji,jj) )
208               ENDIF
209# if ! defined key_vectopt_loop
210            END DO
211# endif
212         END DO
213         CALL lbc_lnk( pgru , 'U', -1. )   ;   CALL lbc_lnk( pgrv , 'V', -1. )   ! Lateral boundary conditions
214         !
215      END IF
216      !
217   END SUBROUTINE zps_hde
218
219
220   SUBROUTINE zps_hde_init
221      !!----------------------------------------------------------------------
222      !!                     ***  ROUTINE zps_hde_init  ***
223      !!
224      !! ** Purpose : Computation of bottom ocean level index at U- and V-points
225      !!                   
226      !!----------------------------------------------------------------------
227      INTEGER ::   ji, jj   ! Dummy loop indices
228      REAL(wp), DIMENSION(jpi,jpj) ::   zti, ztj     ! 2D workspace
229      !!----------------------------------------------------------------------
230      !
231      mbatu(:,:) = 0
232      mbatv(:,:) = 0
233      DO jj = 1, jpjm1
234         DO ji = 1, fs_jpim1   ! vector opt.
235            mbatu(ji,jj) = MAX( MIN( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1, 2 )
236            mbatv(ji,jj) = MAX( MIN( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1, 2 )
237         END DO
238      END DO
239      zti(:,:) = FLOAT( mbatu(:,:) )
240      ztj(:,:) = FLOAT( mbatv(:,:) )
241      ! lateral boundary conditions: T-point, sign unchanged
242      CALL lbc_lnk( zti , 'U', 1. )   ;   CALL lbc_lnk( ztj , 'V', 1. )
243      mbatu(:,:) = MAX( INT( zti(:,:) ), 2 )
244      mbatv(:,:) = MAX( INT( ztj(:,:) ), 2 )
245      !
246   END SUBROUTINE zps_hde_init
247   !!======================================================================
248END MODULE zpshde
Note: See TracBrowser for help on using the repository browser.