New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcrnf.F90 in tags/nemo_v3_2/nemo_v3_2/NEMO/OPA_SRC/SBC – NEMO

source: tags/nemo_v3_2/nemo_v3_2/NEMO/OPA_SRC/SBC/sbcrnf.F90 @ 1878

Last change on this file since 1878 was 1878, checked in by flavoni, 14 years ago

initial test for nemogcm
File size: 13.1 KB
Line 
1MODULE sbcrnf
2   !!======================================================================
3   !!                       ***  MODULE  sbcrnf  ***
4   !! Ocean forcing:  river runoff
5   !!=====================================================================
6   !! History :  OPA  !  2000-11  (R. Hordoir, E. Durand)  NetCDF FORMAT
7   !!   NEMO     1.0  !  2002-09  (G. Madec)  F90: Free form and module
8   !!            3.0  !  2006-07  (G. Madec)  Surface module
9   !!            3.2  !  2009-04  (B. Lemaire)  Introduce iom_put
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   sbc_rnf      : monthly runoffs read in a NetCDF file
14   !!   sbc_rnf_init : runoffs initialisation
15   !!   rnf_mouth    : set river mouth mask
16   !!----------------------------------------------------------------------
17   USE dom_oce         ! ocean space and time domain
18   USE phycst          ! physical constants
19   USE sbc_oce         ! surface boundary condition variables
20   USE fldread         ! ???
21   USE in_out_manager  ! I/O manager
22   USE iom             ! I/O module
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC sbc_rnf          ! routine call in step module
28
29   !                                                     !!* namsbc_rnf namelist *
30   CHARACTER(len=100), PUBLIC ::   cn_dir       = './'    !: Root directory for location of ssr files
31   LOGICAL           , PUBLIC ::   ln_rnf_emp   = .false. !: runoffs into a file to be read or already into precipitation
32   TYPE(FLD_N)       , PUBLIC ::   sn_rnf                 !: information about the runoff file to be read
33   TYPE(FLD_N)       , PUBLIC ::   sn_cnf                 !: information about the runoff mouth file to be read
34   LOGICAL           , PUBLIC ::   ln_rnf_mouth = .false. !: specific treatment in mouths vicinity
35   REAL(wp)          , PUBLIC ::   rn_hrnf      = 0.e0    !: runoffs, depth over which enhanced vertical mixing is used
36   REAL(wp)          , PUBLIC ::   rn_avt_rnf   = 0.e0    !: runoffs, value of the additional vertical mixing coef. [m2/s]
37   REAL(wp)          , PUBLIC ::   rn_rfact     = 1.e0    !: multiplicative factor for runoff
38
39   INTEGER , PUBLIC                     ::   nkrnf = 0   !: number of levels over which Kz is increased at river mouths
40   REAL(wp), PUBLIC, DIMENSION(jpi,jpj) ::   rnfmsk      !: river mouth mask (hori.)
41   REAL(wp), PUBLIC, DIMENSION(jpk)     ::   rnfmsk_z    !: river mouth mask (vert.)
42
43   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_rnf   ! structure of input SST (file information, fields read)
44
45   !!----------------------------------------------------------------------
46   !! NEMO/OPA 3.2 , LOCEAN-IPSL (2009)
47   !! $Id: sbcrnf.F90 1730 2009-11-16 14:34:19Z smasson $
48   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50
51CONTAINS
52
53   SUBROUTINE sbc_rnf( kt )
54      !!----------------------------------------------------------------------
55      !!                  ***  ROUTINE sbc_rnf  ***
56      !!       
57      !! ** Purpose :   Introduce a climatological run off forcing
58      !!
59      !! ** Method  :   Set each river mouth with a monthly climatology
60      !!                provided from different data.
61      !!                CAUTION : upward water flux, runoff forced to be < 0
62      !!
63      !! ** Action  :   runoff updated runoff field at time-step kt
64      !!----------------------------------------------------------------------
65      INTEGER, INTENT(in) ::   kt          ! ocean time step
66      !!
67      INTEGER  ::   ji, jj   ! dummy loop indices
68      INTEGER  ::   ierror   ! temporary integer
69      !!----------------------------------------------------------------------
70      !                                   
71      IF( kt == nit000 ) THEN 
72         IF( .NOT. ln_rnf_emp ) THEN
73            ALLOCATE( sf_rnf(1), STAT=ierror )
74            IF( ierror > 0 ) THEN
75               CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' )   ;   RETURN
76            ENDIF
77            ALLOCATE( sf_rnf(1)%fnow(jpi,jpj) )
78            ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,2) )
79         ENDIF
80         CALL sbc_rnf_init(sf_rnf)
81      ENDIF
82
83      !                                                   !-------------------!
84      IF( .NOT. ln_rnf_emp ) THEN                         !   Update runoff   !
85         !                                                !-------------------!
86         !
87         CALL fld_read( kt, nn_fsbc, sf_rnf )   ! Read Runoffs data and provides it
88         !                                      ! at the current time-step
89
90         ! Runoff reduction only associated to the ORCA2_LIM configuration
91         ! when reading the NetCDF file runoff_1m_nomask.nc
92         IF( cp_cfg == 'orca' .AND. jp_cfg == 2 )   THEN
93            DO jj = 1, jpj
94               DO ji = 1, jpi
95                  IF( gphit(ji,jj) > 40 .AND. gphit(ji,jj) < 65 )   sf_rnf(1)%fnow(ji,jj) = 0.85 * sf_rnf(1)%fnow(ji,jj)
96               END DO
97            END DO
98         ENDIF
99
100         ! C a u t i o n : runoff is negative and in kg/m2/s
101
102         IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
103            emp (:,:) = emp (:,:) - rn_rfact * ABS( sf_rnf(1)%fnow(:,:) )
104            emps(:,:) = emps(:,:) - rn_rfact * ABS( sf_rnf(1)%fnow(:,:) )
105            CALL iom_put( "runoffs", sf_rnf(1)%fnow )         ! runoffs
106         ENDIF
107         !
108      ENDIF
109      !
110   END SUBROUTINE sbc_rnf
111
112
113   SUBROUTINE sbc_rnf_init( sf_rnf )
114      !!----------------------------------------------------------------------
115      !!                  ***  ROUTINE sbc_rnf_init  ***
116      !!
117      !! ** Purpose :   Initialisation of the runoffs if (ln_rnf=T)
118      !!
119      !! ** Method  : - read the runoff namsbc_rnf namelist
120      !!
121      !! ** Action  : - read parameters
122      !!----------------------------------------------------------------------
123      TYPE(FLD), INTENT(inout), DIMENSION(:) :: sf_rnf   ! input data
124      !!
125      NAMELIST/namsbc_rnf/ cn_dir, ln_rnf_emp, sn_rnf, sn_cnf, ln_rnf_mouth,   &
126         &                 rn_hrnf, rn_avt_rnf, rn_rfact
127      !!----------------------------------------------------------------------
128
129      !                                   ! ============
130      !                                   !   Namelist
131      !                                   ! ============
132      ! (NB: frequency positive => hours, negative => months)
133      !            !   file    ! frequency !  variable  ! time intep !  clim  ! 'yearly' or ! weights  ! rotation   !
134      !            !   name    !  (hours)  !   name     !   (T/F)    !  (T/F) !  'monthly'  ! filename ! pairs      !
135      sn_rnf = FLD_N( 'runoffs',    -1     , 'sorunoff' ,  .TRUE.    , .true. ,   'yearly'  , ''       , ''         )
136      sn_cnf = FLD_N( 'runoffs',     0     , 'sorunoff' ,  .FALSE.   , .true. ,   'yearly'  , ''       , ''         )
137
138      !
139      REWIND ( numnam )                         ! Read Namelist namsbc_rnf
140      READ   ( numnam, namsbc_rnf )
141
142      !                                         ! Control print
143      IF(lwp) THEN
144         WRITE(numout,*)
145         WRITE(numout,*) 'sbc_rnf : runoff '
146         WRITE(numout,*) '~~~~~~~ '
147         WRITE(numout,*) '   Namelist namsbc_rnf'
148         WRITE(numout,*) '      runoff in a file to be read                ln_rnf_emp   = ', ln_rnf_emp
149         WRITE(numout,*) '      specific river mouths treatment            ln_rnf_mouth = ', ln_rnf_mouth
150         WRITE(numout,*) '      river mouth additional Kz                  rn_avt_rnf   = ', rn_avt_rnf
151         WRITE(numout,*) '      depth of river mouth additional mixing     rn_hrnf      = ', rn_hrnf
152         WRITE(numout,*) '      multiplicative factor for runoff           rn_rfact     = ', rn_rfact   
153      ENDIF
154
155      !                                   ! ==================
156      !                                   !   Type of runoff
157      !                                   ! ==================
158      !
159      IF( ln_rnf_emp ) THEN                     ! runoffs directly provided in the precipitations
160         IF(lwp) WRITE(numout,*)
161         IF(lwp) WRITE(numout,*) '          runoffs directly provided in the precipitations'
162         !
163      ELSE                                      ! runoffs read in a file : set sf_rnf structure
164         !
165         ! sf_rnf already allocated in main routine
166         ! fill sf_rnf with sn_rnf and control print
167         CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' )
168         !
169      ENDIF
170
171      !                                   ! ========================
172      !                                   !   River mouth vicinity
173      !                                   ! ========================
174      !
175      IF( ln_rnf_mouth ) THEN                   ! Specific treatment in vicinity of river mouths :
176         !                                      !    - Increase Kz in surface layers ( rn_hrnf > 0 )
177         !                                      !    - set to zero SSS damping (ln_ssr=T)
178         !                                      !    - mixed upstream-centered (ln_traadv_cen2=T)
179         !
180         !                                          ! Number of level over which Kz increase
181         nkrnf = 0
182         IF( rn_hrnf > 0.e0 ) THEN
183            nkrnf = 2
184            DO WHILE( nkrnf /= jpkm1 .AND. gdepw_0(nkrnf+1) < rn_hrnf )   ;   nkrnf = nkrnf + 1   ;   END DO
185            IF( ln_sco )   &
186               CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' )
187         ENDIF
188         IF(lwp) WRITE(numout,*)
189         IF(lwp) WRITE(numout,*) '          Specific treatment used in vicinity of river mouths :'
190         IF(lwp) WRITE(numout,*) '             - Increase Kz in surface layers (if rn_hrnf > 0 )'
191         IF(lwp) WRITE(numout,*) '               by ', rn_avt_rnf,' m2/s  over ', nkrnf, ' w-levels'
192         IF(lwp) WRITE(numout,*) '             - set to zero SSS damping       (if ln_ssr=T)'
193         IF(lwp) WRITE(numout,*) '             - mixed upstream-centered       (if ln_traadv_cen2=T)'
194         !
195         CALL rnf_mouth                             ! set river mouth mask
196         !
197      ELSE                                      ! No treatment at river mouths
198         IF(lwp) WRITE(numout,*)
199         IF(lwp) WRITE(numout,*) '          No specific treatment at river mouths'
200         rnfmsk  (:,:) = 0.e0 
201         rnfmsk_z(:)   = 0.e0
202         nkrnf = 0
203      ENDIF
204
205   END SUBROUTINE sbc_rnf_init
206
207
208   SUBROUTINE rnf_mouth
209      !!----------------------------------------------------------------------
210      !!                  ***  ROUTINE rnf_mouth  ***
211      !!       
212      !! ** Purpose :   define the river mouths mask
213      !!
214      !! ** Method  :   read the river mouth mask (=0/1) in the river runoff
215      !!                climatological file. Defined a given vertical structure.
216      !!                CAUTION, the vertical structure is hard coded on the
217      !!                first 5 levels.
218      !!                This fields can be used to:
219      !!                 - set an upstream advection scheme 
220      !!                   (ln_rnf_mouth=T and ln_traadv_cen2=T)
221      !!                 - increase vertical on the top nn_krnf vertical levels
222      !!                   at river runoff input grid point (nn_krnf>=2, see step.F90)
223      !!                 - set to zero SSS restoring flux at river mouth grid points
224      !!
225      !! ** Action  :   rnfmsk   set to 1 at river runoff input, 0 elsewhere
226      !!                rnfmsk_z vertical structure
227      !!----------------------------------------------------------------------
228      USE closea, ONLY :    clo_rnf   ! rnfmsk update routine
229      !
230      INTEGER           ::   inum        ! temporary integers
231      CHARACTER(len=32) ::   cl_rnfile   ! runoff file name
232      !!----------------------------------------------------------------------
233      !
234      IF(lwp) WRITE(numout,*)
235      IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask'
236      IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
237
238      cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
239      IF( .NOT. sn_cnf%ln_clim ) THEN   ;   WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear    ! add year
240         IF( sn_cnf%cltype == 'monthly' )   WRITE(cl_rnfile, '(a,"m",i2)'  ) TRIM( cl_rnfile ), nmonth   ! add month
241      ENDIF
242 
243      ! horizontal mask (read in NetCDF file)
244      CALL iom_open ( cl_rnfile, inum )                           ! open file
245      CALL iom_get  ( inum, jpdom_data, sn_cnf%clvar, rnfmsk )    ! read the river mouth array
246      CALL iom_close( inum )                                      ! close file
247     
248      IF( nclosea == 1 )    CALL clo_rnf( rnfmsk )                ! closed sea inflow set as ruver mouth
249
250      rnfmsk_z(:)   = 0.e0                                        ! vertical structure
251      rnfmsk_z(1)   = 1.0
252      rnfmsk_z(2)   = 1.0                                         ! **********
253      rnfmsk_z(3)   = 0.5                                         ! HARD CODED on the 5 first levels
254      rnfmsk_z(4)   = 0.25                                        ! **********
255      rnfmsk_z(5)   = 0.125
256      !         
257   END SUBROUTINE rnf_mouth
258   
259   !!======================================================================
260END MODULE sbcrnf
Note: See TracBrowser for help on using the repository browser.