New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd.F90 in tags/nemo_v3_2_2/NEMO/LIM_SRC_3 – NEMO

source: tags/nemo_v3_2_2/NEMO/LIM_SRC_3/limthd.F90 @ 2778

Last change on this file since 2778 was 2778, checked in by smasson, 13 years ago

LIM3 compiling in v3_2_2, see ticket#817

  • Property svn:keywords set to Id
File size: 43.9 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in rdmsnif
11   !!----------------------------------------------------------------------
12#if defined key_lim3
13   !!----------------------------------------------------------------------
14   !!   'key_lim3'                                      LIM3 sea-ice model
15   !!----------------------------------------------------------------------
16   !!   lim_thd      : thermodynamic of sea ice
17   !!----------------------------------------------------------------------
18   USE phycst          ! physical constants
19   USE dom_oce         ! ocean space and time domain variables
20   USE ice             ! LIM sea-ice variables
21   USE par_ice
22   USE sbc_oce         ! Surface boundary condition: ocean fields
23   USE sbc_ice         ! Surface boundary condition: ice fields
24   USE thd_ice         ! LIM thermodynamic sea-ice variables
25   USE dom_ice         ! LIM sea-ice domain
26   USE domvvl
27   USE limthd_dif
28   USE limthd_dh
29   USE limthd_sal
30   USE limthd_ent
31   USE limtab
32   USE limvar
33   USE in_out_manager  ! I/O manager
34   USE prtctl          ! Print control
35   USE lbclnk
36   USE lib_mpp
37
38   IMPLICIT NONE
39   PRIVATE
40
41   PUBLIC   lim_thd        ! called by lim_step
42   PUBLIC   lim_thd_init   ! called by iceini
43
44   REAL(wp) ::   epsi20 = 1e-20   ! constant values
45   REAL(wp) ::   epsi16 = 1e-16   !
46   REAL(wp) ::   epsi06 = 1e-06   !
47   REAL(wp) ::   epsi04 = 1e-04   !
48   REAL(wp) ::   zzero  = 0.e0    !
49   REAL(wp) ::   zone   = 1.e0    !
50
51   !! * Substitutions
52#  include "domzgr_substitute.h90"
53#  include "vectopt_loop_substitute.h90"
54   !!----------------------------------------------------------------------
55   !! NEMO/LIM  3.2 ,  UCL-LOCEAN-IPSL (2009)
56   !! $Id$
57   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
58   !!----------------------------------------------------------------------
59
60CONTAINS
61
62   SUBROUTINE lim_thd( kt )
63      !!-------------------------------------------------------------------
64      !!                ***  ROUTINE lim_thd  ***       
65      !! 
66      !! ** Purpose : This routine manages the ice thermodynamic.
67      !!         
68      !! ** Action : - Initialisation of some variables
69      !!             - Some preliminary computation (oceanic heat flux
70      !!               at the ice base, snow acc.,heat budget of the leads)
71      !!             - selection of the icy points and put them in an array
72      !!             - call lim_vert_ther for vert ice thermodynamic
73      !!             - back to the geographic grid
74      !!             - selection of points for lateral accretion
75      !!             - call lim_lat_acc  for the ice accretion
76      !!             - back to the geographic grid
77      !!     
78      !! ** References : H. Goosse et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90
79      !!---------------------------------------------------------------------
80      INTEGER, INTENT(in) ::   kt    ! number of iteration
81      !!
82      INTEGER  ::   ji, jj, jk, jl   ! dummy loop indices
83      INTEGER  ::   nbpb             ! nb of icy pts for thermo. cal.
84      REAL(wp) ::   zfric_umin = 5e-03    ! lower bound for the friction velocity
85      REAL(wp) ::   zfric_umax = 2e-02    ! upper bound for the friction velocity
86      REAL(wp) ::   zinda, zindb, zthsnice, zfric_u    ! temporary scalar
87      REAL(wp) ::   zfntlat, zpareff                   !    -         -
88      REAL(wp) ::   zeps, zareamin, zcoef
89      REAL(wp), DIMENSION(jpi,jpj) ::   zqlbsbq   ! link with lead energy budget qldif
90      !!-------------------------------------------------------------------
91
92     
93      !------------------------------------------------------------------------------!
94      ! 1) Initialization of diagnostic variables                                    !
95      !------------------------------------------------------------------------------!
96      zeps = 1.e-10
97
98      !--------------------
99      ! 1.2) Heat content   
100      !--------------------
101      ! Change the units of heat content; from global units to J.m3
102
103      DO jl = 1, jpl
104         DO jk = 1, nlay_i
105            DO jj = 1, jpj
106               DO ji = 1, jpi
107                  !Energy of melting q(S,T) [J.m-3]
108                  e_i(ji,jj,jk,jl) = e_i(ji,jj,jk,jl) / ( area(ji,jj) * MAX( v_i(ji,jj,jl) , epsi06 ) ) * nlay_i
109                  !0 if no ice and 1 if yes
110                  zindb = 1.0 - MAX ( 0.0 , SIGN ( 1.0 , - ht_i(ji,jj,jl) ) ) 
111                  !convert units ! very important that this line is here
112                  e_i(ji,jj,jk,jl) = e_i(ji,jj,jk,jl) * unit_fac * zindb 
113               END DO
114            END DO
115         END DO
116         DO jk = 1, nlay_s
117            DO jj = 1, jpj
118               DO ji = 1, jpi
119                  !Energy of melting q(S,T) [J.m-3]
120                  e_s(ji,jj,jk,jl) = e_s(ji,jj,jk,jl) / ( area(ji,jj) * MAX( v_s(ji,jj,jl) , epsi06 ) ) * nlay_s
121                  !0 if no ice and 1 if yes
122                  zindb = 1.0 - MAX ( 0.0 , SIGN ( 1.0 , - ht_s(ji,jj,jl) ) ) 
123                  !convert units ! very important that this line is here
124                  e_s(ji,jj,jk,jl) = e_s(ji,jj,jk,jl) * unit_fac * zindb 
125               END DO
126            END DO
127         END DO
128      END DO
129
130      !-----------------------------
131      ! 1.3) Set some dummies to 0
132      !-----------------------------
133      rdvosif(:,:) = 0.e0   ! variation of ice volume at surface
134      rdvobif(:,:) = 0.e0   ! variation of ice volume at bottom
135      fdvolif(:,:) = 0.e0   ! total variation of ice volume
136      rdvonif(:,:) = 0.e0   ! lateral variation of ice volume
137      fstric (:,:) = 0.e0   ! part of solar radiation transmitted through the ice
138      ffltbif(:,:) = 0.e0   ! linked with fstric
139      qfvbq  (:,:) = 0.e0   ! linked with fstric
140      rdmsnif(:,:) = 0.e0   ! variation of snow mass per unit area
141      rdmicif(:,:) = 0.e0   ! variation of ice mass per unit area
142      hicifp (:,:) = 0.e0   ! daily thermodynamic ice production.
143      fsbri  (:,:) = 0.e0   ! brine flux contribution to salt flux to the ocean
144      fhbri  (:,:) = 0.e0   ! brine flux contribution to heat flux to the ocean
145      fseqv  (:,:) = 0.e0   ! equivalent salt flux to the ocean due to ice/growth decay
146
147      !-----------------------------------
148      ! 1.4) Compute global heat content
149      !-----------------------------------
150      qt_i_in  (:,:) = 0.e0
151      qt_s_in  (:,:) = 0.e0
152      qt_i_fin (:,:) = 0.e0
153      qt_s_fin (:,:) = 0.e0
154      sum_fluxq(:,:) = 0.e0
155      fatm     (:,:) = 0.e0
156
157      ! 2) Partial computation of forcing for the thermodynamic sea ice model.      !
158      !-----------------------------------------------------------------------------!
159
160!CDIR NOVERRCHK
161      DO jj = 1, jpj
162!CDIR NOVERRCHK
163         DO ji = 1, jpi
164            zthsnice       = SUM( ht_s(ji,jj,1:jpl) ) + SUM( ht_i(ji,jj,1:jpl) )
165            zindb          = tms(ji,jj) * ( 1.0 - MAX( zzero , SIGN( zone , - zthsnice ) ) ) 
166            phicif(ji,jj)  = vt_i(ji,jj)
167            pfrld(ji,jj)   = 1.0 - at_i(ji,jj)
168            zinda          = 1.0 - MAX( zzero , SIGN( zone , - ( 1.0 - pfrld(ji,jj) ) ) )
169
170            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
171            !           !  practically no "direct lateral ablation"
172            !           
173            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
174            !           !  temperature and turbulent mixing (McPhee, 1992)
175            ! friction velocity
176            zfric_u        = MAX ( MIN( SQRT( ust2s(ji,jj) ) , zfric_umax ) , zfric_umin ) 
177
178            ! here the drag will depend on ice thickness and type (0.006)
179            fdtcn(ji,jj)  = zindb * rau0 * rcp * 0.006  * zfric_u * ( (sst_m(ji,jj) + rt0) - t_bo(ji,jj) ) 
180            ! also category dependent
181            !           !-- Energy from the turbulent oceanic heat flux heat flux coming in the lead
182            qdtcn(ji,jj)  = zindb * fdtcn(ji,jj) * (1.0 - at_i(ji,jj)) * rdt_ice
183            !                       
184
185            ! still need to be updated : fdtcn !!!!
186            !           !-- Lead heat budget (part 1, next one is in limthd_dh
187            !           !-- qldif -- (or qldif_1d in 1d routines)
188            qldif(ji,jj) =  tms(ji,jj) * rdt_ice  * (                             & 
189               &   pfrld(ji,jj)        * (  qsr(ji,jj)                            &   ! solar heat
190               &                            + qns(ji,jj)                          &   ! non solar heat
191               &                            + fdtcn(ji,jj)                        &   ! turbulent ice-ocean heat
192               &                            + fsbbq(ji,jj) * ( 1.0 - zindb )  )   &   ! residual heat from previous step
193               & - pfrld(ji,jj)**betas * sprecip(ji,jj) * lfus                    )   ! latent heat of sprecip melting
194           
195            ! Positive heat budget is used for bottom ablation
196            zfntlat        = 1.0 - MAX( zzero , SIGN( zone ,  - qldif(ji,jj) ) )
197            != 1 if positive heat budget
198            zpareff        = 1.0 - zinda * zfntlat
199            != 0 if ice and positive heat budget and 1 if one of those two is false
200            zqlbsbq(ji,jj) = qldif(ji,jj) * ( 1.0 - zpareff ) / MAX( at_i(ji,jj) * rdt_ice , epsi16 )
201
202            ! Heat budget of the lead, energy transferred from ice to ocean
203            qldif  (ji,jj) = zpareff * qldif(ji,jj)
204            qdtcn  (ji,jj) = zpareff * qdtcn(ji,jj)
205
206            ! Energy needed to bring ocean surface layer until its freezing (qcmif, limflx)
207            qcmif  (ji,jj) =  rau0 * rcp * fse3t(ji,jj,1) * ( t_bo(ji,jj) - (sst_m(ji,jj) + rt0) ) * ( 1. - zinda )
208
209            ! oceanic heat flux (limthd_dh)
210            fbif   (ji,jj) = zindb * (  fsbbq(ji,jj) / MAX( at_i(ji,jj) , epsi20 ) + fdtcn(ji,jj) )
211            !
212         END DO
213      END DO
214
215      !------------------------------------------------------------------------------!
216      ! 3) Select icy points and fulfill arrays for the vectorial grid.           
217      !------------------------------------------------------------------------------!
218
219      DO jl = 1, jpl      !loop over ice categories
220
221         IF( kt == nit000 .AND. lwp ) THEN
222            WRITE(numout,*) ' lim_thd : transfer to 1D vectors. Category no : ', jl 
223            WRITE(numout,*) ' ~~~~~~~~'
224         ENDIF
225
226         zareamin = 1.0e-10
227         nbpb = 0
228         DO jj = 1, jpj
229            DO ji = 1, jpi
230               IF ( a_i(ji,jj,jl) .gt. zareamin ) THEN     
231                  nbpb      = nbpb  + 1
232                  npb(nbpb) = (jj - 1) * jpi + ji
233               ENDIF
234               ! debug point to follow
235               IF ( (ji.eq.jiindx).AND.(jj.eq.jjindx) ) THEN
236                  jiindex_1d = nbpb
237               ENDIF
238            END DO
239         END DO
240
241         !------------------------------------------------------------------------------!
242         ! 4) Thermodynamic computation
243         !------------------------------------------------------------------------------!
244
245         IF( lk_mpp )   CALL mpp_ini_ice( nbpb )
246
247         IF( nbpb > 0 ) THEN  ! If there is no ice, do nothing.
248
249            !-------------------------
250            ! 4.1 Move to 1D arrays
251            !-------------------------
252
253            CALL tab_2d_1d( nbpb, at_i_b     (1:nbpb), at_i            , jpi, jpj, npb(1:nbpb) )
254            CALL tab_2d_1d( nbpb, a_i_b      (1:nbpb), a_i(:,:,jl)     , jpi, jpj, npb(1:nbpb) )
255            CALL tab_2d_1d( nbpb, ht_i_b     (1:nbpb), ht_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
256            CALL tab_2d_1d( nbpb, ht_s_b     (1:nbpb), ht_s(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
257
258            CALL tab_2d_1d( nbpb, t_su_b     (1:nbpb), t_su(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
259            CALL tab_2d_1d( nbpb, sm_i_b     (1:nbpb), sm_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
260            DO jk = 1, nlay_s
261               CALL tab_2d_1d( nbpb, t_s_b(1:nbpb,jk), t_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
262               CALL tab_2d_1d( nbpb, q_s_b(1:nbpb,jk), e_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
263            END DO
264            DO jk = 1, nlay_i
265               CALL tab_2d_1d( nbpb, t_i_b(1:nbpb,jk), t_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
266               CALL tab_2d_1d( nbpb, q_i_b(1:nbpb,jk), e_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
267               CALL tab_2d_1d( nbpb, s_i_b(1:nbpb,jk), s_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
268            END DO
269
270            CALL tab_2d_1d( nbpb, tatm_ice_1d(1:nbpb), tatm_ice(:,:)   , jpi, jpj, npb(1:nbpb) )
271            CALL tab_2d_1d( nbpb, qsr_ice_1d (1:nbpb), qsr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
272            CALL tab_2d_1d( nbpb, fr1_i0_1d  (1:nbpb), fr1_i0          , jpi, jpj, npb(1:nbpb) )
273            CALL tab_2d_1d( nbpb, fr2_i0_1d  (1:nbpb), fr2_i0          , jpi, jpj, npb(1:nbpb) )
274            CALL tab_2d_1d( nbpb, qnsr_ice_1d(1:nbpb), qns_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
275
276#if ! defined key_coupled
277            CALL tab_2d_1d( nbpb, qla_ice_1d (1:nbpb), qla_ice(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
278            CALL tab_2d_1d( nbpb, dqla_ice_1d(1:nbpb), dqla_ice(:,:,jl)   , jpi, jpj, npb(1:nbpb) )
279#endif
280
281            CALL tab_2d_1d( nbpb, dqns_ice_1d(1:nbpb), dqns_ice(:,:,jl)   , jpi, jpj, npb(1:nbpb) )
282            CALL tab_2d_1d( nbpb, t_bo_b     (1:nbpb), t_bo       , jpi, jpj, npb(1:nbpb) )
283            CALL tab_2d_1d( nbpb, sprecip_1d (1:nbpb), sprecip    , jpi, jpj, npb(1:nbpb) ) 
284            CALL tab_2d_1d( nbpb, fbif_1d    (1:nbpb), fbif       , jpi, jpj, npb(1:nbpb) )
285            CALL tab_2d_1d( nbpb, qldif_1d   (1:nbpb), qldif      , jpi, jpj, npb(1:nbpb) )
286            CALL tab_2d_1d( nbpb, rdmicif_1d (1:nbpb), rdmicif    , jpi, jpj, npb(1:nbpb) )
287            CALL tab_2d_1d( nbpb, rdmsnif_1d (1:nbpb), rdmsnif    , jpi, jpj, npb(1:nbpb) )
288            CALL tab_2d_1d( nbpb, dmgwi_1d   (1:nbpb), dmgwi      , jpi, jpj, npb(1:nbpb) )
289            CALL tab_2d_1d( nbpb, qlbbq_1d   (1:nbpb), zqlbsbq    , jpi, jpj, npb(1:nbpb) )
290
291            CALL tab_2d_1d( nbpb, fseqv_1d   (1:nbpb), fseqv      , jpi, jpj, npb(1:nbpb) )
292            CALL tab_2d_1d( nbpb, fsbri_1d   (1:nbpb), fsbri      , jpi, jpj, npb(1:nbpb) )
293            CALL tab_2d_1d( nbpb, fhbri_1d   (1:nbpb), fhbri      , jpi, jpj, npb(1:nbpb) )
294            CALL tab_2d_1d( nbpb, fstbif_1d  (1:nbpb), fstric     , jpi, jpj, npb(1:nbpb) )
295            CALL tab_2d_1d( nbpb, qfvbq_1d   (1:nbpb), qfvbq      , jpi, jpj, npb(1:nbpb) )
296
297            !--------------------------------
298            ! 4.3) Thermodynamic processes
299            !--------------------------------
300
301            IF( con_i )   CALL lim_thd_enmelt( 1, nbpb )   ! computes sea ice energy of melting
302            IF( con_i )   CALL lim_thd_glohec( qt_i_in, qt_s_in, q_i_layer_in, 1, nbpb, jl )
303
304            !                                 !---------------------------------!
305            CALL lim_thd_dif( 1, nbpb, jl )   ! Ice/Snow Temperature profile    !
306            !                                 !---------------------------------!
307
308            CALL lim_thd_enmelt( 1, nbpb )    ! computes sea ice energy of melting compulsory for limthd_dh
309
310            IF( con_i )   CALL lim_thd_glohec ( qt_i_fin, qt_s_fin, q_i_layer_fin, 1, nbpb, jl ) 
311            IF( con_i )   CALL lim_thd_con_dif( 1 , nbpb , jl )
312
313            !                                 !---------------------------------!
314            CALL lim_thd_dh( 1, nbpb, jl )    ! Ice/Snow thickness              !
315            !                                 !---------------------------------!
316
317            !                                 !---------------------------------!
318            CALL lim_thd_ent( 1, nbpb, jl )   ! Ice/Snow enthalpy remapping     !
319            !                                 !---------------------------------!
320
321            !                                 !---------------------------------!
322            CALL lim_thd_sal( 1, nbpb )       ! Ice salinity computation        !
323            !                                 !---------------------------------!
324
325            !           CALL lim_thd_enmelt(1,nbpb)   ! computes sea ice energy of melting
326            IF( con_i )   CALL lim_thd_glohec( qt_i_fin, qt_s_fin, q_i_layer_fin, 1, nbpb, jl ) 
327            IF( con_i )   CALL lim_thd_con_dh ( 1 , nbpb , jl )
328
329            !--------------------------------
330            ! 4.4) Move 1D to 2D vectors
331            !--------------------------------
332
333            CALL tab_1d_2d( nbpb, at_i        , npb, at_i_b(1:nbpb), jpi, jpj )
334            CALL tab_1d_2d( nbpb, ht_i(:,:,jl), npb, ht_i_b(1:nbpb), jpi, jpj )
335            CALL tab_1d_2d( nbpb, ht_s(:,:,jl), npb, ht_s_b(1:nbpb), jpi, jpj )
336            CALL tab_1d_2d( nbpb, a_i (:,:,jl), npb, a_i_b(1:nbpb) , jpi, jpj )
337            CALL tab_1d_2d( nbpb, t_su(:,:,jl), npb, t_su_b(1:nbpb), jpi, jpj )
338            CALL tab_1d_2d( nbpb, sm_i(:,:,jl), npb, sm_i_b(1:nbpb), jpi, jpj )
339
340            DO jk = 1, nlay_s
341               CALL tab_1d_2d( nbpb, t_s(:,:,jk,jl), npb, t_s_b(1:nbpb,jk), jpi, jpj)
342               CALL tab_1d_2d( nbpb, e_s(:,:,jk,jl), npb, q_s_b(1:nbpb,jk), jpi, jpj)
343            END DO
344
345            DO jk = 1, nlay_i
346               CALL tab_1d_2d( nbpb, t_i(:,:,jk,jl), npb, t_i_b(1:nbpb,jk), jpi, jpj)
347               CALL tab_1d_2d( nbpb, e_i(:,:,jk,jl), npb, q_i_b(1:nbpb,jk), jpi, jpj)
348               CALL tab_1d_2d( nbpb, s_i(:,:,jk,jl), npb, s_i_b(1:nbpb,jk), jpi, jpj)
349            END DO
350
351            CALL tab_1d_2d( nbpb, fstric , npb, fstbif_1d (1:nbpb), jpi, jpj )
352            CALL tab_1d_2d( nbpb, qldif  , npb, qldif_1d  (1:nbpb), jpi, jpj )
353            CALL tab_1d_2d( nbpb, qfvbq  , npb, qfvbq_1d  (1:nbpb), jpi, jpj )
354            CALL tab_1d_2d( nbpb, rdmicif, npb, rdmicif_1d(1:nbpb), jpi, jpj )
355            CALL tab_1d_2d( nbpb, rdmsnif, npb, rdmsnif_1d(1:nbpb), jpi, jpj )
356            CALL tab_1d_2d( nbpb, dmgwi  , npb, dmgwi_1d  (1:nbpb), jpi, jpj )
357            CALL tab_1d_2d( nbpb, rdvosif, npb, dvsbq_1d  (1:nbpb), jpi, jpj )
358            CALL tab_1d_2d( nbpb, rdvobif, npb, dvbbq_1d  (1:nbpb), jpi, jpj )
359            CALL tab_1d_2d( nbpb, fdvolif, npb, dvlbq_1d  (1:nbpb), jpi, jpj )
360            CALL tab_1d_2d( nbpb, rdvonif, npb, dvnbq_1d  (1:nbpb), jpi, jpj ) 
361            CALL tab_1d_2d( nbpb, fseqv  , npb, fseqv_1d  (1:nbpb), jpi, jpj )
362
363            IF( num_sal == 2 ) THEN
364               CALL tab_1d_2d( nbpb, fsbri, npb, fsbri_1d(1:nbpb), jpi, jpj )
365               CALL tab_1d_2d( nbpb, fhbri, npb, fhbri_1d(1:nbpb), jpi, jpj )
366            ENDIF
367
368            !+++++
369            !temporary stuff for a dummy version
370            CALL tab_1d_2d( nbpb, dh_i_surf2D, npb, dh_i_surf(1:nbpb)      , jpi, jpj )
371            CALL tab_1d_2d( nbpb, dh_i_bott2D, npb, dh_i_bott(1:nbpb)      , jpi, jpj )
372            CALL tab_1d_2d( nbpb, fsup2D     , npb, fsup     (1:nbpb)      , jpi, jpj )
373            CALL tab_1d_2d( nbpb, focea2D    , npb, focea    (1:nbpb)      , jpi, jpj )
374            CALL tab_1d_2d( nbpb, s_i_newice , npb, s_i_new  (1:nbpb)      , jpi, jpj )
375            CALL tab_1d_2d( nbpb, izero(:,:,jl) , npb, i0    (1:nbpb)      , jpi, jpj )
376            CALL tab_1d_2d( nbpb, qns_ice(:,:,jl), npb, qnsr_ice_1d(1:nbpb), jpi, jpj)
377            !+++++
378
379            IF( lk_mpp )   CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
380         ENDIF
381         !
382      END DO
383
384      !------------------------------------------------------------------------------!
385      ! 5) Global variables, diagnostics
386      !------------------------------------------------------------------------------!
387
388      !------------------------
389      ! 5.1) Ice heat content             
390      !------------------------
391
392      ! Enthalpies are global variables we have to readjust the units
393      zcoef = 1.e0 / ( unit_fac * REAL(nlay_i) )
394      DO jl = 1, jpl
395         DO jk = 1, nlay_i
396            ! Multiply by volume, divide by nlayers so that heat content in 10^9 Joules
397            e_i(:,:,jk,jl) = e_i(:,:,jk,jl) * area(:,:) * a_i(:,:,jl) * ht_i(:,:,jl) * zcoef
398         END DO
399      END DO
400
401      !------------------------
402      ! 5.2) Snow heat content             
403      !------------------------
404
405      ! Enthalpies are global variables we have to readjust the units
406      zcoef = 1.e0 / ( unit_fac * REAL(nlay_s) )
407      DO jl = 1, jpl
408         DO jk = 1, nlay_s
409            ! Multiply by volume, so that heat content in 10^9 Joules
410            e_s(:,:,jk,jl) = e_s(:,:,jk,jl) * area(:,:) * a_i(:,:,jl) * ht_s(:,:,jl) * zcoef
411         END DO
412      END DO
413
414      !----------------------------------
415      ! 5.3) Change thickness to volume
416      !----------------------------------
417      CALL lim_var_eqv2glo
418
419      !--------------------------------------------
420      ! 5.4) Diagnostic thermodynamic growth rates
421      !--------------------------------------------
422      d_v_i_thd(:,:,:) = v_i      (:,:,:) - old_v_i(:,:,:)    ! ice volumes
423      dv_dt_thd(:,:,:) = d_v_i_thd(:,:,:) / rdt_ice * 86400.0
424
425      IF( con_i )   fbif(:,:) = fbif(:,:) + zqlbsbq(:,:)
426
427      IF(ln_ctl) THEN   ! Control print
428         CALL prt_ctl_info(' ')
429         CALL prt_ctl_info(' - Cell values : ')
430         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
431         CALL prt_ctl(tab2d_1=area , clinfo1=' lim_thd  : cell area :')
432         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_thd  : at_i      :')
433         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_thd  : vt_i      :')
434         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_thd  : vt_s      :')
435         DO jl = 1, jpl
436            CALL prt_ctl_info(' ')
437            CALL prt_ctl_info(' - Category : ', ivar1=jl)
438            CALL prt_ctl_info('   ~~~~~~~~~~')
439            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_thd  : a_i      : ')
440            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_thd  : ht_i     : ')
441            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_thd  : ht_s     : ')
442            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_thd  : v_i      : ')
443            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_thd  : v_s      : ')
444            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_thd  : e_s      : ')
445            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_thd  : t_su     : ')
446            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_thd  : t_snow   : ')
447            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_thd  : sm_i     : ')
448            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_thd  : smv_i    : ')
449            DO jk = 1, nlay_i
450               CALL prt_ctl_info(' ')
451               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
452               CALL prt_ctl_info('   ~~~~~~~')
453               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_thd  : t_i      : ')
454               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_thd  : e_i      : ')
455            END DO
456         END DO
457
458      ENDIF
459
460   END SUBROUTINE lim_thd
461
462
463   SUBROUTINE lim_thd_glohec( eti, ets, etilayer, kideb, kiut, jl )
464      !!-----------------------------------------------------------------------
465      !!                   ***  ROUTINE lim_thd_glohec ***
466      !!                 
467      !! ** Purpose :  Compute total heat content for each category
468      !!               Works with 1d vectors only
469      !!-----------------------------------------------------------------------
470      INTEGER , INTENT(in   )                         ::   kideb, kiut   ! bounds for the spatial loop
471      INTEGER , INTENT(in   )                         ::   jl            ! category number
472      REAL(wp), INTENT(  out), DIMENSION (jpij,jpl  ) ::   eti, ets      ! vertically-summed heat content for ice & snow
473      REAL(wp), INTENT(  out), DIMENSION (jpij,jkmax) ::   etilayer      ! heat content for ice layers
474      !!
475      INTEGER  ::   ji,jk   ! loop indices
476      REAL(wp) ::   zeps    ! very small value (1.e-10)
477      !!-----------------------------------------------------------------------
478      eti(:,:) = 0.e0
479      ets(:,:) = 0.e0
480      zeps     = 1.e-10
481
482      DO jk = 1, nlay_i                ! total q over all layers, ice [J.m-2]
483         DO ji = kideb, kiut
484            etilayer(ji,jk) = q_i_b(ji,jk) * ht_i_b(ji) / nlay_i
485            eti     (ji,jl) = eti(ji,jl) + etilayer(ji,jk) 
486         END DO
487      END DO
488      DO ji = kideb, kiut              ! total q over all layers, snow [J.m-2]
489         ets(ji,jl) = ets(ji,jl) + q_s_b(ji,1) * ht_s_b(ji) / nlay_s
490      END DO
491
492      IF(lwp) WRITE(numout,*) ' lim_thd_glohec '
493      IF(lwp) WRITE(numout,*) ' qt_i_in : ', eti(jiindex_1d,jl) / rdt_ice
494      IF(lwp) WRITE(numout,*) ' qt_s_in : ', ets(jiindex_1d,jl) / rdt_ice
495      IF(lwp) WRITE(numout,*) ' qt_in   : ', ( eti(jiindex_1d,jl) + ets(jiindex_1d,jl) ) / rdt_ice
496      !
497   END SUBROUTINE lim_thd_glohec
498
499
500   SUBROUTINE lim_thd_con_dif( kideb, kiut, jl )
501      !!-----------------------------------------------------------------------
502      !!                   ***  ROUTINE lim_thd_con_dif ***
503      !!                 
504      !! ** Purpose :   Test energy conservation after heat diffusion
505      !!-------------------------------------------------------------------
506      INTEGER , INTENT(in   ) ::   kideb, kiut   ! bounds for the spatial loop
507      INTEGER , INTENT(in   ) ::   jl            ! category number
508
509      INTEGER  ::   ji, jk         ! loop indices
510      INTEGER  ::   zji, zjj
511      INTEGER  ::   numce          ! number of points for which conservation is violated
512      REAL(wp) ::   meance         ! mean conservation error
513      REAL(wp) ::   max_cons_err, max_surf_err
514      !!---------------------------------------------------------------------
515
516      max_cons_err =  1.0          ! maximum tolerated conservation error
517      max_surf_err =  0.001        ! maximum tolerated surface error
518
519      !--------------------------
520      ! Increment of energy
521      !--------------------------
522      ! global
523      DO ji = kideb, kiut
524         dq_i(ji,jl) = qt_i_fin(ji,jl) - qt_i_in(ji,jl) + qt_s_fin(ji,jl) - qt_s_in(ji,jl)
525      END DO
526      ! layer by layer
527      dq_i_layer(:,:)    = q_i_layer_fin(:,:) - q_i_layer_in(:,:)
528
529      !----------------------------------------
530      ! Atmospheric heat flux, ice heat budget
531      !----------------------------------------
532
533      DO ji = kideb, kiut
534         zji = MOD( npb(ji) - 1, jpi ) + 1
535         zjj = ( npb(ji) - 1 ) / jpi + 1
536
537         fatm(ji,jl) = qnsr_ice_1d(ji) + (1.0-i0(ji))*qsr_ice_1d(ji)
538
539         sum_fluxq(ji,jl) = fc_su(ji) - fc_bo_i(ji) + qsr_ice_1d(ji)*i0(ji) - fstroc(zji,zjj,jl)
540      END DO
541
542      !--------------------
543      ! Conservation error
544      !--------------------
545
546      DO ji = kideb, kiut
547         cons_error(ji,jl) = ABS( dq_i(ji,jl) / rdt_ice + sum_fluxq(ji,jl) )
548      END DO
549
550      numce = 0
551      meance = 0.0
552      DO ji = kideb, kiut
553         IF ( cons_error(ji,jl) .GT. max_cons_err ) THEN
554            numce = numce + 1
555            meance = meance + cons_error(ji,jl)
556         ENDIF
557      ENDDO
558      IF (numce .GT. 0 ) meance = meance / numce
559
560      WRITE(numout,*) ' Maximum tolerated conservation error : ', max_cons_err
561      WRITE(numout,*) ' After lim_thd_dif, category : ', jl
562      WRITE(numout,*) ' Mean conservation error on big error points ', meance, numit
563      WRITE(numout,*) ' Number of points where there is a cons err gt than c.e. : ', numce, numit
564
565      !-------------------------------------------------------
566      ! Surface error due to imbalance between Fatm and Fcsu
567      !-------------------------------------------------------
568      numce  = 0.0
569      meance = 0.0
570
571      DO ji = kideb, kiut
572         surf_error(ji,jl) = ABS ( fatm(ji,jl) - fc_su(ji) )
573         IF ( ( t_su_b(ji) .LT. rtt ) .AND. ( surf_error(ji,jl) .GT. &
574            max_surf_err ) ) THEN
575            numce = numce + 1 
576            meance = meance + surf_error(ji,jl)
577         ENDIF
578      ENDDO
579      IF (numce .GT. 0 ) meance = meance / numce
580
581      WRITE(numout,*) ' Maximum tolerated surface error : ', max_surf_err
582      WRITE(numout,*) ' After lim_thd_dif, category : ', jl
583      WRITE(numout,*) ' Mean surface error on big error points ', meance, numit
584      WRITE(numout,*) ' Number of points where there is a surf err gt than surf_err : ', numce, numit
585
586      IF (jiindex_1D.GT.0) WRITE(numout,*) ' fc_su      : ', fc_su(jiindex_1d)
587      IF (jiindex_1D.GT.0) WRITE(numout,*) ' fatm       : ', fatm(jiindex_1d,jl)
588      IF (jiindex_1D.GT.0) WRITE(numout,*) ' t_su       : ', t_su_b(jiindex_1d)
589
590      !---------------------------------------
591      ! Write ice state in case of big errors
592      !---------------------------------------
593
594      DO ji = kideb, kiut
595         IF ( ( ( t_su_b(ji) .LT. rtt ) .AND. ( surf_error(ji,jl) .GT. max_surf_err ) ) .OR. &
596            ( cons_error(ji,jl) .GT. max_cons_err  ) ) THEN
597            zji                 = MOD( npb(ji) - 1, jpi ) + 1
598            zjj                 = ( npb(ji) - 1 ) / jpi + 1
599
600            WRITE(numout,*) ' alerte 1     '
601            WRITE(numout,*) ' Untolerated conservation / surface error after '
602            WRITE(numout,*) ' heat diffusion in the ice '
603            WRITE(numout,*) ' Category   : ', jl
604            WRITE(numout,*) ' zji , zjj  : ', zji, zjj
605            WRITE(numout,*) ' lat, lon   : ', gphit(zji,zjj), glamt(zji,zjj)
606            WRITE(numout,*) ' cons_error : ', cons_error(ji,jl)
607            WRITE(numout,*) ' surf_error : ', surf_error(ji,jl)
608            WRITE(numout,*) ' dq_i       : ', - dq_i(ji,jl) / rdt_ice
609            WRITE(numout,*) ' Fdt        : ', sum_fluxq(ji,jl)
610            WRITE(numout,*)
611            !        WRITE(numout,*) ' qt_i_in   : ', qt_i_in(ji,jl)
612            !        WRITE(numout,*) ' qt_s_in   : ', qt_s_in(ji,jl)
613            !        WRITE(numout,*) ' qt_i_fin  : ', qt_i_fin(ji,jl)
614            !        WRITE(numout,*) ' qt_s_fin  : ', qt_s_fin(ji,jl)
615            !        WRITE(numout,*) ' qt        : ', qt_i_fin(ji,jl) + &
616            !                                         qt_s_fin(ji,jl)
617            WRITE(numout,*) ' ht_i       : ', ht_i_b(ji)
618            WRITE(numout,*) ' ht_s       : ', ht_s_b(ji)
619            WRITE(numout,*) ' t_su       : ', t_su_b(ji)
620            WRITE(numout,*) ' t_s        : ', t_s_b(ji,1)
621            WRITE(numout,*) ' t_i        : ', t_i_b(ji,1:nlay_i)
622            WRITE(numout,*) ' t_bo       : ', t_bo_b(ji)
623            WRITE(numout,*) ' q_i        : ', q_i_b(ji,1:nlay_i)
624            WRITE(numout,*) ' s_i        : ', s_i_b(ji,1:nlay_i)
625            WRITE(numout,*) ' tmelts     : ', rtt - tmut*s_i_b(ji,1:nlay_i)
626            WRITE(numout,*)
627            WRITE(numout,*) ' Fluxes '
628            WRITE(numout,*) ' ~~~~~~ '
629            WRITE(numout,*) ' fatm       : ', fatm(ji,jl)
630            WRITE(numout,*) ' fc_su      : ', fc_su    (ji)
631            WRITE(numout,*) ' fstr_inice : ', qsr_ice_1d(ji)*i0(ji)
632            WRITE(numout,*) ' fc_bo      : ', - fc_bo_i  (ji)
633            WRITE(numout,*) ' foc        : ', fbif_1d(ji)
634            WRITE(numout,*) ' fstroc     : ', fstroc   (zji,zjj,jl)
635            WRITE(numout,*) ' i0         : ', i0(ji)
636            WRITE(numout,*) ' qsr_ice    : ', (1.0-i0(ji))*qsr_ice_1d(ji)
637            WRITE(numout,*) ' qns_ice    : ', qnsr_ice_1d(ji)
638            WRITE(numout,*) ' Conduction fluxes : '
639            WRITE(numout,*) ' fc_s      : ', fc_s(ji,0:nlay_s)
640            WRITE(numout,*) ' fc_i      : ', fc_i(ji,0:nlay_i)
641            WRITE(numout,*)
642            WRITE(numout,*) ' Layer by layer ... '
643            WRITE(numout,*) ' dq_snow : ', ( qt_s_fin(ji,jl) - &
644               qt_s_in(ji,jl) )  & 
645               / rdt_ice
646            WRITE(numout,*) ' dfc_snow  : ', fc_s(ji,1) -      &
647               fc_s(ji,0)
648            DO jk = 1, nlay_i
649               WRITE(numout,*) ' layer  : ', jk
650               WRITE(numout,*) ' dq_ice : ', dq_i_layer(ji,jk) / rdt_ice 
651               WRITE(numout,*) ' radab  : ', radab(ji,jk)
652               WRITE(numout,*) ' dfc_i  : ', fc_i(ji,jk) -               &
653                  fc_i(ji,jk-1)
654               WRITE(numout,*) ' tot f  : ', fc_i(ji,jk) -               &
655                  fc_i(ji,jk-1) - radab(ji,jk)
656            END DO
657
658         ENDIF
659
660      END DO
661      !
662   END SUBROUTINE lim_thd_con_dif
663
664
665   SUBROUTINE lim_thd_con_dh(kideb,kiut,jl)
666      !!-----------------------------------------------------------------------
667      !!                   ***  ROUTINE lim_thd_con_dh  ***
668      !!                 
669      !! ** Purpose :   Test energy conservation after enthalpy redistr.
670      !!
671      !! history :
672      !!  9.9  ! 07-04 (M.Vancoppenolle) original code
673      !!-----------------------------------------------------------------------
674      INTEGER, INTENT(in) ::        &
675         kideb, kiut,               &  !: bounds for the spatial loop
676         jl                            !: category number
677
678      REAL(wp)                 ::   &  !: ! goes to trash
679         meance,                    &  !: mean conservation error
680         max_cons_err                  !: maximum tolerated conservation error
681
682      INTEGER ::                    &
683         numce                         !: number of points for which conservation
684      !  is violated
685      INTEGER  ::  ji, zji, zjj        ! loop indices
686      !!---------------------------------------------------------------------
687
688      max_cons_err = 1.0
689
690      !--------------------------
691      ! Increment of energy
692      !--------------------------
693      ! global
694      DO ji = kideb, kiut
695         dq_i(ji,jl) = qt_i_fin(ji,jl) - qt_i_in(ji,jl)  &
696            + qt_s_fin(ji,jl) - qt_s_in(ji,jl)
697      END DO
698      ! layer by layer
699      dq_i_layer(:,:)    = q_i_layer_fin(:,:) - q_i_layer_in(:,:)
700
701      !----------------------------------------
702      ! Atmospheric heat flux, ice heat budget
703      !----------------------------------------
704
705      DO ji = kideb, kiut
706         zji                 = MOD( npb(ji) - 1, jpi ) + 1
707         zjj                 = ( npb(ji) - 1 ) / jpi + 1
708
709         fatm(ji,jl) = &
710            qnsr_ice_1d(ji)                  + & ! atm non solar
711            !         (1.0-i0(ji))*qsr_ice_1d(ji)          ! atm solar
712            qsr_ice_1d(ji)                       ! atm solar
713
714         sum_fluxq(ji,jl)     = fatm(ji,jl) + fbif_1d(ji) - ftotal_fin(ji) & 
715            - fstroc(zji,zjj,jl) 
716         cons_error(ji,jl)   = ABS( dq_i(ji,jl) / rdt_ice + sum_fluxq(ji,jl) )
717      END DO
718
719      !--------------------
720      ! Conservation error
721      !--------------------
722
723      DO ji = kideb, kiut
724         cons_error(ji,jl) = ABS( dq_i(ji,jl) / rdt_ice + sum_fluxq(ji,jl) )
725      END DO
726
727      numce = 0
728      meance = 0.0
729      DO ji = kideb, kiut
730         IF ( cons_error(ji,jl) .GT. max_cons_err ) THEN
731            numce = numce + 1
732            meance = meance + cons_error(ji,jl)
733         ENDIF
734      ENDDO
735      IF (numce .GT. 0 ) meance = meance / numce
736
737      WRITE(numout,*) ' Error report - Category : ', jl
738      WRITE(numout,*) ' ~~~~~~~~~~~~ '
739      WRITE(numout,*) ' Maximum tolerated conservation error : ', max_cons_err
740      WRITE(numout,*) ' After lim_thd_ent, category : ', jl
741      WRITE(numout,*) ' Mean conservation error on big error points ', meance, &
742         numit
743      WRITE(numout,*) ' Number of points where there is a cons err gt than 0.1 W/m2 : ', numce, numit
744
745      !---------------------------------------
746      ! Write ice state in case of big errors
747      !---------------------------------------
748
749      DO ji = kideb, kiut
750         IF ( cons_error(ji,jl) .GT. max_cons_err  ) THEN
751            zji                 = MOD( npb(ji) - 1, jpi ) + 1
752            zjj                 = ( npb(ji) - 1 ) / jpi + 1
753
754            WRITE(numout,*) ' alerte 1 - category : ', jl
755            WRITE(numout,*) ' Untolerated conservation error after limthd_ent '
756            WRITE(numout,*) ' zji , zjj  : ', zji, zjj
757            WRITE(numout,*) ' lat, lon   : ', gphit(zji,zjj), glamt(zji,zjj)
758            WRITE(numout,*) ' * '
759            WRITE(numout,*) ' Ftotal     : ', sum_fluxq(ji,jl)
760            WRITE(numout,*) ' dq_t       : ', - dq_i(ji,jl) / rdt_ice
761            WRITE(numout,*) ' dq_i       : ', - ( qt_i_fin(ji,jl) - qt_i_in(ji,jl) ) / rdt_ice
762            WRITE(numout,*) ' dq_s       : ', - ( qt_s_fin(ji,jl) - qt_s_in(ji,jl) ) / rdt_ice
763            WRITE(numout,*) ' cons_error : ', cons_error(ji,jl)
764            WRITE(numout,*) ' * '
765            WRITE(numout,*) ' Fluxes        --- : '
766            WRITE(numout,*) ' fatm       : ', fatm(ji,jl)
767            WRITE(numout,*) ' foce       : ', fbif_1d(ji)
768            WRITE(numout,*) ' fres       : ', ftotal_fin(ji)
769            WRITE(numout,*) ' fhbri      : ', fhbricat(zji,zjj,jl)
770            WRITE(numout,*) ' * '
771            WRITE(numout,*) ' Heat contents --- : '
772            WRITE(numout,*) ' qt_s_in    : ', qt_s_in(ji,jl) / rdt_ice
773            WRITE(numout,*) ' qt_i_in    : ', qt_i_in(ji,jl) / rdt_ice
774            WRITE(numout,*) ' qt_in      : ', ( qt_i_in(ji,jl) + &
775               qt_s_in(ji,jl) ) / rdt_ice
776            WRITE(numout,*) ' qt_s_fin   : ', qt_s_fin(ji,jl) / rdt_ice
777            WRITE(numout,*) ' qt_i_fin   : ', qt_i_fin(ji,jl) / rdt_ice
778            WRITE(numout,*) ' qt_fin     : ', ( qt_i_fin(ji,jl) + &
779               qt_s_fin(ji,jl) ) / rdt_ice
780            WRITE(numout,*) ' * '
781            WRITE(numout,*) ' Ice variables --- : '
782            WRITE(numout,*) ' ht_i       : ', ht_i_b(ji)
783            WRITE(numout,*) ' ht_s       : ', ht_s_b(ji)
784            WRITE(numout,*) ' dh_s_tot  : ', dh_s_tot(ji)
785            WRITE(numout,*) ' dh_snowice: ', dh_snowice(ji)
786            WRITE(numout,*) ' dh_i_surf : ', dh_i_surf(ji)
787            WRITE(numout,*) ' dh_i_bott : ', dh_i_bott(ji)
788
789         ENDIF
790         !
791      END DO
792      !
793   END SUBROUTINE lim_thd_con_dh
794
795
796   SUBROUTINE lim_thd_enmelt( kideb, kiut )
797      !!-----------------------------------------------------------------------
798      !!                   ***  ROUTINE lim_thd_enmelt ***
799      !!                 
800      !! ** Purpose :   Computes sea ice energy of melting q_i (J.m-3)
801      !!
802      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
803      !!
804      !!-------------------------------------------------------------------
805      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
806      !!
807      INTEGER  ::   ji, jk   !dummy loop indices
808      REAL(wp) ::   ztmelts, zeps   ! temporary scalar
809      !!-------------------------------------------------------------------
810      zeps = 1.e-10
811      !
812      DO jk = 1, nlay_i             ! Sea ice energy of melting
813         DO ji = kideb, kiut
814            ztmelts      =  - tmut  * s_i_b(ji,jk) + rtt 
815            q_i_b(ji,jk) =    rhoic * ( cpic * ( ztmelts - t_i_b(ji,jk) )                                 &
816               &                      + lfus * ( 1.0 - (ztmelts-rtt) / MIN( t_i_b(ji,jk)-rtt, -zeps ) )   &
817               &                      - rcp  * ( ztmelts-rtt  )  ) 
818         END DO
819      END DO
820      DO jk = 1, nlay_s             ! Snow energy of melting
821         DO ji = kideb,kiut
822            q_s_b(ji,jk) = rhosn * ( cpic * ( rtt - t_s_b(ji,jk) ) + lfus )
823         END DO
824      END DO
825      !
826   END SUBROUTINE lim_thd_enmelt
827
828
829   SUBROUTINE lim_thd_init
830
831      !!-----------------------------------------------------------------------
832      !!                   ***  ROUTINE lim_thd_init ***
833      !!                 
834      !! ** Purpose :   Physical constants and parameters linked to the ice
835      !!              thermodynamics
836      !!
837      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
838      !!              parameter values called at the first timestep (nit000)
839      !!
840      !! ** input   :   Namelist namicether
841       !!-------------------------------------------------------------------
842      NAMELIST/namicethd/ hmelt , hiccrit, fraz_swi, maxfrazb, vfrazb, Cfrazb,   &
843         &                hicmin, hiclim, amax  ,                                &
844         &                sbeta  , parlat, hakspl, hibspl, exld,                 &
845         &                hakdif, hnzst  , thth  , parsub, alphs, betas,         & 
846         &                kappa_i, nconv_i_thd, maxer_i_thd, thcon_i_swi
847      !!-------------------------------------------------------------------
848
849      IF(lwp) THEN
850         WRITE(numout,*)
851         WRITE(numout,*) 'lim_thd : Ice Thermodynamics'
852         WRITE(numout,*) '~~~~~~~'
853      ENDIF
854
855      REWIND( numnam_ice )                  ! read Namelist numnam_ice
856      READ  ( numnam_ice , namicethd )
857     
858      IF(lwp) THEN                          ! control print
859         WRITE(numout,*)
860         WRITE(numout,*)'   Namelist of ice parameters for ice thermodynamic computation '
861         WRITE(numout,*)'      maximum melting at the bottom                           hmelt        = ', hmelt
862         WRITE(numout,*)'      ice thick. for lateral accretion in NH (SH)             hiccrit(1/2) = ', hiccrit
863         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       fraz_swi     = ', fraz_swi
864         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   maxfrazb     = ', maxfrazb
865         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  vfrazb       = ', vfrazb
866         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          Cfrazb       = ', Cfrazb
867         WRITE(numout,*)'      ice thick. corr. to max. energy stored in brine pocket  hicmin       = ', hicmin 
868         WRITE(numout,*)'      minimum ice thickness                                   hiclim       = ', hiclim 
869         WRITE(numout,*)'      maximum lead fraction                                   amax         = ', amax
870         WRITE(numout,*)'      numerical carac. of the scheme for diffusion in ice '
871         WRITE(numout,*)'      Cranck-Nicholson (=0.5), implicit (=1), explicit (=0)   sbeta        = ', sbeta
872         WRITE(numout,*)'      percentage of energy used for lateral ablation          parlat       = ', parlat
873         WRITE(numout,*)'      slope of distr. for Hakkinen-Mellor lateral melting     hakspl       = ', hakspl 
874         WRITE(numout,*)'      slope of distribution for Hibler lateral melting        hibspl       = ', hibspl
875         WRITE(numout,*)'      exponent for leads-closure rate                         exld         = ', exld
876         WRITE(numout,*)'      coefficient for diffusions of ice and snow              hakdif       = ', hakdif
877         WRITE(numout,*)'      threshold thick. for comp. of eq. thermal conductivity  zhth         = ', thth 
878         WRITE(numout,*)'      thickness of the surf. layer in temp. computation       hnzst        = ', hnzst
879         WRITE(numout,*)'      switch for snow sublimation  (=1) or not (=0)           parsub       = ', parsub 
880         WRITE(numout,*)'      coefficient for snow density when snow ice formation    alphs        = ', alphs
881         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          betas        = ', betas
882         WRITE(numout,*)'      extinction radiation parameter in sea ice (1.0)         kappa_i      = ', kappa_i
883         WRITE(numout,*)'      maximal n. of iter. for heat diffusion computation      nconv_i_thd  = ', nconv_i_thd
884         WRITE(numout,*)'      maximal err. on T for heat diffusion computation        maxer_i_thd  = ', maxer_i_thd
885         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     thcon_i_swi  = ', thcon_i_swi
886      ENDIF
887      !
888      rcdsn = hakdif * rcdsn 
889      rcdic = hakdif * rcdic
890      !
891   END SUBROUTINE lim_thd_init
892
893#else
894   !!----------------------------------------------------------------------
895   !!   Default option                               NO  LIM3 sea-ice model
896   !!----------------------------------------------------------------------
897CONTAINS
898   SUBROUTINE lim_thd         ! Empty routine
899   END SUBROUTINE lim_thd
900   SUBROUTINE lim_thd_con_dif
901   END SUBROUTINE lim_thd_con_dif
902#endif
903
904   !!======================================================================
905END MODULE limthd
Note: See TracBrowser for help on using the repository browser.