New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcini.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/TOP_SRC – NEMO

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/TOP_SRC/trcini.F90 @ 2431

Last change on this file since 2431 was 2431, checked in by cetlod, 13 years ago

Improve the Offline together with the 1D vertical configuration
  • Property svn:keywords set to Id
File size: 7.5 KB
Line 
1MODULE trcini
2   !!======================================================================
3   !!                         ***  MODULE trcini  ***
4   !! TOP :   Manage the passive tracer initialization
5   !!======================================================================
6   !! History :    -   !  1991-03  ()  original code
7   !!             1.0  !  2005-03 (O. Aumont, A. El Moussaoui) F90
8   !!              -   !  2005-10 (C. Ethe) print control
9   !!             2.0  !  2005-10 (C. Ethe, G. Madec) revised architecture
10   !!----------------------------------------------------------------------
11#if defined key_top
12   !!----------------------------------------------------------------------
13   !!   'key_top'                                                TOP models
14   !!----------------------------------------------------------------------
15   !!----------------------------------------------------------------------
16   !!   trc_init :   Initialization for passive tracer
17   !!----------------------------------------------------------------------
18   USE oce_trc
19   USE trc
20   USE trcrst
21   USE trcnam          ! Namelist read
22   USE trcini_cfc      ! CFC      initialisation
23   USE trcini_lobster  ! LOBSTER  initialisation
24   USE trcini_pisces   ! PISCES   initialisation
25   USE trcini_c14b     ! C14 bomb initialisation
26   USE trcini_my_trc   ! MY_TRC   initialisation
27   USE trcdta   
28#if defined key_offline
29   USE daymod
30#endif
31   USE zpshde          ! partial step: hor. derivative   (zps_hde routine)
32   USE in_out_manager  ! I/O manager
33   USE prtctl_trc      ! Print control passive tracers (prt_ctl_trc_init routine)
34   USE lib_mpp         ! distributed memory computing library
35   
36   IMPLICIT NONE
37   PRIVATE
38   
39   PUBLIC   trc_init   ! called by opa
40
41    !! * Substitutions
42#  include "domzgr_substitute.h90"
43 
44CONTAINS
45   
46   SUBROUTINE trc_init
47      !!---------------------------------------------------------------------
48      !!                     ***  ROUTINE trc_init  ***
49      !!
50      !! ** Purpose :   Initialization of the passive tracer fields
51      !!
52      !! ** Method  : - read namelist
53      !!              - control the consistancy
54      !!              - compute specific initialisations
55      !!              - set initial tracer fields (either read restart
56      !!                or read data or analytical formulation
57      !!---------------------------------------------------------------------
58      INTEGER ::   jk, jn    ! dummy loop indices
59      CHARACTER (len=25) :: charout
60
61      !!---------------------------------------------------------------------
62
63      IF(lwp) WRITE(numout,*)
64      IF(lwp) WRITE(numout,*) 'trc_init : initial set up of the passive tracers'
65      IF(lwp) WRITE(numout,*) '~~~~~~~'
66
67      !                 ! masked grid volume
68      DO jk = 1, jpk
69         cvol(:,:,jk) = e1t(:,:) * e2t(:,:) * fse3t(:,:,jk) * tmask(:,:,jk) * tmask_i(:,:)
70      END DO
71
72      ! total volume of the ocean
73#if ! defined key_degrad
74      areatot = SUM( cvol(:,:,:) )
75#else
76      areatot = SUM( cvol(:,:,:) * facvol(:,:,:) )  ! degrad option: reduction by facvol
77#endif
78      IF( lk_mpp )   CALL mpp_sum( areatot )        ! sum over the global domain 
79
80                                  CALL trc_nam      ! read passive tracers namelists
81
82      ! restart for passive tracer (input)
83      IF( ln_rsttr ) THEN
84         IF(lwp) WRITE(numout,*) '       read a restart file for passive tracer : ', cn_trcrst_in
85         IF(lwp) WRITE(numout,*) ' '
86      ELSE
87         IF(lwp) WRITE(numout,*)
88         DO jn = 1, jptra
89            IF( lwp .AND. lutini(jn) )  &                  ! open input FILE only IF lutini(jn) is true
90            &  WRITE(numout,*) '        read an initial file  for passive tracer number :', jn, ' traceur : ', ctrcnm(jn) 
91         END DO
92      ENDIF
93
94      IF( ln_dm2dc .AND. ( lk_pisces .OR. lk_lobster ) )    &
95         &       CALL ctl_stop( ' The diurnal cycle is not compatible with PISCES or LOBSTER  ' )
96
97      IF( nn_cla == 1 )   &
98         &       CALL ctl_stop( ' Cross Land Advection not yet implemented with passive tracer ; nn_cla must be 0' )
99
100      IF( lk_lobster ) THEN   ;   CALL trc_ini_lobster      ! LOBSTER bio-model
101      ELSE                    ;   IF(lwp) WRITE(numout,*) '          LOBSTER not used'
102      ENDIF
103     
104      IF( lk_pisces  ) THEN   ;   CALL trc_ini_pisces       ! PISCES  bio-model
105      ELSE                    ;   IF(lwp) WRITE(numout,*) '          PISCES not used'
106      ENDIF
107     
108      IF( lk_cfc     ) THEN   ;   CALL trc_ini_cfc          ! CFC     tracers
109      ELSE                    ;   IF(lwp) WRITE(numout,*) '          CFC not used'
110      ENDIF
111
112      IF( lk_c14b    ) THEN   ;   CALL trc_ini_c14b         ! C14 bomb  tracer
113      ELSE                    ;   IF(lwp) WRITE(numout,*) '          C14 not used'
114      ENDIF
115     
116      IF( lk_my_trc  ) THEN   ;   CALL trc_ini_my_trc       ! MY_TRC  tracers
117      ELSE                    ;   IF(lwp) WRITE(numout,*) '          MY_TRC not used'
118      ENDIF
119
120      IF( .NOT. ln_rsttr ) THEN 
121#if defined key_offline
122         CALL day_init      ! calendar
123#endif
124# if defined key_dtatrc
125         ! Initialization of tracer from a file that may also be used for damping
126         CALL trc_dta( nit000 )
127         DO jn = 1, jptra
128            IF( lutini(jn) )   trn(:,:,:,jn) = trdta(:,:,:,jn) * tmask(:,:,:)   ! initialisation from file if required
129         END DO
130# endif
131         trb(:,:,:,:) = trn(:,:,:,:)
132      ELSE
133         !
134         CALL trc_rst_read      ! restart from a file
135         !
136      ENDIF
137
138      tra(:,:,:,:) = 0.
139     
140      IF( ln_zps .AND. .NOT. lk_c1d )   &              ! Partial steps: before horizontal gradient of passive
141      &                     CALL zps_hde( nit000, jptra, trn, gtru, gtrv )       ! tracers at the bottom ocean level
142
143
144      !                 ! Computation content of all tracers
145      trai = 0.e0
146      DO jn = 1, jptra
147#if ! defined key_degrad
148         trai = trai + SUM( trn(:,:,:,jn) * cvol(:,:,:) )
149#else
150         trai = trai + SUM( trn(:,:,:,jn) * cvol(:,:,:) * facvol(:,:,:) ) ! degrad option: reduction by facvol
151#endif
152      END DO     
153      IF( lk_mpp )   CALL mpp_sum( trai )     ! sum over the global domain 
154
155
156      !                 ! control print
157      IF(lwp) WRITE(numout,*)
158      IF(lwp) WRITE(numout,*)
159      IF(lwp) WRITE(numout,*) '          *** Total number of passive tracer jptra = ', jptra
160      IF(lwp) WRITE(numout,*) '          *** Total volume of ocean                = ', areatot
161      IF(lwp) WRITE(numout,*) '          *** Total inital content of all tracers  = ', trai
162      IF(lwp) WRITE(numout,*)
163
164      IF( ln_ctl )   CALL prt_ctl_trc_init      ! control print
165      !
166
167      IF(ln_ctl) THEN      ! print mean trends (used for debugging)
168         WRITE(charout, FMT="('ini ')")
169         CALL prt_ctl_trc_info( charout )
170         CALL prt_ctl_trc( tab4d=trn, mask=tmask, clinfo=ctrcnm )
171      ENDIF
172
173   END SUBROUTINE trc_init
174
175#else
176   !!----------------------------------------------------------------------
177   !!  Empty module :                                     No passive tracer
178   !!----------------------------------------------------------------------
179CONTAINS
180   SUBROUTINE trc_init                      ! Dummy routine   
181   END SUBROUTINE trc_init
182#endif
183
184   !!----------------------------------------------------------------------
185   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
186   !! $Id$
187   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
188   !!======================================================================
189END MODULE trcini
Note: See TracBrowser for help on using the repository browser.