New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limdyn_2.F90 in trunk/NEMO/LIM_SRC_2 – NEMO

source: trunk/NEMO/LIM_SRC_2/limdyn_2.F90 @ 1228

Last change on this file since 1228 was 1228, checked in by smasson, 15 years ago

cleanning related to lim2 namelist, prepare changeset: 1229, see ticket:258
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 11.4 KB
Line 
1MODULE limdyn_2
2   !!======================================================================
3   !!                     ***  MODULE  limdyn_2  ***
4   !!   Sea-Ice dynamics : 
5   !!======================================================================
6   !! History :   1.0  !  01-04  (LIM)  Original code
7   !!             2.0  !  02-08  (C. Ethe, G. Madec)  F90, mpp
8   !!             2.0  !  03-08  (C. Ethe) add lim_dyn_init
9   !!             2.0  !  06-07  (G. Madec)  Surface module
10   !!---------------------------------------------------------------------
11#if defined key_lim2
12   !!----------------------------------------------------------------------
13   !!   'key_lim2' :                                  LIM 2.0 sea-ice model
14   !!----------------------------------------------------------------------
15   !!    lim_dyn_2      : computes ice velocities
16   !!    lim_dyn_init_2 : initialization and namelist read
17   !!----------------------------------------------------------------------
18   USE dom_oce        ! ocean space and time domain
19   USE sbc_oce        !
20   USE phycst         !
21   USE ice_2          !
22   USE ice_oce        !
23   USE dom_ice_2      !
24   USE limistate_2    !
25   USE limrhg_2       ! ice rheology
26
27   USE lbclnk         !
28   USE lib_mpp        !
29   USE in_out_manager ! I/O manager
30   USE prtctl         ! Print control
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   lim_dyn_2 ! routine called by sbc_ice_lim
36
37   !! * Module variables
38   REAL(wp)  ::  rone    = 1.e0   ! constant value
39
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !!   LIM 2.0,  UCL-LOCEAN-IPSL (2006)
43   !! $Id$
44   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46
47CONTAINS
48
49   SUBROUTINE lim_dyn_2( kt )
50      !!-------------------------------------------------------------------
51      !!               ***  ROUTINE lim_dyn_2  ***
52      !!               
53      !! ** Purpose :   compute ice velocity and ocean-ice friction velocity
54      !!               
55      !! ** Method  :
56      !!
57      !! ** Action  : - Initialisation
58      !!              - Call of the dynamic routine for each hemisphere
59      !!              - computation of the friction velocity at the sea-ice base
60      !!              - treatment of the case if no ice dynamic
61      !!---------------------------------------------------------------------
62      INTEGER, INTENT(in) ::   kt     ! number of iteration
63      !!
64      INTEGER  ::   ji, jj             ! dummy loop indices
65      INTEGER  ::   i_j1, i_jpj        ! Starting/ending j-indices for rheology
66      REAL(wp) ::   zcoef              ! temporary scalar
67      REAL(wp), DIMENSION(jpj)     ::   zind           ! i-averaged indicator of sea-ice
68      REAL(wp), DIMENSION(jpj)     ::   zmsk           ! i-averaged of tmask
69      REAL(wp), DIMENSION(jpi,jpj) ::   zu_io, zv_io   ! ice-ocean velocity
70      !!---------------------------------------------------------------------
71
72      IF( kt == nit000 )   CALL lim_dyn_init_2   ! Initialization (first time-step only)
73     
74      IF( ln_limdyn ) THEN
75         !
76         ! Mean ice and snow thicknesses.         
77         hsnm(:,:)  = ( 1.0 - frld(:,:) ) * hsnif(:,:)
78         hicm(:,:)  = ( 1.0 - frld(:,:) ) * hicif(:,:)
79         !
80         !                                     ! Rheology (ice dynamics)
81         !                                     ! ========
82         
83         !  Define the j-limits where ice rheology is computed
84         ! ---------------------------------------------------
85         
86         IF( lk_mpp .OR. nbit_cmp == 1 ) THEN                    ! mpp: compute over the whole domain
87            i_j1 = 1   
88            i_jpj = jpj
89            IF(ln_ctl)   CALL prt_ctl_info( 'lim_dyn  :    i_j1 = ', ivar1=i_j1, clinfo2=' ij_jpj = ', ivar2=i_jpj )
90            CALL lim_rhg_2( i_j1, i_jpj )
91            !
92         ELSE                                 ! optimization of the computational area
93            !
94            DO jj = 1, jpj
95               zind(jj) = SUM( frld (:,jj  ) )   ! = FLOAT(jpj) if ocean everywhere on a j-line
96               zmsk(jj) = SUM( tmask(:,jj,1) )   ! = 0          if land  everywhere on a j-line
97            END DO
98            !
99            IF( l_jeq ) THEN                     ! local domain include both hemisphere
100               !                                 ! Rheology is computed in each hemisphere
101               !                                 ! only over the ice cover latitude strip
102               ! Northern hemisphere
103               i_j1  = njeq
104               i_jpj = jpj
105               DO WHILE ( i_j1 <= jpj .AND. zind(i_j1) == FLOAT(jpi) .AND. zmsk(i_j1) /=0 )
106                  i_j1 = i_j1 + 1
107               END DO
108               i_j1 = MAX( 1, i_j1-1 )
109               IF(ln_ctl)   WRITE(numout,*) 'lim_dyn : NH i_j1 = ', i_j1, ' ij_jpj = ', i_jpj
110               !
111               CALL lim_rhg_2( i_j1, i_jpj )
112               !
113               ! Southern hemisphere
114               i_j1  =  1 
115               i_jpj = njeq
116               DO WHILE ( i_jpj >= 1 .AND. zind(i_jpj) == FLOAT(jpi) .AND. zmsk(i_jpj) /=0 )
117                  i_jpj = i_jpj - 1
118               END DO
119               i_jpj = MIN( jpj, i_jpj+2 )
120               IF(ln_ctl)   WRITE(numout,*) 'lim_dyn : SH i_j1 = ', i_j1, ' ij_jpj = ', i_jpj
121               !
122               CALL lim_rhg_2( i_j1, i_jpj )
123               !
124            ELSE                                 ! local domain extends over one hemisphere only
125               !                                 ! Rheology is computed only over the ice cover
126               !                                 ! latitude strip
127               i_j1  = 1
128               DO WHILE ( i_j1 <= jpj .AND. zind(i_j1) == FLOAT(jpi) .AND. zmsk(i_j1) /=0 )
129                  i_j1 = i_j1 + 1
130               END DO
131               i_j1 = MAX( 1, i_j1-1 )
132   
133               i_jpj  = jpj
134               DO WHILE ( i_jpj >= 1  .AND. zind(i_jpj) == FLOAT(jpi) .AND. zmsk(i_jpj) /=0 )
135                  i_jpj = i_jpj - 1
136               END DO
137               i_jpj = MIN( jpj, i_jpj+2)
138   
139               IF(ln_ctl)   WRITE(numout,*) 'lim_dyn : one hemisphere: i_j1 = ', i_j1, ' ij_jpj = ', i_jpj
140               !
141               CALL lim_rhg_2( i_j1, i_jpj )
142               !
143            ENDIF
144            !
145         ENDIF
146
147         IF(ln_ctl)   CALL prt_ctl(tab2d_1=ui_ice , clinfo1=' lim_dyn  : ui_ice :', tab2d_2=vi_ice , clinfo2=' vi_ice :')
148         
149         ! computation of friction velocity
150         ! --------------------------------
151         ! ice-ocean velocity at U & V-points (ui_ice vi_ice at I-point ; ssu_m, ssv_m at U- & V-points)
152         
153         DO jj = 1, jpjm1
154            DO ji = 1, fs_jpim1   ! vector opt.
155               zu_io(ji,jj) = 0.5 * ( ui_ice(ji+1,jj+1) + ui_ice(ji+1,jj  ) ) - ssu_m(ji,jj)
156               zv_io(ji,jj) = 0.5 * ( vi_ice(ji+1,jj+1) + vi_ice(ji  ,jj+1) ) - ssv_m(ji,jj)
157            END DO
158         END DO
159         ! frictional velocity at T-point
160         DO jj = 2, jpjm1
161            DO ji = fs_2, fs_jpim1   ! vector opt.
162               ust2s(ji,jj) = 0.5 * cw                                                          &
163                  &         * (  zu_io(ji,jj) * zu_io(ji,jj) + zu_io(ji-1,jj) * zu_io(ji-1,jj)   &
164                  &            + zv_io(ji,jj) * zv_io(ji,jj) + zv_io(ji,jj-1) * zv_io(ji,jj-1)   ) * tms(ji,jj)
165            END DO
166         END DO
167         !
168      ELSE      ! no ice dynamics : transmit directly the atmospheric stress to the ocean
169         !
170         zcoef = SQRT( 0.5 ) / rau0
171         DO jj = 2, jpjm1
172            DO ji = fs_2, fs_jpim1   ! vector opt.
173               ust2s(ji,jj) = zcoef * tms(ji,jj) * SQRT(  utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj)   &
174                  &                                     + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1) )
175            END DO
176         END DO
177         !
178      ENDIF
179      !
180      CALL lbc_lnk( ust2s, 'T',  1. )   ! T-point
181      !
182      IF(ln_ctl)   CALL prt_ctl(tab2d_1=ust2s , clinfo1=' lim_dyn  : ust2s :')
183
184   END SUBROUTINE lim_dyn_2
185
186
187   SUBROUTINE lim_dyn_init_2
188      !!-------------------------------------------------------------------
189      !!                  ***  ROUTINE lim_dyn_init_2  ***
190      !!
191      !! ** Purpose :   Physical constants and parameters linked to the ice
192      !!              dynamics
193      !!
194      !! ** Method  :   Read the namicedyn namelist and check the ice-dynamic
195      !!              parameter values
196      !!
197      !! ** input   :   Namelist namicedyn
198      !!-------------------------------------------------------------------
199      NAMELIST/namicedyn/ epsd, alpha,     &
200         &                dm, nbiter, nbitdr, om, resl, cw, angvg, pstar,   &
201         &                c_rhg, etamn, creepl, ecc, ahi0
202      !!-------------------------------------------------------------------
203
204      REWIND ( numnam_ice )                       ! Read Namelist namicedyn
205      READ   ( numnam_ice  , namicedyn )
206
207      IF(lwp) THEN                                ! Control print
208         WRITE(numout,*)
209         WRITE(numout,*) 'lim_dyn_init_2: ice parameters for ice dynamics '
210         WRITE(numout,*) '~~~~~~~~~~~~~~'
211         WRITE(numout,*) '       tolerance parameter                              epsd   = ', epsd
212         WRITE(numout,*) '       coefficient for semi-implicit coriolis           alpha  = ', alpha
213         WRITE(numout,*) '       diffusion constant for dynamics                  dm     = ', dm
214         WRITE(numout,*) '       number of sub-time steps for relaxation          nbiter = ', nbiter
215         WRITE(numout,*) '       maximum number of iterations for relaxation      nbitdr = ', nbitdr
216         WRITE(numout,*) '       relaxation constant                              om     = ', om
217         WRITE(numout,*) '       maximum value for the residual of relaxation     resl   = ', resl
218         WRITE(numout,*) '       drag coefficient for oceanic stress              cw     = ', cw
219         WRITE(numout,*) '       turning angle for oceanic stress                 angvg  = ', angvg, ' degrees'
220         WRITE(numout,*) '       first bulk-rheology parameter                    pstar  = ', pstar
221         WRITE(numout,*) '       second bulk-rhelogy parameter                    c_rhg  = ', c_rhg
222         WRITE(numout,*) '       minimun value for viscosity                      etamn  = ', etamn
223         WRITE(numout,*) '       creep limit                                      creepl = ', creepl
224         WRITE(numout,*) '       eccentricity of the elliptical yield curve       ecc    = ', ecc
225         WRITE(numout,*) '       horizontal diffusivity coeff. for sea-ice        ahi0   = ', ahi0
226      ENDIF
227
228      !  Initialization
229      usecc2 = 1.0 / ( ecc * ecc )
230      rhoco  = rau0 * cw
231      angvg  = angvg * rad      ! convert angvg from degree to radian
232      sangvg = SIN( angvg )
233      cangvg = COS( angvg )
234      pstarh = pstar / 2.0
235      !
236      ahiu(:,:) = ahi0 * umask(:,:,1)            ! Ice eddy Diffusivity coefficients.
237      ahiv(:,:) = ahi0 * vmask(:,:,1)
238      !
239   END SUBROUTINE lim_dyn_init_2
240
241#else
242   !!----------------------------------------------------------------------
243   !!   Default option          Empty module       NO LIM 2.0 sea-ice model
244   !!----------------------------------------------------------------------
245CONTAINS
246   SUBROUTINE lim_dyn_2         ! Empty routine
247   END SUBROUTINE lim_dyn_2
248#endif 
249
250   !!======================================================================
251END MODULE limdyn_2
Note: See TracBrowser for help on using the repository browser.