New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdftke_old.F90 in tags/nemo_v3_2/nemo_v3_2/NEMO/OPA_SRC/ZDF – NEMO

source: tags/nemo_v3_2/nemo_v3_2/NEMO/OPA_SRC/ZDF/zdftke_old.F90 @ 1878

Last change on this file since 1878 was 1878, checked in by flavoni, 14 years ago

initial test for nemogcm
File size: 46.8 KB
Line 
1MODULE zdftke_old
2   !!======================================================================
3   !!                       ***  MODULE  zdftke_old  ***
4   !! Ocean physics:  vertical mixing coefficient computed from the tke
5   !!                 turbulent closure parameterization
6   !!=====================================================================
7   !! History :   OPA  !  1991-03  (b. blanke)  Original code
8   !!             7.0  !  1991-11  (G. Madec)   bug fix
9   !!             7.1  !  1992-10  (G. Madec)   new mixing length and eav
10   !!             7.2  !  1993-03  (M. Guyon)   symetrical conditions
11   !!             7.3  !  1994-08  (G. Madec, M. Imbard)  nn_pdl flag
12   !!             7.5  !  1996-01  (G. Madec)   s-coordinates
13   !!             8.0  !  1997-07  (G. Madec)   lbc
14   !!             8.1  !  1999-01  (E. Stretta) new option for the mixing length
15   !!  NEMO       1.0  !  2002-06  (G. Madec) add zdf_tke_init routine
16   !!              -   !  2002-08  (G. Madec)  rn_cri and Free form, F90
17   !!              -   !  2004-10  (C. Ethe )  1D configuration
18   !!             2.0  !  2006-07  (S. Masson)  distributed restart using iom
19   !!             3.0  !  2008-05  (C. Ethe,  G.Madec) : update TKE physics:
20   !!                              - tke penetration (wind steering)
21   !!                              - suface condition for tke & mixing length
22   !!                              - Langmuir cells
23   !!              -   !  2008-05  (J.-M. Molines, G. Madec)  2D form of avtb
24   !!              -   !  2008-06  (G. Madec)  style + DOCTOR name for namelist parameters
25   !!----------------------------------------------------------------------
26#if defined key_zdftke_old   ||   defined key_esopa
27   !!----------------------------------------------------------------------
28   !!   'key_zdftke_old'                               TKE vertical physics
29   !!----------------------------------------------------------------------
30   !!----------------------------------------------------------------------
31   !!   zdf_tke_old  : update momentum and tracer Kz from a tke scheme
32   !!   zdf_tke_init : initialization, namelist read, and parameters control
33   !!   tke_rst      : read/write tke restart in ocean restart file
34   !!----------------------------------------------------------------------
35   USE oce             ! ocean dynamics and active tracers
36   USE dom_oce         ! ocean space and time domain
37   USE zdf_oce         ! ocean vertical physics
38   USE sbc_oce         ! surface boundary condition: ocean
39   USE phycst          ! physical constants
40   USE zdfmxl          ! mixed layer
41   USE restart         ! only for lrst_oce
42   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
43   USE prtctl          ! Print control
44   USE in_out_manager  ! I/O manager
45   USE iom             ! I/O manager library
46
47   IMPLICIT NONE
48   PRIVATE
49
50   PUBLIC   zdf_tke_old   ! routine called in step module
51
52   LOGICAL , PUBLIC, PARAMETER              ::   lk_zdftke_old = .TRUE.  !: TKE vertical mixing flag
53   REAL(wp), PUBLIC                         ::   eboost              !: multiplicative coeff of the shear product.
54   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   en                  !: now turbulent kinetic energy
55# if defined key_vectopt_memory
56   !                                                                !!! key_vectopt_memory
57   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   etmean              !: coefficient used for horizontal smoothing
58   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   eumean, evmean      !: at t-, u- and v-points
59# endif
60#if defined key_c1d
61   !                                                                !!! 1D cfg only
62   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   e_dis, e_mix        !: dissipation and mixing turbulent lengh scales
63   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   e_pdl, e_ric        !: prandl and local Richardson numbers
64   REAL(wp), PUBLIC, DIMENSION(jpi,jpj)     ::   hlc                 !: save finite Langmuir Circulation depth
65#endif
66
67   !                                       !!! ** Namelist  namzdf_tke  **
68   LOGICAL  ::   ln_rstke = .FALSE.         ! =T restart with tke from a run without tke
69   LOGICAL  ::   ln_mxl0  = .FALSE.         ! mixing length scale surface value as function of wind stress or not
70   LOGICAL  ::   ln_lc    = .FALSE.         ! Langmuir cells (LC) as a source term of TKE or not
71   INTEGER  ::   nn_itke  = 50              ! number of restart iterative loops
72   INTEGER  ::   nn_mxl   =  2              ! type of mixing length (=0/1/2/3)
73   INTEGER  ::   nn_pdl   =  1              ! Prandtl number or not (ratio avt/avm) (=0/1)
74   INTEGER  ::   nn_ave   =  1              ! horizontal average or not on avt, avmu, avmv (=0/1)
75   REAL(wp) ::   rn_ediff = 0.1_wp          ! coefficient for avt: avt=rn_ediff*mxl*sqrt(e)
76   REAL(wp) ::   rn_ediss = 0.7_wp          ! coefficient of the Kolmogoroff dissipation
77   REAL(wp) ::   rn_ebb   = 3.75_wp         ! coefficient of the surface input of tke
78   REAL(wp) ::   rn_efave = 1._wp           ! coefficient for ave : ave=rn_efave*avm
79   REAL(wp) ::   rn_emin  = 0.7071e-6_wp    ! minimum value of tke (m2/s2)
80   REAL(wp) ::   rn_emin0 = 1.e-4_wp        ! surface minimum value of tke (m2/s2)
81   REAL(wp) ::   rn_cri   = 2._wp / 9._wp   ! critic Richardson number
82   INTEGER  ::   nn_etau  = 0               ! type of depth penetration of surface tke (=0/1/2)
83   INTEGER  ::   nn_htau  = 0               ! type of tke profile of penetration (=0/1)
84   REAL(wp) ::   rn_lmin0 = 0.4_wp          ! surface  min value of mixing length
85   REAL(wp) ::   rn_lmin  = 0.1_wp          ! interior min value of mixing length
86   REAL(wp) ::   rn_efr   = 1.0_wp          ! fraction of TKE surface value which penetrates in the ocean
87   REAL(wp) ::   rn_lc    = 0.15_wp         ! coef to compute vertical velocity of Langmuir cells
88
89   !! * Substitutions
90#  include "domzgr_substitute.h90"
91#  include "vectopt_loop_substitute.h90"
92   !!----------------------------------------------------------------------
93   !! NEMO/OPA 3.0 , LOCEAN-IPSL (2008)
94   !! $Id: zdftke_old.F90 1617 2009-08-12 14:59:14Z ctlod $
95   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
96   !!----------------------------------------------------------------------
97
98CONTAINS
99
100   SUBROUTINE zdf_tke_old( kt )
101      !!----------------------------------------------------------------------
102      !!                   ***  ROUTINE zdf_tke_old  ***
103      !!
104      !! ** Purpose :   Compute the vertical eddy viscosity and diffusivity
105      !!      coefficients using a 1.5 turbulent closure scheme.
106      !!
107      !! ** Method  :   The time evolution of the turbulent kinetic energy
108      !!      (tke) is computed from a prognostic equation :
109      !!         d(en)/dt = eboost eav (d(u)/dz)**2         ! shear production
110      !!                  + d( rn_efave eav d(en)/dz )/dz   ! diffusion of tke
111      !!                  + grav/rau0 pdl eav d(rau)/dz     ! stratif. destruc.
112      !!                  - rn_ediss / emxl en**(2/3)       ! dissipation
113      !!      with the boundary conditions:
114      !!         surface: en = max( rn_emin0, rn_ebb sqrt(utau^2 + vtau^2) )
115      !!         bottom : en = rn_emin
116      !!      -1- The dissipation and mixing turbulent lengh scales are computed
117      !!         from the usual diagnostic buoyancy length scale: 
118      !!         mxl= sqrt(2*en)/N  where N is the brunt-vaisala frequency
119      !!         with mxl = rn_lmin at the bottom minimum value of 0.4
120      !!      Four cases :
121      !!         nn_mxl=0 : mxl bounded by the distance to surface and bottom.
122      !!                  zmxld = zmxlm = mxl
123      !!         nn_mxl=1 : mxl bounded by the vertical scale factor.
124      !!                  zmxld = zmxlm = mxl
125      !!         nn_mxl=2 : mxl bounded such that the vertical derivative of mxl
126      !!                  is less than 1 (|d/dz(xml)|<1).
127      !!                  zmxld = zmxlm = mxl
128      !!         nn_mxl=3 : lup = mxl bounded using |d/dz(xml)|<1 from the surface
129      !!                        to the bottom
130      !!                  ldown = mxl bounded using |d/dz(xml)|<1 from the bottom
131      !!                        to the surface
132      !!                  zmxld = sqrt (lup*ldown) ; zmxlm = min(lup,ldown)
133      !!      -2- Compute the now Turbulent kinetic energy. The time differencing
134      !!      is implicit for vertical diffusion term, linearized for kolmo-
135      !!      goroff dissipation term, and explicit forward for both buoyancy
136      !!      and dynamic production terms. Thus a tridiagonal linear system is
137      !!      solved.
138      !!         Note that - the shear production is multiplied by eboost in order
139      !!      to set the critic richardson number to rn_cri (namelist parameter)
140      !!                   - the destruction by stratification term is multiplied
141      !!      by the Prandtl number (defined by an empirical funtion of the local
142      !!      Richardson number) if nn_pdl=1 (namelist parameter)
143      !!      coefficient (zesh2):
144      !!      -3- Compute the now vertical eddy vicosity and diffusivity
145      !!      coefficients from en (before the time stepping) and zmxlm:
146      !!              avm = max( avtb, rn_ediff*zmxlm*en^1/2 )
147      !!              avt = max( avmb, pdl*avm )  (pdl=1 if nn_pdl=0)
148      !!              eav = max( avmb, avm )
149      !!      avt and avm are horizontally averaged to avoid numerical insta-
150      !!      bilities.
151      !!        N.B. The computation is done from jk=2 to jpkm1 except for
152      !!      en. Surface value of avt avmu avmv are set once a time to
153      !!      their background value in routine zdf_tke_init.
154      !!
155      !! ** Action  :   compute en (now turbulent kinetic energy)
156      !!                update avt, avmu, avmv (before vertical eddy coef.)
157      !!
158      !! References : Gaspar et al., JGR, 1990,
159      !!              Blanke and Delecluse, JPO, 1991
160      !!              Mellor and Blumberg, JPO 2004
161      !!              Axell, JGR, 2002
162      !!----------------------------------------------------------------------
163      USE oce,     zwd    =>   ua   ! use ua as workspace
164      USE oce,     zmxlm  =>   va   ! use va as workspace
165      USE oce,     zmxld  =>   ta   ! use ta as workspace
166      USE oce,     ztkelc =>   sa   ! use sa as workspace
167      !
168      INTEGER, INTENT(in) ::   kt   ! ocean time step
169      !
170      INTEGER  ::   ji, jj, jk                      ! dummy loop arguments
171      REAL(wp) ::   zbbrau, zrn2, zesurf            ! temporary scalars
172      REAL(wp) ::   zfact1, ztx2, zdku              !    -         -
173      REAL(wp) ::   zfact2, zty2, zdkv              !    -         -
174      REAL(wp) ::   zfact3, zcoef, zcof, zav        !    -         -
175      REAL(wp) ::   zsh2, zpdl, zri, zsqen, zesh2   !    -         -
176      REAL(wp) ::   zemxl, zemlm, zemlp             !    -         -
177      REAL(wp) ::   zraug, zus, zwlc, zind          !    -         -
178      INTEGER , DIMENSION(jpi,jpj)     ::   imlc    ! 2D workspace
179      REAL(wp), DIMENSION(jpi,jpj)     ::   zhtau   !  -      -
180      REAL(wp), DIMENSION(jpi,jpj)     ::   zhlc    !  -      -
181      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zpelc   ! 3D workspace
182      !!--------------------------------------------------------------------
183
184      IF( kt == nit000  )   CALL zdf_tke_init      ! Initialization (first time-step only)
185
186      !                                            ! Local constant initialization
187      zbbrau =  .5 * rn_ebb / rau0
188      zfact1 = -.5 * rdt * rn_efave
189      zfact2 = 1.5 * rdt * rn_ediss
190      zfact3 = 0.5 * rdt * rn_ediss
191
192      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
193      ! I.  Mixing length
194      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
195
196      ! Buoyancy length scale: l=sqrt(2*e/n**2)
197      ! ---------------------
198      IF( ln_mxl0 ) THEN         ! surface mixing length = F(stress) : l=vkarmn*2.e5*sqrt(utau^2 + vtau^2)/(rau0*g)
199!!gm  this should be useless
200         zmxlm(:,:,1) = 0.e0
201!!gm end
202         zraug = 0.5 * vkarmn * 2.e5 / ( rau0 * grav )
203         DO jj = 2, jpjm1
204!CDIR NOVERRCHK
205            DO ji = fs_2, fs_jpim1   ! vector opt.
206               ztx2 = utau(ji-1,jj  ) + utau(ji,jj)
207               zty2 = vtau(ji  ,jj-1) + vtau(ji,jj)
208               zmxlm(ji,jj,1) = MAX(  rn_lmin0,  zraug * SQRT( ztx2 * ztx2 + zty2 * zty2 )  )
209            END DO
210         END DO
211      ELSE                       ! surface set to the minimum value
212         zmxlm(:,:,1) = rn_lmin0
213      ENDIF
214      zmxlm(:,:,jpk) = rn_lmin   ! bottom set to the interior minium value
215      !
216!CDIR NOVERRCHK
217      DO jk = 2, jpkm1           ! interior value : l=sqrt(2*e/n**2)
218!CDIR NOVERRCHK
219         DO jj = 2, jpjm1
220!CDIR NOVERRCHK
221            DO ji = fs_2, fs_jpim1   ! vector opt.
222               zrn2 = MAX( rn2b(ji,jj,jk), rsmall )
223               zmxlm(ji,jj,jk) = MAX(  rn_lmin,  SQRT( 2. * en(ji,jj,jk) / zrn2 )  )
224            END DO
225         END DO
226      END DO
227
228      ! Physical limits for the mixing length
229      ! -------------------------------------
230      zmxld(:,:, 1 ) = zmxlm(:,:,1)   ! surface set to the minimum value
231      zmxld(:,:,jpk) = rn_lmin        ! bottom  set to the minimum value
232
233      SELECT CASE ( nn_mxl )
234      !
235      CASE ( 0 )           ! bounded by the distance to surface and bottom
236         DO jk = 2, jpkm1
237            DO jj = 2, jpjm1
238               DO ji = fs_2, fs_jpim1   ! vector opt.
239                  zemxl = MIN( fsdepw(ji,jj,jk), zmxlm(ji,jj,jk),   &
240                  &            fsdepw(ji,jj,mbathy(ji,jj)) - fsdepw(ji,jj,jk) )
241                  zmxlm(ji,jj,jk) = zemxl
242                  zmxld(ji,jj,jk) = zemxl
243               END DO
244            END DO
245         END DO
246         !
247      CASE ( 1 )           ! bounded by the vertical scale factor
248         DO jk = 2, jpkm1
249            DO jj = 2, jpjm1
250               DO ji = fs_2, fs_jpim1   ! vector opt.
251                  zemxl = MIN( fse3w(ji,jj,jk), zmxlm(ji,jj,jk) )
252                  zmxlm(ji,jj,jk) = zemxl
253                  zmxld(ji,jj,jk) = zemxl
254               END DO
255            END DO
256         END DO
257         !
258      CASE ( 2 )           ! |dk[xml]| bounded by e3t :
259         DO jk = 2, jpkm1         ! from the surface to the bottom :
260            DO jj = 2, jpjm1
261               DO ji = fs_2, fs_jpim1   ! vector opt.
262                  zmxlm(ji,jj,jk) = MIN( zmxlm(ji,jj,jk-1) + fse3t(ji,jj,jk-1), zmxlm(ji,jj,jk) )
263               END DO
264            END DO
265         END DO
266         DO jk = jpkm1, 2, -1     ! from the bottom to the surface :
267            DO jj = 2, jpjm1
268               DO ji = fs_2, fs_jpim1   ! vector opt.
269                  zemxl = MIN( zmxlm(ji,jj,jk+1) + fse3t(ji,jj,jk+1), zmxlm(ji,jj,jk) )
270                  zmxlm(ji,jj,jk) = zemxl
271                  zmxld(ji,jj,jk) = zemxl
272               END DO
273            END DO
274         END DO
275         !
276      CASE ( 3 )           ! lup and ldown, |dk[xml]| bounded by e3t :
277         DO jk = 2, jpkm1         ! from the surface to the bottom : lup
278            DO jj = 2, jpjm1
279               DO ji = fs_2, fs_jpim1   ! vector opt.
280                  zmxld(ji,jj,jk) = MIN( zmxld(ji,jj,jk-1) + fse3t(ji,jj,jk-1), zmxlm(ji,jj,jk) )
281               END DO
282            END DO
283         END DO
284         DO jk = jpkm1, 2, -1     ! from the bottom to the surface : ldown
285            DO jj = 2, jpjm1
286               DO ji = fs_2, fs_jpim1   ! vector opt.
287                  zmxlm(ji,jj,jk) = MIN( zmxlm(ji,jj,jk+1) + fse3t(ji,jj,jk+1), zmxlm(ji,jj,jk) )
288               END DO
289            END DO
290         END DO
291!CDIR NOVERRCHK
292         DO jk = 2, jpkm1
293!CDIR NOVERRCHK
294            DO jj = 2, jpjm1
295!CDIR NOVERRCHK
296               DO ji = fs_2, fs_jpim1   ! vector opt.
297                  zemlm = MIN ( zmxld(ji,jj,jk),  zmxlm(ji,jj,jk) )
298                  zemlp = SQRT( zmxld(ji,jj,jk) * zmxlm(ji,jj,jk) )
299                  zmxlm(ji,jj,jk) = zemlm
300                  zmxld(ji,jj,jk) = zemlp
301               END DO
302            END DO
303         END DO
304         !
305      END SELECT
306
307# if defined key_c1d
308      ! c1d configuration : save mixing and dissipation turbulent length scales
309      e_dis(:,:,:) = zmxld(:,:,:)
310      e_mix(:,:,:) = zmxlm(:,:,:)
311# endif
312
313      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
314      ! II  TKE Langmuir circulation source term
315      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
316      IF( ln_lc ) THEN
317         !
318         ! Computation of total energy produce by LC : cumulative sum over jk
319         zpelc(:,:,1) =  MAX( rn2b(:,:,1), 0. ) * fsdepw(:,:,1) * fse3w(:,:,1)
320         DO jk = 2, jpk
321            zpelc(:,:,jk)  = zpelc(:,:,jk-1) + MAX( rn2b(:,:,jk), 0. ) * fsdepw(:,:,jk) * fse3w(:,:,jk)
322         END DO
323         !
324         ! Computation of finite Langmuir Circulation depth
325         ! Initialization to the number of w ocean point mbathy
326         imlc(:,:) = mbathy(:,:)
327         DO jk = jpkm1, 2, -1
328            DO jj = 1, jpj
329               DO ji = 1, jpi
330                  ! Last w-level at which zpelc>=0.5*us*us with us=0.016*wind(starting from jpk-1)
331                  zus  = 0.000128 * wndm(ji,jj) * wndm(ji,jj)
332                  IF( zpelc(ji,jj,jk) > zus )   imlc(ji,jj) = jk
333               END DO
334            END DO
335         END DO
336         !
337         ! finite LC depth
338         DO jj = 1, jpj
339            DO ji = 1, jpi
340               zhlc(ji,jj) = fsdepw(ji,jj,imlc(ji,jj))
341            END DO
342         END DO
343         !
344# if defined key_c1d
345         hlc(:,:) = zhlc(:,:) * tmask(:,:,1)      ! c1d configuration: save finite Langmuir Circulation depth
346# endif
347         !
348         ! TKE Langmuir circulation source term
349!CDIR NOVERRCHK
350         DO jk = 2, jpkm1
351!CDIR NOVERRCHK
352            DO jj = 2, jpjm1
353!CDIR NOVERRCHK
354               DO ji = fs_2, fs_jpim1   ! vector opt.
355                  ! Stokes drift
356                  zus  = 0.016 * wndm(ji,jj)
357                  ! computation of vertical velocity due to LC
358                  zind = 0.5 - SIGN( 0.5, fsdepw(ji,jj,jk) - zhlc(ji,jj) )
359                  zwlc = zind * rn_lc * zus * SIN( rpi * fsdepw(ji,jj,jk) / zhlc(ji,jj) )
360                  ! TKE Langmuir circulation source term
361                  ztkelc(ji,jj,jk) = ( zwlc * zwlc * zwlc ) / zhlc(ji,jj)
362               END DO
363            END DO
364         END DO
365         !
366      ENDIF
367
368      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
369      ! III  Tubulent kinetic energy time stepping
370      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
371
372      ! 1. Vertical eddy viscosity on tke (put in zmxlm) and first estimate of avt
373      ! ---------------------------------------------------------------------
374!CDIR NOVERRCHK
375      DO jk = 2, jpkm1
376!CDIR NOVERRCHK
377         DO jj = 2, jpjm1
378!CDIR NOVERRCHK
379            DO ji = fs_2, fs_jpim1   ! vector opt.
380               zsqen = SQRT( en(ji,jj,jk) )
381               zav   = rn_ediff * zmxlm(ji,jj,jk) * zsqen
382               avt  (ji,jj,jk) = MAX( zav, avtb_2d(ji,jj) * avtb(jk) ) * tmask(ji,jj,jk)
383               zmxlm(ji,jj,jk) = MAX( zav, avmb(jk) ) * tmask(ji,jj,jk)
384               zmxld(ji,jj,jk) = zsqen / zmxld(ji,jj,jk)
385            END DO
386         END DO
387      END DO
388
389      ! 2. Surface boundary condition on tke and its eddy viscosity (zmxlm)
390      ! -------------------------------------------------
391      ! en(1)   = rn_ebb sqrt(utau^2+vtau^2) / rau0  (min value rn_emin0)
392      ! zmxlm(1) = avmb(1) and zmxlm(jpk) = 0.
393!CDIR NOVERRCHK
394      DO jj = 2, jpjm1
395!CDIR NOVERRCHK
396         DO ji = fs_2, fs_jpim1   ! vector opt.
397            ztx2 = utau(ji-1,jj  ) + utau(ji,jj)
398            zty2 = vtau(ji  ,jj-1) + vtau(ji,jj)
399            zesurf = zbbrau * SQRT( ztx2 * ztx2 + zty2 * zty2 )
400            en (ji,jj,1) = MAX( zesurf, rn_emin0 ) * tmask(ji,jj,1)
401            zav  =  rn_ediff * zmxlm(ji,jj,1) * SQRT( en(ji,jj,1) )
402            zmxlm(ji,jj,1  ) = MAX( zav, avmb(1)                  ) * tmask(ji,jj,1)
403            avt  (ji,jj,1  ) = MAX( zav, avtb(1) * avtb_2d(ji,jj) ) * tmask(ji,jj,1)
404            zmxlm(ji,jj,jpk) = 0.e0
405         END DO
406      END DO
407
408      ! 3. Now Turbulent kinetic energy (output in en)
409      ! -------------------------------
410      ! Resolution of a tridiagonal linear system by a "methode de chasse"
411      ! computation from level 2 to jpkm1  (e(1) already computed and e(jpk)=0 ).
412
413      SELECT CASE ( nn_pdl )
414      !
415      CASE ( 0 )           ! No Prandtl number
416         DO jk = 2, jpkm1
417            DO jj = 2, jpjm1
418               DO ji = fs_2, fs_jpim1   ! vector opt.
419                  !                                                             ! shear prod. - stratif. destruction
420                  zcoef = 0.5 / fse3w(ji,jj,jk)
421                  zdku = zcoef * (  ub(ji-1, jj ,jk-1) + ub(ji,jj,jk-1)   &          ! shear
422                     &            - ub(ji-1, jj ,jk  ) - ub(ji,jj,jk  )  )
423                  zdkv = zcoef * (  vb( ji ,jj-1,jk-1) + vb(ji,jj,jk-1)   &
424                     &            - vb( ji ,jj-1,jk  ) - vb(ji,jj,jk  )  )
425                  zesh2 =  eboost * ( zdku*zdku + zdkv*zdkv ) - rn2b(ji,jj,jk)        ! coefficient (zesh2)
426                  !
427                  !                                                             ! Matrix
428                  zcof = zfact1 * tmask(ji,jj,jk)
429                  !                                                                  ! lower diagonal
430                  avmv(ji,jj,jk) = zcof * ( zmxlm(ji,jj,jk  ) + zmxlm(ji,jj,jk-1) )   &
431                     &                  / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
432                  !                                                                  ! upper diagonal
433                  avmu(ji,jj,jk) = zcof * ( zmxlm(ji,jj,jk+1) + zmxlm(ji,jj,jk  ) )   &
434                     &                  / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
435                  !                                                                  ! diagonal
436                  zwd(ji,jj,jk) = 1. - avmv(ji,jj,jk) - avmu(ji,jj,jk) + zfact2 * zmxld(ji,jj,jk)
437                  !
438                  !                                                             ! right hand side in en
439                  IF( .NOT. ln_lc ) THEN                                             ! No Langmuir cells
440                     en(ji,jj,jk) = en(ji,jj,jk) + zfact3 * zmxld (ji,jj,jk) * en(ji,jj,jk)   &
441                        &                        +   rdt  * zmxlm (ji,jj,jk) * zesh2
442                  ELSE                                                               ! Langmuir cell source term
443                     en(ji,jj,jk) = en(ji,jj,jk) + zfact3 * zmxld (ji,jj,jk) * en(ji,jj,jk)   &
444                        &                        +   rdt  * zmxlm (ji,jj,jk) * zesh2          &
445                        &                        +   rdt  * ztkelc(ji,jj,jk)
446                  ENDIF
447               END DO
448            END DO
449         END DO
450         !
451      CASE ( 1 )           ! Prandtl number
452         DO jk = 2, jpkm1
453            DO jj = 2, jpjm1
454               DO ji = fs_2, fs_jpim1   ! vector opt.
455                  !                                                             ! shear prod. - stratif. destruction
456                  zcoef = 0.5 / fse3w(ji,jj,jk)                                     
457                  zdku = zcoef * (  ub(ji-1,jj  ,jk-1) + ub(ji,jj,jk-1)   &          ! shear
458                  &               - ub(ji-1,jj  ,jk  ) - ub(ji,jj,jk  )  )
459                  zdkv = zcoef * (  vb(ji  ,jj-1,jk-1) + vb(ji,jj,jk-1)   &
460                  &               - vb(ji  ,jj-1,jk  ) - vb(ji,jj,jk  )  )
461                  zsh2 = zdku * zdku + zdkv * zdkv                                   ! square of shear
462                  zri  = MAX( rn2b(ji,jj,jk), 0. ) / ( zsh2 + 1.e-20 )                ! local Richardson number
463# if defined key_c1d
464                  e_ric(ji,jj,jk) = zri * tmask(ji,jj,jk)                            ! c1d config. : save Ri
465# endif
466                  zpdl = 1.0                                                         ! Prandtl number
467                  IF( zri >= 0.2 )   zpdl = 0.2 / zri
468                  zpdl = MAX( 0.1, zpdl )
469                  zesh2 = eboost * zsh2 - zpdl * rn2b(ji,jj,jk)                       ! coefficient (esh2)
470                  !
471                  !                                                             ! Matrix
472                  zcof = zfact1 * tmask(ji,jj,jk)
473                  !                                                                 ! lower diagonal
474                  avmv(ji,jj,jk) = zcof * ( zmxlm(ji,jj,jk  ) + zmxlm(ji,jj,jk-1) )   &
475                  &                     / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
476                  !                                                                 ! upper diagonal
477                  avmu(ji,jj,jk) = zcof * ( zmxlm(ji,jj,jk+1) + zmxlm(ji,jj,jk  ) )   &
478                  &                     / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
479                  !                                                                 ! diagonal
480                  zwd(ji,jj,jk) = 1. - avmv(ji,jj,jk) - avmu(ji,jj,jk) + zfact2 * zmxld(ji,jj,jk)
481                  !
482                  !                                                             ! right hand side in en
483                  IF( .NOT. ln_lc ) THEN                                             ! No Langmuir cells
484                     en(ji,jj,jk) = en(ji,jj,jk) + zfact3 * zmxld (ji,jj,jk) * en   (ji,jj,jk)   &
485                        &                        +   rdt  * zmxlm (ji,jj,jk) * zesh2
486                  ELSE                                                               ! Langmuir cell source term
487                     en(ji,jj,jk) = en(ji,jj,jk) + zfact3 * zmxld (ji,jj,jk) * en   (ji,jj,jk)   &
488                        &                        +   rdt  * zmxlm (ji,jj,jk) * zesh2             &
489                        &                        +   rdt  * ztkelc(ji,jj,jk)
490                  ENDIF
491                  zmxld(ji,jj,jk) = zpdl * tmask(ji,jj,jk)                      ! store masked Prandlt number in zmxld array
492               END DO
493            END DO
494         END DO
495         !
496      END SELECT
497
498# if defined key_c1d
499      e_pdl(:,:,2:jpkm1) = zmxld(:,:,2:jpkm1)      ! c1d configuration : save masked Prandlt number
500      e_pdl(:,:,      1) = e_pdl(:,:,      2)
501      e_pdl(:,:,    jpk) = e_pdl(:,:,  jpkm1)     
502# endif
503
504      ! 4. Matrix inversion from level 2 (tke prescribed at level 1)
505      !!--------------------------------
506      DO jk = 3, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
507         DO jj = 2, jpjm1
508            DO ji = fs_2, fs_jpim1    ! vector opt.
509               zwd(ji,jj,jk) = zwd(ji,jj,jk) - avmv(ji,jj,jk) * avmu(ji,jj,jk-1) / zwd(ji,jj,jk-1)
510            END DO
511         END DO
512      END DO
513      DO jj = 2, jpjm1                             ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
514         DO ji = fs_2, fs_jpim1    ! vector opt.
515            avmv(ji,jj,2) = en(ji,jj,2) - avmv(ji,jj,2) * en(ji,jj,1)    ! Surface boudary conditions on tke
516         END DO
517      END DO
518      DO jk = 3, jpkm1
519         DO jj = 2, jpjm1
520            DO ji = fs_2, fs_jpim1    ! vector opt.
521               avmv(ji,jj,jk) = en(ji,jj,jk) - avmv(ji,jj,jk) / zwd(ji,jj,jk-1) *avmv(ji,jj,jk-1)
522            END DO
523         END DO
524      END DO
525      DO jj = 2, jpjm1                             ! thrid recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
526         DO ji = fs_2, fs_jpim1    ! vector opt.
527            en(ji,jj,jpkm1) = avmv(ji,jj,jpkm1) / zwd(ji,jj,jpkm1)
528         END DO
529      END DO
530      DO jk = jpk-2, 2, -1
531         DO jj = 2, jpjm1
532            DO ji = fs_2, fs_jpim1    ! vector opt.
533               en(ji,jj,jk) = ( avmv(ji,jj,jk) - avmu(ji,jj,jk) * en(ji,jj,jk+1) ) / zwd(ji,jj,jk)
534            END DO
535         END DO
536      END DO
537      DO jk = 2, jpkm1                             ! set the minimum value of tke
538         DO jj = 2, jpjm1
539            DO ji = fs_2, fs_jpim1   ! vector opt.
540               en(ji,jj,jk) = MAX( en(ji,jj,jk), rn_emin ) * tmask(ji,jj,jk)
541            END DO
542         END DO
543      END DO
544     
545      ! 5. Add extra TKE due to surface and internal wave breaking (nn_etau /= 0)
546      !!----------------------------------------------------------
547      IF( nn_etau /= 0 ) THEN        ! extra tke : en = en + rn_efr * en(1) * exp( -z/zhtau )
548         !
549         SELECT CASE( nn_htau )           ! Choice of the depth of penetration
550         CASE( 0 )                                    ! constant depth penetration (here 10 meters)
551            DO jj = 2, jpjm1
552               DO ji = fs_2, fs_jpim1   ! vector opt.
553                  zhtau(ji,jj) = 10.
554               END DO
555            END DO
556         CASE( 1 )                                    ! meridional profile  1
557            DO jj = 2, jpjm1                          ! ( 0.5m in the tropics to a maximum of 30 m at high lat.)
558               DO ji = fs_2, fs_jpim1   ! vector opt.
559                  zhtau(ji,jj) = MAX( 0.5, 3./4. * MIN( 40., 60.*ABS( SIN( rpi/180. * gphit(ji,jj) ) ) )   )
560               END DO
561            END DO
562         END SELECT
563         !
564         IF( nn_etau == 1 ) THEN          ! extra term throughout the water column
565            DO jk = 2, jpkm1
566               DO jj = 2, jpjm1
567                  DO ji = fs_2, fs_jpim1   ! vector opt.
568                     en(ji,jj,jk) = en(ji,jj,jk)   &
569                        &         + rn_efr * en(ji,jj,1)*EXP( -fsdepw(ji,jj,jk) / zhtau(ji,jj) ) &
570                        &                  * ( 1.e0 - fr_i(ji,jj) )  * tmask(ji,jj,jk)
571                  END DO
572               END DO
573            END DO
574         ELSEIF( nn_etau == 2 ) THEN      ! extra term only at the base of the mixed layer
575            DO jj = 2, jpjm1
576               DO ji = fs_2, fs_jpim1   ! vector opt.
577                  jk = nmln(ji,jj)
578                  en(ji,jj,jk) = en(ji,jj,jk)    &
579                     &         + rn_efr * en(ji,jj,1)*EXP( -fsdepw(ji,jj,jk) / zhtau(ji,jj) ) &
580                     &                   * ( 1.e0 - fr_i(ji,jj) )  * tmask(ji,jj,jk)
581               END DO
582            END DO
583         ENDIF
584         !
585      ENDIF
586
587
588      ! Lateral boundary conditions (sign unchanged)
589      CALL lbc_lnk( en, 'W', 1. )   ;   CALL lbc_lnk( avt, 'W', 1. )
590
591
592      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
593      ! IV.  Before vertical eddy vicosity and diffusivity coefficients
594      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
595      !
596      SELECT CASE ( nn_ave )
597      CASE ( 0 )                                     ! no horizontal average
598         DO jk = 2, jpkm1                                 ! only vertical eddy viscosity
599            DO jj = 2, jpjm1
600               DO ji = fs_2, fs_jpim1   ! vector opt.
601                  avmu(ji,jj,jk) = ( avt  (ji,jj,jk) + avt  (ji+1,jj  ,jk) ) * umask(ji,jj,jk)   &
602                  &     / MAX( 1.,   tmask(ji,jj,jk) + tmask(ji+1,jj  ,jk) )
603                  avmv(ji,jj,jk) = ( avt  (ji,jj,jk) + avt  (ji  ,jj+1,jk) ) * vmask(ji,jj,jk)   &
604                  &     / MAX( 1.,   tmask(ji,jj,jk) + tmask(ji  ,jj+1,jk) )
605               END DO
606            END DO
607         END DO
608         CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )      ! Lateral boundary conditions
609         !
610      CASE ( 1 )                                     ! horizontal average                         ( 1/2  1/2 )
611         !                                                ! Vertical eddy viscosity    avmu = 1/4 ( 1    1   )
612         !                                                !                                       ( 1/2  1/2 )
613         !                                                !
614         !                                                !                                       ( 1/2  1   1/2 )           
615         !                                                !                            avmv = 1/4 ( 1/2  1   1/2 )     
616         DO jk = 2, jpkm1                               
617            DO jj = 2, jpjm1
618               DO ji = fs_2, fs_jpim1   ! vector opt.
619# if defined key_vectopt_memory
620                  !                                       ! caution : vectopt_memory change the solution
621                  !                                       !           (last digit of the solver stat)
622                  avmu(ji,jj,jk) = (      avt(ji,jj  ,jk) + avt(ji+1,jj  ,jk)   &
623                     &              +.5*( avt(ji,jj-1,jk) + avt(ji+1,jj-1,jk)   &
624                     &                   +avt(ji,jj+1,jk) + avt(ji+1,jj+1,jk) ) ) * eumean(ji,jj,jk)
625
626                  avmv(ji,jj,jk) = (      avt(ji  ,jj,jk) + avt(ji  ,jj+1,jk)   &
627                     &              +.5*( avt(ji-1,jj,jk) + avt(ji-1,jj+1,jk)   &
628                     &                   +avt(ji+1,jj,jk) + avt(ji+1,jj+1,jk) ) ) * evmean(ji,jj,jk)
629# else
630                  avmu(ji,jj,jk) = (   avt  (ji,jj  ,jk) + avt  (ji+1,jj  ,jk)   &
631                     &           +.5*( avt  (ji,jj-1,jk) + avt  (ji+1,jj-1,jk)   &
632                     &                +avt  (ji,jj+1,jk) + avt  (ji+1,jj+1,jk) ) ) * umask(ji,jj,jk)   &
633                     &    / MAX( 1.,   tmask(ji,jj  ,jk) + tmask(ji+1,jj  ,jk)   &
634                     &           +.5*( tmask(ji,jj-1,jk) + tmask(ji+1,jj-1,jk)   &
635                     &                +tmask(ji,jj+1,jk) + tmask(ji+1,jj+1,jk) )  )
636
637                  avmv(ji,jj,jk) = (   avt  (ji  ,jj,jk) + avt  (ji  ,jj+1,jk)   &
638                     &           +.5*( avt  (ji-1,jj,jk) + avt  (ji-1,jj+1,jk)   &
639                     &                +avt  (ji+1,jj,jk) + avt  (ji+1,jj+1,jk) ) ) * vmask(ji,jj,jk)   &
640                     &   /  MAX( 1.,   tmask(ji  ,jj,jk) + tmask(ji  ,jj+1,jk)   &
641                     &           +.5*( tmask(ji-1,jj,jk) + tmask(ji-1,jj+1,jk)   &
642                     &                +tmask(ji+1,jj,jk) + tmask(ji+1,jj+1,jk) )  )
643# endif
644               END DO
645            END DO
646         END DO
647         CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )      ! Lateral boundary conditions
648         !
649         !                                                ! Vertical eddy diffusivity             (1 2 1)
650         !                                                !                            avt = 1/16 (2 4 2)
651         !                                                !                                       (1 2 1)
652         DO jk = 2, jpkm1         
653            DO jj = 2, jpjm1
654               DO ji = fs_2, fs_jpim1   ! vector opt.
655#  if defined key_vectopt_memory
656                  avt(ji,jj,jk) = ( avmu(ji,jj,jk) + avmu(ji-1,jj  ,jk)                          &
657                     &            + avmv(ji,jj,jk) + avmv(ji  ,jj-1,jk)  ) * etmean(ji,jj,jk)
658#  else
659                  avt(ji,jj,jk) = ( avmu (ji,jj,jk) + avmu (ji-1,jj  ,jk)                        &
660                     &            + avmv (ji,jj,jk) + avmv (ji  ,jj-1,jk)  ) * tmask(ji,jj,jk)   &
661                     &  / MAX( 1.,  umask(ji,jj,jk) + umask(ji-1,jj  ,jk)                        &
662                     &            + vmask(ji,jj,jk) + vmask(ji  ,jj-1,jk)  )
663#  endif
664               END DO
665            END DO
666         END DO
667         !
668      END SELECT
669      !
670      IF( nn_pdl == 1 ) THEN                            ! Ponderation by the Prandtl number (nn_pdl=1)
671         DO jk = 2, jpkm1 
672            DO jj = 2, jpjm1
673               DO ji = fs_2, fs_jpim1   ! vector opt.
674                  zpdl = zmxld(ji,jj,jk)
675                  avt(ji,jj,jk) = MAX( zpdl * avt(ji,jj,jk), avtb_2d(ji,jj) * avtb(jk) ) * tmask(ji,jj,jk)
676               END DO
677            END DO
678         END DO
679      ENDIF
680      !
681      DO jk = 2, jpkm1                                  ! Minimum value on the eddy viscosity
682         avmu(:,:,jk) = MAX( avmu(:,:,jk), avmb(jk) ) * umask(:,:,jk)
683         avmv(:,:,jk) = MAX( avmv(:,:,jk), avmb(jk) ) * vmask(:,:,jk)
684      END DO
685
686      CALL lbc_lnk( avt, 'W', 1. )                      ! Lateral boundary conditions on avt  (sign unchanged)
687
688      IF( lrst_oce )   CALL tke_rst( kt, 'WRITE' )      ! write en in restart file
689
690      IF(ln_ctl) THEN
691         CALL prt_ctl( tab3d_1=en  , clinfo1=' tke  - e: ', tab3d_2=avt, clinfo2=' t: ', ovlap=1, kdim=jpk)
692         CALL prt_ctl( tab3d_1=avmu, clinfo1=' tke  - u: ', mask1=umask,                   &
693            &          tab3d_2=avmv, clinfo2=       ' v: ', mask2=vmask, ovlap=1, kdim=jpk )
694      ENDIF
695      !
696   END SUBROUTINE zdf_tke_old
697
698
699   SUBROUTINE zdf_tke_init
700      !!----------------------------------------------------------------------
701      !!                  ***  ROUTINE zdf_tke_init  ***
702      !!                     
703      !! ** Purpose :   Initialization of the vertical eddy diffivity and
704      !!      viscosity when using a tke turbulent closure scheme
705      !!
706      !! ** Method  :   Read the namzdf_tke namelist and check the parameters
707      !!      called at the first timestep (nit000)
708      !!
709      !! ** input   :   Namlist namzdf_tke
710      !!
711      !! ** Action  :   Increase by 1 the nstop flag is setting problem encounter
712      !!
713      !!----------------------------------------------------------------------
714      USE dynzdf_exp
715      USE trazdf_exp
716      !
717# if defined key_vectopt_memory
718      INTEGER ::   ji, jj, jk   ! dummy loop indices
719# else
720      INTEGER ::           jk   ! dummy loop indices
721# endif
722      !!
723      NAMELIST/namzdf_tke/ ln_rstke, rn_ediff, rn_ediss, rn_ebb  , rn_efave, rn_emin,   &
724         &                 rn_emin0, rn_cri  , nn_itke , nn_mxl  , nn_pdl  , nn_ave ,   &
725         &                 ln_mxl0 , rn_lmin , rn_lmin0, nn_etau,   &
726         &                 nn_htau , rn_efr  , ln_lc   , rn_lc 
727      !!----------------------------------------------------------------------
728
729      ! Read Namelist namzdf_tke : Turbulente Kinetic Energy
730      ! --------------------
731      REWIND ( numnam )
732      READ   ( numnam, namzdf_tke )
733
734      ! Compute boost associated with the Richardson critic
735      !     (control values: rn_cri = 0.3   ==> eboost=1.25 for nn_pdl=1)
736      !     (                rn_cri = 0.222 ==> eboost=1.               )
737      eboost = rn_cri * ( 2. + rn_ediss / rn_ediff ) / 2.
738
739
740
741      ! Parameter control and print
742      ! ---------------------------
743      ! Control print
744      IF(lwp) THEN
745         WRITE(numout,*)
746         WRITE(numout,*) 'zdf_tke_init : tke turbulent closure scheme (old scheme)'
747         WRITE(numout,*) '~~~~~~~~~~~~'
748         WRITE(numout,*) '          Namelist namzdf_tke : set tke mixing parameters'
749         WRITE(numout,*) '             restart with tke from no tke              ln_rstke = ', ln_rstke
750         WRITE(numout,*) '             coef. to compute avt                      rn_ediff = ', rn_ediff
751         WRITE(numout,*) '             Kolmogoroff dissipation coef.             rn_ediss = ', rn_ediss
752         WRITE(numout,*) '             tke surface input coef.                   rn_ebb   = ', rn_ebb
753         WRITE(numout,*) '             tke diffusion coef.                       rn_efave = ', rn_efave
754         WRITE(numout,*) '             minimum value of tke                      rn_emin  = ', rn_emin
755         WRITE(numout,*) '             surface minimum value of tke              rn_emin0 = ', rn_emin0
756         WRITE(numout,*) '             number of restart iter loops              nn_itke  = ', nn_itke
757         WRITE(numout,*) '             mixing length type                        nn_mxl   = ', nn_mxl
758         WRITE(numout,*) '             prandl number flag                        nn_pdl   = ', nn_pdl
759         WRITE(numout,*) '             horizontal average flag                   nn_ave   = ', nn_ave
760         WRITE(numout,*) '             critic Richardson nb                      rn_cri   = ', rn_cri
761         WRITE(numout,*) '                and its associated coeff.              eboost   = ', eboost
762         WRITE(numout,*) '             surface mixing length = F(stress) or not  ln_mxl0  = ', ln_mxl0
763         WRITE(numout,*) '             surface  mixing length minimum value      rn_lmin0 = ', rn_lmin0
764         WRITE(numout,*) '             interior mixing length minimum value      rn_lmin0 = ', rn_lmin0
765         WRITE(numout,*) '             test param. to add tke induced by wind    nn_etau  = ', nn_etau
766         WRITE(numout,*) '             flag for computation of exp. tke profile  nn_htau  = ', nn_htau
767         WRITE(numout,*) '             % of rn_emin0 which pene. the thermocline rn_efr   = ', rn_efr
768         WRITE(numout,*) '             flag to take into acc.  Langmuir circ.    ln_lc    = ', ln_lc
769         WRITE(numout,*) '             coef to compute verticla velocity of LC   rn_lc    = ', rn_lc
770         WRITE(numout,*)
771      ENDIF
772
773      ! Check of some namelist values
774      IF( nn_mxl  < 0    .OR. nn_mxl  > 3   )   CALL ctl_stop( 'bad flag: nn_mxl is  0, 1 or 2 ' )
775      IF( nn_pdl  < 0    .OR. nn_pdl  > 1   )   CALL ctl_stop( 'bad flag: nn_pdl is  0 or 1    ' )
776      IF( nn_ave  < 0    .OR. nn_ave  > 1   )   CALL ctl_stop( 'bad flag: nn_ave is  0 or 1    ' )
777      IF( nn_htau < 0    .OR. nn_htau > 1   )   CALL ctl_stop( 'bad flag: nn_htau is 0 or 1    ' )
778      IF( rn_lc   < 0.15 .OR. rn_lc   > 0.2 )   CALL ctl_stop( 'bad value: rn_lc must be between 0.15 and 0.2 ' )
779
780      IF( nn_etau == 2 )   CALL zdf_mxl( nit000 )      ! Initialization of nmln
781
782      ! Horizontal average : initialization of weighting arrays
783      ! -------------------
784      !
785      SELECT CASE ( nn_ave )
786      ! Notice: mean arrays have not to by defined at local domain boundaries due to the vertical nature of TKE
787      !
788      CASE ( 0 )                ! no horizontal average
789         IF(lwp) WRITE(numout,*) '          no horizontal average on avt, avmu, avmv'
790         IF(lwp) WRITE(numout,*) '          only in very high horizontal resolution !'
791# if defined key_vectopt_memory
792         ! caution vectopt_memory change the solution (last digit of the solver stat)
793         ! weighting mean arrays etmean, eumean and evmean
794         !           ( 1  1 )                                          ( 1 )
795         ! avt = 1/4 ( 1  1 )     avmu = 1/2 ( 1  1 )       avmv=  1/2 ( 1 )
796         !                         
797         etmean(:,:,:) = 0.e0
798         eumean(:,:,:) = 0.e0
799         evmean(:,:,:) = 0.e0
800         !
801         DO jk = 1, jpkm1
802            DO jj = 2, jpjm1
803               DO ji = fs_2, fs_jpim1   ! vector opt.
804                  etmean(ji,jj,jk) = tmask(ji,jj,jk) / MAX( 1.,  umask(ji,jj,jk) + umask(ji-1,jj  ,jk)   &
805                  &                                            + vmask(ji,jj,jk) + vmask(ji  ,jj-1,jk) )
806                  eumean(ji,jj,jk) = umask(ji,jj,jk) / MAX( 1.,  tmask(ji,jj,jk) + tmask(ji+1,jj  ,jk) )
807                  evmean(ji,jj,jk) = vmask(ji,jj,jk) / MAX( 1.,  tmask(ji,jj,jk) + tmask(ji  ,jj+1,jk) )
808               END DO
809            END DO
810         END DO
811# endif
812         !
813      CASE ( 1 )                ! horizontal average
814         IF(lwp) WRITE(numout,*) '          horizontal average on avt, avmu, avmv'
815# if defined key_vectopt_memory
816         ! caution vectopt_memory change the solution (last digit of the solver stat)
817         ! weighting mean arrays etmean, eumean and evmean
818         !           ( 1  1 )              ( 1/2  1/2 )             ( 1/2  1  1/2 )
819         ! avt = 1/4 ( 1  1 )   avmu = 1/4 ( 1    1   )   avmv= 1/4 ( 1/2  1  1/2 )
820         !                                 ( 1/2  1/2 )
821         etmean(:,:,:) = 0.e0
822         eumean(:,:,:) = 0.e0
823         evmean(:,:,:) = 0.e0
824         !
825         DO jk = 1, jpkm1
826            DO jj = 2, jpjm1
827               DO ji = fs_2, fs_jpim1   ! vector opt.
828                  etmean(ji,jj,jk) = tmask(ji,jj,jk) / MAX( 1.,   umask(ji-1,jj  ,jk) + umask(ji  ,jj  ,jk)   &
829                  &                                       +       vmask(ji  ,jj-1,jk) + vmask(ji  ,jj  ,jk) )
830                  eumean(ji,jj,jk) = umask(ji,jj,jk) / MAX( 1.,   tmask(ji  ,jj  ,jk) + tmask(ji+1,jj  ,jk)   &
831                  &                                       +.5 * ( tmask(ji  ,jj-1,jk) + tmask(ji+1,jj-1,jk)   &
832                  &                                             + tmask(ji  ,jj+1,jk) + tmask(ji+1,jj+1,jk) )  )
833                  evmean(ji,jj,jk) = vmask(ji,jj,jk) / MAX( 1.,   tmask(ji  ,jj  ,jk) + tmask(ji  ,jj+1,jk)   &
834                  &                                       +.5 * ( tmask(ji-1,jj  ,jk) + tmask(ji-1,jj+1,jk)   &
835                  &                                             + tmask(ji+1,jj  ,jk) + tmask(ji+1,jj+1,jk) )  )
836               END DO
837            END DO
838         END DO
839# endif
840         !
841      END SELECT
842
843      ! Initialization of vertical eddy coef. to the background value
844      ! -------------------------------------------------------------
845      DO jk = 1, jpk
846         avt (:,:,jk) = avtb(jk) * tmask(:,:,jk)
847         avmu(:,:,jk) = avmb(jk) * umask(:,:,jk)
848         avmv(:,:,jk) = avmb(jk) * vmask(:,:,jk)
849      END DO
850
851
852      ! read or initialize turbulent kinetic energy ( en )
853      ! -------------------------------------------------
854      CALL tke_rst( nit000, 'READ' )
855      !
856   END SUBROUTINE zdf_tke_init
857
858
859   SUBROUTINE tke_rst( kt, cdrw )
860     !!---------------------------------------------------------------------
861     !!                   ***  ROUTINE ts_rst  ***
862     !!                     
863     !! ** Purpose :   Read or write TKE file (en) in restart file
864     !!
865     !! ** Method  :   use of IOM library
866     !!                if the restart does not contain TKE, en is either
867     !!                set to rn_emin or recomputed (nn_itke/=0)
868     !!----------------------------------------------------------------------
869     INTEGER         , INTENT(in) ::   kt         ! ocean time-step
870     CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
871     !
872     INTEGER ::   jit   ! dummy loop indices
873     !!----------------------------------------------------------------------
874     !
875     IF( TRIM(cdrw) == 'READ' ) THEN
876        IF( ln_rstart ) THEN
877           IF( iom_varid( numror, 'en', ldstop = .FALSE. ) > 0 .AND. .NOT.(ln_rstke) ) THEN
878              CALL iom_get( numror, jpdom_autoglo, 'en', en )
879           ELSE
880              IF( lwp .AND. iom_varid( numror, 'en', ldstop = .FALSE. ) > 0 )   &
881                 &                       WRITE(numout,*) ' ===>>>> : previous run without tke scheme'
882              IF( lwp .AND. ln_rstke )   WRITE(numout,*) ' ===>>>> : We do not use en from the restart file'
883              IF( lwp                )   WRITE(numout,*) ' ===>>>> : en is set by iterative loop'
884              en (:,:,:) = rn_emin * tmask(:,:,:)
885              DO jit = 2, nn_itke + 1
886                 CALL zdf_tke_old( jit )
887              END DO
888           ENDIF
889        ELSE
890           en(:,:,:) = rn_emin * tmask(:,:,:)      ! no restart: en set to its minimum value
891        ENDIF
892     ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
893        CALL iom_rstput( kt, nitrst, numrow, 'en', en )
894     ENDIF
895     !
896   END SUBROUTINE tke_rst
897
898#else
899   !!----------------------------------------------------------------------
900   !!   Dummy module :                                        NO TKE scheme
901   !!----------------------------------------------------------------------
902   LOGICAL, PUBLIC, PARAMETER ::   lk_zdftke_old = .FALSE.   !: TKE flag
903CONTAINS
904   SUBROUTINE zdf_tke_old( kt )          ! Empty routine
905      WRITE(*,*) 'zdf_tke_old: You should not have seen this print! error?', kt
906   END SUBROUTINE zdf_tke_old
907#endif
908
909   !!======================================================================
910END MODULE zdftke_old
Note: See TracBrowser for help on using the repository browser.