source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/TOP_SRC/trcini.F90 @ 2287

MODULE trcini
   !!======================================================================
   !!                         ***  MODULE trcini  ***
   !! TOP :   Manage the passive tracer initialization
   !!======================================================================
   !! History :    -   !  1991-03  ()  original code
   !!             1.0  !  2005-03 (O. Aumont, A. El Moussaoui) F90
   !!              -   !  2005-10 (C. Ethe) print control
   !!             2.0  !  2005-10 (C. Ethe, G. Madec) revised architecture
   !!----------------------------------------------------------------------
#if defined key_top
   !!----------------------------------------------------------------------
   !!   'key_top'                                                TOP models
   !!----------------------------------------------------------------------
   !!----------------------------------------------------------------------
   !!   trc_init :   Initialization for passive tracer
   !!----------------------------------------------------------------------
   USE oce_trc
   USE trc
   USE trcrst
   USE trcnam          ! Namelist read
   USE trcini_cfc      ! CFC      initialisation
   USE trcini_lobster  ! LOBSTER  initialisation
   USE trcini_pisces   ! PISCES   initialisation
   USE trcini_c14b     ! C14 bomb initialisation
   USE trcini_my_trc   ! MY_TRC   initialisation
   USE trcdta   
#if defined key_offline
   USE daymod
#endif
   USE zpshde          ! partial step: hor. derivative   (zps_hde routine)
   USE in_out_manager  ! I/O manager
   USE prtctl_trc      ! Print control passive tracers (prt_ctl_trc_init routine)
   USE lib_mpp         ! distributed memory computing library
   
   IMPLICIT NONE
   PRIVATE
   
   PUBLIC   trc_init   ! called by opa

    !! * Substitutions
#  include "domzgr_substitute.h90"
  
CONTAINS
   
   SUBROUTINE trc_init
      !!---------------------------------------------------------------------
      !!                     ***  ROUTINE trc_init  ***
      !!
      !! ** Purpose :   Initialization of the passive tracer fields 
      !!
      !! ** Method  : - read namelist
      !!              - control the consistancy 
      !!              - compute specific initialisations
      !!              - set initial tracer fields (either read restart 
      !!                or read data or analytical formulation
      !!---------------------------------------------------------------------
      INTEGER ::   jk, jn    ! dummy loop indices
      CHARACTER (len=25) :: charout

      !!---------------------------------------------------------------------

      IF(lwp) WRITE(numout,*)
      IF(lwp) WRITE(numout,*) 'trc_init : initial set up of the passive tracers'
      IF(lwp) WRITE(numout,*) '~~~~~~~'

      !                 ! masked grid volume
      DO jk = 1, jpk
         cvol(:,:,jk) = e1t(:,:) * e2t(:,:) * fse3t(:,:,jk) * tmask(:,:,jk) * tmask_i(:,:)
      END DO

      ! total volume of the ocean
#if ! defined key_degrad
      areatot = SUM( cvol(:,:,:) )
#else
      areatot = SUM( cvol(:,:,:) * facvol(:,:,:) )  ! degrad option: reduction by facvol
#endif
      IF( lk_mpp )   CALL mpp_sum( areatot )        ! sum over the global domain  

                                  CALL trc_nam      ! read passive tracers namelists

      ! restart for passive tracer (input)
      IF( ln_rsttr ) THEN
         IF(lwp) WRITE(numout,*) '       read a restart file for passive tracer : ', cn_trcrst_in
         IF(lwp) WRITE(numout,*) ' '
      ELSE
         IF(lwp) WRITE(numout,*)
         DO jn = 1, jptra
            IF( lwp .AND. lutini(jn) )  &                  ! open input FILE only IF lutini(jn) is true
            &  WRITE(numout,*) '        read an initial file  for passive tracer number :', jn, ' traceur : ', ctrcnm(jn) 
         END DO
      ENDIF

      IF( ln_dm2dc .AND. ( lk_pisces .OR. lk_lobster ) )    &
      &       CALL ctl_stop( ' The diurnal cycle is not compatible with PISCES or LOBSTER  ' )

      IF( lk_lobster ) THEN   ;   CALL trc_ini_lobster      ! LOBSTER bio-model
      ELSE                    ;   IF(lwp) WRITE(numout,*) '          LOBSTER not used'
      ENDIF
      
      IF( lk_pisces  ) THEN   ;   CALL trc_ini_pisces       ! PISCES  bio-model
      ELSE                    ;   IF(lwp) WRITE(numout,*) '          PISCES not used'
      ENDIF
      
      IF( lk_cfc     ) THEN   ;   CALL trc_ini_cfc          ! CFC     tracers
      ELSE                    ;   IF(lwp) WRITE(numout,*) '          CFC not used'
      ENDIF

      IF( lk_c14b    ) THEN   ;   CALL trc_ini_c14b         ! C14 bomb  tracer
      ELSE                    ;   IF(lwp) WRITE(numout,*) '          C14 not used'
      ENDIF
      
      IF( lk_my_trc  ) THEN   ;   CALL trc_ini_my_trc       ! MY_TRC  tracers
      ELSE                    ;   IF(lwp) WRITE(numout,*) '          MY_TRC not used'
      ENDIF

      IF( .NOT. ln_rsttr ) THEN 
#if defined key_offline
         CALL day_init      ! calendar
#endif
# if defined key_dtatrc
         ! Initialization of tracer from a file that may also be used for damping
         CALL trc_dta( nit000 )
         DO jn = 1, jptra
            IF( lutini(jn) )   trn(:,:,:,jn) = trdta(:,:,:,jn) * tmask(:,:,:)   ! initialisation from file if required
         END DO
# endif
         trb(:,:,:,:) = trn(:,:,:,:)
      ELSE
         !
         CALL trc_rst_read      ! restart from a file
         !
      ENDIF

      tra(:,:,:,:) = 0.
      
      IF( ln_zps .AND. .NOT. lk_trc_c1d )   &              ! Partial steps: before horizontal gradient of passive
      &                     CALL zps_hde( nit000, jptra, trn, gtru, gtrv )       ! tracers at the bottom ocean level


      !                 ! Computation content of all tracers
      trai = 0.e0
      DO jn = 1, jptra
#if ! defined key_degrad
         trai = trai + SUM( trn(:,:,:,jn) * cvol(:,:,:) )
#else
         trai = trai + SUM( trn(:,:,:,jn) * cvol(:,:,:) * facvol(:,:,:) ) ! degrad option: reduction by facvol
#endif
      END DO      
      IF( lk_mpp )   CALL mpp_sum( trai )     ! sum over the global domain  


      !                 ! control print
      IF(lwp) WRITE(numout,*)
      IF(lwp) WRITE(numout,*)
      IF(lwp) WRITE(numout,*) '          *** Total number of passive tracer jptra = ', jptra
      IF(lwp) WRITE(numout,*) '          *** Total volume of ocean                = ', areatot
      IF(lwp) WRITE(numout,*) '          *** Total inital content of all tracers  = ', trai
      IF(lwp) WRITE(numout,*)

      IF( ln_ctl )   CALL prt_ctl_trc_init      ! control print
      !

      IF(ln_ctl) THEN      ! print mean trends (used for debugging)
         WRITE(charout, FMT="('ini ')")
         CALL prt_ctl_trc_info( charout )
         CALL prt_ctl_trc( tab4d=trn, mask=tmask, clinfo=ctrcnm )
      ENDIF

   END SUBROUTINE trc_init

#else
   !!----------------------------------------------------------------------
   !!  Empty module :                                     No passive tracer
   !!----------------------------------------------------------------------
CONTAINS
   SUBROUTINE trc_init                      ! Dummy routine   
   END SUBROUTINE trc_init
#endif

   !!----------------------------------------------------------------------
   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
   !! $Id$ 
   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
   !!======================================================================
END MODULE trcini