New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
step.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/step.F90 @ 2305

Last change on this file since 2305 was 2305, checked in by davestorkey, 13 years ago

Updates to BDY - DOCTOR standards
  • Property svn:keywords set to Id
File size: 16.2 KB
Line 
1MODULE step
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping    : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (G. Madec)  Original code
7   !!             -   !  1991-11  (G. Madec)
8   !!             -   !  1992-06  (M. Imbard)  add a first output record
9   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
10   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
11   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
12   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
13   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
14   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
15   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
16   !!             -   !  2004-08  (C. Talandier) New trends organization
17   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
18   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             -   !  2006-07  (S. Masson)  restart using iom
21   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
22   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
23   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25   !!----------------------------------------------------------------------
26
27   !!----------------------------------------------------------------------
28   !!   stp            : OPA system time-stepping
29   !!----------------------------------------------------------------------
30   USE step_oce         ! time stepping definition modules
31#if defined key_top
32   USE trcstp          ! passive tracer time-stepping      (trc_stp routine)
33#endif
34
35   USE zdfgls          ! generic length scale case
36   USE asminc          ! assimilation increments    (tra_asm_inc, dyn_asm_inc routines)
37   USE stpctl          ! time stepping control            (stp_ctl routine)
38   USE restart         ! ocean restart                    (rst_wri routine)
39   USE prtctl          ! Print control                    (prt_ctl routine)
40
41#if defined key_agrif
42   USE agrif_opa_sponge ! Momemtum and tracers sponges
43#endif
44
45   IMPLICIT NONE
46   PRIVATE
47
48   PUBLIC   stp        ! called by opa.F90
49
50   !! * Substitutions
51#  include "domzgr_substitute.h90"
52#  include "zdfddm_substitute.h90"
53   !!----------------------------------------------------------------------
54   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
55   !! $Id$
56   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
57   !!----------------------------------------------------------------------
58
59CONTAINS
60
61#if defined key_agrif
62   SUBROUTINE stp( )
63      INTEGER             ::   kstp   ! ocean time-step index
64#else
65   SUBROUTINE stp( kstp )
66      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
67#endif
68      !!----------------------------------------------------------------------
69      !!                     ***  ROUTINE stp  ***
70      !!                     
71      !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.)
72      !!              - Time stepping of LIM (dynamic and thermodynamic eqs.)
73      !!              - Tme stepping  of TRC (passive tracer eqs.)
74      !!
75      !! ** Method  : -1- Update forcings and data 
76      !!              -2- Update ocean physics
77      !!              -3- Compute the t and s trends
78      !!              -4- Update t and s
79      !!              -5- Compute the momentum trends
80      !!              -6- Update the horizontal velocity
81      !!              -7- Compute the diagnostics variables (rd,N2, div,cur,w)
82      !!              -8- Outputs and diagnostics
83      !!----------------------------------------------------------------------
84      INTEGER ::   jk       ! dummy loop indice
85      INTEGER ::   indic    ! error indicator if < 0
86      !! ---------------------------------------------------------------------
87
88#if defined key_agrif
89      kstp = nit000 + Agrif_Nb_Step()
90# if defined key_iomput
91      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap
92# endif   
93#endif   
94                             indic = 0                ! reset to no error condition
95      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
96                             CALL iom_setkt( kstp )   ! say to iom that we are at time step kstp
97
98      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
99      ! Update data, open boundaries, surface boundary condition (including sea-ice)
100      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
101      IF( lk_dtatem  )   CALL dta_tem( kstp )         ! update 3D temperature data
102      IF( lk_dtasal  )   CALL dta_sal( kstp )         ! update 3D salinity data
103                         CALL sbc    ( kstp )         ! Sea Boundary Condition (including sea-ice)
104      IF( lk_obc     )   CALL obc_dta( kstp )         ! update dynamic and tracer data at open boundaries
105      IF( lk_obc     )   CALL obc_rad( kstp )         ! compute phase velocities at open boundaries
106      IF( lk_bdy     )   CALL bdy_dta_frs( kstp )     ! update dynamic and tracer data for FRS conditions (BDY)
107
108      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
109      !  Ocean dynamics : ssh, wn, hdiv, rot                                 !
110      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
111                         CALL ssh_wzv( kstp )         ! after ssh & vertical velocity
112
113      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
114      ! Ocean physics update                (ua, va, ta, sa used as workspace)
115      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
116                         CALL bn2( tsb, rn2b )        ! before Brunt-Vaisala frequency
117                         CALL bn2( tsn, rn2  )        ! now    Brunt-Vaisala frequency
118      !
119      !  VERTICAL PHYSICS   
120                         CALL zdf_bfr( kstp )         ! bottom friction
121      !                                               ! Vertical eddy viscosity and diffusivity coefficients
122      IF( lk_zdfric     )   CALL zdf_ric    ( kstp )  ! Richardson number dependent Kz
123      IF( lk_zdftke     )   CALL zdf_tke    ( kstp )  ! TKE closure scheme for Kz
124      IF( lk_zdfgls     )   CALL zdf_gls    ( kstp )  ! GLS closure scheme for Kz
125      IF( lk_zdfkpp     )   CALL zdf_kpp    ( kstp )  ! KPP closure scheme for Kz
126      IF( lk_zdfcst     )   THEN                      ! Constant Kz (reset avt, avm[uv] to the background value)
127         avt (:,:,:) = rn_avt0 * tmask(:,:,:)
128         avmu(:,:,:) = rn_avm0 * umask(:,:,:)
129         avmv(:,:,:) = rn_avm0 * vmask(:,:,:)
130      ENDIF
131      IF( ln_rnf_mouth ) THEN                         ! increase diffusivity at rivers mouths
132         DO jk = 2, nkrnf   ;   avt(:,:,jk) = avt(:,:,jk) + 2.e0 * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk)   ;   END DO
133      ENDIF
134      IF( ln_zdfevd  )   CALL zdf_evd( kstp )         ! enhanced vertical eddy diffusivity
135
136      IF( lk_zdftmx  )   CALL zdf_tmx( kstp )         ! tidal vertical mixing
137
138      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
139         &               CALL zdf_ddm( kstp )         ! double diffusive mixing
140                         CALL zdf_mxl( kstp )         ! mixed layer depth
141
142                                                      ! write tke information in the restart file
143      IF( lrst_oce .AND. lk_zdftke )   CALL tke_rst( kstp, 'WRITE' )
144                                                      ! write gls information in the restart file
145      IF( lrst_oce .AND. lk_zdfgls )   CALL gls_rst( kstp, 'WRITE' )
146      !
147      !  LATERAL  PHYSICS
148      !
149      IF( lk_ldfslp ) THEN                            ! slope of lateral mixing
150                         CALL eos( tsb, rhd )                ! before in situ density
151         IF( ln_zps )    CALL zps_hde( kstp, jpts, tsb, gtsu, gtsv,  &    ! Partial steps: before horizontal gradient
152            &                                      rhd, gru , grv  )      ! of t, s, rd at the last ocean level
153         IF ( .NOT. ln_traldf_grif ) THEN
154                         CALL ldf_slp( kstp, rhd, rn2b )        ! before slope of the lateral mixing
155         ELSE
156                         CALL ldf_slp_grif( kstp )
157                         IF ( ln_dynldf_bilap .OR. ln_dynldf_iso ) CALL ldf_slp( kstp, rhd, rn2b )
158      ENDIF
159      ENDIF
160#if defined key_traldf_c2d
161      IF( lk_traldf_eiv )   CALL ldf_eiv( kstp )      ! eddy induced velocity coefficient
162#  endif
163
164      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
165      ! diagnostics and outputs             (ua, va, ta, sa used as workspace)
166      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
167      IF( lk_floats  )   CALL flo_stp( kstp )         ! drifting Floats
168      IF( lk_diahth  )   CALL dia_hth( kstp )         ! Thermocline depth (20 degres isotherm depth)
169      IF( lk_diagap  )   CALL dia_gap( kstp )         ! basin averaged diagnostics
170      IF( lk_diahdy  )   CALL dia_hdy( kstp )         ! dynamical heigh diagnostics
171      IF( lk_diafwb  )   CALL dia_fwb( kstp )         ! Fresh water budget diagnostics
172      IF( lk_diaobs  )   CALL dia_obs( kstp )         ! obs-minus-model (assimilation) diagnostics
173      IF( ln_diaptr  )   CALL dia_ptr( kstp )         ! Poleward TRansports diagnostics
174      IF( lk_diaar5  )   CALL dia_ar5( kstp )         ! ar5 diag
175                         CALL dia_wri( kstp )         ! ocean model: outputs
176
177#if defined key_top
178      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
179      ! Passive Tracer Model
180      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
181                         CALL trc_stp( kstp )         ! time-stepping
182#endif
183
184      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
185      ! Active tracers                              (ua, va used as workspace)
186      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
187                             tsa(:,:,:,:) = 0.e0               ! set tracer trends to zero
188
189      IF(  ln_asmiau .AND. &
190         & ln_trainc     )   CALL tra_asm_inc( kstp )       ! apply tracer assimilation increment
191                             CALL tra_sbc    ( kstp )       ! surface boundary condition
192      IF( ln_traqsr      )   CALL tra_qsr    ( kstp )       ! penetrative solar radiation qsr
193      IF( lk_trabbc      )   CALL tra_bbc    ( kstp )       ! bottom heat flux
194      IF( lk_trabbl      )   CALL tra_bbl    ( kstp )       ! advective (and/or diffusive) bottom boundary layer scheme
195      IF( lk_tradmp      )   CALL tra_dmp    ( kstp )       ! internal damping trends
196                             CALL tra_adv    ( kstp )       ! horizontal & vertical advection
197      IF( n_cla == 1     )   CALL tra_cla    ( kstp )       ! Cross Land Advection (Update Hor. advection)
198      IF( lk_zdfkpp )        CALL tra_kpp    ( kstp )       ! KPP non-local tracer fluxes
199                             CALL tra_ldf    ( kstp )       ! lateral mixing
200#if defined key_agrif
201                             CALL tra_unswap
202      IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_tra          ! tracers sponge
203                             CALL tra_swap
204#endif
205                             CALL tra_zdf    ( kstp )       ! vertical mixing and after tracer fields
206
207      IF( ln_dynhpg_imp  ) THEN                             ! semi-implicit hpg (time stepping then eos)
208         IF( ln_zdfnpc   )   CALL tra_npc    ( kstp )            ! update after fields by non-penetrative convection
209                             CALL tra_nxt    ( kstp )            ! tracer fields at next time step
210                             CALL eos( tsa, rhd, rhop )       ! Time-filtered in situ density for hpg computation
211         IF( ln_zps      )   CALL zps_hde( kstp, jpts, tsa, gtsu, gtsv,  &    ! zps: time filtered hor. derivative
212            &                                          rhd, gru , grv  )      ! of t, s, rd at the last ocean level
213         
214      ELSE                                                  ! centered hpg  (eos then time stepping)
215                             CALL eos( tsn, rhd, rhop )       ! now in situ density for hpg computation
216         IF( ln_zps      )   CALL zps_hde( kstp, jpts, tsn, gtsu, gtsv,  &    ! zps: now hor. derivative
217            &                                          rhd, gru , grv  )      ! of t, s, rd at the last ocean level
218         IF( ln_zdfnpc   )   CALL tra_npc    ( kstp )       ! update after fields by non-penetrative convection
219                             CALL tra_nxt    ( kstp )       ! tracer fields at next time step
220      ENDIF
221                             CALL tra_unswap
222
223      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
224      ! Dynamics                                    (ta, sa used as workspace)
225      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
226                               ua(:,:,:) = 0.e0             ! set dynamics trends to zero
227                               va(:,:,:) = 0.e0
228
229      IF(  ln_asmiau .AND. &
230         & ln_dyninc     )     CALL dyn_asm_inc( kstp )       ! apply dynamics assimilation increment
231                               CALL dyn_adv( kstp )         ! advection (vector or flux form)
232                               CALL dyn_vor( kstp )         ! vorticity term including Coriolis
233                               CALL dyn_ldf( kstp )         ! lateral mixing
234#if defined key_agrif
235      IF(.NOT. Agrif_Root())   CALL Agrif_Sponge_dyn        ! momemtum sponge
236#endif
237                               CALL dyn_hpg( kstp )         ! horizontal gradient of Hydrostatic pressure
238                               CALL dyn_bfr( kstp )           ! bottom friction   
239                               CALL dyn_zdf( kstp )         ! vertical diffusion
240                               CALL dyn_spg( kstp, indic )  ! surface pressure gradient
241                               CALL dyn_nxt( kstp )         ! lateral velocity at next time step
242
243                               CALL ssh_nxt( kstp )         ! sea surface height at next time step
244
245      IF( ln_diahsb        )   CALL dia_hsb( kstp )         ! - ML - global conservation diagnostics
246
247      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
248      ! Control and restarts
249      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
250                               CALL stp_ctl( kstp, indic )
251      IF( indic < 0        )   THEN
252                               CALL ctl_stop( 'step: indic < 0' )
253                               CALL dia_wri_state( 'output.abort', kstp )
254      ENDIF
255      IF( kstp == nit000   )   CALL iom_close( numror )     ! close input  ocean restart file
256      IF( lrst_oce         )   CALL rst_write    ( kstp )   ! write output ocean restart file
257      IF( lk_obc           )   CALL obc_rst_write( kstp )   ! write open boundary restart file
258
259      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
260      ! Trends                              (ua, va, ta, sa used as workspace)
261      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
262      IF( nstop == 0 ) THEN                         
263         IF( lk_trddyn     )   CALL trd_dwr( kstp )         ! trends: dynamics
264         IF( lk_trdtra     )   CALL trd_twr( kstp )         ! trends: active tracers
265         IF( lk_trdmld     )   CALL trd_mld( kstp )         ! trends: Mixed-layer
266         IF( lk_trdvor     )   CALL trd_vor( kstp )         ! trends: vorticity budget
267      ENDIF
268
269      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
270      ! Coupled mode
271      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
272      IF( lk_cpl           )   CALL sbc_cpl_snd( kstp )     ! coupled mode : field exchanges
273      !
274      !
275   END SUBROUTINE stp
276
277   !!======================================================================
278END MODULE step
Note: See TracBrowser for help on using the repository browser.