New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynadv_cen2.F90 in branches/r6232_hadgem3_cplfld/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/r6232_hadgem3_cplfld/NEMOGCM/NEMO/OPA_SRC/DYN/dynadv_cen2.F90 @ 7462

Last change on this file since 7462 was 7462, checked in by jcastill, 7 years ago

Remove svn keys

File size: 8.3 KB
Line 
1MODULE dynadv_cen2
2   !!======================================================================
3   !!                       ***  MODULE  dynadv  ***
4   !! Ocean dynamics: Update the momentum trend with the flux form advection
5   !!                 using a 2nd order centred scheme
6   !!======================================================================
7   !! History :  2.0  ! 2006-08  (G. Madec, S. Theetten)  Original code
8   !!            3.2  ! 2009-07  (R. Benshila)  Suppression of rigid-lid option
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   dyn_adv_cen2       : flux form momentum advection (ln_dynadv_cen2=T)
13   !!                        trends using a 2nd order centred scheme 
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE trd_oce        ! trends: ocean variables
18   USE trddyn         ! trend manager: dynamics
19   !
20   USE in_out_manager ! I/O manager
21   USE lib_mpp        ! MPP library
22   USE prtctl         ! Print control
23   USE wrk_nemo       ! Memory Allocation
24   USE timing         ! Timing
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   dyn_adv_cen2   ! routine called by step.F90
30
31   !! * Substitutions
32#  include "domzgr_substitute.h90"
33#  include "vectopt_loop_substitute.h90"
34   !!----------------------------------------------------------------------
35   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
36   !! $Id$
37   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
38   !!----------------------------------------------------------------------
39CONTAINS
40
41   SUBROUTINE dyn_adv_cen2( kt )
42      !!----------------------------------------------------------------------
43      !!                  ***  ROUTINE dyn_adv_cen2  ***
44      !!
45      !! ** Purpose :   Compute the now momentum advection trend in flux form
46      !!              and the general trend of the momentum equation.
47      !!
48      !! ** Method  :   Trend evaluated using now fields (centered in time)
49      !!
50      !! ** Action  :   (ua,va) updated with the now vorticity term trend
51      !!----------------------------------------------------------------------
52      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
53      !
54      INTEGER  ::   ji, jj, jk   ! dummy loop indices
55      REAL(wp) ::   zbu, zbv     ! local scalars
56      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zfu_t, zfv_t, zfu_f, zfv_f, zfu_uw, zfv_vw, zfw
57      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zfu, zfv
58      !!----------------------------------------------------------------------
59      !
60      IF( nn_timing == 1 )  CALL timing_start('dyn_adv_cen2')
61      !
62      CALL wrk_alloc( jpi, jpj, jpk, zfu_t, zfv_t, zfu_f, zfv_f, zfu_uw, zfv_vw, zfu, zfv, zfw )
63      !
64      IF( kt == nit000 .AND. lwp ) THEN
65         WRITE(numout,*)
66         WRITE(numout,*) 'dyn_adv_cen2 : 2nd order flux form momentum advection'
67         WRITE(numout,*) '~~~~~~~~~~~~'
68      ENDIF
69      !
70      IF( l_trddyn ) THEN           ! Save ua and va trends
71         zfu_uw(:,:,:) = ua(:,:,:)
72         zfv_vw(:,:,:) = va(:,:,:)
73      ENDIF
74
75      !                                      ! ====================== !
76      !                                      !  Horizontal advection  !
77      DO jk = 1, jpkm1                       ! ====================== !
78         !                                         ! horizontal volume fluxes
79         zfu(:,:,jk) = 0.25 * e2u(:,:) * fse3u(:,:,jk) * un(:,:,jk)
80         zfv(:,:,jk) = 0.25 * e1v(:,:) * fse3v(:,:,jk) * vn(:,:,jk)
81         !
82         DO jj = 1, jpjm1                          ! horizontal momentum fluxes at T- and F-point
83            DO ji = 1, fs_jpim1   ! vector opt.
84               zfu_t(ji+1,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji+1,jj  ,jk) )
85               zfv_f(ji  ,jj  ,jk) = ( zfv(ji,jj,jk) + zfv(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji  ,jj+1,jk) )
86               zfu_f(ji  ,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji+1,jj  ,jk) )
87               zfv_t(ji  ,jj+1,jk) = ( zfv(ji,jj,jk) + zfv(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji  ,jj+1,jk) )
88            END DO
89         END DO
90         DO jj = 2, jpjm1                          ! divergence of horizontal momentum fluxes
91            DO ji = fs_2, fs_jpim1   ! vector opt.
92               zbu = e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
93               zbv = e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
94               !
95               ua(ji,jj,jk) = ua(ji,jj,jk) - (  zfu_t(ji+1,jj  ,jk) - zfu_t(ji  ,jj  ,jk)    &
96                  &                           + zfv_f(ji  ,jj  ,jk) - zfv_f(ji  ,jj-1,jk)  ) / zbu
97               va(ji,jj,jk) = va(ji,jj,jk) - (  zfu_f(ji  ,jj  ,jk) - zfu_f(ji-1,jj  ,jk)    &
98                  &                           + zfv_t(ji  ,jj+1,jk) - zfv_t(ji  ,jj  ,jk)  ) / zbv
99            END DO
100         END DO
101      END DO
102      !
103      IF( l_trddyn ) THEN                          ! save the horizontal advection trend for diagnostic
104         zfu_uw(:,:,:) = ua(:,:,:) - zfu_uw(:,:,:)
105         zfv_vw(:,:,:) = va(:,:,:) - zfv_vw(:,:,:)
106         CALL trd_dyn( zfu_uw, zfv_vw, jpdyn_keg, kt )
107         zfu_t(:,:,:) = ua(:,:,:)
108         zfv_t(:,:,:) = va(:,:,:)
109      ENDIF
110      !
111
112      !                                      ! ==================== !
113      !                                      !  Vertical advection  !
114      DO jk = 1, jpkm1                       ! ==================== !
115         !                                         ! Vertical volume fluxesÊ
116         zfw(:,:,jk) = 0.25 * e1t(:,:) * e2t(:,:) * wn(:,:,jk)
117         !
118         IF( jk == 1 ) THEN                        ! surface/bottom advective fluxes                   
119            zfu_uw(:,:,jpk) = 0.e0                      ! Bottom  value : flux set to zero
120            zfv_vw(:,:,jpk) = 0.e0
121            !                                           ! Surface value :
122            IF( lk_vvl ) THEN                                ! variable volume : flux set to zero
123               zfu_uw(:,:, 1 ) = 0.e0   
124               zfv_vw(:,:, 1 ) = 0.e0
125            ELSE                                             ! constant volume : advection through the surface
126               DO jj = 2, jpjm1
127                  DO ji = fs_2, fs_jpim1
128                     zfu_uw(ji,jj, 1 ) = 2.e0 * ( zfw(ji,jj,1) + zfw(ji+1,jj  ,1) ) * un(ji,jj,1)
129                     zfv_vw(ji,jj, 1 ) = 2.e0 * ( zfw(ji,jj,1) + zfw(ji  ,jj+1,1) ) * vn(ji,jj,1)
130                  END DO
131               END DO
132            ENDIF
133         ELSE                                      ! interior fluxes
134            DO jj = 2, jpjm1
135               DO ji = fs_2, fs_jpim1   ! vector opt.
136                  zfu_uw(ji,jj,jk) = ( zfw(ji,jj,jk)+ zfw(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji,jj,jk-1) )
137                  zfv_vw(ji,jj,jk) = ( zfw(ji,jj,jk)+ zfw(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji,jj,jk-1) )
138               END DO
139            END DO
140         ENDIF
141      END DO
142      DO jk = 1, jpkm1                             ! divergence of vertical momentum flux divergence
143         DO jj = 2, jpjm1 
144            DO ji = fs_2, fs_jpim1   ! vector opt.
145               ua(ji,jj,jk) =  ua(ji,jj,jk) - ( zfu_uw(ji,jj,jk) - zfu_uw(ji,jj,jk+1) )    &
146                  &  / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) )
147               va(ji,jj,jk) =  va(ji,jj,jk) - ( zfv_vw(ji,jj,jk) - zfv_vw(ji,jj,jk+1) )    &
148                  &  / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) )
149            END DO
150         END DO
151      END DO
152      !
153      IF( l_trddyn ) THEN                          ! save the vertical advection trend for diagnostic
154         zfu_t(:,:,:) = ua(:,:,:) - zfu_t(:,:,:)
155         zfv_t(:,:,:) = va(:,:,:) - zfv_t(:,:,:)
156         CALL trd_dyn( zfu_t, zfv_t, jpdyn_zad, kt )
157      ENDIF
158      !                                            ! Control print
159      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' cen2 adv - Ua: ', mask1=umask,   &
160         &                       tab3d_2=va, clinfo2=           ' Va: ', mask2=vmask, clinfo3='dyn' )
161      !
162      CALL wrk_dealloc( jpi, jpj, jpk, zfu_t, zfv_t, zfu_f, zfv_f, zfu_uw, zfv_vw, zfu, zfv, zfw )
163      !
164      IF( nn_timing == 1 )  CALL timing_stop('dyn_adv_cen2')
165      !
166   END SUBROUTINE dyn_adv_cen2
167
168   !!==============================================================================
169END MODULE dynadv_cen2
Note: See TracBrowser for help on using the repository browser.