New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in tags/nemo_v3_2/nemo_v3_2/NEMO/OPA_SRC/DYN – NEMO

source: tags/nemo_v3_2/nemo_v3_2/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 1878

Last change on this file since 1878 was 1878, checked in by flavoni, 14 years ago

initial test for nemogcm
File size: 52.0 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  1.0  !  87-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  91-11  (G. Madec)
8   !!            7.0  !  96-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  97-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  02-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  02-08  (A. Bozec)  hpg_zps: Original code
12   !!            9.0  !  05-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                           Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!            9.0  !  05-11  (G. Madec) style & small optimisation
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!   dyn_hpg      : update the momentum trend with the now horizontal
19   !!                  gradient of the hydrostatic pressure
20   !!       hpg_ctl  : initialisation and control of options
21   !!       hpg_zco  : z-coordinate scheme
22   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
23   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
24   !!       hpg_hel  : s-coordinate (helsinki modification)
25   !!       hpg_wdj  : s-coordinate (weighted density jacobian)
26   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
27   !!       hpg_rot  : s-coordinate (ROTated axes scheme)
28   !!----------------------------------------------------------------------
29   USE oce             ! ocean dynamics and tracers
30   USE dom_oce         ! ocean space and time domain
31   USE phycst          ! physical constants
32   USE in_out_manager  ! I/O manager
33   USE trdmod          ! ocean dynamics trends
34   USE trdmod_oce      ! ocean variables trends
35   USE prtctl          ! Print control
36   USE lbclnk          ! lateral boundary condition
37
38   IMPLICIT NONE
39   PRIVATE
40
41   PUBLIC   dyn_hpg    ! routine called by step module
42
43   !                                              !!* Namelist namdyn_hpg : hydrostatic pressure gradient
44   LOGICAL , PUBLIC ::   ln_hpg_zco    = .TRUE.    !: z-coordinate - full steps
45   LOGICAL , PUBLIC ::   ln_hpg_zps    = .FALSE.   !: z-coordinate - partial steps (interpolation)
46   LOGICAL , PUBLIC ::   ln_hpg_sco    = .FALSE.   !: s-coordinate (standard jacobian formulation)
47   LOGICAL , PUBLIC ::   ln_hpg_hel    = .FALSE.   !: s-coordinate (helsinki modification)
48   LOGICAL , PUBLIC ::   ln_hpg_wdj    = .FALSE.   !: s-coordinate (weighted density jacobian)
49   LOGICAL , PUBLIC ::   ln_hpg_djc    = .FALSE.   !: s-coordinate (Density Jacobian with Cubic polynomial)
50   LOGICAL , PUBLIC ::   ln_hpg_rot    = .FALSE.   !: s-coordinate (ROTated axes scheme)
51   REAL(wp), PUBLIC ::   rn_gamma      = 0.e0      !: weighting coefficient
52   LOGICAL , PUBLIC ::   ln_dynhpg_imp = .FALSE.   !: semi-implicite hpg flag
53   INTEGER , PUBLIC ::   nn_dynhpg_rst = 0         !: add dynhpg implicit variables in restart ot not
54
55   INTEGER  ::   nhpg  =  0   ! = 0 to 6, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags)
56
57   !! * Substitutions
58#  include "domzgr_substitute.h90"
59#  include "vectopt_loop_substitute.h90"
60   !!----------------------------------------------------------------------
61   !!   OPA 9.0 , LOCEAN-IPSL (2005)
62   !! $Id: dynhpg.F90 1601 2009-08-11 10:09:19Z ctlod $
63   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
64   !!----------------------------------------------------------------------
65
66CONTAINS
67
68   SUBROUTINE dyn_hpg( kt )
69      !!---------------------------------------------------------------------
70      !!                  ***  ROUTINE dyn_hpg  ***
71      !!
72      !! ** Method  :   Call the hydrostatic pressure gradient routine
73      !!              using the scheme defined in the namelist
74      !!   
75      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
76      !!             - Save the trend (l_trddyn=T)
77      !!----------------------------------------------------------------------
78      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
79      !!
80      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ztrdu, ztrdv   ! 3D temporary workspace
81      !!----------------------------------------------------------------------
82   
83      IF( kt == nit000 )   CALL hpg_ctl      ! initialisation & control of options
84
85      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
86         ztrdu(:,:,:) = ua(:,:,:) 
87         ztrdv(:,:,:) = va(:,:,:) 
88      ENDIF     
89
90      SELECT CASE ( nhpg )      ! Hydrastatic pressure gradient computation
91      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
92      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
93      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
94      CASE (  3 )   ;   CALL hpg_hel    ( kt )      ! s-coordinate (helsinki modification)
95      CASE (  4 )   ;   CALL hpg_wdj    ( kt )      ! s-coordinate (weighted density jacobian)
96      CASE (  5 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
97      CASE (  6 )   ;   CALL hpg_rot    ( kt )      ! s-coordinate (ROTated axes scheme)
98      END SELECT
99
100      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
101         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
102         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
103         CALL trd_mod( ztrdu, ztrdv, jpdyn_trd_hpg, 'DYN', kt )
104      ENDIF         
105      !
106      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
107         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
108      !
109   END SUBROUTINE dyn_hpg
110
111
112   SUBROUTINE hpg_ctl
113      !!----------------------------------------------------------------------
114      !!                 ***  ROUTINE hpg_ctl  ***
115      !!
116      !! ** Purpose :   initializations for the hydrostatic pressure gradient
117      !!              computation and consistency control
118      !!
119      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
120      !!      with the type of vertical coordinate used (zco, zps, sco)
121      !!----------------------------------------------------------------------
122      INTEGER ::   ioptio = 0      ! temporary integer
123      !!
124!     NAMELIST/namdyn_hpg/ ln_hpg_zco   , ln_hpg_zps   , ln_hpg_sco, ln_hpg_hel,   &
125!        &                 ln_hpg_wdj   , ln_hpg_djc   , ln_hpg_rot, rn_gamma  ,   &
126!        &                 ln_dynhpg_imp, nn_dynhpg_rst
127      !!----------------------------------------------------------------------
128
129!     REWIND ( numnam )               ! Namelist namdyn_hpg : already read in opa.F90 module
130!     READ   ( numnam, namdyn_hpg )
131
132      IF(lwp) THEN                    ! Control print
133         WRITE(numout,*)
134         WRITE(numout,*) 'dyn_hpg : hydrostatic pressure gradient'
135         WRITE(numout,*) '~~~~~~~'
136         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
137         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
138         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
139         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
140         WRITE(numout,*) '      s-coord. (helsinki modification)                  ln_hpg_hel    = ', ln_hpg_hel
141         WRITE(numout,*) '      s-coord. (weighted density jacobian)              ln_hpg_wdj    = ', ln_hpg_wdj
142         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
143         WRITE(numout,*) '      s-coord. (ROTated axes scheme)                    ln_hpg_rot    = ', ln_hpg_rot
144         WRITE(numout,*) '      weighting coeff. (wdj scheme)                     rn_gamma      = ', rn_gamma
145         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
146         WRITE(numout,*) '      add in restart dynhpg semi-implicit variable      nn_dynhpg_rst = ', nn_dynhpg_rst
147      ENDIF
148
149      IF( .NOT. ln_dynhpg_imp )   nn_dynhpg_rst = 0      ! force no adding dynhpg implicit variables in restart
150
151      IF( lk_vvl .AND. .NOT. ln_hpg_sco )   THEN
152         CALL ctl_stop( 'hpg_ctl : variable volume key_vvl compatible only with the standard jacobian formulation hpg_sco')
153      ENDIF
154
155      !                               ! Set nhpg from ln_hpg_... flags
156      IF( ln_hpg_zco )   nhpg = 0
157      IF( ln_hpg_zps )   nhpg = 1
158      IF( ln_hpg_sco )   nhpg = 2
159      IF( ln_hpg_hel )   nhpg = 3
160      IF( ln_hpg_wdj )   nhpg = 4
161      IF( ln_hpg_djc )   nhpg = 5
162      IF( ln_hpg_rot )   nhpg = 6
163
164      !                               ! Consitency check
165      ioptio = 0 
166      IF( ln_hpg_zco )   ioptio = ioptio + 1
167      IF( ln_hpg_zps )   ioptio = ioptio + 1
168      IF( ln_hpg_sco )   ioptio = ioptio + 1
169      IF( ln_hpg_hel )   ioptio = ioptio + 1
170      IF( ln_hpg_wdj )   ioptio = ioptio + 1
171      IF( ln_hpg_djc )   ioptio = ioptio + 1
172      IF( ln_hpg_rot )   ioptio = ioptio + 1
173      IF ( ioptio /= 1 )   CALL ctl_stop( ' NO or several hydrostatic pressure gradient options used' )
174
175      !
176   END SUBROUTINE hpg_ctl
177
178
179   SUBROUTINE hpg_zco( kt )
180      !!---------------------------------------------------------------------
181      !!                  ***  ROUTINE hpg_zco  ***
182      !!
183      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
184      !!      The now hydrostatic pressure gradient at a given level, jk,
185      !!      is computed by taking the vertical integral of the in-situ
186      !!      density gradient along the model level from the suface to that
187      !!      level:    zhpi = grav .....
188      !!                zhpj = grav .....
189      !!      add it to the general momentum trend (ua,va).
190      !!            ua = ua - 1/e1u * zhpi
191      !!            va = va - 1/e2v * zhpj
192      !!
193      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
194      !!----------------------------------------------------------------------
195      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
196      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
197      !!
198      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
199      !!
200      INTEGER  ::   ji, jj, jk       ! dummy loop indices
201      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
202      !!----------------------------------------------------------------------
203     
204      IF( kt == nit000 ) THEN
205         IF(lwp) WRITE(numout,*)
206         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
207         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
208      ENDIF
209     
210      ! Local constant initialization
211      zcoef0 = - grav * 0.5
212
213      ! Surface value
214      DO jj = 2, jpjm1
215         DO ji = fs_2, fs_jpim1   ! vector opt.
216            zcoef1 = zcoef0 * fse3w(ji,jj,1)
217            ! hydrostatic pressure gradient
218            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
219            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
220            ! add to the general momentum trend
221            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
222            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
223         END DO
224      END DO
225      !
226      ! interior value (2=<jk=<jpkm1)
227      DO jk = 2, jpkm1
228         DO jj = 2, jpjm1
229            DO ji = fs_2, fs_jpim1   ! vector opt.
230               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
231               ! hydrostatic pressure gradient
232               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
233                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
234                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
235
236               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
237                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
238                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
239               ! add to the general momentum trend
240               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
241               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
242            END DO
243         END DO
244      END DO
245      !
246   END SUBROUTINE hpg_zco
247
248
249   SUBROUTINE hpg_zps( kt )
250      !!---------------------------------------------------------------------
251      !!                 ***  ROUTINE hpg_zps  ***
252      !!                   
253      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
254      !!
255      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
256      !!----------------------------------------------------------------------
257      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
258      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
259      !!
260      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
261      !!
262      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
263      INTEGER  ::   iku, ikv                         ! temporary integers
264      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
265      !!----------------------------------------------------------------------
266
267      IF( kt == nit000 ) THEN
268         IF(lwp) WRITE(numout,*)
269         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
270         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
271      ENDIF
272
273      ! Local constant initialization
274      zcoef0 = - grav * 0.5
275
276      !  Surface value
277      DO jj = 2, jpjm1
278         DO ji = fs_2, fs_jpim1   ! vector opt.
279            zcoef1 = zcoef0 * fse3w(ji,jj,1)
280            ! hydrostatic pressure gradient
281            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
282            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
283            ! add to the general momentum trend
284            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
285            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
286         END DO
287      END DO
288
289      ! interior value (2=<jk=<jpkm1)
290      DO jk = 2, jpkm1
291         DO jj = 2, jpjm1
292            DO ji = fs_2, fs_jpim1   ! vector opt.
293               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
294               ! hydrostatic pressure gradient
295               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
296                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
297                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
298
299               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
300                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
301                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
302               ! add to the general momentum trend
303               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
304               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
305            END DO
306         END DO
307      END DO
308
309      ! partial steps correction at the last level  (new gradient with  intgrd.F)
310# if defined key_vectopt_loop
311         jj = 1
312         DO ji = jpi+2, jpij-jpi-1   ! vector opt. (forced unrolling)
313# else
314      DO jj = 2, jpjm1
315         DO ji = 2, jpim1
316# endif
317            iku = MIN ( mbathy(ji,jj), mbathy(ji+1,jj) ) - 1
318            ikv = MIN ( mbathy(ji,jj), mbathy(ji,jj+1) ) - 1
319            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
320            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
321            ! on i-direction
322            IF ( iku > 2 ) THEN
323               ! subtract old value
324               ua(ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)
325               ! compute the new one
326               zhpi (ji,jj,iku) = zhpi(ji,jj,iku-1)   &
327                  + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
328               ! add the new one to the general momentum trend
329               ua(ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)
330            ENDIF
331            ! on j-direction
332            IF ( ikv > 2 ) THEN
333               ! subtract old value
334               va(ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)
335               ! compute the new one
336               zhpj (ji,jj,ikv) = zhpj(ji,jj,ikv-1)   &
337                  + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
338               ! add the new one to the general momentum trend
339               va(ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)
340            ENDIF
341# if ! defined key_vectopt_loop
342         END DO
343# endif
344      END DO
345      !
346   END SUBROUTINE hpg_zps
347
348
349   SUBROUTINE hpg_sco( kt )
350      !!---------------------------------------------------------------------
351      !!                  ***  ROUTINE hpg_sco  ***
352      !!
353      !! ** Method  :   s-coordinate case. Jacobian scheme.
354      !!      The now hydrostatic pressure gradient at a given level, jk,
355      !!      is computed by taking the vertical integral of the in-situ
356      !!      density gradient along the model level from the suface to that
357      !!      level. s-coordinates (ln_sco): a corrective term is added
358      !!      to the horizontal pressure gradient :
359      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
360      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
361      !!      add it to the general momentum trend (ua,va).
362      !!         ua = ua - 1/e1u * zhpi
363      !!         va = va - 1/e2v * zhpj
364      !!
365      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
366      !!----------------------------------------------------------------------
367      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
368      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
369      !!
370      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
371      !!
372      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
373      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
374      !!----------------------------------------------------------------------
375
376      IF( kt == nit000 ) THEN
377         IF(lwp) WRITE(numout,*)
378         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
379         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
380      ENDIF
381
382      ! Local constant initialization
383      zcoef0 = - grav * 0.5
384      ! To use density and not density anomaly
385      IF ( lk_vvl ) THEN   ;     znad = 1.            ! Variable volume
386      ELSE                 ;     znad = 0.e0          ! Fixed volume
387      ENDIF
388
389      ! Surface value
390      DO jj = 2, jpjm1
391         DO ji = fs_2, fs_jpim1   ! vector opt.   
392            ! hydrostatic pressure gradient along s-surfaces
393            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
394               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
395            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
396               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
397            ! s-coordinate pressure gradient correction
398            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2*znad )   &
399               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
400            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2*znad )   &
401               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
402            ! add to the general momentum trend
403            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
404            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
405         END DO 
406      END DO   
407           
408      ! interior value (2=<jk=<jpkm1)
409      DO jk = 2, jpkm1                                 
410         DO jj = 2, jpjm1     
411            DO ji = fs_2, fs_jpim1   ! vector opt.     
412               ! hydrostatic pressure gradient along s-surfaces
413               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   & 
414                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   & 
415                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
416               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
417                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
418                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
419               ! s-coordinate pressure gradient correction
420               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2*znad )   &
421                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
422               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2*znad )   &
423                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
424               ! add to the general momentum trend
425               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
426               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
427            END DO
428         END DO
429      END DO
430      !
431   END SUBROUTINE hpg_sco
432
433
434   SUBROUTINE hpg_hel( kt )
435      !!---------------------------------------------------------------------
436      !!                  ***  ROUTINE hpg_hel  ***
437      !!
438      !! ** Method  :   s-coordinate case.
439      !!      The now hydrostatic pressure gradient at a given level
440      !!      jk is computed by taking the vertical integral of the in-situ
441      !!      density gradient along the model level from the suface to that
442      !!      level. s-coordinates (ln_sco): a corrective term is added
443      !!      to the horizontal pressure gradient :
444      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
445      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
446      !!      add it to the general momentum trend (ua,va).
447      !!         ua = ua - 1/e1u * zhpi
448      !!         va = va - 1/e2v * zhpj
449      !!
450      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
451      !!             - Save the trend (l_trddyn=T)
452      !!----------------------------------------------------------------------
453      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
454      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
455      !!
456      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
457      !!
458      INTEGER  ::   ji, jj, jk           ! dummy loop indices
459      REAL(wp) ::   zcoef0, zuap, zvap   ! temporary scalars
460      !!----------------------------------------------------------------------
461
462      IF( kt == nit000 ) THEN
463         IF(lwp) WRITE(numout,*)
464         IF(lwp) WRITE(numout,*) 'dyn:hpg_hel : hydrostatic pressure gradient trend'
465         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, helsinki modified scheme'
466      ENDIF
467
468      ! Local constant initialization
469      zcoef0 = - grav * 0.5
470 
471      ! Surface value
472      DO jj = 2, jpjm1
473         DO ji = fs_2, fs_jpim1   ! vector opt.
474            ! hydrostatic pressure gradient along s-surfaces
475            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3t(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)  &
476               &                                  - fse3t(ji  ,jj  ,1) * rhd(ji  ,jj  ,1) )
477            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3t(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)  &
478               &                                  - fse3t(ji  ,jj  ,1) * rhd(ji  ,jj  ,1) )
479            ! s-coordinate pressure gradient correction
480            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) )   &
481               &           * ( fsdept(ji+1,jj,1) - fsdept(ji,jj,1) ) / e1u(ji,jj)
482            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) )   &
483               &           * ( fsdept(ji,jj+1,1) - fsdept(ji,jj,1) ) / e2v(ji,jj)
484            ! add to the general momentum trend
485            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
486            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
487         END DO
488      END DO
489      !
490      ! interior value (2=<jk=<jpkm1)
491      DO jk = 2, jpkm1
492         DO jj = 2, jpjm1
493            DO ji = fs_2, fs_jpim1   ! vector opt.
494               ! hydrostatic pressure gradient along s-surfaces
495               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
496                  &           +  zcoef0 / e1u(ji,jj) * ( fse3t(ji+1,jj,jk  ) * rhd(ji+1,jj,jk)     &
497                  &                                     -fse3t(ji  ,jj,jk  ) * rhd(ji  ,jj,jk)   ) &
498                  &           +  zcoef0 / e1u(ji,jj) * ( fse3t(ji+1,jj,jk-1) * rhd(ji+1,jj,jk-1)   &
499                  &                                     -fse3t(ji  ,jj,jk-1) * rhd(ji  ,jj,jk-1) )
500               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
501                  &           +  zcoef0 / e2v(ji,jj) * ( fse3t(ji,jj+1,jk  ) * rhd(ji,jj+1,jk)   &
502                  &                                     -fse3t(ji,jj  ,jk  ) * rhd(ji,jj,  jk)   ) &
503                  &           +  zcoef0 / e2v(ji,jj) * ( fse3t(ji,jj+1,jk-1) * rhd(ji,jj+1,jk-1) &
504                  &                                     -fse3t(ji,jj  ,jk-1) * rhd(ji,jj,  jk-1) )
505               ! s-coordinate pressure gradient correction
506               zuap = - zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )   &
507                  &            * ( fsdept(ji+1,jj,jk) - fsdept(ji,jj,jk) ) / e1u(ji,jj)
508               zvap = - zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )   &
509                  &            * ( fsdept(ji,jj+1,jk) - fsdept(ji,jj,jk) ) / e2v(ji,jj)
510               ! add to the general momentum trend
511               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
512               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
513            END DO
514         END DO
515      END DO
516      !
517   END SUBROUTINE hpg_hel
518
519
520   SUBROUTINE hpg_wdj( kt )
521      !!---------------------------------------------------------------------
522      !!                  ***  ROUTINE hpg_wdj  ***
523      !!
524      !! ** Method  :   Weighted Density Jacobian (wdj) scheme (song 1998)
525      !!      The weighting coefficients from the namelist parameter rn_gamma
526      !!      (alpha=0.5-rn_gamma ; beta=1-alpha=0.5+rn_gamma
527      !!
528      !! Reference : Song, Mon. Wea. Rev., 126, 3213-3230, 1998.
529      !!----------------------------------------------------------------------
530      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
531      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
532      !!
533      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
534      !!
535      INTEGER  ::   ji, jj, jk           ! dummy loop indices
536      REAL(wp) ::   zcoef0, zuap, zvap   ! temporary scalars
537      REAL(wp) ::   zalph , zbeta        !    "         "
538      !!----------------------------------------------------------------------
539
540      IF( kt == nit000 ) THEN
541         IF(lwp) WRITE(numout,*)
542         IF(lwp) WRITE(numout,*) 'dyn:hpg_wdj : hydrostatic pressure gradient trend'
543         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   Weighted Density Jacobian'
544      ENDIF
545
546      ! Local constant initialization
547      zcoef0 = - grav * 0.5
548      zalph  = 0.5 - rn_gamma    ! weighting coefficients (alpha=0.5-rn_gamma
549      zbeta  = 0.5 + rn_gamma    !                        (beta =1-alpha=0.5+rn_gamma
550
551      ! Surface value (no ponderation)
552      DO jj = 2, jpjm1
553         DO ji = fs_2, fs_jpim1   ! vector opt.
554            ! hydrostatic pressure gradient along s-surfaces
555            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * (  fse3w(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)   &
556               &                                   - fse3w(ji  ,jj  ,1) * rhd(ji  ,jj  ,1)  )
557            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * (  fse3w(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)   &
558               &                                   - fse3w(ji  ,jj  ,1) * rhd(ji,  jj  ,1)  )
559            ! s-coordinate pressure gradient correction
560            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) )   &
561               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
562            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) )   &
563               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
564            ! add to the general momentum trend
565            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
566            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
567         END DO
568      END DO
569
570      ! Interior value (2=<jk=<jpkm1) (weighted with zalph & zbeta)
571      DO jk = 2, jpkm1
572         DO jj = 2, jpjm1
573            DO ji = fs_2, fs_jpim1   ! vector opt.
574               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)                            &
575                  &           * (   (            fsde3w(ji+1,jj,jk  ) + fsde3w(ji,jj,jk  )        &
576                  &                            - fsde3w(ji+1,jj,jk-1) - fsde3w(ji,jj,jk-1)    )   &
577                  &               * (  zalph * ( rhd   (ji+1,jj,jk-1) - rhd   (ji,jj,jk-1) )      &
578                  &                  + zbeta * ( rhd   (ji+1,jj,jk  ) - rhd   (ji,jj,jk  ) )  )   &
579                  &             -   (            rhd   (ji+1,jj,jk  ) + rhd   (ji,jj,jk  )        &
580                  &                           - rhd   (ji+1,jj,jk-1) - rhd   (ji,jj,jk-1)     )   &
581                  &               * (  zalph * ( fsde3w(ji+1,jj,jk-1) - fsde3w(ji,jj,jk-1) )      &
582                  &                  + zbeta * ( fsde3w(ji+1,jj,jk  ) - fsde3w(ji,jj,jk  ) )  )  )
583               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)                            &
584                  &           * (   (           fsde3w(ji,jj+1,jk  ) + fsde3w(ji,jj,jk  )         &
585                  &                           - fsde3w(ji,jj+1,jk-1) - fsde3w(ji,jj,jk-1)     )   &
586                  &               * (  zalph * ( rhd   (ji,jj+1,jk-1) - rhd   (ji,jj,jk-1) )      &
587                  &                  + zbeta * ( rhd   (ji,jj+1,jk  ) - rhd   (ji,jj,jk  ) )  )   &
588                  &             -   (            rhd   (ji,jj+1,jk  ) + rhd   (ji,jj,jk  )        &
589                  &                            - rhd   (ji,jj+1,jk-1) - rhd   (ji,jj,jk-1)    )   &
590                  &               * (  zalph * ( fsde3w(ji,jj+1,jk-1) - fsde3w(ji,jj,jk-1) )      &
591                  &                  + zbeta * ( fsde3w(ji,jj+1,jk  ) - fsde3w(ji,jj,jk  ) )  )  )
592               ! add to the general momentum trend
593               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
594               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
595            END DO
596         END DO
597      END DO
598      !
599   END SUBROUTINE hpg_wdj
600
601
602   SUBROUTINE hpg_djc( kt )
603      !!---------------------------------------------------------------------
604      !!                  ***  ROUTINE hpg_djc  ***
605      !!
606      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
607      !!
608      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
609      !!----------------------------------------------------------------------
610      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
611      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
612      !!
613      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
614      !!
615      INTEGER  ::   ji, jj, jk          ! dummy loop indices
616      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
617      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
618      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
619      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhox, dzx, drhou, dzu, rho_i   ! 3D workspace
620      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhoy, dzy, drhov, dzv, rho_j   !  "      "
621      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhoz, dzz, drhow, dzw, rho_k   !  "      "
622      !!----------------------------------------------------------------------
623
624      IF( kt == nit000 ) THEN
625         IF(lwp) WRITE(numout,*)
626         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
627         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
628      ENDIF
629
630
631      ! Local constant initialization
632      zcoef0 = - grav * 0.5
633      z1_10  = 1.0 / 10.0
634      z1_12  = 1.0 / 12.0
635
636      !----------------------------------------------------------------------------------------
637      !  compute and store in provisional arrays elementary vertical and horizontal differences
638      !----------------------------------------------------------------------------------------
639
640!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
641
642      DO jk = 2, jpkm1
643         DO jj = 2, jpjm1
644            DO ji = fs_2, fs_jpim1   ! vector opt.
645               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
646               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
647               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
648               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
649               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
650               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
651            END DO
652         END DO
653      END DO
654
655      !-------------------------------------------------------------------------
656      ! compute harmonic averages using eq. 5.18
657      !-------------------------------------------------------------------------
658      zep = 1.e-15
659
660!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
661!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
662
663      DO jk = 2, jpkm1
664         DO jj = 2, jpjm1
665            DO ji = fs_2, fs_jpim1   ! vector opt.
666               cffw = 2.0 * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
667
668               cffu = 2.0 * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
669               cffx = 2.0 * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
670 
671               cffv = 2.0 * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
672               cffy = 2.0 * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
673
674               IF( cffw > zep) THEN
675                  drhow(ji,jj,jk) = 2.0 *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
676                     &                  / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
677               ELSE
678                  drhow(ji,jj,jk) = 0.e0
679               ENDIF
680
681               dzw(ji,jj,jk) = 2.0 *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
682                  &                / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
683
684               IF( cffu > zep ) THEN
685                  drhou(ji,jj,jk) = 2.0 *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
686                     &                  / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
687               ELSE
688                  drhou(ji,jj,jk ) = 0.e0
689               ENDIF
690
691               IF( cffx > zep ) THEN
692                  dzu(ji,jj,jk) = 2.0*dzx(ji+1,jj,jk)*dzx(ji,jj,jk)   &
693                     &            /(dzx(ji+1,jj,jk)+dzx(ji,jj,jk))
694               ELSE
695                  dzu(ji,jj,jk) = 0.e0
696               ENDIF
697
698               IF( cffv > zep ) THEN
699                  drhov(ji,jj,jk) = 2.0 *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
700                     &                  / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
701               ELSE
702                  drhov(ji,jj,jk) = 0.e0
703               ENDIF
704
705               IF( cffy > zep ) THEN
706                  dzv(ji,jj,jk) = 2.0 *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
707                     &                / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
708               ELSE
709                  dzv(ji,jj,jk) = 0.e0
710               ENDIF
711
712            END DO
713         END DO
714      END DO
715
716      !----------------------------------------------------------------------------------
717      ! apply boundary conditions at top and bottom using 5.36-5.37
718      !----------------------------------------------------------------------------------
719      drhow(:,:, 1 ) = 1.5 * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5 * drhow(:,:,  2  )
720      drhou(:,:, 1 ) = 1.5 * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5 * drhou(:,:,  2  )
721      drhov(:,:, 1 ) = 1.5 * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5 * drhov(:,:,  2  )
722
723      drhow(:,:,jpk) = 1.5 * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5 * drhow(:,:,jpkm1)
724      drhou(:,:,jpk) = 1.5 * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5 * drhou(:,:,jpkm1)
725      drhov(:,:,jpk) = 1.5 * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5 * drhov(:,:,jpkm1)
726
727
728      !--------------------------------------------------------------
729      ! Upper half of top-most grid box, compute and store
730      !-------------------------------------------------------------
731
732!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
733!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
734
735      DO jj = 2, jpjm1
736         DO ji = fs_2, fs_jpim1   ! vector opt.
737            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )            &
738               &                   * (  rhd(ji,jj,1)                                 &
739               &                     + 0.5 * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
740               &                           * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
741               &                           / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  ) 
742         END DO
743      END DO
744
745!!bug gm    : here also, simplification is possible
746!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
747
748      DO jk = 2, jpkm1
749         DO jj = 2, jpjm1
750            DO ji = fs_2, fs_jpim1   ! vector opt.
751
752               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
753                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
754                  &            - grav * z1_10 * (                                                                     &
755                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
756                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
757                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
758                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
759                  &                             )
760
761               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
762                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
763                  &            - grav* z1_10 * (                                                                      &
764                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
765                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
766                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
767                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
768                  &                            )
769
770               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
771                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
772                  &            - grav* z1_10 * (                                                                      &
773                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
774                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
775                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
776                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
777                  &                            )
778
779            END DO
780         END DO
781      END DO
782      CALL lbc_lnk(rho_k,'W',1.)
783      CALL lbc_lnk(rho_i,'U',1.)
784      CALL lbc_lnk(rho_j,'V',1.)
785
786
787      ! ---------------
788      !  Surface value
789      ! ---------------
790      DO jj = 2, jpjm1
791         DO ji = fs_2, fs_jpim1   ! vector opt.
792            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
793            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
794            ! add to the general momentum trend
795            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
796            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
797         END DO
798      END DO
799
800      ! ----------------
801      !  interior value   (2=<jk=<jpkm1)
802      ! ----------------
803      DO jk = 2, jpkm1
804         DO jj = 2, jpjm1 
805            DO ji = fs_2, fs_jpim1   ! vector opt.
806               ! hydrostatic pressure gradient along s-surfaces
807               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
808                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
809                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
810               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
811                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
812                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
813               ! add to the general momentum trend
814               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
815               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
816            END DO
817         END DO
818      END DO
819      !
820   END SUBROUTINE hpg_djc
821
822
823   SUBROUTINE hpg_rot( kt )
824      !!---------------------------------------------------------------------
825      !!                  ***  ROUTINE hpg_rot  ***
826      !!
827      !! ** Method  :   rotated axes scheme (Thiem and Berntsen 2005)
828      !!
829      !! Reference: Thiem & Berntsen, Ocean Modelling, In press, 2005.
830      !!----------------------------------------------------------------------
831      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
832      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
833      !!
834      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
835      !!
836      INTEGER  ::   ji, jj, jk          ! dummy loop indices
837      REAL(wp) ::   zforg, zcoef0, zuap, zmskd1, zmskd1m   ! temporary scalar
838      REAL(wp) ::   zfrot        , zvap, zmskd2, zmskd2m   !    "         "
839      REAL(wp), DIMENSION(jpi,jpj)     ::   zdistr, zsina, zcosa                ! 2D workspace
840      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpiorg, zhpirot, zhpitra, zhpine   ! 3D workspace
841      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpjorg, zhpjrot, zhpjtra, zhpjne   !  "      "
842      !!----------------------------------------------------------------------
843
844      IF( kt == nit000 ) THEN
845         IF(lwp) WRITE(numout,*)
846         IF(lwp) WRITE(numout,*) 'dyn:hpg_rot : hydrostatic pressure gradient trend'
847         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, rotated axes scheme used'
848      ENDIF
849
850      ! -------------------------------
851      !  Local constant initialization
852      ! -------------------------------
853      zcoef0 = - grav * 0.5
854      zforg  = 0.95e0
855      zfrot  = 1.e0 - zforg
856
857      ! inverse of the distance between 2 diagonal T-points (defined at F-point) (here zcoef0/distance)
858      zdistr(:,:) = zcoef0 / SQRT( e1f(:,:)*e1f(:,:) + e2f(:,:)*e1f(:,:) )
859
860      ! sinus and cosinus of diagonal angle at F-point
861      zsina(:,:) = ATAN2( e2f(:,:), e1f(:,:) )
862      zcosa(:,:) = COS( zsina(:,:) )
863      zsina(:,:) = SIN( zsina(:,:) )
864
865      ! ---------------
866      !  Surface value
867      ! ---------------
868      ! compute and add to the general trend the pressure gradients along the axes
869      DO jj = 2, jpjm1
870         DO ji = fs_2, fs_jpim1   ! vector opt.
871            ! hydrostatic pressure gradient along s-surfaces
872            zhpiorg(ji,jj,1) = zcoef0 / e1u(ji,jj) * (  fse3t(ji+1,jj,1) * rhd(ji+1,jj,1)   &
873               &                                      - fse3t(ji  ,jj,1) * rhd(ji  ,jj,1)  )
874            zhpjorg(ji,jj,1) = zcoef0 / e2v(ji,jj) * (  fse3t(ji,jj+1,1) * rhd(ji,jj+1,1)   &
875               &                                      - fse3t(ji,jj  ,1) * rhd(ji,jj  ,1)  )
876            ! s-coordinate pressure gradient correction
877            zuap = -zcoef0 * ( rhd   (ji+1,jj  ,1) + rhd   (ji,jj,1) )   &
878               &           * ( fsdept(ji+1,jj  ,1) - fsdept(ji,jj,1) ) / e1u(ji,jj)
879            zvap = -zcoef0 * ( rhd   (ji  ,jj+1,1) + rhd   (ji,jj,1) )   &
880               &           * ( fsdept(ji  ,jj+1,1) - fsdept(ji,jj,1) ) / e2v(ji,jj)
881            ! add to the general momentum trend
882            ua(ji,jj,1) = ua(ji,jj,1) + zforg * ( zhpiorg(ji,jj,1) + zuap )
883            va(ji,jj,1) = va(ji,jj,1) + zforg * ( zhpjorg(ji,jj,1) + zvap )
884         END DO
885      END DO
886
887      ! compute the pressure gradients in the diagonal directions
888      DO jj = 1, jpjm1
889         DO ji = 1, fs_jpim1   ! vector opt.
890            zmskd1 = tmask(ji+1,jj+1,1) * tmask(ji  ,jj,1)      ! mask in the 1st diagnonal
891            zmskd2 = tmask(ji  ,jj+1,1) * tmask(ji+1,jj,1)      ! mask in the 2nd diagnonal
892            ! hydrostatic pressure gradient along s-surfaces
893            zhpitra(ji,jj,1) = zdistr(ji,jj) * zmskd1 * (  fse3t(ji+1,jj+1,1) * rhd(ji+1,jj+1,1)   &
894               &                                         - fse3t(ji  ,jj  ,1) * rhd(ji  ,jj  ,1)  )
895            zhpjtra(ji,jj,1) = zdistr(ji,jj) * zmskd2 * (  fse3t(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)   &
896               &                                         - fse3t(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)  )
897            ! s-coordinate pressure gradient correction
898            zuap = -zdistr(ji,jj) * zmskd1 * ( rhd   (ji+1,jj+1,1) + rhd   (ji  ,jj,1) )   &
899               &                           * ( fsdept(ji+1,jj+1,1) - fsdept(ji  ,jj,1) )
900            zvap = -zdistr(ji,jj) * zmskd2 * ( rhd   (ji  ,jj+1,1) + rhd   (ji+1,jj,1) )   &
901               &                           * ( fsdept(ji  ,jj+1,1) - fsdept(ji+1,jj,1) )
902            ! back rotation
903            zhpine(ji,jj,1) = zcosa(ji,jj) * ( zhpitra(ji,jj,1) + zuap )   &
904               &            - zsina(ji,jj) * ( zhpjtra(ji,jj,1) + zvap )
905            zhpjne(ji,jj,1) = zsina(ji,jj) * ( zhpitra(ji,jj,1) + zuap )   &
906               &            + zcosa(ji,jj) * ( zhpjtra(ji,jj,1) + zvap )
907         END DO
908      END DO
909
910      ! interpolate and add to the general trend the diagonal gradient
911      DO jj = 2, jpjm1
912         DO ji = fs_2, fs_jpim1   ! vector opt.
913            ! averaging
914            zhpirot(ji,jj,1) = 0.5 * ( zhpine(ji,jj,1) + zhpine(ji  ,jj-1,1) )
915            zhpjrot(ji,jj,1) = 0.5 * ( zhpjne(ji,jj,1) + zhpjne(ji-1,jj  ,1) )
916            ! add to the general momentum trend
917            ua(ji,jj,1) = ua(ji,jj,1) + zfrot * zhpirot(ji,jj,1) 
918            va(ji,jj,1) = va(ji,jj,1) + zfrot * zhpjrot(ji,jj,1) 
919         END DO
920      END DO
921
922      ! -----------------
923      ! 2. interior value (2=<jk=<jpkm1)
924      ! -----------------
925      ! compute and add to the general trend the pressure gradients along the axes
926      DO jk = 2, jpkm1
927         DO jj = 2, jpjm1
928            DO ji = fs_2, fs_jpim1   ! vector opt.
929               ! hydrostatic pressure gradient along s-surfaces
930               zhpiorg(ji,jj,jk) = zhpiorg(ji,jj,jk-1)                                                 &
931                  &              +  zcoef0 / e1u(ji,jj) * (  fse3t(ji+1,jj,jk  ) * rhd(ji+1,jj,jk  )   &
932                  &                                        - fse3t(ji  ,jj,jk  ) * rhd(ji  ,jj,jk  )   &
933                  &                                        + fse3t(ji+1,jj,jk-1) * rhd(ji+1,jj,jk-1)   &
934                  &                                        - fse3t(ji  ,jj,jk-1) * rhd(ji  ,jj,jk-1)  )
935               zhpjorg(ji,jj,jk) = zhpjorg(ji,jj,jk-1)                                                 &
936                  &              +  zcoef0 / e2v(ji,jj) * (  fse3t(ji,jj+1,jk  ) * rhd(ji,jj+1,jk  )   &
937                  &                                        - fse3t(ji,jj  ,jk  ) * rhd(ji,jj,  jk  )   &
938                  &                                        + fse3t(ji,jj+1,jk-1) * rhd(ji,jj+1,jk-1)   &
939                  &                                        - fse3t(ji,jj  ,jk-1) * rhd(ji,jj,  jk-1)  )
940               ! s-coordinate pressure gradient correction
941               zuap = - zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) )   &
942                  &            * ( fsdept(ji+1,jj  ,jk) - fsdept(ji,jj,jk) ) / e1u(ji,jj)
943               zvap = - zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) )   &
944                  &            * ( fsdept(ji  ,jj+1,jk) - fsdept(ji,jj,jk) ) / e2v(ji,jj)
945               ! add to the general momentum trend
946               ua(ji,jj,jk) = ua(ji,jj,jk) + zforg*( zhpiorg(ji,jj,jk) + zuap )
947               va(ji,jj,jk) = va(ji,jj,jk) + zforg*( zhpjorg(ji,jj,jk) + zvap )
948            END DO
949         END DO
950      END DO
951
952      ! compute the pressure gradients in the diagonal directions
953      DO jk = 2, jpkm1
954         DO jj = 1, jpjm1
955            DO ji = 1, fs_jpim1   ! vector opt.
956               zmskd1  = tmask(ji+1,jj+1,jk  ) * tmask(ji  ,jj,jk  )      ! level jk   mask in the 1st diagnonal
957               zmskd1m = tmask(ji+1,jj+1,jk-1) * tmask(ji  ,jj,jk-1)      ! level jk-1    "               "     
958               zmskd2  = tmask(ji  ,jj+1,jk  ) * tmask(ji+1,jj,jk  )      ! level jk   mask in the 2nd diagnonal
959               zmskd2m = tmask(ji  ,jj+1,jk-1) * tmask(ji+1,jj,jk-1)      ! level jk-1    "               "     
960               ! hydrostatic pressure gradient along s-surfaces
961               zhpitra(ji,jj,jk) = zhpitra(ji,jj,jk-1)                                                       &
962                  &              + zdistr(ji,jj) * zmskd1  * ( fse3t(ji+1,jj+1,jk  ) * rhd(ji+1,jj+1,jk)     &
963                  &                                           -fse3t(ji  ,jj  ,jk  ) * rhd(ji  ,jj  ,jk) )   &
964                  &              + zdistr(ji,jj) * zmskd1m * ( fse3t(ji+1,jj+1,jk-1) * rhd(ji+1,jj+1,jk-1)   &
965                  &                                           -fse3t(ji  ,jj  ,jk-1) * rhd(ji  ,jj  ,jk-1) )
966               zhpjtra(ji,jj,jk) = zhpjtra(ji,jj,jk-1)                                                       &
967                  &              + zdistr(ji,jj) * zmskd2  * ( fse3t(ji  ,jj+1,jk  ) * rhd(ji  ,jj+1,jk)     &
968                  &                                           -fse3t(ji+1,jj  ,jk  ) * rhd(ji+1,jj,  jk) )   &
969                  &              + zdistr(ji,jj) * zmskd2m * ( fse3t(ji  ,jj+1,jk-1) * rhd(ji  ,jj+1,jk-1)   &
970                  &                                           -fse3t(ji+1,jj  ,jk-1) * rhd(ji+1,jj,  jk-1) )
971               ! s-coordinate pressure gradient correction
972               zuap = - zdistr(ji,jj) * zmskd1 * ( rhd   (ji+1,jj+1,jk) + rhd   (ji  ,jj,jk) )   &
973                  &                            * ( fsdept(ji+1,jj+1,jk) - fsdept(ji  ,jj,jk) )
974               zvap = - zdistr(ji,jj) * zmskd2 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji+1,jj,jk) )   &
975                  &                            * ( fsdept(ji  ,jj+1,jk) - fsdept(ji+1,jj,jk) )
976               ! back rotation
977               zhpine(ji,jj,jk) = zcosa(ji,jj) * ( zhpitra(ji,jj,jk) + zuap )   &
978                  &             - zsina(ji,jj) * ( zhpjtra(ji,jj,jk) + zvap )
979               zhpjne(ji,jj,jk) = zsina(ji,jj) * ( zhpitra(ji,jj,jk) + zuap )   &
980                  &             + zcosa(ji,jj) * ( zhpjtra(ji,jj,jk) + zvap )
981            END DO
982         END DO
983      END DO
984
985      ! interpolate and add to the general trend
986      DO jk = 2, jpkm1
987         DO jj = 2, jpjm1
988            DO ji = fs_2, fs_jpim1   ! vector opt.
989               ! averaging
990               zhpirot(ji,jj,jk) = 0.5 * ( zhpine(ji,jj,jk) + zhpine(ji  ,jj-1,jk) )
991               zhpjrot(ji,jj,jk) = 0.5 * ( zhpjne(ji,jj,jk) + zhpjne(ji-1,jj  ,jk) )
992               ! add to the general momentum trend
993               ua(ji,jj,jk) = ua(ji,jj,jk) + zfrot * zhpirot(ji,jj,jk) 
994               va(ji,jj,jk) = va(ji,jj,jk) + zfrot * zhpjrot(ji,jj,jk) 
995            END DO
996         END DO
997      END DO
998      !
999   END SUBROUTINE hpg_rot
1000
1001   !!======================================================================
1002END MODULE dynhpg
Note: See TracBrowser for help on using the repository browser.