New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zlys.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/TOP_SRC/PISCES – NEMO

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/TOP_SRC/PISCES/p4zlys.F90 @ 2287

Last change on this file since 2287 was 2287, checked in by smasson, 14 years ago

update licence of all NEMO files...
  • Property svn:keywords set to Id
File size: 8.8 KB
Line 
1MODULE p4zlys
2   !!======================================================================
3   !!                         ***  MODULE p4zlys  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!----------------------------------------------------------------------
12#if defined key_pisces
13   !!----------------------------------------------------------------------
14   !!   'key_pisces'                                       PISCES bio-model
15   !!----------------------------------------------------------------------
16   !!   p4z_lys        :   Compute the CaCO3 dissolution
17   !!   p4z_lys_init   :   Read the namelist parameters
18   !!----------------------------------------------------------------------
19   USE trc
20   USE oce_trc         !
21   USE trc
22   USE sms_pisces
23   USE prtctl_trc
24   USE iom
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_lys         ! called in trcsms_pisces.F90
30   PUBLIC   p4z_lys_init    ! called in trcsms_pisces.F90
31
32   !! * Shared module variables
33   REAL(wp), PUBLIC ::   &
34     kdca = 0.327e3_wp   ,  &  !:
35     nca  = 1.0_wp             !:
36
37   !! * Module variables
38   REAL(wp) :: &
39      calcon = 1.03E-2        ! mean calcite concentration [Ca2+] in sea water [mole/kg solution]
40
41   INTEGER ::               &
42     rmtss                    !: number of seconds per month
43
44   !!----------------------------------------------------------------------
45   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
46   !! $Id$
47   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49
50CONTAINS
51
52   SUBROUTINE p4z_lys( kt )
53      !!---------------------------------------------------------------------
54      !!                     ***  ROUTINE p4z_lys  ***
55      !!
56      !! ** Purpose :   CALCULATES DEGREE OF CACO3 SATURATION IN THE WATER
57      !!                COLUMN, DISSOLUTION/PRECIPITATION OF CACO3 AND LOSS
58      !!                OF CACO3 TO THE CACO3 SEDIMENT POOL.
59      !!
60      !! ** Method  : - ???
61      !!---------------------------------------------------------------------
62      INTEGER, INTENT(in) ::   kt ! ocean time step
63      INTEGER  ::   ji, jj, jk, jn
64      REAL(wp) ::   zbot, zalk, zdic, zph, zremco3, zah2
65      REAL(wp) ::   zdispot, zfact, zalka
66      REAL(wp) ::   zomegaca, zexcess, zexcess0
67      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zco3
68#if defined key_diatrc && defined key_iomput
69      REAL(wp) ::   zrfact2
70      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zcaldiss
71#endif
72      CHARACTER (len=25) :: charout
73      !!---------------------------------------------------------------------
74
75      zco3(:,:,:) = 0.
76
77# if defined key_diatrc && defined key_iomput
78      zcaldiss(:,:,:) = 0.
79# endif
80      !     -------------------------------------------
81      !     COMPUTE [CO3--] and [H+] CONCENTRATIONS
82      !     -------------------------------------------
83     
84      DO jn = 1, 5                               !  BEGIN OF ITERATION
85         !
86!CDIR NOVERRCHK
87         DO jk = 1, jpkm1
88!CDIR NOVERRCHK
89            DO jj = 1, jpj
90!CDIR NOVERRCHK
91               DO ji = 1, jpi
92
93                  ! SET DUMMY VARIABLE FOR TOTAL BORATE
94                  zbot  = borat(ji,jj,jk)
95
96                  ! SET DUMMY VARIABLE FOR TOTAL BORATE
97                  zbot  = borat(ji,jj,jk)
98                  zfact = rhop (ji,jj,jk) / 1000. + rtrn
99
100                  ! SET DUMMY VARIABLE FOR [H+]
101                  zph   = hi(ji,jj,jk) * tmask(ji,jj,jk) / zfact + ( 1.-tmask(ji,jj,jk) ) * 1.e-9
102
103                  ! SET DUMMY VARIABLE FOR [SUM(CO2)]GIVEN
104                  zdic  = trn(ji,jj,jk,jpdic) / zfact
105                  zalka = trn(ji,jj,jk,jptal) / zfact
106
107                  ! CALCULATE [ALK]([CO3--], [HCO3-])
108                  zalk  = zalka - (  akw3(ji,jj,jk) / zph - zph   &
109                     &             + zbot / (1.+ zph / akb3(ji,jj,jk) )  )
110
111                  ! CALCULATE [H+] and [CO3--]
112                  zah2 = SQRT( (zdic-zalk)*(zdic-zalk)+   &
113                     &     4.*(zalk*ak23(ji,jj,jk)/ak13(ji,jj,jk))   &
114                     &     *(2*zdic-zalk))
115
116                  zah2=0.5*ak13(ji,jj,jk)/zalk*((zdic-zalk)+zah2)
117                  zco3(ji,jj,jk) = zalk/(2.+zah2/ak23(ji,jj,jk))*zfact
118
119                  hi(ji,jj,jk)  = zah2*zfact
120
121               END DO
122            END DO
123         END DO
124         !
125      END DO 
126
127      !     ---------------------------------------------------------
128      !        CALCULATE DEGREE OF CACO3 SATURATION AND CORRESPONDING
129      !        DISSOLOUTION AND PRECIPITATION OF CACO3 (BE AWARE OF
130      !        MGCO3)
131      !     ---------------------------------------------------------
132
133      DO jk = 1, jpkm1
134         DO jj = 1, jpj
135            DO ji = 1, jpi
136
137               ! DEVIATION OF [CO3--] FROM SATURATION VALUE
138               zomegaca = ( calcon * zco3(ji,jj,jk) ) / aksp(ji,jj,jk)
139
140               ! SET DEGREE OF UNDER-/SUPERSATURATION
141               zexcess0 = MAX( 0., ( 1.- zomegaca ) )
142               zexcess  = zexcess0**nca
143
144               ! AMOUNT CACO3 (12C) THAT RE-ENTERS SOLUTION
145               !       (ACCORDING TO THIS FORMULATION ALSO SOME PARTICULATE
146               !       CACO3 GETS DISSOLVED EVEN IN THE CASE OF OVERSATURATION)
147# if defined key_degrad
148              zdispot = kdca * zexcess * trn(ji,jj,jk,jpcal) * facvol(ji,jj,jk)
149# else
150              zdispot = kdca * zexcess * trn(ji,jj,jk,jpcal)
151# endif
152
153              !  CHANGE OF [CO3--] , [ALK], PARTICULATE [CACO3],
154              !       AND [SUM(CO2)] DUE TO CACO3 DISSOLUTION/PRECIPITATION
155              zremco3 = zdispot / rmtss
156              zco3(ji,jj,jk) = zco3(ji,jj,jk) + zremco3 * rfact
157              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + 2. * zremco3
158              tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) -      zremco3
159              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) +      zremco3
160
161# if defined key_diatrc && defined key_iomput
162              zcaldiss(ji,jj,jk) = zremco3  ! calcite dissolution
163# endif
164            END DO
165         END DO
166      END DO
167
168# if defined key_diatrc
169#  if ! defined key_iomput
170      trc3d(:,:,:,jp_pcs0_3d    ) = hi  (:,:,:)          * tmask(:,:,:)
171      trc3d(:,:,:,jp_pcs0_3d + 1) = zco3(:,:,:)          * tmask(:,:,:)
172      trc3d(:,:,:,jp_pcs0_3d + 2) = aksp(:,:,:) / calcon * tmask(:,:,:)
173#  else
174      zrfact2 = 1.e3 * rfact2r
175      CALL iom_put( "PH"    , hi      (:,:,:)           * tmask(:,:,:) )
176      CALL iom_put( "CO3"   , zco3    (:,:,:)           * tmask(:,:,:) )
177      CALL iom_put( "CO3sat", aksp    (:,:,:) / calcon  * tmask(:,:,:) )
178      CALL iom_put( "DCAL"  , zcaldiss(:,:,:) * zrfact2 * tmask(:,:,:) )
179#  endif
180# endif
181      !
182       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
183         WRITE(charout, FMT="('lys ')")
184         CALL prt_ctl_trc_info(charout)
185         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
186       ENDIF
187
188   END SUBROUTINE p4z_lys
189
190   SUBROUTINE p4z_lys_init
191
192      !!----------------------------------------------------------------------
193      !!                  ***  ROUTINE p4z_lys_init  ***
194      !!
195      !! ** Purpose :   Initialization of CaCO3 dissolution parameters
196      !!
197      !! ** Method  :   Read the nampiscal namelist and check the parameters
198      !!      called at the first timestep (nit000)
199      !!
200      !! ** input   :   Namelist nampiscal
201      !!
202      !!----------------------------------------------------------------------
203
204      NAMELIST/nampiscal/ kdca, nca
205
206      REWIND( numnat )                     ! read numnat
207      READ  ( numnat, nampiscal )
208
209      IF(lwp) THEN                         ! control print
210         WRITE(numout,*) ' '
211         WRITE(numout,*) ' Namelist parameters for CaCO3 dissolution, nampiscal'
212         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
213         WRITE(numout,*) '    diss. rate constant calcite (per month)   kdca      =', kdca
214         WRITE(numout,*) '    order of reaction for calcite dissolution nca       =', nca
215      ENDIF
216
217      ! Number of seconds per month
218      rmtss =  nyear_len(1) * rday / raamo
219
220   END SUBROUTINE p4z_lys_init
221
222#else
223   !!======================================================================
224   !!  Dummy module :                                   No PISCES bio-model
225   !!======================================================================
226CONTAINS
227   SUBROUTINE p4z_lys( kt )                   ! Empty routine
228      INTEGER, INTENT( in ) ::   kt
229      WRITE(*,*) 'p4z_lys: You should not have seen this print! error?', kt
230   END SUBROUTINE p4z_lys
231#endif 
232   !!======================================================================
233END MODULE  p4zlys
Note: See TracBrowser for help on using the repository browser.