source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/step.F90 @ 2370

Last change on this file since 2370 was 2370, checked in by gm, 10 years ago

v3.3beta: ice-ocean stress at kt with VP & EVP (LIM-2 and -3)

  • Property svn:keywords set to Id
File size: 16.0 KB
Line 
1MODULE step
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping    : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (G. Madec)  Original code
7   !!             -   !  1991-11  (G. Madec)
8   !!             -   !  1992-06  (M. Imbard)  add a first output record
9   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
10   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
11   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
12   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
13   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
14   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
15   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
16   !!             -   !  2004-08  (C. Talandier) New trends organization
17   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
18   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             -   !  2006-07  (S. Masson)  restart using iom
21   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
22   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
23   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25   !!----------------------------------------------------------------------
26
27   !!----------------------------------------------------------------------
28   !!   stp             : OPA system time-stepping
29   !!----------------------------------------------------------------------
30   USE step_oce         ! time stepping definition modules
31#if defined key_top
32   USE trcstp           ! passive tracer time-stepping      (trc_stp routine)
33#endif
34   USE asminc           ! assimilation increments    (tra_asm_inc, dyn_asm_inc routines)
35   USE stpctl           ! time stepping control            (stp_ctl routine)
36   USE restart          ! ocean restart                    (rst_wri routine)
37   USE prtctl           ! Print control                    (prt_ctl routine)
38
39#if defined key_agrif
40   USE agrif_opa_sponge ! Momemtum and tracers sponges
41#endif
42
43   IMPLICIT NONE
44   PRIVATE
45
46   PUBLIC   stp   ! called by opa.F90
47
48   !! * Substitutions
49#  include "domzgr_substitute.h90"
50#  include "zdfddm_substitute.h90"
51   !!----------------------------------------------------------------------
52   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
53   !! $Id$
54   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
55   !!----------------------------------------------------------------------
56CONTAINS
57
58#if defined key_agrif
59   SUBROUTINE stp( )
60      INTEGER             ::   kstp   ! ocean time-step index
61#else
62   SUBROUTINE stp( kstp )
63      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
64#endif
65      !!----------------------------------------------------------------------
66      !!                     ***  ROUTINE stp  ***
67      !!                     
68      !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.)
69      !!              - Time stepping of LIM (dynamic and thermodynamic eqs.)
70      !!              - Tme stepping  of TRC (passive tracer eqs.)
71      !!
72      !! ** Method  : -1- Update forcings and data 
73      !!              -2- Update ocean physics
74      !!              -3- Compute the t and s trends
75      !!              -4- Update t and s
76      !!              -5- Compute the momentum trends
77      !!              -6- Update the horizontal velocity
78      !!              -7- Compute the diagnostics variables (rd,N2, div,cur,w)
79      !!              -8- Outputs and diagnostics
80      !!----------------------------------------------------------------------
81      INTEGER ::   jk       ! dummy loop indice
82      INTEGER ::   indic    ! error indicator if < 0
83      !! ---------------------------------------------------------------------
84
85#if defined key_agrif
86      kstp = nit000 + Agrif_Nb_Step()
87# if defined key_iomput
88      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap
89# endif   
90#endif   
91                             indic = 0                ! reset to no error condition
92      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
93                             CALL iom_setkt( kstp )   ! say to iom that we are at time step kstp
94
95      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
96      ! Update data, open boundaries, surface boundary condition (including sea-ice)
97      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
98      IF( lk_dtatem  )   CALL dta_tem( kstp )         ! update 3D temperature data
99      IF( lk_dtasal  )   CALL dta_sal( kstp )         ! update 3D salinity data
100                         CALL sbc    ( kstp )         ! Sea Boundary Condition (including sea-ice)
101      IF( lk_obc     )   CALL obc_dta( kstp )         ! update dynamic and tracer data at open boundaries
102      IF( lk_obc     )   CALL obc_rad( kstp )         ! compute phase velocities at open boundaries
103      IF( lk_bdy     )   CALL bdy_dta_frs( kstp )     ! update dynamic and tracer data for FRS conditions (BDY)
104
105      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
106      !  Ocean dynamics : ssh, wn, hdiv, rot                                 !
107      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
108                         CALL ssh_wzv( kstp )         ! after ssh & vertical velocity
109
110      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
111      ! Ocean physics update                (ua, va, ta, sa used as workspace)
112      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
113                         CALL bn2( tsb, rn2b )        ! before Brunt-Vaisala frequency
114                         CALL bn2( tsn, rn2  )        ! now    Brunt-Vaisala frequency
115      !
116      !  VERTICAL PHYSICS   
117                         CALL zdf_bfr( kstp )         ! bottom friction
118      !                                               ! Vertical eddy viscosity and diffusivity coefficients
119      IF( lk_zdfric     )   CALL zdf_ric    ( kstp )  ! Richardson number dependent Kz
120      IF( lk_zdftke     )   CALL zdf_tke    ( kstp )  ! TKE closure scheme for Kz
121      IF( lk_zdfgls     )   CALL zdf_gls    ( kstp )  ! GLS closure scheme for Kz
122      IF( lk_zdfkpp     )   CALL zdf_kpp    ( kstp )  ! KPP closure scheme for Kz
123      IF( lk_zdfcst     )   THEN                      ! Constant Kz (reset avt, avm[uv] to the background value)
124         avt (:,:,:) = rn_avt0 * tmask(:,:,:)
125         avmu(:,:,:) = rn_avm0 * umask(:,:,:)
126         avmv(:,:,:) = rn_avm0 * vmask(:,:,:)
127      ENDIF
128      IF( ln_rnf_mouth ) THEN                         ! increase diffusivity at rivers mouths
129         DO jk = 2, nkrnf   ;   avt(:,:,jk) = avt(:,:,jk) + 2.e0 * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk)   ;   END DO
130      ENDIF
131      IF( ln_zdfevd  )   CALL zdf_evd( kstp )         ! enhanced vertical eddy diffusivity
132
133      IF( lk_zdftmx  )   CALL zdf_tmx( kstp )         ! tidal vertical mixing
134
135      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
136         &               CALL zdf_ddm( kstp )         ! double diffusive mixing
137                         CALL zdf_mxl( kstp )         ! mixed layer depth
138
139                                                      ! write tke information in the restart file
140      IF( lrst_oce .AND. lk_zdftke )   CALL tke_rst( kstp, 'WRITE' )
141                                                      ! write gls information in the restart file
142      IF( lrst_oce .AND. lk_zdfgls )   CALL gls_rst( kstp, 'WRITE' )
143      !
144      !  LATERAL  PHYSICS
145      !
146      IF( lk_ldfslp ) THEN                            ! slope of lateral mixing
147                         CALL eos( tsb, rhd )                ! before in situ density
148         IF( ln_zps )    CALL zps_hde( kstp, jpts, tsb, gtsu, gtsv,  &    ! Partial steps: before horizontal gradient
149            &                                      rhd, gru , grv  )      ! of t, s, rd at the last ocean level
150         IF( ln_traldf_grif ) THEN                           ! before slope for Griffies operator
151                         CALL ldf_slp_grif( kstp )
152         ELSE
153                         CALL ldf_slp( kstp, rhd, rn2b )     ! before slope for Madec operator
154         ENDIF
155      ENDIF
156#if defined key_traldf_c2d
157      IF( lk_traldf_eiv )   CALL ldf_eiv( kstp )      ! eddy induced velocity coefficient
158#  endif
159
160      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
161      ! diagnostics and outputs             (ua, va, ta, sa used as workspace)
162      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
163      IF( lk_floats  )   CALL flo_stp( kstp )         ! drifting Floats
164      IF( lk_diahth  )   CALL dia_hth( kstp )         ! Thermocline depth (20 degres isotherm depth)
165      IF( lk_diafwb  )   CALL dia_fwb( kstp )         ! Fresh water budget diagnostics
166      IF( lk_diaobs  )   CALL dia_obs( kstp )         ! obs-minus-model (assimilation) diagnostics
167      IF( ln_diaptr  )   CALL dia_ptr( kstp )         ! Poleward TRansports diagnostics
168      IF( lk_diaar5  )   CALL dia_ar5( kstp )         ! ar5 diag
169                         CALL dia_wri( kstp )         ! ocean model: outputs
170
171#if defined key_top
172      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
173      ! Passive Tracer Model
174      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
175                         CALL trc_stp( kstp )         ! time-stepping
176#endif
177
178      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
179      ! Active tracers                              (ua, va used as workspace)
180      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
181                             tsa(:,:,:,:) = 0.e0               ! set tracer trends to zero
182
183      IF(  ln_asmiau .AND. &
184         & ln_trainc     )   CALL tra_asm_inc( kstp )       ! apply tracer assimilation increment
185                             CALL tra_sbc    ( kstp )       ! surface boundary condition
186      IF( ln_traqsr      )   CALL tra_qsr    ( kstp )       ! penetrative solar radiation qsr
187      IF( ln_trabbc      )   CALL tra_bbc    ( kstp )       ! bottom heat flux
188      IF( lk_trabbl      )   CALL tra_bbl    ( kstp )       ! advective (and/or diffusive) bottom boundary layer scheme
189      IF( lk_tradmp      )   CALL tra_dmp    ( kstp )       ! internal damping trends
190                             CALL tra_adv    ( kstp )       ! horizontal & vertical advection
191      IF( n_cla == 1     )   CALL tra_cla    ( kstp )       ! Cross Land Advection (Update Hor. advection)
192      IF( lk_zdfkpp )        CALL tra_kpp    ( kstp )       ! KPP non-local tracer fluxes
193                             CALL tra_ldf    ( kstp )       ! lateral mixing
194#if defined key_agrif
195                             CALL tra_unswap
196      IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_tra          ! tracers sponge
197                             CALL tra_swap
198#endif
199                             CALL tra_zdf    ( kstp )       ! vertical mixing and after tracer fields
200
201      IF( ln_dynhpg_imp  ) THEN                             ! semi-implicit hpg (time stepping then eos)
202         IF( ln_zdfnpc   )   CALL tra_npc    ( kstp )            ! update after fields by non-penetrative convection
203                             CALL tra_nxt    ( kstp )            ! tracer fields at next time step
204                             CALL eos( tsa, rhd, rhop )       ! Time-filtered in situ density for hpg computation
205         IF( ln_zps      )   CALL zps_hde( kstp, jpts, tsa, gtsu, gtsv,  &    ! zps: time filtered hor. derivative
206            &                                          rhd, gru , grv  )      ! of t, s, rd at the last ocean level
207         
208      ELSE                                                  ! centered hpg  (eos then time stepping)
209                             CALL eos( tsn, rhd, rhop )       ! now in situ density for hpg computation
210         IF( ln_zps      )   CALL zps_hde( kstp, jpts, tsn, gtsu, gtsv,  &    ! zps: now hor. derivative
211            &                                          rhd, gru , grv  )      ! of t, s, rd at the last ocean level
212         IF( ln_zdfnpc   )   CALL tra_npc    ( kstp )       ! update after fields by non-penetrative convection
213                             CALL tra_nxt    ( kstp )       ! tracer fields at next time step
214      ENDIF
215                             CALL tra_unswap
216
217      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
218      ! Dynamics                                    (ta, sa used as workspace)
219      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
220                               ua(:,:,:) = 0.e0             ! set dynamics trends to zero
221                               va(:,:,:) = 0.e0
222
223      IF(  ln_asmiau .AND. &
224         & ln_dyninc     )     CALL dyn_asm_inc( kstp )       ! apply dynamics assimilation increment
225                               CALL dyn_adv( kstp )         ! advection (vector or flux form)
226                               CALL dyn_vor( kstp )         ! vorticity term including Coriolis
227                               CALL dyn_ldf( kstp )         ! lateral mixing
228#if defined key_agrif
229      IF(.NOT. Agrif_Root())   CALL Agrif_Sponge_dyn        ! momemtum sponge
230#endif
231                               CALL dyn_hpg( kstp )         ! horizontal gradient of Hydrostatic pressure
232                               CALL dyn_bfr( kstp )           ! bottom friction   
233                               CALL dyn_zdf( kstp )         ! vertical diffusion
234                               CALL dyn_spg( kstp, indic )  ! surface pressure gradient
235                               CALL dyn_nxt( kstp )         ! lateral velocity at next time step
236
237                               CALL ssh_nxt( kstp )         ! sea surface height at next time step
238
239      IF( ln_diahsb        )   CALL dia_hsb( kstp )         ! - ML - global conservation diagnostics
240
241      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
242      ! Control and restarts
243      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
244                               CALL stp_ctl( kstp, indic )
245      IF( indic < 0        )   THEN
246                               CALL ctl_stop( 'step: indic < 0' )
247                               CALL dia_wri_state( 'output.abort', kstp )
248      ENDIF
249      IF( kstp == nit000   )   CALL iom_close( numror )     ! close input  ocean restart file
250      IF( lrst_oce         )   CALL rst_write    ( kstp )   ! write output ocean restart file
251      IF( lk_obc           )   CALL obc_rst_write( kstp )   ! write open boundary restart file
252
253      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
254      ! Trends                              (ua, va, ta, sa used as workspace)
255      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
256      IF( nstop == 0 ) THEN                         
257         IF( lk_trddyn     )   CALL trd_dwr( kstp )         ! trends: dynamics
258         IF( lk_trdtra     )   CALL trd_twr( kstp )         ! trends: active tracers
259         IF( lk_trdmld     )   CALL trd_mld( kstp )         ! trends: Mixed-layer
260         IF( lk_trdvor     )   CALL trd_vor( kstp )         ! trends: vorticity budget
261      ENDIF
262
263      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
264      ! Coupled mode
265      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
266      IF( lk_cpl           )   CALL sbc_cpl_snd( kstp )     ! coupled mode : field exchanges
267      !
268      !
269   END SUBROUTINE stp
270
271   !!======================================================================
272END MODULE step
Note: See TracBrowser for help on using the repository browser.