New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfgls.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfgls.F90 @ 2497

Last change on this file since 2497 was 2497, checked in by gm, 13 years ago

v3.3beta: #780 zdfgls error in bottom friction formulation
  • Property svn:keywords set to Id
File size: 58.3 KB
Line 
1MODULE zdfgls
2   !!======================================================================
3   !!                       ***  MODULE  zdfgls  ***
4   !! Ocean physics:  vertical mixing coefficient computed from the gls
5   !!                 turbulent closure parameterization
6   !!======================================================================
7   !! History :   3.0  !  2009-09  (G. Reffray)  Original code
8   !!             3.3  !  2010-10  (C. Bricaud)  Add in the reference
9   !!----------------------------------------------------------------------
10#if defined key_zdfgls   ||   defined key_esopa
11   !!----------------------------------------------------------------------
12   !!   'key_zdfgls'                 Generic Length Scale vertical physics
13   !!----------------------------------------------------------------------
14   !!   zdf_gls      : update momentum and tracer Kz from a gls scheme
15   !!   zdf_gls_init : initialization, namelist read, and parameters control
16   !!   gls_rst      : read/write gls restart in ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! ocean space and time domain : variable volume layer
21   USE zdf_oce        ! ocean vertical physics
22   USE sbc_oce        ! surface boundary condition: ocean
23   USE phycst         ! physical constants
24   USE zdfmxl         ! mixed layer
25   USE restart        ! only for lrst_oce
26   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
27   USE prtctl         ! Print control
28   USE in_out_manager ! I/O manager
29   USE iom            ! I/O manager library
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   zdf_gls        ! routine called in step module
35   PUBLIC   zdf_gls_init   ! routine called in opa module
36   PUBLIC   gls_rst        ! routine called in step module
37
38   LOGICAL , PUBLIC, PARAMETER              ::   lk_zdfgls = .TRUE.  !: TKE vertical mixing flag
39   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   en                  !: now turbulent kinetic energy
40   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   mxln                !: now mixing length
41   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   zwall               !: wall function
42   REAL(wp), PUBLIC, DIMENSION(jpi,jpj)     ::   ustars2             !: Squared surface velocity scale at T-points
43   REAL(wp), PUBLIC, DIMENSION(jpi,jpj)     ::   ustarb2             !: Squared bottom  velocity scale at T-points
44
45   !                                         !!! ** Namelist  namzdf_gls  **
46   LOGICAL  ::   ln_crban      = .FALSE.      ! =T use Craig and Banner scheme
47   LOGICAL  ::   ln_length_lim = .FALSE.      ! use limit on the dissipation rate under stable stratification (Galperin et al. 1988)
48   LOGICAL  ::   ln_sigpsi     = .FALSE.      ! Activate Burchard (2003) modification for k-eps closure & wave breaking mixing
49   INTEGER  ::   nn_tkebc_surf = 0            ! TKE surface boundary condition (=0/1)
50   INTEGER  ::   nn_tkebc_bot  = 0            ! TKE bottom boundary condition (=0/1)
51   INTEGER  ::   nn_psibc_surf = 0            ! PSI surface boundary condition (=0/1)
52   INTEGER  ::   nn_psibc_bot  = 0            ! PSI bottom boundary condition (=0/1)
53   INTEGER  ::   nn_stab_func  = 0            ! stability functions G88, KC or Canuto (=0/1/2)
54   INTEGER  ::   nn_clos       = 0            ! closure 0/1/2/3 MY82/k-eps/k-w/gen
55   REAL(wp) ::   rn_clim_galp  = 0.53_wp      ! Holt 2008 value for k-eps: 0.267
56   REAL(wp) ::   rn_epsmin     = 1.e-12_wp    ! minimum value of dissipation (m2/s3)
57   REAL(wp) ::   rn_emin       = 1.e-6_wp     ! minimum value of TKE (m2/s2)
58   REAL(wp) ::   rn_charn      = 2.e+5_wp     ! Charnock constant for surface breaking waves mixing : 1400. (standard) or 2.e5 (Stacey value)
59   REAL(wp) ::   rn_crban      = 100._wp      ! Craig and Banner constant for surface breaking waves mixing
60
61   REAL(wp) ::   hsro          =  0.003_wp    ! Minimum surface roughness
62   REAL(wp) ::   hbro          =  0.003_wp    ! Bottom roughness (m)
63   REAL(wp) ::   rcm_sf        =  0.73_wp     ! Shear free turbulence parameters
64   REAL(wp) ::   ra_sf         = -2.0_wp      ! Must be negative -2 < ra_sf < -1
65   REAL(wp) ::   rl_sf         =  0.2_wp      ! 0 <rl_sf<vkarmn   
66   REAL(wp) ::   rghmin        = -0.28_wp
67   REAL(wp) ::   rgh0          =  0.0329_wp
68   REAL(wp) ::   rghcri        =  0.03_wp
69   REAL(wp) ::   ra1           =  0.92_wp
70   REAL(wp) ::   ra2           =  0.74_wp
71   REAL(wp) ::   rb1           = 16.60_wp
72   REAL(wp) ::   rb2           = 10.10_wp         
73   REAL(wp) ::   re2           =  1.33_wp         
74   REAL(wp) ::   rl1           =  0.107_wp
75   REAL(wp) ::   rl2           =  0.0032_wp
76   REAL(wp) ::   rl3           =  0.0864_wp
77   REAL(wp) ::   rl4           =  0.12_wp
78   REAL(wp) ::   rl5           = 11.9_wp
79   REAL(wp) ::   rl6           =  0.4_wp
80   REAL(wp) ::   rl7           =  0.0_wp
81   REAL(wp) ::   rl8           =  0.48_wp
82   REAL(wp) ::   rm1           =  0.127_wp
83   REAL(wp) ::   rm2           =  0.00336_wp
84   REAL(wp) ::   rm3           =  0.0906_wp
85   REAL(wp) ::   rm4           =  0.101_wp
86   REAL(wp) ::   rm5           = 11.2_wp
87   REAL(wp) ::   rm6           =  0.4_wp
88   REAL(wp) ::   rm7           =  0.0_wp
89   REAL(wp) ::   rm8           =  0.318_wp
90   
91   REAL(wp) ::   rc02, rc02r, rc03, rc04                          ! coefficients deduced from above parameters
92   REAL(wp) ::   rc03_sqrt2_galp                                  !     -           -           -        -
93   REAL(wp) ::   rsbc_tke1, rsbc_tke2, rsbc_tke3, rfact_tke       !     -           -           -        -
94   REAL(wp) ::   rsbc_psi1, rsbc_psi2, rsbc_psi3, rfact_psi       !     -           -           -        -
95   REAL(wp) ::   rsbc_mb  , rsbc_std , rsbc_zs                    !     -           -           -        -
96   REAL(wp) ::   rc0, rc2, rc3, rf6, rcff, rc_diff                !     -           -           -        -
97   REAL(wp) ::   rs0, rs1, rs2, rs4, rs5, rs6                     !     -           -           -        -
98   REAL(wp) ::   rd0, rd1, rd2, rd3, rd4, rd5                     !     -           -           -        -
99   REAL(wp) ::   rsc_tke, rsc_psi, rpsi1, rpsi2, rpsi3, rsc_psi0  !     -           -           -        -
100   REAL(wp) ::   rpsi3m, rpsi3p, rpp, rmm, rnn                    !     -           -           -        -
101
102   !! * Substitutions
103#  include "domzgr_substitute.h90"
104#  include "vectopt_loop_substitute.h90"
105   !!----------------------------------------------------------------------
106   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
107   !! $Id $
108   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
109   !!----------------------------------------------------------------------
110CONTAINS
111
112   SUBROUTINE zdf_gls( kt )
113      !!----------------------------------------------------------------------
114      !!                   ***  ROUTINE zdf_gls  ***
115      !!
116      !! ** Purpose :   Compute the vertical eddy viscosity and diffusivity
117      !!              coefficients using the GLS turbulent closure scheme.
118      !!----------------------------------------------------------------------
119      USE oce,     z_elem_a  =>   ua   ! use ua as workspace
120      USE oce,     z_elem_b  =>   va   ! use va as workspace
121      USE oce,     z_elem_c  =>   ta   ! use ta as workspace
122      USE oce,     psi       =>   sa   ! use sa as workspace
123      !
124      INTEGER, INTENT(in) ::   kt ! ocean time step
125      INTEGER  ::   ji, jj, jk, ibot, ibotm1, dir  ! dummy loop arguments
126      REAL(wp) ::   zesh2, zsigpsi, zcoef, zex1, zex2   ! local scalars
127      REAL(wp) ::   ztx2, zty2, zup, zdown, zcof        !   -      -
128      REAL(wp) ::   zratio, zrn2, zflxb, sh             !   -      -
129      REAL(wp) ::   prod, buoy, diss, zdiss, sm         !   -      -
130      REAL(wp) ::   gh, gm, shr, dif, zsqen, zav        !   -      -
131      REAL(wp), DIMENSION(jpi,jpj)     ::   zdep        !
132      REAL(wp), DIMENSION(jpi,jpj)     ::   zflxs       ! Turbulence fluxed induced by internal waves
133      REAL(wp), DIMENSION(jpi,jpj)     ::   zhsro       ! Surface roughness (surface waves)
134      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   eb          ! tke at time before
135      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   mxlb        ! mixing length at time before
136      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   shear       ! vertical shear
137      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   eps         ! dissipation rate
138      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zwall_psi   ! Wall function use in the wb case (ln_sigpsi.AND.ln_crban=T)
139      !!--------------------------------------------------------------------
140
141      ! Preliminary computing
142
143      ustars2 = 0._wp   ;   ustarb2 = 0._wp   ;   psi  = 0._wp   ;   zwall_psi = 0._wp
144
145      ! Compute surface and bottom friction at T-points
146!CDIR NOVERRCHK
147      DO jj = 2, jpjm1
148!CDIR NOVERRCHK
149         DO ji = fs_2, fs_jpim1   ! vector opt.
150            !
151            ! surface friction
152            ustars2(ji,jj) = rau0r * taum(ji,jj) * tmask(ji,jj,1)
153            !
154            ! bottom friction (explicit before friction)
155            ! Note that we chose here not to bound the friction as in dynbfr)
156            ztx2 = (  bfrua(ji,jj)  * ub(ji,jj,mbku(ji,jj)) + bfrua(ji-1,jj) * ub(ji-1,jj,mbku(ji-1,jj))  )   &
157               & * ( 1._wp - 0.5_wp * umask(ji,jj,1) * umask(ji-1,jj,1)  )
158            zty2 = (  bfrva(ji,jj)  * vb(ji,jj,mbkv(ji,jj)) + bfrva(ji,jj-1) * vb(ji,jj-1,mbkv(ji,jj-1))  )   &
159               & * ( 1._wp - 0.5_wp * vmask(ji,jj,1) * vmask(ji,jj-1,1)  )
160            ustarb2(ji,jj) = SQRT( ztx2 * ztx2 + zty2 * zty2 ) * tmask(ji,jj,1)
161         END DO
162      END DO 
163
164      ! In case of breaking surface waves mixing,
165      ! Compute surface roughness length according to Charnock formula:
166      IF( ln_crban ) THEN   ;   zhsro(:,:) = MAX(rsbc_zs * ustars2(:,:), hsro)
167      ELSE                  ;   zhsro(:,:) = hsro
168      ENDIF
169
170      ! Compute shear and dissipation rate
171      DO jk = 2, jpkm1
172         DO jj = 2, jpjm1
173            DO ji = fs_2, fs_jpim1   ! vector opt.
174               avmu(ji,jj,jk) = avmu(ji,jj,jk) * ( un(ji,jj,jk-1) - un(ji,jj,jk) )   &
175                  &                            * ( ub(ji,jj,jk-1) - ub(ji,jj,jk) )   &
176                  &                            / (  fse3uw_n(ji,jj,jk)               &
177                  &                            *    fse3uw_b(ji,jj,jk) )
178               avmv(ji,jj,jk) = avmv(ji,jj,jk) * ( vn(ji,jj,jk-1) - vn(ji,jj,jk) )   &
179                  &                            * ( vb(ji,jj,jk-1) - vb(ji,jj,jk) )   &
180                  &                            / (  fse3vw_n(ji,jj,jk)               &
181                  &                            *    fse3vw_b(ji,jj,jk) )
182               eps(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT(en(ji,jj,jk)) / mxln(ji,jj,jk)
183            END DO
184         END DO
185      END DO
186      !
187      ! Lateral boundary conditions (avmu,avmv) (sign unchanged)
188      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )
189
190      ! Save tke at before time step
191      eb  (:,:,:) = en  (:,:,:)
192      mxlb(:,:,:) = mxln(:,:,:)
193
194      IF( nn_clos == 0 ) THEN    ! Mellor-Yamada
195         DO jk = 2, jpkm1
196            DO jj = 2, jpjm1 
197               DO ji = fs_2, fs_jpim1   ! vector opt.
198                  zup   = mxln(ji,jj,jk) * fsdepw(ji,jj,mbkt(ji,jj)+1)
199                  zdown = vkarmn * fsdepw(ji,jj,jk) * ( -fsdepw(ji,jj,jk) + fsdepw(ji,jj,mbkt(ji,jj)+1) )
200                  zcoef = ( zup / MAX( zdown, rsmall ) )
201                  zwall (ji,jj,jk) = ( 1._wp + re2 * zcoef*zcoef ) * tmask(ji,jj,jk)
202               END DO
203            END DO
204         END DO
205      ENDIF
206
207      !!---------------------------------!!
208      !!   Equation to prognostic k      !!
209      !!---------------------------------!!
210      !
211      ! Now Turbulent kinetic energy (output in en)
212      ! -------------------------------
213      ! Resolution of a tridiagonal linear system by a "methode de chasse"
214      ! computation from level 2 to jpkm1  (e(1) computed after and e(jpk)=0 ).
215      ! The surface boundary condition are set after
216      ! The bottom boundary condition are also set after. In standard e(bottom)=0.
217      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
218      ! Warning : after this step, en : right hand side of the matrix
219
220      DO jk = 2, jpkm1
221         DO jj = 2, jpjm1
222            DO ji = fs_2, fs_jpim1   ! vector opt.
223               !
224               ! shear prod. at w-point weightened by mask
225               shear(ji,jj,jk) =  ( avmu(ji-1,jj,jk) + avmu(ji,jj,jk) ) / MAX( 1.e0 , umask(ji-1,jj,jk) + umask(ji,jj,jk) )   &
226                  &             + ( avmv(ji,jj-1,jk) + avmv(ji,jj,jk) ) / MAX( 1.e0 , vmask(ji,jj-1,jk) + vmask(ji,jj,jk) )
227               !
228               ! stratif. destruction
229               buoy = - avt(ji,jj,jk) * rn2(ji,jj,jk)
230               !
231               ! shear prod. - stratif. destruction
232               diss = eps(ji,jj,jk)
233               !
234               dir = 0.5_wp + SIGN( 0.5_wp, shear(ji,jj,jk) + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
235               !
236               zesh2 = dir*(shear(ji,jj,jk)+buoy)+(1._wp-dir)*shear(ji,jj,jk)          ! production term
237               zdiss = dir*(diss/en(ji,jj,jk))   +(1._wp-dir)*(diss-buoy)/en(ji,jj,jk) ! dissipation term
238               !
239               ! Compute a wall function from 1. to rsc_psi*zwall/rsc_psi0
240               ! Note that as long that Dirichlet boundary conditions are NOT set at the first and last levels (GOTM style)
241               ! there is no need to set a boundary condition for zwall_psi at the top and bottom boundaries.
242               ! Otherwise, this should be rsc_psi/rsc_psi0
243               IF( ln_sigpsi ) THEN
244                  zsigpsi = MIN( 1._wp, zesh2 / eps(ji,jj,jk) )     ! 0. <= zsigpsi <= 1.
245                  zwall_psi(ji,jj,jk) = rsc_psi / (  zsigpsi * rsc_psi + (1._wp-zsigpsi) * rsc_psi0 / MAX( zwall(ji,jj,jk), 1._wp )  )
246               ELSE
247                  zwall_psi(ji,jj,jk) = 1._wp
248               ENDIF
249               !
250               ! building the matrix
251               zcof = rfact_tke * tmask(ji,jj,jk)
252               !
253               ! lower diagonal
254               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
255                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
256               !
257               ! upper diagonal
258               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
259                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
260               !
261               ! diagonal
262               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
263                  &                       + rdt * zdiss * tmask(ji,jj,jk) 
264               !
265               ! right hand side in en
266               en(ji,jj,jk) = en(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
267            END DO
268         END DO
269      END DO
270      !
271      z_elem_b(:,:,jpk) = 1._wp
272      !
273      ! Set surface condition on zwall_psi (1 at the bottom)
274      IF( ln_sigpsi ) THEN
275         zcoef = rsc_psi / rsc_psi0
276         DO jj = 2, jpjm1
277            DO ji = fs_2, fs_jpim1   ! vector opt.
278               zwall_psi(ji,jj,1) = zcoef
279            END DO
280         END DO
281      ENDIF
282
283      ! Surface boundary condition on tke
284      ! ---------------------------------
285      !
286      SELECT CASE ( nn_tkebc_surf )
287      !
288      CASE ( 0 )             ! Dirichlet case
289         !
290         IF (ln_crban) THEN     ! Wave induced mixing case
291            !                      ! en(1) = q2(1) = 0.5 * (15.8 * Ccb)^(2/3) * u*^2
292            !                      ! balance between the production and the dissipation terms including the wave effect
293            en(:,:,1) = MAX( rsbc_tke1 * ustars2(:,:), rn_emin )
294            z_elem_a(:,:,1) = en(:,:,1)
295            z_elem_c(:,:,1) = 0._wp
296            z_elem_b(:,:,1) = 1._wp
297            !
298            ! one level below
299            en(:,:,2) = MAX( rsbc_tke1 * ustars2(:,:) * ( (zhsro(:,:)+fsdepw(:,:,2))/zhsro(:,:) )**ra_sf, rn_emin )
300            z_elem_a(:,:,2) = 0._wp
301            z_elem_c(:,:,2) = 0._wp
302            z_elem_b(:,:,2) = 1._wp
303            !
304         ELSE                   ! No wave induced mixing case
305            !                      ! en(1) = u*^2/C0^2  &  l(1)  = K*zs
306            !                      ! balance between the production and the dissipation terms
307            en(:,:,1) = MAX( rc02r * ustars2(:,:), rn_emin )
308            z_elem_a(:,:,1) = en(:,:,1) 
309            z_elem_c(:,:,1) = 0._wp
310            z_elem_b(:,:,1) = 1._wp
311            !
312            ! one level below
313            en(:,:,2) = MAX( rc02r * ustars2(:,:), rn_emin )
314            z_elem_a(:,:,2) = 0._wp
315            z_elem_c(:,:,2) = 0._wp
316            z_elem_b(:,:,2) = 1._wp
317            !
318         ENDIF
319         !
320      CASE ( 1 )             ! Neumann boundary condition on d(e)/dz
321         !
322         IF (ln_crban) THEN ! Shear free case: d(e)/dz= Fw
323            !
324            ! Dirichlet conditions at k=1 (Cosmetic)
325            en(:,:,1) = MAX( rsbc_tke1 * ustars2(:,:), rn_emin )
326            z_elem_a(:,:,1) = en(:,:,1)
327            z_elem_c(:,:,1) = 0._wp
328            z_elem_b(:,:,1) = 1._wp
329            ! at k=2, set de/dz=Fw
330            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
331            z_elem_a(:,:,2) = 0._wp       
332            zflxs(:,:) = rsbc_tke3 * ustars2(:,:)**1.5_wp * ( (zhsro(:,:)+fsdept(:,:,1) ) / zhsro(:,:) )**(1.5*ra_sf)
333            en(:,:,2) = en(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
334            !
335         ELSE                   ! No wave induced mixing case: d(e)/dz=0.
336            !
337            ! Dirichlet conditions at k=1 (Cosmetic)
338            en(:,:,1) = MAX( rc02r * ustars2(:,:), rn_emin )
339            z_elem_a(:,:,1) = en(:,:,1)
340            z_elem_c(:,:,1) = 0._wp
341            z_elem_b(:,:,1) = 1._wp
342            ! at k=2 set de/dz=0.:
343            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2)  ! Remove z_elem_a from z_elem_b
344            z_elem_a(:,:,2) = 0._wp
345            !
346         ENDIF
347         !
348      END SELECT
349
350      ! Bottom boundary condition on tke
351      ! --------------------------------
352      !
353      SELECT CASE ( nn_tkebc_bot )
354      !
355      CASE ( 0 )             ! Dirichlet
356         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = rn_lmin
357         !                      ! Balance between the production and the dissipation terms
358!CDIR NOVERRCHK
359         DO jj = 2, jpjm1
360!CDIR NOVERRCHK
361            DO ji = fs_2, fs_jpim1   ! vector opt.
362               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
363               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
364               !
365               ! Bottom level Dirichlet condition:
366               z_elem_a(ji,jj,ibot  ) = 0._wp
367               z_elem_c(ji,jj,ibot  ) = 0._wp
368               z_elem_b(ji,jj,ibot  ) = 1._wp
369               en(ji,jj,ibot  ) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
370               !
371               ! Just above last level, Dirichlet condition again
372               z_elem_a(ji,jj,ibotm1) = 0._wp
373               z_elem_c(ji,jj,ibotm1) = 0._wp
374               z_elem_b(ji,jj,ibotm1) = 1._wp
375               en(ji,jj,ibotm1) = MAX( rc02r * ustarb2(ji,jj), rn_emin ) 
376            END DO
377         END DO
378         !
379      CASE ( 1 )             ! Neumman boundary condition
380         !                     
381!CDIR NOVERRCHK
382         DO jj = 2, jpjm1
383!CDIR NOVERRCHK
384            DO ji = fs_2, fs_jpim1   ! vector opt.
385               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
386               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
387               !
388               ! Bottom level Dirichlet condition:
389               z_elem_a(ji,jj,ibot) = 0._wp
390               z_elem_c(ji,jj,ibot) = 0._wp
391               z_elem_b(ji,jj,ibot) = 1._wp
392               en(ji,jj,ibot) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
393               !
394               ! Just above last level: Neumann condition
395               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1)   ! Remove z_elem_c from z_elem_b
396               z_elem_c(ji,jj,ibotm1) = 0._wp
397            END DO
398         END DO
399         !
400      END SELECT
401
402      ! Matrix inversion (en prescribed at surface and the bottom)
403      ! ----------------------------------------------------------
404      !
405      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
406         DO jj = 2, jpjm1
407            DO ji = fs_2, fs_jpim1    ! vector opt.
408               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
409            END DO
410         END DO
411      END DO
412      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
413         DO jj = 2, jpjm1
414            DO ji = fs_2, fs_jpim1    ! vector opt.
415               z_elem_a(ji,jj,jk) = en(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
416            END DO
417         END DO
418      END DO
419      DO jk = jpk-1, 2, -1                         ! thrid recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
420         DO jj = 2, jpjm1
421            DO ji = fs_2, fs_jpim1    ! vector opt.
422               en(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * en(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
423            END DO
424         END DO
425      END DO
426      !                                            ! set the minimum value of tke
427      en(:,:,:) = MAX( en(:,:,:), rn_emin )
428     
429      !!----------------------------------------!!
430      !!   Solve prognostic equation for psi    !!
431      !!----------------------------------------!!
432
433      ! Set psi to previous time step value
434      !
435      SELECT CASE ( nn_clos )
436      !
437      CASE( 0 )               ! k-kl  (Mellor-Yamada)
438         DO jk = 2, jpkm1
439            DO jj = 2, jpjm1
440               DO ji = fs_2, fs_jpim1   ! vector opt.
441                  psi(ji,jj,jk)  = en(ji,jj,jk) * mxln(ji,jj,jk)
442               END DO
443            END DO
444         END DO
445         !
446      CASE( 1 )               ! k-eps
447         DO jk = 2, jpkm1
448            DO jj = 2, jpjm1
449               DO ji = fs_2, fs_jpim1   ! vector opt.
450                  psi(ji,jj,jk)  = eps(ji,jj,jk)
451               END DO
452            END DO
453         END DO
454         !
455      CASE( 2 )               ! k-w
456         DO jk = 2, jpkm1
457            DO jj = 2, jpjm1
458               DO ji = fs_2, fs_jpim1   ! vector opt.
459                  psi(ji,jj,jk)  = SQRT( en(ji,jj,jk) ) / ( rc0 * mxln(ji,jj,jk) )
460               END DO
461            END DO
462         END DO
463         !
464      CASE( 3 )               ! generic
465         DO jk = 2, jpkm1
466            DO jj = 2, jpjm1
467               DO ji = fs_2, fs_jpim1   ! vector opt.
468                  psi(ji,jj,jk)  = rc02 * en(ji,jj,jk) * mxln(ji,jj,jk)**rnn 
469               END DO
470            END DO
471         END DO
472         !
473      END SELECT
474      !
475      ! Now gls (output in psi)
476      ! -------------------------------
477      ! Resolution of a tridiagonal linear system by a "methode de chasse"
478      ! computation from level 2 to jpkm1  (e(1) already computed and e(jpk)=0 ).
479      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
480      ! Warning : after this step, en : right hand side of the matrix
481
482      DO jk = 2, jpkm1
483         DO jj = 2, jpjm1
484            DO ji = fs_2, fs_jpim1   ! vector opt.
485               !
486               ! psi / k
487               zratio = psi(ji,jj,jk) / eb(ji,jj,jk) 
488               !
489               ! psi3+ : stable : B=-KhN²<0 => N²>0 if rn2>0 dir = 1 (stable) otherwise dir = 0 (unstable)
490               dir = 0.5_wp + SIGN( 0.5_wp, rn2(ji,jj,jk) )
491               !
492               rpsi3 = dir * rpsi3m + ( 1._wp - dir ) * rpsi3p
493               !
494               ! shear prod. - stratif. destruction
495               prod = rpsi1 * zratio * shear(ji,jj,jk)
496               !
497               ! stratif. destruction
498               buoy = rpsi3 * zratio * (- avt(ji,jj,jk) * rn2(ji,jj,jk) )
499               !
500               ! shear prod. - stratif. destruction
501               diss = rpsi2 * zratio * zwall(ji,jj,jk) * eps(ji,jj,jk)
502               !
503               dir = 0.5_wp + SIGN( 0.5_wp, prod + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
504               !
505               zesh2 = dir * ( prod + buoy )          + (1._wp - dir ) * prod                        ! production term
506               zdiss = dir * ( diss / psi(ji,jj,jk) ) + (1._wp - dir ) * (diss-buoy) / psi(ji,jj,jk) ! dissipation term
507               !                                                       
508               ! building the matrix
509               zcof = rfact_psi * zwall_psi(ji,jj,jk) * tmask(ji,jj,jk)
510               ! lower diagonal
511               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
512                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
513               ! upper diagonal
514               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
515                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
516               ! diagonal
517               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
518                  &                       + rdt * zdiss * tmask(ji,jj,jk)
519               !
520               ! right hand side in psi
521               psi(ji,jj,jk) = psi(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
522            END DO
523         END DO
524      END DO
525      !
526      z_elem_b(:,:,jpk) = 1._wp
527
528      ! Surface boundary condition on psi
529      ! ---------------------------------
530      !
531      SELECT CASE ( nn_psibc_surf )
532      !
533      CASE ( 0 )             ! Dirichlet boundary conditions
534         !
535         IF( ln_crban ) THEN       ! Wave induced mixing case
536            !                      ! en(1) = q2(1) = 0.5 * (15.8 * Ccb)^(2/3) * u*^2
537            !                      ! balance between the production and the dissipation terms including the wave effect
538            zdep(:,:) = rl_sf * zhsro(:,:)
539            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
540            z_elem_a(:,:,1) = psi(:,:,1)
541            z_elem_c(:,:,1) = 0._wp
542            z_elem_b(:,:,1) = 1._wp
543            !
544            ! one level below
545            zex1 = (rmm*ra_sf+rnn)
546            zex2 = (rmm*ra_sf)
547            zdep(:,:) = ( (zhsro(:,:) + fsdepw(:,:,2))**zex1 ) / zhsro(:,:)**zex2
548            psi (:,:,2) = rsbc_psi1 * ustars2(:,:)**rmm * zdep(:,:) * tmask(:,:,1)
549            z_elem_a(:,:,2) = 0._wp
550            z_elem_c(:,:,2) = 0._wp
551            z_elem_b(:,:,2) = 1._wp
552            !
553         ELSE                   ! No wave induced mixing case
554            !                      ! en(1) = u*^2/C0^2  &  l(1)  = K*zs
555            !                      ! balance between the production and the dissipation terms
556            !
557            zdep(:,:) = vkarmn * zhsro(:,:)
558            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
559            z_elem_a(:,:,1) = psi(:,:,1)
560            z_elem_c(:,:,1) = 0._wp
561            z_elem_b(:,:,1) = 1._wp
562            !
563            ! one level below
564            zdep(:,:) = vkarmn * ( zhsro(:,:) + fsdepw(:,:,2) )
565            psi (:,:,2) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
566            z_elem_a(:,:,2) = 0._wp
567            z_elem_c(:,:,2) = 0._wp
568            z_elem_b(:,:,2) = 1.
569            !
570         ENDIF
571         !
572      CASE ( 1 )             ! Neumann boundary condition on d(psi)/dz
573         !
574         IF( ln_crban ) THEN     ! Wave induced mixing case
575            !
576            zdep(:,:) = rl_sf * zhsro(:,:)
577            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
578            z_elem_a(:,:,1) = psi(:,:,1)
579            z_elem_c(:,:,1) = 0._wp
580            z_elem_b(:,:,1) = 1._wp
581            !
582            ! Neumann condition at k=2
583            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
584            z_elem_a(:,:,2) = 0._wp
585            !
586            ! Set psi vertical flux at the surface:
587            zdep(:,:) = (zhsro(:,:) + fsdept(:,:,1))**(rmm*ra_sf+rnn-1._wp) / zhsro(:,:)**(rmm*ra_sf)
588            zflxs(:,:) = rsbc_psi3 * ( zwall_psi(:,:,1)*avm(:,:,1) + zwall_psi(:,:,2)*avm(:,:,2) ) & 
589               &                   * en(:,:,1)**rmm * zdep         
590            psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
591            !
592      ELSE                   ! No wave induced mixing
593            !
594            zdep(:,:) = vkarmn * zhsro(:,:)
595            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
596            z_elem_a(:,:,1) = psi(:,:,1)
597            z_elem_c(:,:,1) = 0._wp
598            z_elem_b(:,:,1) = 1._wp
599            !
600            ! Neumann condition at k=2
601            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
602            z_elem_a(ji,jj,2) = 0._wp
603            !
604            ! Set psi vertical flux at the surface:
605            zdep(:,:)  = zhsro(:,:) + fsdept(:,:,1)
606            zflxs(:,:) = rsbc_psi2 * ( avm(:,:,1) + avm(:,:,2) ) * en(:,:,1)**rmm * zdep**(rnn-1._wp)
607            psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
608            !     
609         ENDIF
610         !
611      END SELECT
612
613      ! Bottom boundary condition on psi
614      ! --------------------------------
615      !
616      SELECT CASE ( nn_psibc_bot )
617      !
618      CASE ( 0 )             ! Dirichlet
619         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = vkarmn * hbro
620         !                      ! Balance between the production and the dissipation terms
621!CDIR NOVERRCHK
622         DO jj = 2, jpjm1
623!CDIR NOVERRCHK
624            DO ji = fs_2, fs_jpim1   ! vector opt.
625               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
626               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
627               zdep(ji,jj) = vkarmn * hbro
628               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
629               z_elem_a(ji,jj,ibot) = 0._wp
630               z_elem_c(ji,jj,ibot) = 0._wp
631               z_elem_b(ji,jj,ibot) = 1._wp
632               !
633               ! Just above last level, Dirichlet condition again (GOTM like)
634               zdep(ji,jj) = vkarmn * ( hbro + fse3t(ji,jj,ibotm1) )
635               psi (ji,jj,ibotm1) = rc0**rpp * en(ji,jj,ibot  )**rmm * zdep(ji,jj)**rnn
636               z_elem_a(ji,jj,ibotm1) = 0._wp
637               z_elem_c(ji,jj,ibotm1) = 0._wp
638               z_elem_b(ji,jj,ibotm1) = 1._wp
639            END DO
640         END DO
641         !
642      CASE ( 1 )             ! Neumman boundary condition
643         !                     
644!CDIR NOVERRCHK
645         DO jj = 2, jpjm1
646!CDIR NOVERRCHK
647            DO ji = fs_2, fs_jpim1   ! vector opt.
648               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
649               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
650               !
651               ! Bottom level Dirichlet condition:
652               zdep(ji,jj) = vkarmn * hbro
653               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
654               !
655               z_elem_a(ji,jj,ibot) = 0._wp
656               z_elem_c(ji,jj,ibot) = 0._wp
657               z_elem_b(ji,jj,ibot) = 1._wp
658               !
659               ! Just above last level: Neumann condition with flux injection
660               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1) ! Remove z_elem_c from z_elem_b
661               z_elem_c(ji,jj,ibotm1) = 0.
662               !
663               ! Set psi vertical flux at the bottom:
664               zdep(ji,jj) = hbro + 0.5_wp*fse3t(ji,jj,ibotm1)
665               zflxb = rsbc_psi2 * ( avm(ji,jj,ibot) + avm(ji,jj,ibotm1) )   &
666                  &  * (0.5_wp*(en(ji,jj,ibot)+en(ji,jj,ibotm1)))**rmm * zdep(ji,jj)**(rnn-1._wp)
667               psi(ji,jj,ibotm1) = psi(ji,jj,ibotm1) + zflxb / fse3w(ji,jj,ibotm1)
668            END DO
669         END DO
670         !
671      END SELECT
672
673      ! Matrix inversion
674      ! ----------------
675      !
676      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
677         DO jj = 2, jpjm1
678            DO ji = fs_2, fs_jpim1    ! vector opt.
679               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
680            END DO
681         END DO
682      END DO
683      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
684         DO jj = 2, jpjm1
685            DO ji = fs_2, fs_jpim1    ! vector opt.
686               z_elem_a(ji,jj,jk) = psi(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
687            END DO
688         END DO
689      END DO
690      DO jk = jpk-1, 2, -1                         ! Third recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
691         DO jj = 2, jpjm1
692            DO ji = fs_2, fs_jpim1    ! vector opt.
693               psi(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * psi(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
694            END DO
695         END DO
696      END DO
697
698      ! Set dissipation
699      !----------------
700
701      SELECT CASE ( nn_clos )
702      !
703      CASE( 0 )               ! k-kl  (Mellor-Yamada)
704         DO jk = 1, jpkm1
705            DO jj = 2, jpjm1
706               DO ji = fs_2, fs_jpim1   ! vector opt.
707                  eps(ji,jj,jk) = rc03 * en(ji,jj,jk) * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / psi(ji,jj,jk)
708               END DO
709            END DO
710         END DO
711         !
712      CASE( 1 )               ! k-eps
713         DO jk = 1, jpkm1
714            DO jj = 2, jpjm1
715               DO ji = fs_2, fs_jpim1   ! vector opt.
716                  eps(ji,jj,jk) = psi(ji,jj,jk)
717               END DO
718            END DO
719         END DO
720         !
721      CASE( 2 )               ! k-w
722         DO jk = 1, jpkm1
723            DO jj = 2, jpjm1
724               DO ji = fs_2, fs_jpim1   ! vector opt.
725                  eps(ji,jj,jk) = rc04 * en(ji,jj,jk) * psi(ji,jj,jk) 
726               END DO
727            END DO
728         END DO
729         !
730      CASE( 3 )               ! generic
731         zcoef = rc0**( 3._wp  + rpp/rnn )
732         zex1  =      ( 1.5_wp + rmm/rnn )
733         zex2  = -1._wp / rnn
734         DO jk = 1, jpkm1
735            DO jj = 2, jpjm1
736               DO ji = fs_2, fs_jpim1   ! vector opt.
737                  eps(ji,jj,jk) = zcoef * en(ji,jj,jk)**zex1 * psi(ji,jj,jk)**zex2
738               END DO
739            END DO
740         END DO
741         !
742      END SELECT
743
744      ! Limit dissipation rate under stable stratification
745      ! --------------------------------------------------
746      DO jk = 1, jpkm1 ! Note that this set boundary conditions on mxln at the same time
747         DO jj = 2, jpjm1
748            DO ji = fs_2, fs_jpim1    ! vector opt.
749               ! limitation
750               eps(ji,jj,jk)  = MAX( eps(ji,jj,jk), rn_epsmin )
751               mxln(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / eps(ji,jj,jk)
752               ! Galperin criterium (NOTE : Not required if the proper value of C3 in stable cases is calculated)
753               zrn2 = MAX( rn2(ji,jj,jk), rsmall )
754               mxln(ji,jj,jk) = MIN(  rn_clim_galp * SQRT( 2._wp * en(ji,jj,jk) / zrn2 ), mxln(ji,jj,jk)  )
755            END DO
756         END DO
757      END DO 
758
759      !
760      ! Stability function and vertical viscosity and diffusivity
761      ! ---------------------------------------------------------
762      !
763      SELECT CASE ( nn_stab_func )
764      !
765      CASE ( 0 , 1 )             ! Galperin or Kantha-Clayson stability functions
766         DO jk = 2, jpkm1
767            DO jj = 2, jpjm1
768               DO ji = fs_2, fs_jpim1   ! vector opt.
769                  ! zcof =  l²/q²
770                  zcof = mxlb(ji,jj,jk) * mxlb(ji,jj,jk) / ( 2._wp*eb(ji,jj,jk) )
771                  ! Gh = -N²l²/q²
772                  gh = - rn2(ji,jj,jk) * zcof
773                  gh = MIN( gh, rgh0   )
774                  gh = MAX( gh, rghmin )
775                  ! Stability functions from Kantha and Clayson (if C2=C3=0 => Galperin)
776                  sh = ra2*( 1._wp-6._wp*ra1/rb1 ) / ( 1.-3.*ra2*gh*(6.*ra1+rb2*( 1._wp-rc3 ) ) )
777                  sm = ( rb1**(-1._wp/3._wp) + ( 18._wp*ra1*ra1 + 9._wp*ra1*ra2*(1._wp-rc2) )*sh*gh ) / (1._wp-9._wp*ra1*ra2*gh)
778                  !
779                  ! Store stability function in avmu and avmv
780                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
781                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
782               END DO
783            END DO
784         END DO
785         !
786      CASE ( 2, 3 )               ! Canuto stability functions
787         DO jk = 2, jpkm1
788            DO jj = 2, jpjm1
789               DO ji = fs_2, fs_jpim1   ! vector opt.
790                  ! zcof =  l²/q²
791                  zcof = mxlb(ji,jj,jk)*mxlb(ji,jj,jk) / ( 2._wp * eb(ji,jj,jk) )
792                  ! Gh = -N²l²/q²
793                  gh = - rn2(ji,jj,jk) * zcof
794                  gh = MIN( gh, rgh0   )
795                  gh = MAX( gh, rghmin )
796                  gh = gh * rf6
797                  ! Gm =  M²l²/q² Shear number
798                  shr = shear(ji,jj,jk) / MAX( avm(ji,jj,jk), rsmall )
799                  gm = MAX( shr * zcof , 1.e-10 )
800                  gm = gm * rf6
801                  gm = MIN ( (rd0 - rd1*gh + rd3*gh*gh) / (rd2-rd4*gh) , gm )
802                  ! Stability functions from Canuto
803                  rcff = rd0 - rd1*gh +rd2*gm + rd3*gh*gh - rd4*gh*gm + rd5*gm*gm
804                  sm = (rs0 - rs1*gh + rs2*gm) / rcff
805                  sh = (rs4 - rs5*gh + rs6*gm) / rcff
806                  !
807                  ! Store stability function in avmu and avmv
808                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
809                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
810               END DO
811            END DO
812         END DO
813         !
814      END SELECT
815
816      ! Boundary conditions on stability functions for momentum (Neumann):
817      ! Lines below are useless if GOTM style Dirichlet conditions are used
818      zcoef = rcm_sf / SQRT( 2._wp )
819      DO jj = 2, jpjm1
820         DO ji = fs_2, fs_jpim1   ! vector opt.
821            avmv(ji,jj,1) = zcoef
822         END DO
823      END DO
824      zcoef = rc0 / SQRT( 2._wp )
825      DO jj = 2, jpjm1
826         DO ji = fs_2, fs_jpim1   ! vector opt.
827            avmv(ji,jj,mbkt(ji,jj)+1) = zcoef
828         END DO
829      END DO
830
831      ! Compute diffusivities/viscosities
832      ! The computation below could be restrained to jk=2 to jpkm1 if GOTM style Dirichlet conditions are used
833      DO jk = 1, jpk
834         DO jj = 2, jpjm1
835            DO ji = fs_2, fs_jpim1   ! vector opt.
836               zsqen         = SQRT( 2._wp * en(ji,jj,jk) ) * mxln(ji,jj,jk)
837               zav           = zsqen * avmu(ji,jj,jk)
838               avt(ji,jj,jk) = MAX( zav, avtb(jk) )*tmask(ji,jj,jk) ! apply mask for zdfmxl routine
839               zav           = zsqen * avmv(ji,jj,jk)
840               avm(ji,jj,jk) = MAX( zav, avmb(jk) ) ! Note that avm is not masked at the surface and the bottom
841            END DO
842         END DO
843      END DO
844      !
845      ! Lateral boundary conditions (sign unchanged)
846      avt(:,:,1)  = 0._wp
847      CALL lbc_lnk( avm, 'W', 1. )   ;   CALL lbc_lnk( avt, 'W', 1. )
848
849      DO jk = 2, jpkm1            !* vertical eddy viscosity at u- and v-points
850         DO jj = 2, jpjm1
851            DO ji = fs_2, fs_jpim1   ! vector opt.
852               avmu(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji+1,jj  ,jk) ) * umask(ji,jj,jk)
853               avmv(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji  ,jj+1,jk) ) * vmask(ji,jj,jk)
854            END DO
855         END DO
856      END DO
857      avmu(:,:,1) = 0._wp             ;   avmv(:,:,1) = 0._wp                 ! set surface to zero
858      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )       ! Lateral boundary conditions
859
860      IF(ln_ctl) THEN
861         CALL prt_ctl( tab3d_1=en  , clinfo1=' gls  - e: ', tab3d_2=avt, clinfo2=' t: ', ovlap=1, kdim=jpk)
862         CALL prt_ctl( tab3d_1=avmu, clinfo1=' gls  - u: ', mask1=umask,                   &
863            &          tab3d_2=avmv, clinfo2=       ' v: ', mask2=vmask, ovlap=1, kdim=jpk )
864      ENDIF
865      !
866   END SUBROUTINE zdf_gls
867
868
869   SUBROUTINE zdf_gls_init
870      !!----------------------------------------------------------------------
871      !!                  ***  ROUTINE zdf_gls_init  ***
872      !!                     
873      !! ** Purpose :   Initialization of the vertical eddy diffivity and
874      !!      viscosity when using a gls turbulent closure scheme
875      !!
876      !! ** Method  :   Read the namzdf_gls namelist and check the parameters
877      !!      called at the first timestep (nit000)
878      !!
879      !! ** input   :   Namlist namzdf_gls
880      !!
881      !! ** Action  :   Increase by 1 the nstop flag is setting problem encounter
882      !!
883      !!----------------------------------------------------------------------
884      USE dynzdf_exp
885      USE trazdf_exp
886      !
887      INTEGER ::   jk    ! dummy loop indices
888      REAL(wp)::   zcr   ! local scalar
889      !!
890      NAMELIST/namzdf_gls/rn_emin, rn_epsmin, ln_length_lim, &
891         &            rn_clim_galp, ln_crban, ln_sigpsi,     &
892         &            rn_crban, rn_charn,                    &
893         &            nn_tkebc_surf, nn_tkebc_bot,           &
894         &            nn_psibc_surf, nn_psibc_bot,           &
895         &            nn_stab_func, nn_clos
896      !!----------------------------------------------------------
897
898      REWIND ( numnam )                !* Read Namelist namzdf_gls
899      READ   ( numnam, namzdf_gls )
900
901      IF(lwp) THEN                     !* Control print
902         WRITE(numout,*)
903         WRITE(numout,*) 'zdf_gls_init : gls turbulent closure scheme'
904         WRITE(numout,*) '~~~~~~~~~~~~'
905         WRITE(numout,*) '   Namelist namzdf_gls : set gls mixing parameters'
906         WRITE(numout,*) '      minimum value of en                           rn_emin       = ', rn_emin
907         WRITE(numout,*) '      minimum value of eps                          rn_epsmin     = ', rn_epsmin
908         WRITE(numout,*) '      Limit dissipation rate under stable stratif.  ln_length_lim = ', ln_length_lim
909         WRITE(numout,*) '      Galperin limit (Standard: 0.53, Holt: 0.26)   rn_clim_galp  = ', rn_clim_galp
910         WRITE(numout,*) '      TKE Surface boundary condition                nn_tkebc_surf = ', nn_tkebc_surf
911         WRITE(numout,*) '      TKE Bottom boundary condition                 nn_tkebc_bot  = ', nn_tkebc_bot
912         WRITE(numout,*) '      PSI Surface boundary condition                nn_psibc_surf = ', nn_psibc_surf
913         WRITE(numout,*) '      PSI Bottom boundary condition                 nn_psibc_bot  = ', nn_psibc_bot
914         WRITE(numout,*) '      Craig and Banner scheme                       ln_crban      = ', ln_crban
915         WRITE(numout,*) '      Modify psi Schmidt number (wb case)           ln_sigpsi     = ', ln_sigpsi
916         WRITE(numout,*) '      Craig and Banner coefficient                  rn_crban       = ', rn_crban
917         WRITE(numout,*) '      Charnock coefficient                          rn_charn       = ', rn_charn
918         WRITE(numout,*) '      Stability functions                           nn_stab_func   = ', nn_stab_func
919         WRITE(numout,*) '      Type of closure                               nn_clos        = ', nn_clos
920         WRITE(numout,*) '   Hard coded parameters'
921         WRITE(numout,*) '      Surface roughness (m)                         hsro          = ', hsro
922         WRITE(numout,*) '      Bottom roughness (m)                          hbro          = ', hbro
923      ENDIF
924
925      !                                !* Check of some namelist values
926      IF( nn_tkebc_surf < 0 .OR. nn_tkebc_surf > 1 ) CALL ctl_stop( 'bad flag: nn_tkebc_surf is 0 or 1' )
927      IF( nn_psibc_surf < 0 .OR. nn_psibc_surf > 1 ) CALL ctl_stop( 'bad flag: nn_psibc_surf is 0 or 1' )
928      IF( nn_tkebc_bot  < 0 .OR. nn_tkebc_bot  > 1 ) CALL ctl_stop( 'bad flag: nn_tkebc_bot is 0 or 1' )
929      IF( nn_psibc_bot  < 0 .OR. nn_psibc_bot  > 1 ) CALL ctl_stop( 'bad flag: nn_psibc_bot is 0 or 1' )
930      IF( nn_stab_func  < 0 .OR. nn_stab_func  > 3 ) CALL ctl_stop( 'bad flag: nn_stab_func is 0, 1, 2 and 3' )
931      IF( nn_clos       < 0 .OR. nn_clos       > 3 ) CALL ctl_stop( 'bad flag: nn_clos is 0, 1, 2 or 3' )
932
933      ! Initialisation of the parameters for the choosen closure
934      ! --------------------------------------------------------
935      !
936      SELECT CASE ( nn_clos )
937      !
938      CASE( 0 )               ! k-kl  (Mellor-Yamada)
939         !
940         IF(lwp) WRITE(numout,*) 'The choosen closure is k-kl closed to the classical Mellor-Yamada'
941         rpp     = 0._wp
942         rmm     = 1._wp
943         rnn     = 1._wp
944         rsc_tke = 1.96_wp
945         rsc_psi = 1.96_wp
946         rpsi1   = 0.9_wp
947         rpsi3p  = 1._wp
948         rpsi2   = 0.5_wp
949         !
950         SELECT CASE ( nn_stab_func )
951         CASE( 0, 1 )   ;   rpsi3m = 2.53_wp       ! G88 or KC stability functions
952         CASE( 2 )      ;   rpsi3m = 2.38_wp       ! Canuto A stability functions
953         CASE( 3 )      ;   rpsi3m = 2.38          ! Canuto B stability functions (caution : constant not identified)
954         END SELECT
955         !
956      CASE( 1 )               ! k-eps
957         !
958         IF(lwp) WRITE(numout,*) 'The choosen closure is k-eps'
959         rpp     =  3._wp
960         rmm     =  1.5_wp
961         rnn     = -1._wp
962         rsc_tke =  1._wp
963         rsc_psi =  1.3_wp  ! Schmidt number for psi
964         rpsi1   =  1.44_wp
965         rpsi3p  =  1._wp
966         rpsi2   =  1.92_wp
967         !
968         SELECT CASE ( nn_stab_func )
969         CASE( 0, 1 )   ;   rpsi3m = -0.52_wp      ! G88 or KC stability functions
970         CASE( 2 )      ;   rpsi3m = -0.629_wp     ! Canuto A stability functions
971         CASE( 3 )      ;   rpsi3m = -0.566        ! Canuto B stability functions
972         END SELECT
973         !
974      CASE( 2 )               ! k-omega
975         !
976         IF(lwp) WRITE(numout,*) 'The choosen closure is k-omega'
977         rpp     = -1._wp
978         rmm     =  0.5_wp
979         rnn     = -1._wp
980         rsc_tke =  2._wp
981         rsc_psi =  2._wp
982         rpsi1   =  0.555_wp
983         rpsi3p  =  1._wp
984         rpsi2   =  0.833_wp
985         !
986         SELECT CASE ( nn_stab_func )
987         CASE( 0, 1 )   ;   rpsi3m = -0.58_wp       ! G88 or KC stability functions
988         CASE( 2 )      ;   rpsi3m = -0.64_wp       ! Canuto A stability functions
989         CASE( 3 )      ;   rpsi3m = -0.64_wp       ! Canuto B stability functions caution : constant not identified)
990         END SELECT
991         !
992      CASE( 3 )               ! generic
993         !
994         IF(lwp) WRITE(numout,*) 'The choosen closure is generic'
995         rpp     = 2._wp
996         rmm     = 1._wp
997         rnn     = -0.67_wp
998         rsc_tke = 0.8_wp
999         rsc_psi = 1.07_wp
1000         rpsi1   = 1._wp
1001         rpsi3p  = 1._wp
1002         rpsi2   = 1.22_wp
1003         !
1004         SELECT CASE ( nn_stab_func )
1005         CASE( 0, 1 )   ;   rpsi3m = 0.1_wp         ! G88 or KC stability functions
1006         CASE( 2 )      ;   rpsi3m = 0.05_wp        ! Canuto A stability functions
1007         CASE( 3 )      ;   rpsi3m = 0.05_wp        ! Canuto B stability functions caution : constant not identified)
1008         END SELECT
1009         !
1010      END SELECT
1011
1012      ! Initialisation of the parameters of the stability functions
1013      ! -----------------------------------------------------------
1014      !
1015      SELECT CASE ( nn_stab_func )
1016      !
1017      CASE ( 0 )             ! Galperin stability functions
1018         !
1019         IF(lwp) WRITE(numout,*) 'Stability functions from Galperin'
1020         rc2     =  0._wp
1021         rc3     =  0._wp
1022         rc_diff =  1._wp
1023         rc0     =  0.5544_wp
1024         rcm_sf  =  0.9884_wp
1025         rghmin  = -0.28_wp
1026         rgh0    =  0.0233_wp
1027         rghcri  =  0.02_wp
1028         !
1029      CASE ( 1 )             ! Kantha-Clayson stability functions
1030         !
1031         IF(lwp) WRITE(numout,*) 'Stability functions from Kantha-Clayson'
1032         rc2     =  0.7_wp
1033         rc3     =  0.2_wp
1034         rc_diff =  1._wp
1035         rc0     =  0.5544_wp
1036         rcm_sf  =  0.9884_wp
1037         rghmin  = -0.28_wp
1038         rgh0    =  0.0233_wp
1039         rghcri  =  0.02_wp
1040         !
1041      CASE ( 2 )             ! Canuto A stability functions
1042         !
1043         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto A'
1044         rs0 = 1.5_wp * rl1 * rl5*rl5
1045         rs1 = -rl4*(rl6+rl7) + 2._wp*rl4*rl5*(rl1-(1._wp/3._wp)*rl2-rl3) + 1.5_wp*rl1*rl5*rl8
1046         rs2 = -(3._wp/8._wp) * rl1*(rl6*rl6-rl7*rl7)
1047         rs4 = 2._wp * rl5
1048         rs5 = 2._wp * rl4
1049         rs6 = (2._wp/3._wp) * rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.5_wp * rl5*rl1 * (3._wp*rl3-rl2)   &
1050            &                                                    + 0.75_wp * rl1 * ( rl6 - rl7 )
1051         rd0 = 3._wp * rl5*rl5
1052         rd1 = rl5 * ( 7._wp*rl4 + 3._wp*rl8 )
1053         rd2 = rl5*rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.75_wp*(rl6*rl6 - rl7*rl7 )
1054         rd3 = rl4 * ( 4._wp*rl4 + 3._wp*rl8)
1055         rd4 = rl4 * ( rl2 * rl6 - 3._wp*rl3*rl7 - rl5*(rl2*rl2 - rl3*rl3 ) ) + rl5*rl8 * ( 3._wp*rl3*rl3 - rl2*rl2 )
1056         rd5 = 0.25_wp * ( rl2*rl2 - 3._wp *rl3*rl3 ) * ( rl6*rl6 - rl7*rl7 )
1057         rc0 = 0.5268_wp
1058         rf6 = 8._wp / (rc0**6._wp)
1059         rc_diff = SQRT(2._wp) / (rc0**3._wp)
1060         rcm_sf  =  0.7310_wp
1061         rghmin  = -0.28_wp
1062         rgh0    =  0.0329_wp
1063         rghcri  =  0.03_wp
1064         !
1065      CASE ( 3 )             ! Canuto B stability functions
1066         !
1067         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto B'
1068         rs0 = 1.5_wp * rm1 * rm5*rm5
1069         rs1 = -rm4 * (rm6+rm7) + 2._wp * rm4*rm5*(rm1-(1._wp/3._wp)*rm2-rm3) + 1.5_wp * rm1*rm5*rm8
1070         rs2 = -(3._wp/8._wp) * rm1 * (rm6*rm6-rm7*rm7 )
1071         rs4 = 2._wp * rm5
1072         rs5 = 2._wp * rm4
1073         rs6 = (2._wp/3._wp) * rm5 * (3._wp*rm3*rm3-rm2*rm2) - 0.5_wp * rm5*rm1*(3._wp*rm3-rm2) + 0.75_wp * rm1*(rm6-rm7)
1074         rd0 = 3._wp * rm5*rm5
1075         rd1 = rm5 * (7._wp*rm4 + 3._wp*rm8)
1076         rd2 = rm5*rm5 * (3._wp*rm3*rm3 - rm2*rm2) - 0.75_wp * (rm6*rm6 - rm7*rm7)
1077         rd3 = rm4 * ( 4._wp*rm4 + 3._wp*rm8 )
1078         rd4 = rm4 * ( rm2*rm6 -3._wp*rm3*rm7 - rm5*(rm2*rm2 - rm3*rm3) ) + rm5 * rm8 * ( 3._wp*rm3*rm3 - rm2*rm2 )
1079         rd5 = 0.25_wp * ( rm2*rm2 - 3._wp*rm3*rm3 ) * ( rm6*rm6 - rm7*rm7 )
1080         rc0 = 0.5268_wp            !!       rc0 = 0.5540_wp (Warner ...) to verify !
1081         rf6 = 8._wp / ( rc0**6._wp )
1082         rc_diff = SQRT(2._wp)/(rc0**3.)
1083         rcm_sf  =  0.7470_wp
1084         rghmin  = -0.28_wp
1085         rgh0    =  0.0444_wp
1086         rghcri  =  0.0414_wp
1087         !
1088      END SELECT
1089   
1090      ! Set Schmidt number for psi diffusion in the wave breaking case
1091      ! See equation 13 of Carniel et al, Ocean modelling, 30, 225-239, 2009
1092      ! or equation (17) of Burchard, JPO, 31, 3133-3145, 2001
1093      IF( ln_sigpsi .AND. ln_crban ) THEN
1094         zcr = SQRT( 1.5_wp*rsc_tke ) * rcm_sf / vkarmn
1095         rsc_psi0 = vkarmn*vkarmn / ( rpsi2 * rcm_sf*rcm_sf )                       & 
1096        &         * ( rnn*rnn - 4._wp/3._wp * zcr*rnn*rmm - 1._wp/3._wp * zcr*rnn   &
1097        &           + 2._wp/9._wp * rmm * zcr*zcr + 4._wp/9._wp * zcr*zcr * rmm*rmm )                                 
1098      ELSE
1099         rsc_psi0 = rsc_psi
1100      ENDIF
1101 
1102      ! Shear free turbulence parameters:
1103      !
1104      ra_sf  = -4._wp * rnn * SQRT( rsc_tke ) / ( (1._wp+4._wp*rmm) * SQRT( rsc_tke )   &
1105         &                                      - SQRT(rsc_tke + 24._wp*rsc_psi0*rpsi2 ) )
1106      rl_sf  = rc0 * SQRT( rc0 / rcm_sf )                                                                   &
1107         &         * SQRT(  (  (1._wp + 4._wp*rmm + 8._wp*rmm*rmm) * rsc_tke                                &
1108         &                   + 12._wp * rsc_psi0 * rpsi2                                                    &
1109         &                   - (1._wp + 4._wp*rmm) * SQRT( rsc_tke*(rsc_tke+ 24._wp*rsc_psi0*rpsi2) )  )    &
1110         &                / ( 12._wp*rnn*rnn )                                                              )
1111
1112      !
1113      IF(lwp) THEN      ! Control print
1114         WRITE(numout,*)
1115         WRITE(numout,*) 'Limit values'
1116         WRITE(numout,*) '~~~~~~~~~~~~'
1117         WRITE(numout,*) 'Parameter  m = ',rmm
1118         WRITE(numout,*) 'Parameter  n = ',rnn
1119         WRITE(numout,*) 'Parameter  p = ',rpp
1120         WRITE(numout,*) 'rpsi1   = ',rpsi1
1121         WRITE(numout,*) 'rpsi2   = ',rpsi2
1122         WRITE(numout,*) 'rpsi3m  = ',rpsi3m
1123         WRITE(numout,*) 'rpsi3p  = ',rpsi3p
1124         WRITE(numout,*) 'rsc_tke = ',rsc_tke
1125         WRITE(numout,*) 'rsc_psi = ',rsc_psi
1126         WRITE(numout,*) 'rsc_psi0 = ',rsc_psi0
1127         WRITE(numout,*) 'rc0     = ',rc0
1128         WRITE(numout,*)
1129         WRITE(numout,*) 'Shear free turbulence parameters:'
1130         WRITE(numout,*) 'rcm_sf  = ',rcm_sf
1131         WRITE(numout,*) 'ra_sf   = ',ra_sf
1132         WRITE(numout,*) 'rl_sf   = ',rl_sf
1133         WRITE(numout,*)
1134      ENDIF
1135
1136      ! Constants initialization
1137      rc02  = rc0  * rc0   ;   rc02r = 1. / rc02
1138      rc03  = rc02 * rc0
1139      rc04  = rc03 * rc0
1140      rc03_sqrt2_galp = rc03 / SQRT(2._wp) / rn_clim_galp
1141      rsbc_mb   = 0.5_wp * (15.8_wp*rn_crban)**(2._wp/3._wp)               ! Surf. bound. cond. from Mellor and Blumberg
1142      rsbc_std  = 3.75_wp                                                  ! Surf. bound. cond. standard (prod=diss)
1143      rsbc_tke1 = (-rsc_tke*rn_crban/(rcm_sf*ra_sf*rl_sf))**(2._wp/3._wp)  ! k_eps = 53.  Dirichlet + Wave breaking
1144      rsbc_tke2 = 0.5_wp / rau0
1145      rsbc_tke3 = rdt * rn_crban                                                         ! Neumann + Wave breaking
1146      rsbc_zs   = rn_charn / grav                                                        ! Charnock formula
1147      rsbc_psi1 = rc0**rpp * rsbc_tke1**rmm * rl_sf**rnn                           ! Dirichlet + Wave breaking
1148      rsbc_psi2 = -0.5_wp * rdt * rc0**rpp * rnn * vkarmn**rnn / rsc_psi                   ! Neumann + NO Wave breaking
1149      rsbc_psi3 = -0.5_wp * rdt * rc0**rpp * rl_sf**rnn / rsc_psi  * (rnn + rmm*ra_sf) ! Neumann + Wave breaking
1150      rfact_tke = -0.5_wp / rsc_tke * rdt               ! Cst used for the Diffusion term of tke
1151      rfact_psi = -0.5_wp / rsc_psi * rdt               ! Cst used for the Diffusion term of tke
1152
1153      !                                !* Wall proximity function
1154      zwall (:,:,:) = 1._wp * tmask(:,:,:)
1155
1156      !                                !* set vertical eddy coef. to the background value
1157      DO jk = 1, jpk
1158         avt (:,:,jk) = avtb(jk) * tmask(:,:,jk)
1159         avm (:,:,jk) = avmb(jk) * tmask(:,:,jk)
1160         avmu(:,:,jk) = avmb(jk) * umask(:,:,jk)
1161         avmv(:,:,jk) = avmb(jk) * vmask(:,:,jk)
1162      END DO
1163      !                                !* read or initialize all required files
1164      CALL gls_rst( nit000, 'READ' )
1165      !
1166   END SUBROUTINE zdf_gls_init
1167
1168
1169   SUBROUTINE gls_rst( kt, cdrw )
1170      !!---------------------------------------------------------------------
1171      !!                   ***  ROUTINE ts_rst  ***
1172      !!                     
1173      !! ** Purpose :   Read or write TKE file (en) in restart file
1174      !!
1175      !! ** Method  :   use of IOM library
1176      !!                if the restart does not contain TKE, en is either
1177      !!                set to rn_emin or recomputed (nn_igls/=0)
1178      !!----------------------------------------------------------------------
1179      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1180      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1181      !
1182      INTEGER ::   jit, jk   ! dummy loop indices
1183      INTEGER ::   id1, id2, id3, id4, id5, id6, id7, id8
1184      INTEGER ::   ji, jj, ikbu, ikbv
1185      REAL(wp)::   cbx, cby
1186      !!----------------------------------------------------------------------
1187      !
1188      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
1189         !                                   ! ---------------
1190         IF( ln_rstart ) THEN                   !* Read the restart file
1191            id1 = iom_varid( numror, 'en'   , ldstop = .FALSE. )
1192            id2 = iom_varid( numror, 'avt'  , ldstop = .FALSE. )
1193            id3 = iom_varid( numror, 'avm'  , ldstop = .FALSE. )
1194            id4 = iom_varid( numror, 'avmu' , ldstop = .FALSE. )
1195            id5 = iom_varid( numror, 'avmv' , ldstop = .FALSE. )
1196            id6 = iom_varid( numror, 'mxln' , ldstop = .FALSE. )
1197            !
1198            IF( MIN( id1, id2, id3, id4, id5, id6, id7, id8 ) > 0 ) THEN        ! all required arrays exist
1199               CALL iom_get( numror, jpdom_autoglo, 'en'    , en     )
1200               CALL iom_get( numror, jpdom_autoglo, 'avt'   , avt    )
1201               CALL iom_get( numror, jpdom_autoglo, 'avm'   , avm    )
1202               CALL iom_get( numror, jpdom_autoglo, 'avmu'  , avmu   )
1203               CALL iom_get( numror, jpdom_autoglo, 'avmv'  , avmv   )
1204               CALL iom_get( numror, jpdom_autoglo, 'mxln'  , mxln   )
1205            ELSE                       
1206               IF(lwp) WRITE(numout,*) ' ===>>>> : previous run without gls scheme, en and mxln computed by iterative loop'
1207               en  (:,:,:) = rn_emin
1208               mxln(:,:,:) = 0.001       
1209               DO jit = nit000 + 1, nit000 + 10   ;   CALL zdf_gls( jit )   ;   END DO
1210            ENDIF
1211         ELSE                                   !* Start from rest
1212            IF(lwp) WRITE(numout,*) ' ===>>>> : Initialisation of en and mxln by background values'
1213            en  (:,:,:) = rn_emin
1214            mxln(:,:,:) = 0.001       
1215         ENDIF
1216         !
1217      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
1218         !                                   ! -------------------
1219         IF(lwp) WRITE(numout,*) '---- gls-rst ----'
1220         CALL iom_rstput( kt, nitrst, numrow, 'en'   , en    )
1221         CALL iom_rstput( kt, nitrst, numrow, 'avt'  , avt   )
1222         CALL iom_rstput( kt, nitrst, numrow, 'avm'  , avm   )
1223         CALL iom_rstput( kt, nitrst, numrow, 'avmu' , avmu  )
1224         CALL iom_rstput( kt, nitrst, numrow, 'avmv' , avmv  )
1225         CALL iom_rstput( kt, nitrst, numrow, 'mxln' , mxln  )
1226         !
1227      ENDIF
1228      !
1229   END SUBROUTINE gls_rst
1230
1231#else
1232   !!----------------------------------------------------------------------
1233   !!   Dummy module :                                        NO TKE scheme
1234   !!----------------------------------------------------------------------
1235   LOGICAL, PUBLIC, PARAMETER ::   lk_zdfgls = .FALSE.   !: TKE flag
1236CONTAINS
1237   SUBROUTINE zdf_gls_init           ! Empty routine
1238      WRITE(*,*) 'zdf_gls_init: You should not have seen this print! error?'
1239   END SUBROUTINE zdf_gls_init
1240   SUBROUTINE zdf_gls( kt )          ! Empty routine
1241      WRITE(*,*) 'zdf_gls: You should not have seen this print! error?', kt
1242   END SUBROUTINE zdf_gls
1243   SUBROUTINE gls_rst( kt, cdrw )          ! Empty routine
1244      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1245      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1246      WRITE(*,*) 'gls_rst: You should not have seen this print! error?', kt, cdrw
1247   END SUBROUTINE gls_rst
1248#endif
1249
1250   !!======================================================================
1251END MODULE zdfgls
1252
Note: See TracBrowser for help on using the repository browser.