New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limrhg_2.F90 in trunk/NEMO/LIM_SRC_2 – NEMO

source: trunk/NEMO/LIM_SRC_2/limrhg_2.F90 @ 888

Last change on this file since 888 was 888, checked in by ctlod, 16 years ago

merge dev_001_SBC branche with the trunk to include the New Surface Module package, see ticket: #113
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 32.7 KB
Line 
1MODULE limrhg_2
2   !!======================================================================
3   !!                     ***  MODULE  limrhg_2  ***
4   !!   Ice rheology :  performs sea ice rheology
5   !!======================================================================
6   !! History :  0.0  !  93-12  (M.A. Morales Maqueda.)  Original code
7   !!            1.0  !  94-12  (H. Goosse)
8   !!            2.0  !  03-12  (C. Ethe, G. Madec)  F90, mpp
9   !!            " "  !  06-08  (G. Madec)  surface module, ice-stress at I-point
10   !!            " "  !  09-09  (G. Madec)  Huge verctor optimisation
11   !!----------------------------------------------------------------------
12#if defined key_lim2
13   !!----------------------------------------------------------------------
14   !!   'key_lim2'                                    LIM 2.0 sea-ice model
15   !!----------------------------------------------------------------------
16   !!----------------------------------------------------------------------
17   !!   lim_rhg_2   : computes ice velocities
18   !!----------------------------------------------------------------------
19   USE par_oce        ! ocean parameter
20   USE ice_oce        ! ice variables
21   USE sbc_ice        ! surface boundary condition: ice variables
22   USE dom_ice_2      ! domaine: ice variables
23   USE phycst         ! physical constant
24   USE ice_2          ! ice variables
25   USE lbclnk         ! lateral boundary condition
26   USE lib_mpp        ! MPP library
27   USE in_out_manager ! I/O manager
28   USE prtctl         ! Print control
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   lim_rhg_2 ! routine called by lim_dyn
34
35   REAL(wp) ::   rzero   = 0.e0   ! constant value: zero
36   REAL(wp) ::   rone    = 1.e0   !            and  one
37
38   !! * Substitutions
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !!   LIM 2.0,  UCL-LOCEAN-IPSL (2006)
42   !! $ Id: $
43   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45
46CONTAINS
47
48   SUBROUTINE lim_rhg_2( k_j1, k_jpj )
49      !!-------------------------------------------------------------------
50      !!                 ***  SUBROUTINR lim_rhg_2  ***
51      !!
52      !! ** purpose :   determines the velocity field of sea ice by using
53      !!  atmospheric (wind stress) and oceanic (water stress and surface
54      !!  tilt) forcings. Ice-ice interaction is described by a non-linear
55      !!  viscous-plastic law including shear strength and a bulk rheology.
56      !!
57      !! ** Action  : - compute ui_ice, vi_ice the sea-ice velocity defined
58      !!              at I-point
59      !!-------------------------------------------------------------------
60      INTEGER, INTENT(in) ::   k_j1    ! southern j-index for ice computation
61      INTEGER, INTENT(in) ::   k_jpj   ! northern j-index for ice computation
62      !!
63      INTEGER ::   ji, jj              ! dummy loop indices
64      INTEGER ::   iter, jter          ! temporary integers
65      CHARACTER (len=50) ::   charout
66      REAL(wp) ::   ze11  , ze12  , ze22  , ze21       ! temporary scalars
67      REAL(wp) ::   zt11  , zt12  , zt21  , zt22       !    "         "
68      REAL(wp) ::   zvis11, zvis21, zvis12, zvis22     !    "         "
69      REAL(wp) ::   zgphsx, ztagnx, zunw, zur, zusw    !    "         "
70      REAL(wp) ::   zgphsy, ztagny, zvnw, zvr          !    "         "
71      REAL(wp) ::   zresm,  za, zac, zmod
72      REAL(wp) ::   zmpzas, zstms, zindu, zusdtp, zmassdt, zcorlal
73      REAL(wp) ::   ztrace2, zdeter, zdelta, zmask, zdgp, zdgi, zdiag
74      REAL(wp) ::   za1, zb1, zc1, zd1
75      REAL(wp) ::   za2, zb2, zc2, zd2, zden
76      REAL(wp) ::   zs11_11, zs11_12, zs11_21, zs11_22
77      REAL(wp) ::   zs12_11, zs12_12, zs12_21, zs12_22
78      REAL(wp) ::   zs21_11, zs21_12, zs21_21, zs21_22
79      REAL(wp) ::   zs22_11, zs22_12, zs22_21, zs22_22
80      REAL(wp), DIMENSION(jpi,  jpj  ) ::   zfrld, zmass, zcorl
81      REAL(wp), DIMENSION(jpi,  jpj  ) ::   za1ct, za2ct, zresr
82      REAL(wp), DIMENSION(jpi,  jpj  ) ::   zc1u, zc1v, zc2u, zc2v
83      REAL(wp), DIMENSION(jpi,  jpj  ) ::   zsang
84      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zu0, zv0
85      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zu_n, zv_n
86      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zu_a, zv_a
87      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zviszeta, zviseta
88      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zzfrld, zztms
89      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zi1, zi2, zmasst, zpresh
90
91      !!-------------------------------------------------------------------
92
93!!bug
94!!    ui_oce(:,:) = 0.e0
95!!    vi_oce(:,:) = 0.e0
96!!    write(*,*) 'rhg min, max u & v', maxval(ui_oce), minval(ui_oce), maxval(vi_oce), minval(vi_oce)
97!!bug
98     
99      !  Store initial velocities
100      !  ----------------
101      zztms(:,0    ) = 0.e0       ;    zzfrld(:,0    ) = 0.e0
102      zztms(:,jpj+1) = 0.e0       ;    zzfrld(:,jpj+1) = 0.e0
103      zu0(:,0    ) = 0.e0         ;    zv0(:,0    ) = 0.e0
104      zu0(:,jpj+1) = 0.e0         ;    zv0(:,jpj+1) = 0.e0
105      zztms(:,1:jpj) = tms(:,:)   ;    zzfrld(:,1:jpj) = frld(:,:)
106      zu0(:,1:jpj) = ui_ice(:,:)   ;    zv0(:,1:jpj) = vi_ice(:,:)
107
108      zu_a(:,:)    = zu0(:,:)     ;   zv_a(:,:) = zv0(:,:)
109      zu_n(:,:)    = zu0(:,:)     ;   zv_n(:,:) = zv0(:,:)
110
111!i
112      zi1   (:,:) = 0.e0
113      zi2   (:,:) = 0.e0
114      zpresh(:,:) = 0.e0
115      zmasst(:,:) = 0.e0
116!i
117!!gm violant
118      zfrld(:,:) =0.e0
119      zcorl(:,:) =0.e0
120      zmass(:,:) =0.e0
121      za1ct(:,:) =0.e0
122      za2ct(:,:) =0.e0
123!!gm end
124
125      zviszeta(:,:) = 0.e0
126      zviseta (:,:) = 0.e0
127
128!i    zviszeta(:,0    ) = 0.e0    ;    zviseta(:,0    ) = 0.e0
129!i    zviszeta(:,jpj  ) = 0.e0    ;    zviseta(:,jpj  ) = 0.e0
130!i    zviszeta(:,jpj+1) = 0.e0    ;    zviseta(:,jpj+1) = 0.e0
131
132
133      ! Ice mass, ice strength, and wind stress at the center            |
134      ! of the grid squares.                                             |
135      !-------------------------------------------------------------------
136
137!CDIR NOVERRCHK
138      DO jj = k_j1 , k_jpj-1
139!CDIR NOVERRCHK
140         DO ji = 1 , jpi
141            ! only the sinus changes its sign with the hemisphere
142            zsang(ji,jj)  = SIGN( 1.e0, fcor(ji,jj) ) * sangvg   ! only the sinus changes its sign with the hemisphere
143            !
144            zmasst(ji,jj) = tms(ji,jj) * ( rhosn * hsnm(ji,jj) + rhoic * hicm(ji,jj) )
145            zpresh(ji,jj) = tms(ji,jj) *  pstarh * hicm(ji,jj) * EXP( -c_rhg * frld(ji,jj) )
146!!gm  :: stress given at I-point (F-point for the ocean) only compute the ponderation with the ice fraction (1-frld)
147            zi1(ji,jj)    = tms(ji,jj) * ( 1.0 - frld(ji,jj) )
148            zi2(ji,jj)    = tms(ji,jj) * ( 1.0 - frld(ji,jj) )
149         END DO
150      END DO
151
152
153      !---------------------------------------------------------------------------
154      !  Wind stress, coriolis and mass terms at the corners of the grid squares |
155      !  Gradient of ice strenght.                                               |
156      !---------------------------------------------------------------------------
157         
158      DO jj = k_j1+1, k_jpj-1
159         DO ji = fs_2, jpi
160            zstms = zztms(ji,jj  ) * wght(ji,jj,2,2) + zztms(ji-1,jj  ) * wght(ji,jj,1,2)   &
161               &  + zztms(ji,jj-1) * wght(ji,jj,2,1) + zztms(ji-1,jj-1) * wght(ji,jj,1,1)
162            zusw  = 1.0 / MAX( zstms, epsd )
163
164            zt11 = zztms(ji  ,jj  ) * zzfrld(ji  ,jj  ) 
165            zt12 = zztms(ji-1,jj  ) * zzfrld(ji-1,jj  ) 
166            zt21 = zztms(ji  ,jj-1) * zzfrld(ji  ,jj-1) 
167            zt22 = zztms(ji-1,jj-1) * zzfrld(ji-1,jj-1)
168
169            ! Leads area.
170            zfrld(ji,jj) =  (  zt11 * wght(ji,jj,2,2) + zt12 * wght(ji,jj,1,2)   &
171               &             + zt21 * wght(ji,jj,2,1) + zt22 * wght(ji,jj,1,1) ) * zusw
172
173            ! Mass and coriolis coeff. at I-point
174            zmass(ji,jj) = ( zmasst(ji,jj  ) * wght(ji,jj,2,2) + zmasst(ji-1,jj  ) * wght(ji,jj,1,2)   &
175               &           + zmasst(ji,jj-1) * wght(ji,jj,2,1) + zmasst(ji-1,jj-1) * wght(ji,jj,1,1) ) * zusw
176            zcorl(ji,jj) = zmass(ji,jj) * fcor(ji,jj)
177
178            ! Wind stress.
179            ! always provide stress at I-point (ocean F-point)
180            ztagnx = ( zi1(ji,jj  ) * wght(ji,jj,2,2) + zi1(ji-1,jj  ) * wght(ji,jj,1,2)   &
181               &     + zi1(ji,jj-1) * wght(ji,jj,2,1) + zi1(ji-1,jj-1) * wght(ji,jj,1,1) ) * zusw * utaui_ice(ji,jj)
182            ztagny = ( zi2(ji,jj  ) * wght(ji,jj,2,2) + zi2(ji-1,jj  ) * wght(ji,jj,1,2)   &
183               &     + zi2(ji,jj-1) * wght(ji,jj,2,1) + zi2(ji-1,jj-1) * wght(ji,jj,1,1) ) * zusw * vtaui_ice(ji,jj)
184
185            ! Gradient of ice strength
186            zgphsx =   ( alambd(ji,jj,2,2,2,1) - alambd(ji,jj,2,1,2,1) ) * zpresh(ji  ,jj-1)   &
187               &     + ( alambd(ji,jj,2,2,2,2) - alambd(ji,jj,2,1,2,2) ) * zpresh(ji  ,jj  )   &
188               &     - ( alambd(ji,jj,2,2,1,1) + alambd(ji,jj,2,1,1,1) ) * zpresh(ji-1,jj-1)   &
189               &     - ( alambd(ji,jj,2,2,1,2) + alambd(ji,jj,2,1,1,2) ) * zpresh(ji-1,jj  )
190
191            zgphsy = - ( alambd(ji,jj,1,1,2,1) + alambd(ji,jj,1,2,2,1) ) * zpresh(ji  ,jj-1)   &
192               &     - ( alambd(ji,jj,1,1,1,1) + alambd(ji,jj,1,2,1,1) ) * zpresh(ji-1,jj-1)   &
193               &     + ( alambd(ji,jj,1,1,2,2) - alambd(ji,jj,1,2,2,2) ) * zpresh(ji  ,jj  )   &
194               &     + ( alambd(ji,jj,1,1,1,2) - alambd(ji,jj,1,2,1,2) ) * zpresh(ji-1,jj  )
195
196            ! Computation of the velocity field taking into account the ice-ice interaction.                                 
197            ! Terms that are independent of the ice velocity field.
198            za1ct(ji,jj) = ztagnx - zcorl(ji,jj) * vi_oce(ji,jj) - zgphsx
199            za2ct(ji,jj) = ztagny + zcorl(ji,jj) * ui_oce(ji,jj) - zgphsy
200         END DO
201      END DO
202
203
204      ! SOLUTION OF THE MOMENTUM EQUATION.
205      !------------------------------------------
206      !                                                   ! ==================== !
207      DO iter = 1 , 2 * nbiter                            !    loop over iter    !
208         !                                                ! ==================== !       
209         zindu = MOD( iter , 2 )
210         zusdtp = ( zindu * 2.0 + ( 1.0 - zindu ) * 1.0 )  * REAL( nbiter ) / rdt_ice
211
212         ! Computation of free drift field for free slip boundary conditions.
213
214!CDIR NOVERRCHK
215         DO jj = k_j1, k_jpj-1
216!CDIR NOVERRCHK
217            DO ji = 1, fs_jpim1
218               !- Rate of strain tensor.
219               zt11 =   akappa(ji,jj,1,1) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) - zu_a(ji,jj  ) - zu_a(ji  ,jj+1) )  &
220                  &   + akappa(ji,jj,1,2) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) + zv_a(ji,jj  ) + zv_a(ji  ,jj+1) )
221               zt12 = - akappa(ji,jj,2,2) * ( zu_a(ji  ,jj) + zu_a(ji+1,jj  ) - zu_a(ji,jj+1) - zu_a(ji+1,jj+1) )  &
222                  &   - akappa(ji,jj,2,1) * ( zv_a(ji  ,jj) + zv_a(ji+1,jj  ) + zv_a(ji,jj+1) + zv_a(ji+1,jj+1) )
223               zt22 = - akappa(ji,jj,2,2) * ( zv_a(ji  ,jj) + zv_a(ji+1,jj  ) - zv_a(ji,jj+1) - zv_a(ji+1,jj+1) )  &
224                  &   + akappa(ji,jj,2,1) * ( zu_a(ji  ,jj) + zu_a(ji+1,jj  ) + zu_a(ji,jj+1) + zu_a(ji+1,jj+1) )
225               zt21 =   akappa(ji,jj,1,1) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) - zv_a(ji,jj  ) - zv_a(ji  ,jj+1) )  &
226                  &   - akappa(ji,jj,1,2) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) + zu_a(ji,jj  ) + zu_a(ji  ,jj+1) )
227
228               !- Rate of strain tensor.
229               zdgp = zt11 + zt22
230               zdgi = zt12 + zt21
231               ztrace2 = zdgp * zdgp 
232               zdeter  = zt11 * zt22 - 0.25 * zdgi * zdgi
233
234               !  Creep limit depends on the size of the grid.
235               zdelta = MAX( SQRT( ztrace2 + ( ztrace2 - 4.0 * zdeter ) * usecc2 ),  creepl)
236
237               !-  Computation of viscosities.
238               zviszeta(ji,jj) = MAX( zpresh(ji,jj) / zdelta, etamn )
239               zviseta (ji,jj) = zviszeta(ji,jj) * usecc2
240            END DO
241         END DO
242
243         !-  Determination of zc1u, zc2u, zc1v and zc2v.
244         DO jj = k_j1+1, k_jpj-1
245            DO ji = fs_2, fs_jpim1
246               !* zc1u , zc2v
247               zvis11 = 2.0 * zviseta (ji-1,jj-1) + dm
248               zvis12 =       zviseta (ji-1,jj-1) + dm
249               zvis21 =       zviseta (ji-1,jj-1)
250               zvis22 =       zviszeta(ji-1,jj-1) - zviseta(ji-1,jj-1)
251               zdiag  = zvis22 * ( akappa(ji-1,jj-1,1,1) + akappa(ji-1,jj-1,2,1) )
252               zs11_11 =  zvis11 * akappa(ji-1,jj-1,1,1) + zdiag
253               zs12_11 =  zvis12 * akappa(ji-1,jj-1,2,2) - zvis21 * akappa(ji-1,jj-1,1,2)
254               zs21_11 = -zvis12 * akappa(ji-1,jj-1,1,2) + zvis21 * akappa(ji-1,jj-1,2,2)
255               zs22_11 =  zvis11 * akappa(ji-1,jj-1,2,1) + zdiag
256
257               zvis11 = 2.0 * zviseta (ji,jj-1) + dm
258               zvis22 =       zviszeta(ji,jj-1) - zviseta(ji,jj-1)
259               zvis12 =       zviseta (ji,jj-1) + dm
260               zvis21 =       zviseta (ji,jj-1)
261               zdiag = zvis22 * ( -akappa(ji,jj-1,1,1) + akappa(ji,jj-1,2,1) )
262               zs11_21 = -zvis11 * akappa(ji,jj-1,1,1) + zdiag
263               zs12_21 =  zvis12 * akappa(ji,jj-1,2,2) - zvis21 * akappa(ji,jj-1,1,2)
264               zs22_21 =  zvis11 * akappa(ji,jj-1,2,1) + zdiag
265               zs21_21 = -zvis12 * akappa(ji,jj-1,1,2) + zvis21 * akappa(ji,jj-1,2,2)
266
267               zvis11 = 2.0 * zviseta (ji-1,jj) + dm
268               zvis22 =       zviszeta(ji-1,jj) - zviseta(ji-1,jj)
269               zvis12 =       zviseta (ji-1,jj) + dm
270               zvis21 =       zviseta (ji-1,jj)
271               zdiag = zvis22 * ( akappa(ji-1,jj,1,1) + akappa(ji-1,jj,2,1) )
272               zs11_12 =  zvis11 * akappa(ji-1,jj,1,1) + zdiag
273               zs12_12 = -zvis12 * akappa(ji-1,jj,2,2) - zvis21 * akappa(ji-1,jj,1,2)
274               zs22_12 =  zvis11 * akappa(ji-1,jj,2,1) + zdiag
275               zs21_12 = -zvis12 * akappa(ji-1,jj,1,2) - zvis21 * akappa(ji-1,jj,2,2)
276
277               zvis11 = 2.0 * zviseta (ji,jj) + dm
278               zvis22 =       zviszeta(ji,jj) - zviseta(ji,jj)
279               zvis12 =       zviseta (ji,jj) + dm
280               zvis21 =       zviseta (ji,jj)
281               zdiag = zvis22 * ( -akappa(ji,jj,1,1) + akappa(ji,jj,2,1) )
282               zs11_22 = -zvis11 * akappa(ji,jj,1,1) + zdiag
283               zs12_22 = -zvis12 * akappa(ji,jj,2,2) - zvis21 * akappa(ji,jj,1,2)
284               zs22_22 =  zvis11 * akappa(ji,jj,2,1) + zdiag
285               zs21_22 = -zvis12 * akappa(ji,jj,1,2) - zvis21 * akappa(ji,jj,2,2)
286
287               zc1u(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs11_21 + alambd(ji,jj,2,2,2,2) * zs11_22   &
288                  &          - alambd(ji,jj,2,2,1,1) * zs11_11 - alambd(ji,jj,2,2,1,2) * zs11_12   &
289                  &          - alambd(ji,jj,1,1,2,1) * zs12_21 - alambd(ji,jj,1,1,1,1) * zs12_11   &
290                  &          + alambd(ji,jj,1,1,2,2) * zs12_22 + alambd(ji,jj,1,1,1,2) * zs12_12   &
291                  &          + alambd(ji,jj,1,2,1,1) * zs21_11 + alambd(ji,jj,1,2,2,1) * zs21_21   &
292                  &          + alambd(ji,jj,1,2,1,2) * zs21_12 + alambd(ji,jj,1,2,2,2) * zs21_22   &
293                  &          - alambd(ji,jj,2,1,1,1) * zs22_11 - alambd(ji,jj,2,1,2,1) * zs22_21   &
294                  &          - alambd(ji,jj,2,1,1,2) * zs22_12 - alambd(ji,jj,2,1,2,2) * zs22_22
295
296               zc2u(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs21_21 + alambd(ji,jj,2,2,2,2) * zs21_22   &
297                  &          - alambd(ji,jj,2,2,1,1) * zs21_11 - alambd(ji,jj,2,2,1,2) * zs21_12   &
298                  &          - alambd(ji,jj,1,1,2,1) * zs22_21 - alambd(ji,jj,1,1,1,1) * zs22_11   &
299                  &          + alambd(ji,jj,1,1,2,2) * zs22_22 + alambd(ji,jj,1,1,1,2) * zs22_12   &
300                  &          - alambd(ji,jj,1,2,1,1) * zs11_11 - alambd(ji,jj,1,2,2,1) * zs11_21   &
301                  &          - alambd(ji,jj,1,2,1,2) * zs11_12 - alambd(ji,jj,1,2,2,2) * zs11_22   &
302                  &          + alambd(ji,jj,2,1,1,1) * zs12_11 + alambd(ji,jj,2,1,2,1) * zs12_21   &
303                  &          + alambd(ji,jj,2,1,1,2) * zs12_12 + alambd(ji,jj,2,1,2,2) * zs12_22
304
305               !* zc1v , zc2v.
306               zvis11 = 2.0 * zviseta (ji-1,jj-1) + dm
307               zvis22 =       zviszeta(ji-1,jj-1) - zviseta(ji-1,jj-1)
308               zvis12 =       zviseta (ji-1,jj-1) + dm
309               zvis21 =       zviseta (ji-1,jj-1)
310               zdiag = zvis22 * ( akappa(ji-1,jj-1,1,2) + akappa(ji-1,jj-1,2,2) )
311               zs11_11 =  zvis11 * akappa(ji-1,jj-1,1,2) + zdiag
312               zs12_11 = -zvis12 * akappa(ji-1,jj-1,2,1) + zvis21 * akappa(ji-1,jj-1,1,1)
313               zs22_11 =  zvis11 * akappa(ji-1,jj-1,2,2) + zdiag
314               zs21_11 =  zvis12 * akappa(ji-1,jj-1,1,1) - zvis21 * akappa(ji-1,jj-1,2,1)
315 
316               zvis11 = 2.0 * zviseta (ji,jj-1) + dm
317               zvis22 =       zviszeta(ji,jj-1) - zviseta(ji,jj-1)
318               zvis12 =       zviseta (ji,jj-1) + dm
319               zvis21 =       zviseta (ji,jj-1)
320               zdiag = zvis22 * ( akappa(ji,jj-1,1,2) + akappa(ji,jj-1,2,2) )
321               zs11_21 =  zvis11 * akappa(ji,jj-1,1,2) + zdiag
322               zs12_21 = -zvis12 * akappa(ji,jj-1,2,1) - zvis21 * akappa(ji,jj-1,1,1)
323               zs22_21 =  zvis11 * akappa(ji,jj-1,2,2) + zdiag
324               zs21_21 = -zvis12 * akappa(ji,jj-1,1,1) - zvis21 * akappa(ji,jj-1,2,1)
325
326               zvis11 = 2.0 * zviseta (ji-1,jj) + dm
327               zvis22 =       zviszeta(ji-1,jj) - zviseta(ji-1,jj)
328               zvis12 =       zviseta (ji-1,jj) + dm
329               zvis21 =       zviseta (ji-1,jj)
330               zdiag = zvis22 * ( akappa(ji-1,jj,1,2) - akappa(ji-1,jj,2,2) )
331               zs11_12 =  zvis11 * akappa(ji-1,jj,1,2) + zdiag
332               zs12_12 = -zvis12 * akappa(ji-1,jj,2,1) + zvis21 * akappa(ji-1,jj,1,1)
333               zs22_12 = -zvis11 * akappa(ji-1,jj,2,2) + zdiag
334               zs21_12 =  zvis12 * akappa(ji-1,jj,1,1) - zvis21 * akappa(ji-1,jj,2,1)
335
336               zvis11 = 2.0 * zviseta (ji,jj) + dm
337               zvis22 =       zviszeta(ji,jj) - zviseta(ji,jj)
338               zvis12 =       zviseta (ji,jj) + dm
339               zvis21 =       zviseta (ji,jj)
340               zdiag = zvis22 * ( akappa(ji,jj,1,2) - akappa(ji,jj,2,2) )
341               zs11_22 =  zvis11 * akappa(ji,jj,1,2) + zdiag
342               zs12_22 = -zvis12 * akappa(ji,jj,2,1) - zvis21 * akappa(ji,jj,1,1)
343               zs22_22 = -zvis11 * akappa(ji,jj,2,2) + zdiag
344               zs21_22 = -zvis12 * akappa(ji,jj,1,1) - zvis21 * akappa(ji,jj,2,1)
345
346               zc1v(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs11_21 + alambd(ji,jj,2,2,2,2) * zs11_22   &
347                  &          - alambd(ji,jj,2,2,1,1) * zs11_11 - alambd(ji,jj,2,2,1,2) * zs11_12   &
348                  &          - alambd(ji,jj,1,1,2,1) * zs12_21 - alambd(ji,jj,1,1,1,1) * zs12_11   &
349                  &          + alambd(ji,jj,1,1,2,2) * zs12_22 + alambd(ji,jj,1,1,1,2) * zs12_12   &
350                  &          + alambd(ji,jj,1,2,1,1) * zs21_11 + alambd(ji,jj,1,2,2,1) * zs21_21   &
351                  &          + alambd(ji,jj,1,2,1,2) * zs21_12 + alambd(ji,jj,1,2,2,2) * zs21_22   &
352                  &          - alambd(ji,jj,2,1,1,1) * zs22_11 - alambd(ji,jj,2,1,2,1) * zs22_21   &
353                  &          - alambd(ji,jj,2,1,1,2) * zs22_12 - alambd(ji,jj,2,1,2,2) * zs22_22
354
355               zc2v(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs21_21 + alambd(ji,jj,2,2,2,2) * zs21_22   &
356                  &          - alambd(ji,jj,2,2,1,1) * zs21_11 - alambd(ji,jj,2,2,1,2) * zs21_12   &
357                  &          - alambd(ji,jj,1,1,2,1) * zs22_21 - alambd(ji,jj,1,1,1,1) * zs22_11   &
358                  &          + alambd(ji,jj,1,1,2,2) * zs22_22 + alambd(ji,jj,1,1,1,2) * zs22_12   &
359                  &          - alambd(ji,jj,1,2,1,1) * zs11_11 - alambd(ji,jj,1,2,2,1) * zs11_21   &
360                  &          - alambd(ji,jj,1,2,1,2) * zs11_12 - alambd(ji,jj,1,2,2,2) * zs11_22   &
361                  &          + alambd(ji,jj,2,1,1,1) * zs12_11 + alambd(ji,jj,2,1,2,1) * zs12_21   &
362                  &          + alambd(ji,jj,2,1,1,2) * zs12_12 + alambd(ji,jj,2,1,2,2) * zs12_22
363            END DO
364         END DO
365
366         ! GAUSS-SEIDEL method
367         !                                                      ! ================ !
368iflag:   DO jter = 1 , nbitdr                                   !    Relaxation    !
369            !                                                   ! ================ !
370!CDIR NOVERRCHK
371            DO jj = k_j1+1, k_jpj-1
372!CDIR NOVERRCHK
373               DO ji = fs_2, fs_jpim1
374                  !
375                  ze11 =   akappa(ji,jj-1,1,1) * zu_a(ji+1,jj) + akappa(ji,jj-1,1,2) * zv_a(ji+1,jj)
376                  ze12 = + akappa(ji,jj-1,2,2) * zu_a(ji+1,jj) - akappa(ji,jj-1,2,1) * zv_a(ji+1,jj)
377                  ze22 = + akappa(ji,jj-1,2,2) * zv_a(ji+1,jj) + akappa(ji,jj-1,2,1) * zu_a(ji+1,jj)
378                  ze21 =   akappa(ji,jj-1,1,1) * zv_a(ji+1,jj) - akappa(ji,jj-1,1,2) * zu_a(ji+1,jj)
379                  zvis11 = 2.0 * zviseta (ji,jj-1) + dm
380                  zvis22 =       zviszeta(ji,jj-1) - zviseta(ji,jj-1)
381                  zvis12 =       zviseta (ji,jj-1) + dm
382                  zvis21 =       zviseta (ji,jj-1)
383                  zdiag = zvis22 * ( ze11 + ze22 )
384                  zs11_21 =  zvis11 * ze11 + zdiag
385                  zs12_21 =  zvis12 * ze12 + zvis21 * ze21
386                  zs22_21 =  zvis11 * ze22 + zdiag
387                  zs21_21 =  zvis12 * ze21 + zvis21 * ze12
388
389                  ze11 =   akappa(ji-1,jj,1,1) * ( zu_a(ji  ,jj+1) - zu_a(ji-1,jj+1) )   &
390                     &   + akappa(ji-1,jj,1,2) * ( zv_a(ji  ,jj+1) + zv_a(ji-1,jj+1) )
391                  ze12 = + akappa(ji-1,jj,2,2) * ( zu_a(ji-1,jj+1) + zu_a(ji  ,jj+1) )   &
392                     &   - akappa(ji-1,jj,2,1) * ( zv_a(ji-1,jj+1) + zv_a(ji  ,jj+1) )
393                  ze22 = + akappa(ji-1,jj,2,2) * ( zv_a(ji-1,jj+1) + zv_a(ji  ,jj+1) )   &
394                     &   + akappa(ji-1,jj,2,1) * ( zu_a(ji-1,jj+1) + zu_a(ji  ,jj+1) )
395                  ze21 =   akappa(ji-1,jj,1,1) * ( zv_a(ji  ,jj+1) - zv_a(ji-1,jj+1) )   &
396                     &   - akappa(ji-1,jj,1,2) * ( zu_a(ji  ,jj+1) + zu_a(ji-1,jj+1) )
397                  zvis11 = 2.0 * zviseta (ji-1,jj) + dm
398                  zvis22 =       zviszeta(ji-1,jj) - zviseta(ji-1,jj)
399                  zvis12 =       zviseta (ji-1,jj) + dm
400                  zvis21 =       zviseta (ji-1,jj)
401                  zdiag = zvis22 * ( ze11 + ze22 )
402                  zs11_12 =  zvis11 * ze11 + zdiag
403                  zs12_12 =  zvis12 * ze12 + zvis21 * ze21
404                  zs22_12 =  zvis11 * ze22 + zdiag
405                  zs21_12 =  zvis12 * ze21 + zvis21 * ze12
406
407                  ze11 =   akappa(ji,jj,1,1) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) - zu_a(ji  ,jj+1) )   &
408                     &   + akappa(ji,jj,1,2) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) + zv_a(ji  ,jj+1) )
409                  ze12 = - akappa(ji,jj,2,2) * ( zu_a(ji+1,jj) - zu_a(ji  ,jj+1) - zu_a(ji+1,jj+1) )   &
410                     &   - akappa(ji,jj,2,1) * ( zv_a(ji+1,jj) + zv_a(ji  ,jj+1) + zv_a(ji+1,jj+1) )
411                  ze22 = - akappa(ji,jj,2,2) * ( zv_a(ji+1,jj) - zv_a(ji  ,jj+1) - zv_a(ji+1,jj+1) )   &
412                     &   + akappa(ji,jj,2,1) * ( zu_a(ji+1,jj) + zu_a(ji  ,jj+1) + zu_a(ji+1,jj+1) )
413                  ze21 =   akappa(ji,jj,1,1) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) - zv_a(ji  ,jj+1) )   &
414                     &   - akappa(ji,jj,1,2) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) + zu_a(ji  ,jj+1) )
415                  zvis11 = 2.0 * zviseta (ji,jj) + dm
416                  zvis22 =       zviszeta(ji,jj) - zviseta(ji,jj)
417                  zvis12 =       zviseta (ji,jj) + dm
418                  zvis21 =       zviseta (ji,jj)
419                  zdiag = zvis22 * ( ze11 + ze22 )
420                  zs11_22 =  zvis11 * ze11 + zdiag
421                  zs12_22 =  zvis12 * ze12 + zvis21 * ze21
422                  zs22_22 =  zvis11 * ze22 + zdiag
423                  zs21_22 =  zvis12 * ze21 + zvis21 * ze12
424
425            ! 2nd part
426                  ze11 =   akappa(ji-1,jj-1,1,1) * ( zu_a(ji  ,jj-1) - zu_a(ji-1,jj-1) - zu_a(ji-1,jj) )   &
427                     &   + akappa(ji-1,jj-1,1,2) * ( zv_a(ji  ,jj-1) + zv_a(ji-1,jj-1) + zv_a(ji-1,jj) )
428                  ze12 = - akappa(ji-1,jj-1,2,2) * ( zu_a(ji-1,jj-1) + zu_a(ji  ,jj-1) - zu_a(ji-1,jj) )   &
429                     &   - akappa(ji-1,jj-1,2,1) * ( zv_a(ji-1,jj-1) + zv_a(ji  ,jj-1) + zv_a(ji-1,jj) )
430                  ze22 = - akappa(ji-1,jj-1,2,2) * ( zv_a(ji-1,jj-1) + zv_a(ji  ,jj-1) - zv_a(ji-1,jj) )   &
431                     &   + akappa(ji-1,jj-1,2,1) * ( zu_a(ji-1,jj-1) + zu_a(ji  ,jj-1) + zu_a(ji-1,jj) )
432                  ze21 =   akappa(ji-1,jj-1,1,1) * ( zv_a(ji  ,jj-1) - zv_a(ji-1,jj-1) - zv_a(ji-1,jj) )   &
433                     &  -  akappa(ji-1,jj-1,1,2) * ( zu_a(ji  ,jj-1) + zu_a(ji-1,jj-1) + zu_a(ji-1,jj) )
434                  zvis11 = 2.0 * zviseta (ji-1,jj-1) + dm
435                  zvis22 =       zviszeta(ji-1,jj-1) - zviseta(ji-1,jj-1)
436                  zvis12 =       zviseta (ji-1,jj-1) + dm
437                  zvis21 =       zviseta (ji-1,jj-1)
438                  zdiag = zvis22 * ( ze11 + ze22 )
439                  zs11_11 =  zvis11 * ze11 + zdiag
440                  zs12_11 =  zvis12 * ze12 + zvis21 * ze21
441                  zs22_11 =  zvis11 * ze22 + zdiag
442                  zs21_11 =  zvis12 * ze21 + zvis21 * ze12
443
444                  ze11 =   akappa(ji,jj-1,1,1) * ( zu_a(ji+1,jj-1) - zu_a(ji  ,jj-1) )   &
445                     &   + akappa(ji,jj-1,1,2) * ( zv_a(ji+1,jj-1) + zv_a(ji  ,jj-1) )
446                  ze12 = - akappa(ji,jj-1,2,2) * ( zu_a(ji  ,jj-1) + zu_a(ji+1,jj-1) )   &
447                     &   - akappa(ji,jj-1,2,1) * ( zv_a(ji  ,jj-1) + zv_a(ji+1,jj-1) )
448                  ze22 = - akappa(ji,jj-1,2,2) * ( zv_a(ji  ,jj-1) + zv_a(ji+1,jj-1) )   &
449                     &   + akappa(ji,jj-1,2,1) * ( zu_a(ji  ,jj-1) + zu_a(ji+1,jj-1) )
450                  ze21 =   akappa(ji,jj-1,1,1) * ( zv_a(ji+1,jj-1) - zv_a(ji  ,jj-1) )   &
451                     &   - akappa(ji,jj-1,1,2) * ( zu_a(ji+1,jj-1) + zu_a(ji  ,jj-1) )
452                  zvis11 = 2.0 * zviseta (ji,jj-1) + dm
453                  zvis22 =       zviszeta(ji,jj-1) - zviseta(ji,jj-1)
454                  zvis12 =       zviseta (ji,jj-1) + dm
455                  zvis21 =       zviseta (ji,jj-1)
456                  zdiag = zvis22 * ( ze11 + ze22 )
457                  zs11_21 =  zs11_21 + zvis11 * ze11 + zdiag
458                  zs12_21 =  zs12_21 + zvis12 * ze12 + zvis21 * ze21
459                  zs22_21 =  zs22_21 + zvis11 * ze22 + zdiag
460                  zs21_21 =  zs21_21 + zvis12 * ze21 + zvis21 * ze12
461
462                  ze11 = - akappa(ji-1,jj,1,1) * zu_a(ji-1,jj) + akappa(ji-1,jj,1,2) * zv_a(ji-1,jj)
463                  ze12 = - akappa(ji-1,jj,2,2) * zu_a(ji-1,jj) - akappa(ji-1,jj,2,1) * zv_a(ji-1,jj)
464                  ze22 = - akappa(ji-1,jj,2,2) * zv_a(ji-1,jj) + akappa(ji-1,jj,2,1) * zu_a(ji-1,jj)
465                  ze21 = - akappa(ji-1,jj,1,1) * zv_a(ji-1,jj) - akappa(ji-1,jj,1,2) * zu_a(ji-1,jj)
466                  zvis11 = 2.0 * zviseta (ji-1,jj) + dm
467                  zvis22 =       zviszeta(ji-1,jj) - zviseta(ji-1,jj)
468                  zvis12 =       zviseta (ji-1,jj) + dm
469                  zvis21 =       zviseta (ji-1,jj)
470                  zdiag = zvis22 * ( ze11 + ze22 )
471                  zs11_12 =  zs11_12 + zvis11 * ze11 + zdiag
472                  zs12_12 =  zs12_12 + zvis12 * ze12 + zvis21 * ze21
473                  zs22_12 =  zs22_12 + zvis11 * ze22 + zdiag
474                  zs21_12 =  zs21_12 + zvis12 * ze21 + zvis21 * ze12
475
476                  zd1 = + alambd(ji,jj,2,2,2,1) * zs11_21 + alambd(ji,jj,2,2,2,2) * zs11_22  &
477                     &  - alambd(ji,jj,2,2,1,1) * zs11_11 - alambd(ji,jj,2,2,1,2) * zs11_12  &
478                     &  - alambd(ji,jj,1,1,2,1) * zs12_21 - alambd(ji,jj,1,1,1,1) * zs12_11  &
479                     &  + alambd(ji,jj,1,1,2,2) * zs12_22 + alambd(ji,jj,1,1,1,2) * zs12_12  &
480                     &  + alambd(ji,jj,1,2,1,1) * zs21_11 + alambd(ji,jj,1,2,2,1) * zs21_21  &
481                     &  + alambd(ji,jj,1,2,1,2) * zs21_12 + alambd(ji,jj,1,2,2,2) * zs21_22  &
482                     &  - alambd(ji,jj,2,1,1,1) * zs22_11 - alambd(ji,jj,2,1,2,1) * zs22_21  &
483                     &  - alambd(ji,jj,2,1,1,2) * zs22_12 - alambd(ji,jj,2,1,2,2) * zs22_22
484
485                  zd2 = + alambd(ji,jj,2,2,2,1) * zs21_21 + alambd(ji,jj,2,2,2,2) * zs21_22  &
486                     &  - alambd(ji,jj,2,2,1,1) * zs21_11 - alambd(ji,jj,2,2,1,2) * zs21_12  &
487                     &  - alambd(ji,jj,1,1,2,1) * zs22_21 - alambd(ji,jj,1,1,1,1) * zs22_11  &
488                     &  + alambd(ji,jj,1,1,2,2) * zs22_22 + alambd(ji,jj,1,1,1,2) * zs22_12  &
489                     &  - alambd(ji,jj,1,2,1,1) * zs11_11 - alambd(ji,jj,1,2,2,1) * zs11_21  &
490                     &  - alambd(ji,jj,1,2,1,2) * zs11_12 - alambd(ji,jj,1,2,2,2) * zs11_22  &
491                     &  + alambd(ji,jj,2,1,1,1) * zs12_11 + alambd(ji,jj,2,1,2,1) * zs12_21  &
492                     &  + alambd(ji,jj,2,1,1,2) * zs12_12 + alambd(ji,jj,2,1,2,2) * zs12_22
493
494                  zur     = zu_a(ji,jj) - ui_oce(ji,jj)
495                  zvr     = zv_a(ji,jj) - vi_oce(ji,jj)
496!!!!
497                  zmod    = SQRT( zur*zur + zvr*zvr ) * ( 1.0 - zfrld(ji,jj) )
498                  za      = rhoco * zmod
499!!!!
500!!gm chg resul    za      = rhoco * SQRT( zur*zur + zvr*zvr ) * ( 1.0 - zfrld(ji,jj) )
501                  zac     = za * cangvg
502                  zmpzas  = alpha * zcorl(ji,jj) + za * zsang(ji,jj)
503                  zmassdt = zusdtp * zmass(ji,jj)
504                  zcorlal = ( 1.0 - alpha ) * zcorl(ji,jj)
505
506                  za1 =  zmassdt * zu0(ji,jj) + zcorlal * zv0(ji,jj) + za1ct(ji,jj)   &
507                     &        + za * ( cangvg * ui_oce(ji,jj) - zsang(ji,jj) * vi_oce(ji,jj) )
508                  za2 =  zmassdt * zv0(ji,jj) - zcorlal * zu0(ji,jj) + za2ct(ji,jj)   &
509                     &        + za * ( cangvg * vi_oce(ji,jj) + zsang(ji,jj) * ui_oce(ji,jj) )
510                  zb1    = zmassdt + zac - zc1u(ji,jj)
511                  zb2    = zmpzas        - zc2u(ji,jj)
512                  zc1    = zmpzas        + zc1v(ji,jj)
513                  zc2    = zmassdt + zac - zc2v(ji,jj)
514                  zdeter = zc1 * zb2 + zc2 * zb1
515                  zden   = SIGN( rone, zdeter) / MAX( epsd , ABS( zdeter ) )
516                  zunw   = (  ( za1 + zd1 ) * zc2 + ( za2 + zd2 ) * zc1 ) * zden
517                  zvnw   = (  ( za2 + zd2 ) * zb1 - ( za1 + zd1 ) * zb2 ) * zden
518                  zmask  = ( 1.0 - MAX( rzero, SIGN( rone , 1.0 - zmass(ji,jj) ) ) ) * tmu(ji,jj)
519
520                  zu_n(ji,jj) = ( zu_a(ji,jj) + om * ( zunw - zu_a(ji,jj) ) * tmu(ji,jj) ) * zmask
521                  zv_n(ji,jj) = ( zv_a(ji,jj) + om * ( zvnw - zv_a(ji,jj) ) * tmu(ji,jj) ) * zmask
522               END DO
523            END DO
524
525            CALL lbc_lnk( zu_n(:,1:jpj), 'I', -1. )
526            CALL lbc_lnk( zv_n(:,1:jpj), 'I', -1. )
527
528            ! Test of Convergence
529            DO jj = k_j1+1 , k_jpj-1
530               zresr(:,jj) = MAX( ABS( zu_a(:,jj) - zu_n(:,jj) ) , ABS( zv_a(:,jj) - zv_n(:,jj) ) )
531            END DO
532            zresm = MAXVAL( zresr(1:jpi,k_j1+1:k_jpj-1) )
533!!!! this should be faster on scalar processor
534!           zresm = MAXVAL(  MAX( ABS( zu_a(1:jpi,k_j1+1:k_jpj-1) - zu_n(1:jpi,k_j1+1:k_jpj-1) ),   &
535!              &                  ABS( zv_a(1:jpi,k_j1+1:k_jpj-1) - zv_n(1:jpi,k_j1+1:k_jpj-1) ) )  )
536!!!!
537            IF( lk_mpp )   CALL mpp_max( zresm )   ! max over the global domain
538
539            DO jj = k_j1, k_jpj
540               zu_a(:,jj) = zu_n(:,jj)
541               zv_a(:,jj) = zv_n(:,jj)
542            END DO
543
544            IF( zresm <= resl )   EXIT   iflag
545
546            !                                                   ! ================ !
547         END DO    iflag                                        !  end Relaxation  !
548         !                                                      ! ================ !
549
550         IF( zindu == 0 ) THEN      ! even iteration
551            DO jj = k_j1 , k_jpj-1
552               zu0(:,jj) = zu_a(:,jj)
553               zv0(:,jj) = zv_a(:,jj)
554            END DO
555         ENDIF
556         !                                                ! ==================== !
557      END DO                                              !  end loop over iter  !
558      !                                                   ! ==================== !
559
560      ui_ice(:,:) = zu_a(:,1:jpj)
561      vi_ice(:,:) = zv_a(:,1:jpj)
562
563      IF(ln_ctl) THEN
564         WRITE(charout,FMT="('lim_rhg  : res =',D23.16, ' iter =',I4)") zresm, jter
565         CALL prt_ctl_info(charout)
566         CALL prt_ctl(tab2d_1=ui_ice, clinfo1=' lim_rhg  : ui_ice :', tab2d_2=vi_ice, clinfo2=' vi_ice :')
567      ENDIF
568
569   END SUBROUTINE lim_rhg_2
570
571#else
572   !!----------------------------------------------------------------------
573   !!   Default option          Dummy module       NO 2.0 LIM sea-ice model
574   !!----------------------------------------------------------------------
575CONTAINS
576   SUBROUTINE lim_rhg_2( k1 , k2 )       ! Dummy routine
577      WRITE(*,*) 'lim_rhg_2: You should not have seen this print! error?', k1, k2
578   END SUBROUTINE lim_rhg_2
579#endif
580
581   !!==============================================================================
582END MODULE limrhg_2
Note: See TracBrowser for help on using the repository browser.