New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zpshde.F90 in tags/nemo_v3_2/nemo_v3_2/NEMO/OFF_SRC/TRA – NEMO

source: tags/nemo_v3_2/nemo_v3_2/NEMO/OFF_SRC/TRA/zpshde.F90 @ 1878

Last change on this file since 1878 was 1878, checked in by flavoni, 14 years ago

initial test for nemogcm
File size: 10.9 KB
Line 
1MODULE zpshde
2   !!==============================================================================
3   !!                       ***  MODULE zpshde   ***
4   !! z-coordinate - partial step : Horizontal Derivative
5   !!==============================================================================
6   
7   !!----------------------------------------------------------------------
8   !!   zps_hde      :  Horizontal DErivative of T, S and rd at the last
9   !!                   ocean level (Z-coord. with Partial Steps)
10   !!----------------------------------------------------------------------
11   !! * Modules used
12   USE dom_oce         ! ocean space domain variables
13   USE oce             ! ocean dynamics and tracers variables
14   USE phycst          ! physical constants
15   USE in_out_manager  ! I/O manager
16   USE eosbn2          ! ocean equation of state
17   USE lbclnk          ! lateral boundary conditions (or mpp link)
18
19   IMPLICIT NONE
20   PRIVATE
21
22   !! * Routine accessibility
23   PUBLIC zps_hde          ! routine called by step.F90
24
25   !! * module variables
26   INTEGER, DIMENSION(jpi,jpj) ::   &
27      mbatu, mbatv      ! bottom ocean level index at U- and V-points
28
29   !! * Substitutions
30#  include "domzgr_substitute.h90"
31#  include "vectopt_loop_substitute.h90"
32   !!----------------------------------------------------------------------
33   !!----------------------------------------------------------------------
34   !!  OPA 9.0 , LOCEAN-IPSL (2005)
35   !! $Id: zpshde.F90 1326 2009-02-20 10:08:16Z cetlod $
36   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
37   !!----------------------------------------------------------------------
38CONTAINS
39
40   SUBROUTINE zps_hde ( kt, ptem, psal, prd ,   &
41                            pgtu, pgsu, pgru,   &
42                            pgtv, pgsv, pgrv  )
43      !!----------------------------------------------------------------------
44      !!                     ***  ROUTINE zps_hde  ***
45      !!                   
46      !! ** Purpose :   Compute the horizontal derivative of T, S and rd
47      !!      at u- and v-points with a linear interpolation for z-coordinate
48      !!      with partial steps.
49      !!
50      !! ** Method  :   In z-coord with partial steps, scale factors on last
51      !!      levels are different for each grid point, so that T, S and rd
52      !!      points are not at the same depth as in z-coord. To have horizontal
53      !!      gradients again, we interpolate T and S at the good depth :
54      !!      Linear interpolation of T, S   
55      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
56      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
57      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
58      !!         This formulation computes the two cases:
59      !!                 CASE 1                   CASE 2 
60      !!         k-1  ___ ___________   k-1   ___ ___________
61      !!                    Ti  T~                  T~  Ti+1
62      !!                  _____                        _____
63      !!         k        |   |Ti+1     k           Ti |   |
64      !!                  |   |____                ____|   |
65      !!              ___ |   |   |           ___  |   |   |
66      !!                 
67      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
68      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
69      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
70      !!          or
71      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
72      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
73      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
74      !!          Idem for di(s) and dj(s)         
75      !!
76      !!      For rho, we call eos_insitu_2d which will compute rd~(t~,s~) at
77      !!      the good depth zh from interpolated T and S for the different
78      !!      formulation of the equation of state (eos).
79      !!      Gradient formulation for rho :
80      !!          di(rho) = rd~ - rd(i,j,k) or rd (i+1,j,k) - rd~
81      !!
82      !! ** Action  : - pgtu, pgsu, pgru: horizontal gradient of T, S
83      !!                and rd at U-points
84      !!              - pgtv, pgsv, pgrv: horizontal gradient of T, S
85      !!                and rd at V-points
86      !!
87      !! History :
88      !!   8.5  !  02-04  (A. Bozec)  Original code
89      !!   8.5  !  02-08  (G. Madec E. Durand)  Optimization and Free form
90      !!----------------------------------------------------------------------
91      !! * Arguments
92      INTEGER, INTENT( in ) ::   kt ! ocean time-step index
93      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT( in ) ::   &
94         ptem, psal, prd            ! 3D T, S and rd fields
95      REAL(wp), DIMENSION(jpi,jpj), INTENT( out ) ::   &
96         pgtu, pgsu, pgru,       &  ! horizontal grad. of T, S and rd at u-
97         pgtv, pgsv, pgrv           ! and v-points of the partial step level
98
99      !! * Local declarations
100      INTEGER ::   ji, jj,       &  ! Dummy loop indices
101                   iku,ikv          ! partial step level at u- and v-points
102      REAL(wp), DIMENSION(jpi,jpj) ::   &
103         zti, ztj, zsi, zsj,     &  ! interpolated value of T, S
104         zri, zrj,               &  ! and rd
105         zhgi, zhgj                 ! depth of interpolation for eos2d
106      REAL(wp) ::   &
107         ze3wu, ze3wv,           &  ! temporary scalars
108         zmaxu1, zmaxu2,         &  !    "         "
109         zmaxv1, zmaxv2             !    "         "
110
111      ! Initialization (first time-step only): compute mbatu and mbatv
112      IF( kt == nit000 ) THEN
113         mbatu(:,:) = 0
114         mbatv(:,:) = 0
115         DO jj = 1, jpjm1
116            DO ji = 1, fs_jpim1   ! vector opt.
117               mbatu(ji,jj) = MAX( MIN( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1, 2 )
118               mbatv(ji,jj) = MAX( MIN( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1, 2 )
119            END DO
120         END DO
121         zti(:,:) = FLOAT( mbatu(:,:) )
122         ztj(:,:) = FLOAT( mbatv(:,:) )
123         ! lateral boundary conditions: T-point, sign unchanged
124         CALL lbc_lnk( zti , 'U', 1. )
125         CALL lbc_lnk( ztj , 'V', 1. )
126         mbatu(:,:) = MAX( INT( zti(:,:) ), 2 )
127         mbatv(:,:) = MAX( INT( ztj(:,:) ), 2 )
128      ENDIF
129     
130
131      ! Interpolation of T and S at the last ocean level
132# if defined key_vectopt_loop
133         jj = 1
134         DO ji = 1, jpij-jpi   ! vector opt. (forced unrolled)
135# else
136      DO jj = 1, jpjm1
137         DO ji = 1, jpim1
138# endif
139            ! last level
140            iku = mbatu(ji,jj)
141            ikv = mbatv(ji,jj)
142
143            ze3wu  = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
144            ze3wv  = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
145            zmaxu1 =  ze3wu / fse3w(ji+1,jj  ,iku)
146            zmaxu2 = -ze3wu / fse3w(ji  ,jj  ,iku)
147            zmaxv1 =  ze3wv / fse3w(ji  ,jj+1,ikv)
148            zmaxv2 = -ze3wv / fse3w(ji  ,jj  ,ikv)
149
150            ! i- direction
151
152            IF( ze3wu >= 0. ) THEN      ! case 1
153               ! interpolated values of T and S
154               zti(ji,jj) = ptem(ji+1,jj,iku) + zmaxu1 * ( ptem(ji+1,jj,iku-1) - ptem(ji+1,jj,iku) )
155               zsi(ji,jj) = psal(ji+1,jj,iku) + zmaxu1 * ( psal(ji+1,jj,iku-1) - psal(ji+1,jj,iku) )
156               ! depth of the partial step level
157               zhgi(ji,jj) = fsdept(ji,jj,iku)
158               ! gradient of T and S
159               pgtu(ji,jj) = umask(ji,jj,1) * ( zti(ji,jj) - ptem(ji,jj,iku) )
160               pgsu(ji,jj) = umask(ji,jj,1) * ( zsi(ji,jj) - psal(ji,jj,iku) )
161
162            ELSE                        ! case 2
163               ! interpolated values of T and S
164               zti(ji,jj) = ptem(ji,jj,iku) + zmaxu2 * ( ptem(ji,jj,iku-1) - ptem(ji,jj,iku) )
165               zsi(ji,jj) = psal(ji,jj,iku) + zmaxu2 * ( psal(ji,jj,iku-1) - psal(ji,jj,iku) )
166               ! depth of the partial step level
167               zhgi(ji,jj) = fsdept(ji+1,jj,iku)
168               ! gradient of T and S
169               pgtu(ji,jj) = umask(ji,jj,1) * ( ptem(ji+1,jj,iku) - zti (ji,jj) )
170               pgsu(ji,jj) = umask(ji,jj,1) * ( psal(ji+1,jj,iku) - zsi (ji,jj) )
171            ENDIF
172
173            ! j- direction
174
175            IF( ze3wv >= 0. ) THEN      ! case 1
176               ! interpolated values of T and S
177               ztj(ji,jj) = ptem(ji,jj+1,ikv) + zmaxv1 * ( ptem(ji,jj+1,ikv-1) - ptem(ji,jj+1,ikv) )
178               zsj(ji,jj) = psal(ji,jj+1,ikv) + zmaxv1 * ( psal(ji,jj+1,ikv-1) - psal(ji,jj+1,ikv) )
179               ! depth of the partial step level
180               zhgj(ji,jj) = fsdept(ji,jj,ikv) 
181               ! gradient of T and S
182               pgtv(ji,jj) = vmask(ji,jj,1) * ( ztj(ji,jj) - ptem(ji,jj,ikv) )
183               pgsv(ji,jj) = vmask(ji,jj,1) * ( zsj(ji,jj) - psal(ji,jj,ikv) )
184
185            ELSE                        ! case 2
186               ! interpolated values of T and S
187               ztj(ji,jj) = ptem(ji,jj,ikv) + zmaxv2 * ( ptem(ji,jj,ikv-1) - ptem(ji,jj,ikv) )
188               zsj(ji,jj) = psal(ji,jj,ikv) + zmaxv2 * ( psal(ji,jj,ikv-1) - psal(ji,jj,ikv) ) 
189               ! depth of the partial step level
190               zhgj(ji,jj) = fsdept(ji,jj+1,ikv) 
191               ! gradient of T and S
192               pgtv(ji,jj) = vmask(ji,jj,1) * ( ptem(ji,jj+1,ikv) - ztj(ji,jj) )
193               pgsv(ji,jj) = vmask(ji,jj,1) * ( psal(ji,jj+1,ikv) - zsj(ji,jj) )
194            ENDIF
195# if ! defined key_vectopt_loop
196         END DO
197# endif
198      END DO
199
200      ! Compute interpolated rd from zti, zsi, ztj, zsj for the 2 cases at the depth of the partial
201      ! step and store it in  zri, zrj for each  case
202      CALL eos( zti, zsi, zhgi, zri )
203      CALL eos( ztj, zsj, zhgj, zrj )
204
205
206      ! Gradient of density at the last level
207# if defined key_vectopt_loop 
208         jj = 1
209         DO ji = 1, jpij-jpi   ! vector opt. (forced unrolled)
210# else
211      DO jj = 1, jpjm1
212         DO ji = 1, jpim1
213# endif
214            iku = mbatu(ji,jj)
215            ikv = mbatv(ji,jj)
216            ze3wu  = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
217            ze3wv  = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
218            IF( ze3wu >= 0. ) THEN    ! i-direction: case 1
219               pgru(ji,jj) = umask(ji,jj,1) * ( zri(ji,jj) - prd(ji,jj,iku) )
220            ELSE                      ! i-direction: case 2
221               pgru(ji,jj) = umask(ji,jj,1) * ( prd(ji+1,jj,iku) - zri(ji,jj) )
222            ENDIF
223            IF( ze3wv >= 0. ) THEN    ! j-direction: case 1
224               pgrv(ji,jj) = vmask(ji,jj,1) * ( zrj(ji,jj) - prd(ji,jj,ikv) ) 
225            ELSE                      ! j-direction: case 2
226               pgrv(ji,jj) = vmask(ji,jj,1) * ( prd(ji,jj+1,ikv) - zrj(ji,jj) )
227            ENDIF
228# if ! defined key_vectopt_loop
229         END DO
230# endif
231      END DO
232
233      ! Lateral boundary conditions on each gradient
234      CALL lbc_lnk( pgtu , 'U', -1. )   ;   CALL lbc_lnk( pgtv , 'V', -1. )
235      CALL lbc_lnk( pgsu , 'U', -1. )   ;   CALL lbc_lnk( pgsv , 'V', -1. )
236      CALL lbc_lnk( pgru , 'U', -1. )   ;   CALL lbc_lnk( pgrv , 'V', -1. )
237
238   END SUBROUTINE zps_hde
239
240   !!======================================================================
241END MODULE zpshde
Note: See TracBrowser for help on using the repository browser.