New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcldf_iso_zps.F90 in tags/nemo_v3_2/nemo_v3_2/NEMO/TOP_SRC/TRP – NEMO

source: tags/nemo_v3_2/nemo_v3_2/NEMO/TOP_SRC/TRP/trcldf_iso_zps.F90 @ 1878

Last change on this file since 1878 was 1878, checked in by flavoni, 14 years ago

initial test for nemogcm

File size: 16.9 KB
Line 
1MODULE trcldf_iso_zps
2   !!======================================================================
3   !!                   ***  MODULE  trcldf_iso_zps  ***
4   !! Ocean passive tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :       !  94-08  (G. Madec, M. Imbard)
7   !!                 !  97-05  (G. Madec)  split into traldf and trazdf
8   !!            8.5  !  02-08  (G. Madec)  Free form, F90
9   !!            9.0  !  04-03  (C. Ethe)  adapted for passive tracers
10   !!                 !  07-02  (C. Deltel)  Diagnose ML trends for passive tracers
11   !!----------------------------------------------------------------------
12#if key_top &&  defined key_ldfslp 
13   !!----------------------------------------------------------------------
14   !!   'key_ldfslp'               slope of the lateral diffusive direction
15   !!----------------------------------------------------------------------
16   !!   trc_ldf_iso_zps : update the tracer trend with the horizontal
17   !!                     component of a iso-neutral laplacian operator
18   !!----------------------------------------------------------------------
19   USE oce_trc             ! ocean dynamics and active tracers variables
20   USE trp_trc                 ! ocean passive tracers variables
21   USE prtctl_trc          ! Print control for debbuging
22   USE trdmld_trc
23   USE trdmld_trc_oce     
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC trc_ldf_iso_zps  ! routine called by step.F90
29
30   !! * Substitutions
31#  include "top_substitute.h90"
32   !!----------------------------------------------------------------------
33   !!   TOP 1.0 , LOCEAN-IPSL (2005)
34   !! $Header: /home/opalod/NEMOCVSROOT/NEMO/TOP_SRC/TRP/trcldf_iso_zps.F90,v 1.10 2006/09/12 11:10:14 opalod Exp $
35   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
36   !!----------------------------------------------------------------------
37
38CONTAINS
39
40   SUBROUTINE trc_ldf_iso_zps( kt )
41      !!----------------------------------------------------------------------
42      !!                  ***  ROUTINE trc_ldf_iso_zps  ***
43      !!
44      !! ** Purpose :   Compute the before horizontal tracer  diffusive
45      !!      trend and add it to the general trend of tracer equation.
46      !!
47      !! ** Method  :   The horizontal component of the lateral diffusive trends
48      !!      is provided by a 2nd order operator rotated along neural or geopo-
49      !!      tential surfaces to which an eddy induced advection can be added
50      !!      It is computed using before fields (forward in time) and isopyc-
51      !!      nal or geopotential slopes computed in routine ldfslp.
52      !!
53      !!      horizontal fluxes associated with the rotated lateral mixing:
54      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
55      !!               - aht       e2u*uslp    dk[ mi(mk(trb)) ]
56      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
57      !!               - aht       e2u*vslp    dk[ mj(mk(trb)) ]
58      !!      add horizontal Eddy Induced advective fluxes (lk_traldf_eiv=T):
59      !!         zftu = zftu - dk-1[ aht e2u mi(wslpi) ] mi( trb )
60      !!         zftv = zftv - dk-1[ aht e1v mj(wslpj) ] mj( trb )
61      !!      take the horizontal divergence of the fluxes:
62      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
63      !!      Add this trend to the general trend tra :
64      !!         tra = tra + difft
65      !!
66      !!      'key_trdtra' defined: the trend is saved for diagnostics.
67      !!
68      !!      macro-tasked on horizontal slab (jk-loop).
69      !!
70      !! ** Action :
71      !!         Update tra arrays with the before along level biharmonic
72      !!      mixing trend.
73      !!         Save the trends if 'key_trdmld_trc' defined
74      !!----------------------------------------------------------------------
75      USE oce_trc       , zftu => ua,  &  ! use ua as workspace
76         &                zftv => va      ! use va as workspace
77      !!
78      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
79      INTEGER ::   ji, jj, jk,jn          ! dummy loop indices
80      INTEGER ::   iku, ikv               ! temporary integer
81      REAL(wp) ::   &
82         zabe1, zabe2, zcof1, zcof2,   &  ! temporary scalars
83         zmsku, zmskv, zbtr, ztra
84
85      REAL(wp), DIMENSION(jpi,jpj) ::   &
86         zdkt , zdk1t                     ! temporary workspace
87
88      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   & 
89         zgtbu, zgtbv               ! temporary workspace
90
91#if defined key_trcldf_eiv
92      REAL(wp), DIMENSION(jpi,jpj) ::   &
93         zftug, zftvg                     ! temporary workspace
94      REAL(wp) ::   &
95         z_hdivn_x, z_hdivn_y, zcg1, zcg2,  &
96         zuwk, zvwk, zuwk1, zvwk1
97#endif
98      CHARACTER (len=22) :: charout
99      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrtrd
100      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrtrd_xei
101      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrtrd_yei
102      !!----------------------------------------------------------------------
103
104      IF( kt == nittrc000 ) THEN
105         IF(lwp) WRITE(numout,*)
106         IF(lwp) WRITE(numout,*) 'trc_ldf_iso_zps : iso neutral laplacian diffusion in '
107         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~   z-coordinates with partial steps'
108#if defined key_trcldf_eiv && defined key_diaeiv
109         u_trc_eiv(:,:,:) = 0.e0
110         v_trc_eiv(:,:,:) = 0.e0
111#endif
112      ENDIF
113
114      IF( l_trdtrc ) THEN
115         ALLOCATE( ztrtrd(jpi,jpj,jpk) )
116#   if defined key_trcldf_eiv
117         ALLOCATE( ztrtrd_xei(jpi,jpj,jpk) )
118         ALLOCATE( ztrtrd_yei(jpi,jpj,jpk) )
119#   endif
120      ENDIF
121
122      !                                                          ! ===========
123      DO jn = 1, jptra                                           ! tracer loop
124         !                                                       ! ===========
125         IF( l_trdtrc ) ztrtrd(:,:,:) = tra(:,:,:,jn)   ! save trends
126     
127         zgtbu(:,:,:) = 0.     ;     zgtbv(:,:,:) = 0.
128         ! Horizontal passive tracer gradient
129         DO jk = 1, jpk
130            DO jj = 1, jpj-1
131               DO ji = 1, fs_jpim1   ! vector opt.
132                  zgtbu(ji,jj,jk) = tmask(ji,jj,jk) * ( trb(ji+1,jj  ,jk,jn) - trb(ji,jj,jk,jn) )
133                  zgtbv(ji,jj,jk) = tmask(ji,jj,jk) * ( trb(ji  ,jj+1,jk,jn) - trb(ji,jj,jk,jn) )
134               END DO
135            END DO
136         END DO
137         ! partial steps correction at the last level
138         DO jj = 1, jpj-1
139            DO ji = 1, jpi-1
140               ! last level
141               iku = MIN( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1
142               ikv = MIN( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1
143               zgtbu(ji,jj,iku) = gtru(ji,jj,jn)               
144               zgtbv(ji,jj,ikv) = gtrv(ji,jj,jn)               
145            END DO
146         END DO
147
148         !                                                ! ===============
149         DO jk = 1, jpkm1                                 ! Horizontal slab
150            !                                             ! ===============
151            ! 1. Vertical tracer gradient at level jk and jk+1
152            ! ------------------------------------------------
153            ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
154
155            zdk1t(:,:) = ( trb(:,:,jk,jn) - trb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
156
157            IF( jk == 1 ) THEN
158               zdkt(:,:) = zdk1t(:,:)
159            ELSE
160               zdkt(:,:) = ( trb(:,:,jk-1,jn) - trb(:,:,jk,jn) ) * tmask(:,:,jk)
161            ENDIF
162
163            ! 2. Horizontal fluxes
164            ! --------------------
165
166            DO jj = 1 , jpjm1
167               DO ji = 1, fs_jpim1   ! vector opt.
168                  zabe1 = ( fsahtru(ji,jj,jk) + ahtrb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
169                  zabe2 = ( fsahtrv(ji,jj,jk) + ahtrb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
170
171                  zmsku = 1. / MAX(  tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
172                       &           + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
173
174                  zmskv = 1. / MAX(  tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
175                       &           + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
176
177                  zcof1 = -fsahtru(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
178                  zcof2 = -fsahtrv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
179
180                  zftu(ji,jj,jk) = umask(ji,jj,jk) * (  zabe1 * zgtbu(ji,jj,jk)   &
181                       &                              + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
182                       &                                         + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  )
183                  zftv(ji,jj,jk) = vmask(ji,jj,jk) * (  zabe2 * zgtbv(ji,jj,jk)   &
184                       &                              + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
185                       &                                         + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  )
186               END DO
187            END DO
188
189# if defined key_trcldf_eiv
190
191            ! ... Eddy induced horizontal advective fluxes
192            DO jj = 1, jpjm1
193               DO ji = 1, fs_jpim1   ! vector opt.
194                  zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj  ,jk  ) ) * fsaeitru(ji,jj,jk  ) * umask(ji,jj,jk  )
195                  zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj  ,jk+1) ) * fsaeitru(ji,jj,jk+1) * umask(ji,jj,jk+1)
196                  zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji  ,jj+1,jk  ) ) * fsaeitrv(ji,jj,jk  ) * vmask(ji,jj,jk  )
197                  zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji  ,jj+1,jk+1) ) * fsaeitrv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
198
199                  zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 )
200                  zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 )
201
202                  zftug(ji,jj) = zcg1 * ( trb(ji+1,jj,jk,jn) + trb(ji,jj,jk,jn) )
203                  zftvg(ji,jj) = zcg2 * ( trb(ji,jj+1,jk,jn) + trb(ji,jj,jk,jn) )
204
205                  zftu(ji,jj,jk) = zftu(ji,jj,jk) + zftug(ji,jj)
206                  zftv(ji,jj,jk) = zftv(ji,jj,jk) + zftvg(ji,jj)
207
208#   if defined key_diaeiv
209                  u_trc_eiv(ji,jj,jk) = -2. * zcg1 / ( e2u(ji,jj) * fse3u(ji,jj,jk) )
210                  v_trc_eiv(ji,jj,jk) = -2. * zcg2 / ( e1v(ji,jj) * fse3v(ji,jj,jk) )
211#   endif
212               END DO
213            END DO
214# endif
215
216            ! 3. Second derivative (divergence) and add to the general trend
217            ! --------------------------------------------------------------
218
219            DO jj = 2 , jpjm1
220               DO ji = fs_2, fs_jpim1   ! vector opt.
221                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
222                  ztra = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
223                  tra(ji,jj,jk,jn) = tra (ji,jj,jk,jn) + ztra
224               END DO
225            END DO
226
227#if defined key_trc_diatrd
228            DO jj = 2 , jpjm1
229               DO ji = fs_2, fs_jpim1   ! vector opt.
230                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
231                  IF( luttrd(jn) ) THEN
232                     trtrd (ji,jj,jk,ikeep(jn),4) = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,  jj,jk) )
233                     trtrd (ji,jj,jk,ikeep(jn),5) = zbtr * ( zftv(ji,jj,jk) - zftv(ji  ,jj-1,jk) )
234                  ENDIF
235#   if defined key_trcldf_eiv
236                  IF( luttrd(jn) ) THEN
237                     trtrd (ji,jj,jk,ikeep(jn),4) = trtrd(ji,jj,jk,ikeep(jn),4)    &
238                     &                            - zbtr * ( zftug(ji,jj) - zftug(ji-1,jj  ) ) 
239                     trtrd (ji,jj,jk,ikeep(jn),5) = trtrd(ji,jj,jk,ikeep(jn),5)    &
240                     &                            - zbtr * ( zftvg(ji,jj) - zftvg(ji  ,jj-1) )
241                  ENDIF
242#   endif
243               END DO
244            END DO
245#endif
246
247            !                                          ! ===============
248         END DO                                        !   End of slab 
249         !                                             ! ===============
250
251         ! 4. Save the horizontal diffusive and advective (eiv) trends for diagnostics
252         ! ---------------------------------------------------------------------------
253         IF( l_trdtrc ) THEN
254
255            ! 4.1) Compute the eiv ZONAL & MERIDIONAL advective trends
256
257#   if defined key_trcldf_eiv
258            !                                                ! ===============
259            DO jk = 1, jpkm1                                 ! Horizontal slab
260               !                                             ! ===============
261
262               DO jj = 1, jpjm1
263                  DO ji = 1, fs_jpim1   ! vector opt.
264                     zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj  ,jk  ) ) * fsaeitru(ji,jj,jk  ) * umask(ji,jj,jk  )
265                     zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj  ,jk+1) ) * fsaeitru(ji,jj,jk+1) * umask(ji,jj,jk+1)
266                     zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji  ,jj+1,jk  ) ) * fsaeitrv(ji,jj,jk  ) * vmask(ji,jj,jk  )
267                     zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji  ,jj+1,jk+1) ) * fsaeitrv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
268                     
269                     zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 )
270                     zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 )
271                     
272                     zftug(ji,jj) = zcg1 * ( trb(ji+1,jj,jk,jn) + trb(ji,jj,jk,jn) )
273                     zftvg(ji,jj) = zcg2 * ( trb(ji,jj+1,jk,jn) + trb(ji,jj,jk,jn) )
274                  END DO
275               END DO
276
277               DO jj = 2 , jpjm1
278                  DO ji = fs_2, fs_jpim1   ! vector opt.
279                 
280                     zbtr = 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
281
282                     !-- Compute zonal & meridional divergences of the eiv field :
283                     !     d_x[u_trc_eiv] = 1/(e1t*e2t*e3t) ( di[e2u*e3u u_trc_eiv] )
284                     !     d_y[v_trc_eiv] = 1/(e1t*e2t*e3t) ( dj[e1v*e3v v_trc_eiv] )
285                     !   N.B.  This is only possible if key_diaeiv is switched on.
286#       if defined key_diaeiv
287                     z_hdivn_x = (  e2u(ji  ,jj) * fse3u(ji  ,jj,jk) * u_trc_eiv(ji  ,jj  ,jk)  &
288                          &       - e2u(ji-1,jj) * fse3u(ji-1,jj,jk) * u_trc_eiv(ji-1,jj  ,jk) ) * zbtr
289                     z_hdivn_y = (  e1v(ji,  jj) * fse3v(ji,jj  ,jk) * v_trc_eiv(ji,  jj  ,jk)  &
290                          &       - e1v(ji,jj-1) * fse3v(ji,jj-1,jk) * v_trc_eiv(ji  ,jj-1,jk) ) * zbtr
291#       else
292                     z_hdivn_x = 0.e0   ;   z_hdivn_y = 0.e0 
293#       endif
294                     !-- Compute the zonal advective trends associated with eiv
295                     ztrtrd_xei(ji,jj,jk) = zbtr * ( zftug(ji,jj) - zftug(ji-1,jj  ) )          &
296                          &                 - trn(ji,jj,jk,jn) * z_hdivn_x
297                     
298                     !-- Compute the merid. advective trends associated with eiv
299                     ztrtrd_yei(ji,jj,jk) = zbtr * ( zftvg(ji,jj) - zftvg(ji  ,jj-1) )          &
300                          &                 - trn(ji,jj,jk,jn) * z_hdivn_y
301
302                  END DO
303               END DO
304               !                                             ! ===============
305            END DO                                           !   End of slab 
306            !                                                ! ===============
307#   else
308            ztrtrd_xei(:,:,:) = 0.e0
309            ztrtrd_yei(:,:,:) = 0.e0
310#   endif
311            ! 4.2) Substract the eddy induced velocity
312            ztrtrd(:,:,:) = tra(:,:,:,jn) - ztrtrd(:,:,:) - ztrtrd_xei(:,:,:) - ztrtrd_yei(:,:,:)
313
314            IF (luttrd(jn)) CALL trd_mod_trc( ztrtrd    , jn, jptrc_trd_ldf, kt )
315#   if defined key_trcldf_eiv
316            IF (luttrd(jn)) CALL trd_mod_trc( ztrtrd_xei, jn, jptrc_trd_xei, kt )
317            IF (luttrd(jn)) CALL trd_mod_trc( ztrtrd_yei, jn, jptrc_trd_yei, kt )
318#   endif
319
320         ENDIF
321         !                                                       ! ===========
322      END DO                                                     ! tracer loop
323      !                                                          ! ===========
324      IF( l_trdtrc ) THEN
325         DEALLOCATE( ztrtrd )
326#   if defined key_trcldf_eiv
327         DEALLOCATE( ztrtrd_xei )
328         DEALLOCATE( ztrtrd_yei )
329#   endif
330      ENDIF
331
332      IF( ln_ctl ) THEN    ! print mean trends (used for debugging)
333         WRITE(charout, FMT="('ldf - iso/zps')")
334         CALL prt_ctl_trc_info( charout )
335         CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd' )
336      ENDIF
337
338   END SUBROUTINE trc_ldf_iso_zps
339
340#else
341   !!----------------------------------------------------------------------
342   !!   default option :   Dummy code   NO rotation of the diffusive tensor
343   !!----------------------------------------------------------------------
344CONTAINS
345   SUBROUTINE trc_ldf_iso_zps( kt )               ! Empty routine
346      INTEGER, INTENT(in) :: kt
347      WRITE(*,*) 'trc_ldf_iso_zps: You should not have seen this print! error?', kt
348   END SUBROUTINE trc_ldf_iso_zps
349#endif
350
351   !!==============================================================================
352END MODULE trcldf_iso_zps
Note: See TracBrowser for help on using the repository browser.