New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcopt.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/TOP_SRC/LOBSTER – NEMO

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/TOP_SRC/LOBSTER/trcopt.F90 @ 2287

Last change on this file since 2287 was 2287, checked in by smasson, 14 years ago

update licence of all NEMO files...
  • Property svn:keywords set to Id
File size: 6.6 KB
Line 
1MODULE trcopt
2   !!======================================================================
3   !!                         ***  MODULE trcopt  ***
4   !! TOP :   LOBSTER Compute the light availability in the water column
5   !!======================================================================
6   !! History :    -   !  1995-05  (M. Levy) Original code
7   !!              -   !  1999-09  (J.-M. Andre, M. Levy)
8   !!              -   !  1999-11  (C. Menkes, M.-A. Foujols) itabe initial
9   !!              -   !  2000-02  (M.A. Foujols) change x**y par exp(y*log(x))
10   !!   NEMO      2.0  !  2007-12  (C. Deltel, G. Madec)  F90
11   !!             3.2  !  2009-04  (C. Ethe, G. Madec)  minor optimisation + style
12   !!----------------------------------------------------------------------
13#if defined key_lobster
14   !!----------------------------------------------------------------------
15   !!   'key_lobster'                                     LOBSTER bio-model
16   !!----------------------------------------------------------------------
17   !!   trc_opt        :   Compute the light availability in the water column
18   !!----------------------------------------------------------------------
19   USE oce_trc         !
20   USE trc
21   USE sms_lobster
22   USE prtctl_trc      ! Print control for debbuging
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   trc_opt   ! called in trcprg.F90
28
29   !!* Substitution
30#  include "top_substitute.h90"
31   !!----------------------------------------------------------------------
32   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
33   !! $Id$
34   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
35   !!----------------------------------------------------------------------
36
37CONTAINS
38
39   SUBROUTINE trc_opt( kt )
40      !!---------------------------------------------------------------------
41      !!                     ***  ROUTINE trc_opt  ***
42      !!
43      !! ** Purpose :   computes the light propagation in the water column
44      !!              and the euphotic layer depth
45      !!
46      !! ** Method  :   local par is computed in w layers using light propagation
47      !!              mean par in t layers are computed by integration
48      !!
49!!gm please remplace the '???' by true comments
50      !! ** Action  :   xpar   ???
51      !!                neln   ???
52      !!                xze    ???
53      !!---------------------------------------------------------------------
54      INTEGER, INTENT( in ) ::   kt   ! index of the time stepping
55      !!
56      INTEGER  ::   ji, jj, jk          ! dummy loop indices
57      CHARACTER (len=25) ::   charout   ! temporary character
58      REAL(wp) ::   zpig                ! log of the total pigment
59      REAL(wp) ::   zkr, zkg            ! total absorption coefficient in red and green
60      REAL(wp) ::   zcoef               ! temporary scalar
61      REAL(wp), DIMENSION(jpi,jpj)     ::   zpar100         ! irradiance at euphotic layer depth
62      REAL(wp), DIMENSION(jpi,jpj)     ::   zpar0m          ! irradiance just below the surface
63      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zparr, zparg    ! red and green compound of par
64
65      !!---------------------------------------------------------------------
66
67      IF( kt == nit000 ) THEN
68         IF(lwp) WRITE(numout,*)
69         IF(lwp) WRITE(numout,*) ' trc_opt : LOBSTER optic-model'
70         IF(lwp) WRITE(numout,*) ' ~~~~~~~ '
71      ENDIF
72
73      !                                          ! surface irradiance
74      zpar0m (:,:)   = qsr   (:,:) * 0.43        ! ------------------
75      zpar100(:,:)   = zpar0m(:,:) * 0.01
76      xpar   (:,:,1) = zpar0m(:,:)
77      zparr  (:,:,1) = zpar0m(:,:) * 0.5
78      zparg  (:,:,1) = zpar0m(:,:) * 0.5
79
80      !                                          ! Photosynthetically Available Radiation (PAR)
81      zcoef = 12 * redf / rcchl / rpig           ! --------------------------------------
82      DO jk = 2, jpk                                  ! local par at w-levels
83         DO jj = 1, jpj
84            DO ji = 1, jpi
85               zpig = LOG(  MAX( TINY(0.), trn(ji,jj,jk-1,jp_lob_phy) ) * zcoef  )
86               zkr  = xkr0 + xkrp * EXP( xlr * zpig )
87               zkg  = xkg0 + xkgp * EXP( xlg * zpig )
88               zparr(ji,jj,jk) = zparr(ji,jj,jk-1) * EXP( -zkr * fse3t(ji,jj,jk-1) )
89               zparg(ji,jj,jk) = zparg(ji,jj,jk-1) * EXP( -zkg * fse3t(ji,jj,jk-1) )
90            END DO
91        END DO
92      END DO
93      DO jk = 1, jpkm1                                ! mean par at t-levels
94         DO jj = 1, jpj
95            DO ji = 1, jpi
96               zpig = LOG(  MAX( TINY(0.), trn(ji,jj,jk,jp_lob_phy) ) * zcoef  )
97               zkr  = xkr0 + xkrp * EXP( xlr * zpig )
98               zkg  = xkg0 + xkgp * EXP( xlg * zpig )
99               zparr(ji,jj,jk) = zparr(ji,jj,jk) / ( zkr * fse3t(ji,jj,jk) ) * ( 1 - EXP( -zkr * fse3t(ji,jj,jk) ) )
100               zparg(ji,jj,jk) = zparg(ji,jj,jk) / ( zkg * fse3t(ji,jj,jk) ) * ( 1 - EXP( -zkg * fse3t(ji,jj,jk) ) )
101               xpar (ji,jj,jk) = MAX( zparr(ji,jj,jk) + zparg(ji,jj,jk), 1.e-15 )
102            END DO
103         END DO
104      END DO
105
106      !                                          ! Euphotic layer
107      !                                          ! --------------
108      neln(:,:) = 1                                   ! euphotic layer level
109      DO jk = 1, jpk                                  ! (i.e. 1rst T-level strictly below EL bottom)
110         DO jj = 1, jpj
111           DO ji = 1, jpi
112              IF( xpar(ji,jj,jk) >= zpar100(ji,jj) )   neln(ji,jj) = jk + 1 
113              !                                       ! nb. this is to ensure compatibility with
114              !                                       ! nmld_trc definition in trd_mld_trc_zint
115           END DO
116         END DO
117      END DO
118      !                                               ! Euphotic layer depth
119      DO jj = 1, jpj
120         DO ji = 1, jpi
121            xze(ji,jj) = fsdepw(ji,jj,neln(ji,jj))
122         END DO
123      END DO
124
125
126      IF(ln_ctl) THEN      ! print mean trends (used for debugging)
127         WRITE(charout, FMT="('opt')")
128         CALL prt_ctl_trc_info( charout )
129         CALL prt_ctl_trc( tab4d=trn, mask=tmask, clinfo=ctrcnm )
130      ENDIF
131      !
132   END SUBROUTINE trc_opt
133
134#else
135   !!======================================================================
136   !!  Dummy module :                                   No PISCES bio-model
137   !!======================================================================
138CONTAINS
139   SUBROUTINE trc_opt( kt )                   ! Empty routine
140      INTEGER, INTENT( in ) ::   kt
141      WRITE(*,*) 'trc_opt: You should not have seen this print! error?', kt
142   END SUBROUTINE trc_opt
143#endif 
144
145   !!======================================================================
146END MODULE  trcopt
Note: See TracBrowser for help on using the repository browser.