New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limtrp_2.F90 in trunk/NEMO/LIM_SRC_2 – NEMO

source: trunk/NEMO/LIM_SRC_2/limtrp_2.F90 @ 888

Last change on this file since 888 was 888, checked in by ctlod, 16 years ago

merge dev_001_SBC branche with the trunk to include the New Surface Module package, see ticket: #113

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 15.4 KB
Line 
1MODULE limtrp_2
2   !!======================================================================
3   !!                       ***  MODULE limtrp_2   ***
4   !! LIM 2.0 transport ice model : sea-ice advection/diffusion
5   !!======================================================================
6#if defined key_lim2
7   !!----------------------------------------------------------------------
8   !!   'key_lim2' :                                  LIM 2.0 sea-ice model
9   !!----------------------------------------------------------------------
10   !!   lim_trp_2      : advection/diffusion process of sea ice
11   !!   lim_trp_init_2 : initialization and namelist read
12   !!----------------------------------------------------------------------
13   !! * Modules used
14   USE phycst
15   USE dom_oce
16   USE daymod
17   USE in_out_manager  ! I/O manager
18   USE ice_oce         ! ice variables
19   USE dom_ice_2
20   USE ice_2
21   USE iceini_2
22   USE limistate_2
23   USE limadv_2
24   USE limhdf_2
25   USE lbclnk
26   USE lib_mpp
27
28   IMPLICIT NONE
29   PRIVATE
30
31   !! * Routine accessibility
32   PUBLIC lim_trp_2     ! called by sbc_ice_lim_2
33
34   !! * Shared module variables
35   REAL(wp), PUBLIC  ::   &  !:
36      bound  = 0.e0          !: boundary condit. (0.0 no-slip, 1.0 free-slip)
37
38   !! * Module variables
39   REAL(wp)  ::           &  ! constant values
40      epsi06 = 1.e-06  ,  &
41      epsi03 = 1.e-03  ,  &
42      epsi16 = 1.e-16  ,  &
43      rzero  = 0.e0    ,  &
44      rone   = 1.e0
45
46   !! * Substitution
47#  include "vectopt_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !!   LIM 2.0,  UCL-LOCEAN-IPSL (2005)
50   !! $ Id: $
51   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
52   !!----------------------------------------------------------------------
53
54CONTAINS
55
56   SUBROUTINE lim_trp_2( kt )
57      !!-------------------------------------------------------------------
58      !!                   ***  ROUTINE lim_trp_2 ***
59      !!                   
60      !! ** purpose : advection/diffusion process of sea ice
61      !!
62      !! ** method  : variables included in the process are scalar,   
63      !!     other values are considered as second order.
64      !!     For advection, a second order Prather scheme is used. 
65      !!
66      !! ** action :
67      !!
68      !! History :
69      !!   1.0  !  00-01 (LIM)  Original code
70      !!        !  01-05 (G. Madec, R. Hordoir) opa norm
71      !!   2.0  !  04-01 (G. Madec, C. Ethe)  F90, mpp
72      !!---------------------------------------------------------------------
73      INTEGER, INTENT(in) ::   kt     ! number of iteration
74
75      INTEGER  ::   ji, jj, jk,   &  ! dummy loop indices
76         &          initad           ! number of sub-timestep for the advection
77
78      REAL(wp) ::  &                             
79         zindb  ,  &
80         zacrith, &
81         zindsn , &
82         zindic , &
83         zusvosn, &
84         zusvoic, &
85         zignm  , &
86         zindhe , &
87         zvbord , &
88         zcfl   , &
89         zusnit , &
90         zrtt, ztsn, ztic1, ztic2
91
92      REAL(wp), DIMENSION(jpi,jpj)  ::   &  ! temporary workspace
93         zui_u , zvi_v , zsm   ,         &
94         zs0ice, zs0sn , zs0a  ,         &
95         zs0c0 , zs0c1 , zs0c2 ,         &
96         zs0st
97      !---------------------------------------------------------------------
98
99      IF( kt == nit000  )   CALL lim_trp_init_2      ! Initialization (first time-step only)
100
101      zsm(:,:) = area(:,:)
102     
103      IF( ln_limdyn ) THEN
104         !-------------------------------------!
105         !   Advection of sea ice properties   !
106         !-------------------------------------!
107
108         ! ice velocities at ocean U- and V-points (zui_u,zvi_v)
109         ! ---------------------------------------
110         ! zvbord factor between 1 and 2 to take into account slip or no-slip boundary conditions.       
111         zvbord = 1.0 + ( 1.0 - bound )
112         DO jj = 1, jpjm1
113            DO ji = 1, jpim1
114               zui_u(ji,jj) = ( ui_ice(ji+1,jj  ) + ui_ice(ji+1,jj+1) ) / ( MAX( tmu(ji+1,jj  ) + tmu(ji+1,jj+1), zvbord ) )
115               zvi_v(ji,jj) = ( vi_ice(ji  ,jj+1) + vi_ice(ji+1,jj+1) ) / ( MAX( tmu(ji  ,jj+1) + tmu(ji+1,jj+1), zvbord ) )
116            END DO
117         END DO
118         ! Lateral boundary conditions on zui_u, zvi_v
119         CALL lbc_lnk( zui_u, 'U', -1. )
120         CALL lbc_lnk( zvi_v, 'V', -1. )
121
122         ! CFL test for stability
123         ! ----------------------
124         zcfl  = 0.e0
125         zcfl  = MAX( zcfl, MAXVAL( ABS( zui_u(1:jpim1, :     ) ) * rdt_ice / e1u(1:jpim1, :     ) ) )
126         zcfl  = MAX( zcfl, MAXVAL( ABS( zvi_v( :     ,1:jpjm1) ) * rdt_ice / e2v( :     ,1:jpjm1) ) )
127
128         IF (lk_mpp ) CALL mpp_max(zcfl)
129
130         IF ( zcfl > 0.5 .AND. lwp )   WRITE(numout,*) 'lim_trp_2 : violation of cfl criterion the ',nday,'th day, cfl = ',zcfl
131
132         ! content of properties
133         ! ---------------------
134         zs0sn (:,:) =  hsnm(:,:) * area(:,:)                 ! Snow volume.
135         zs0ice(:,:) =  hicm (:,:) * area(:,:)                ! Ice volume.
136         zs0a  (:,:) =  ( 1.0 - frld(:,:) ) * area(:,:)       ! Surface covered by ice.
137         zs0c0 (:,:) =  tbif(:,:,1) / rt0_snow * zs0sn(:,:)   ! Heat content of the snow layer.
138         zs0c1 (:,:) =  tbif(:,:,2) / rt0_ice  * zs0ice(:,:)  ! Heat content of the first ice layer.
139         zs0c2 (:,:) =  tbif(:,:,3) / rt0_ice  * zs0ice(:,:)  ! Heat content of the second ice layer.
140         zs0st (:,:) =  qstoif(:,:) / xlic     * zs0a(:,:)    ! Heat reservoir for brine pockets.
141         
142 
143         ! Advection
144         ! ---------
145         ! If ice drift field is too fast, use an appropriate time step for advection.         
146         initad = 1 + INT( MAX( rzero, SIGN( rone, zcfl-0.5 ) ) )
147         zusnit = 1.0 / REAL( initad ) 
148         
149         IF ( MOD( nday , 2 ) == 0) THEN
150            DO jk = 1,initad
151               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
152               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
153               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
154               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
155               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
156               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
157               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
158               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
159               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
160               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
161               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
162               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
163               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
164               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
165            END DO
166         ELSE
167            DO jk = 1, initad
168               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
169               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
170               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
171               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
172               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
173               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
174               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
175               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
176               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
177               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
178               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
179               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
180               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
181               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
182            END DO
183         ENDIF
184                       
185         ! recover the properties from their contents
186         ! ------------------------------------------
187         zs0ice(:,:) = zs0ice(:,:) / area(:,:)
188         zs0sn (:,:) = zs0sn (:,:) / area(:,:)
189         zs0a  (:,:) = zs0a  (:,:) / area(:,:)
190         zs0c0 (:,:) = zs0c0 (:,:) / area(:,:)
191         zs0c1 (:,:) = zs0c1 (:,:) / area(:,:)
192         zs0c2 (:,:) = zs0c2 (:,:) / area(:,:)
193         zs0st (:,:) = zs0st (:,:) / area(:,:)
194
195
196         !-------------------------------------!
197         !   Diffusion of sea ice properties   !
198         !-------------------------------------!
199
200         ! Masked eddy diffusivity coefficient at ocean U- and V-points
201         ! ------------------------------------------------------------
202         DO jj = 1, jpjm1          ! NB: has not to be defined on jpj line and jpi row
203            DO ji = 1 , fs_jpim1   ! vector opt.
204               pahu(ji,jj) = ( 1.0 - MAX( rzero, SIGN( rone, -zs0a(ji  ,jj) ) ) )   &
205                  &        * ( 1.0 - MAX( rzero, SIGN( rone, -zs0a(ji+1,jj) ) ) ) * ahiu(ji,jj)
206               pahv(ji,jj) = ( 1.0 - MAX( rzero, SIGN( rone, -zs0a(ji,jj  ) ) ) )   &
207                  &        * ( 1.0 - MAX( rzero, SIGN( rone,- zs0a(ji,jj+1) ) ) ) * ahiv(ji,jj)
208            END DO
209         END DO
210
211         ! diffusion
212         ! ---------
213         CALL lim_hdf_2( zs0ice )
214         CALL lim_hdf_2( zs0sn  )
215         CALL lim_hdf_2( zs0a   )
216         CALL lim_hdf_2( zs0c0  )
217         CALL lim_hdf_2( zs0c1  )
218         CALL lim_hdf_2( zs0c2  )
219         CALL lim_hdf_2( zs0st  )
220
221         zs0ice(:,:) = MAX( rzero, zs0ice(:,:) * area(:,:) )    !!bug:  est-ce utile
222         zs0sn (:,:) = MAX( rzero, zs0sn (:,:) * area(:,:) )    !!bug:  cf /area  juste apres
223         zs0a  (:,:) = MAX( rzero, zs0a  (:,:) * area(:,:) )    !! suppression des 2 change le resultat...
224         zs0c0 (:,:) = MAX( rzero, zs0c0 (:,:) * area(:,:) )
225         zs0c1 (:,:) = MAX( rzero, zs0c1 (:,:) * area(:,:) )
226         zs0c2 (:,:) = MAX( rzero, zs0c2 (:,:) * area(:,:) )
227         zs0st (:,:) = MAX( rzero, zs0st (:,:) * area(:,:) )
228
229
230         ! -------------------------------------------------------------------!
231         !   Up-dating and limitation of sea ice properties after transport   !
232         ! -------------------------------------------------------------------!
233
234         ! Up-dating and limitation of sea ice properties after transport.
235         DO jj = 1, jpj
236!!!iii      zindhe = REAL( MAX( 0, isign(1, jj - njeq ) ) )              !ibug mpp  !!bugmpp  njeq!
237            zindhe = MAX( 0.e0, SIGN( 1.e0, fcor(1,jj) ) )              ! = 0 for SH, =1 for NH
238            DO ji = 1, jpi
239
240               ! Recover mean values over the grid squares.
241               zs0sn (ji,jj) = MAX( rzero, zs0sn (ji,jj)/area(ji,jj) )
242               zs0ice(ji,jj) = MAX( rzero, zs0ice(ji,jj)/area(ji,jj) )
243               zs0a  (ji,jj) = MAX( rzero, zs0a  (ji,jj)/area(ji,jj) )
244               zs0c0 (ji,jj) = MAX( rzero, zs0c0 (ji,jj)/area(ji,jj) )
245               zs0c1 (ji,jj) = MAX( rzero, zs0c1 (ji,jj)/area(ji,jj) )
246               zs0c2 (ji,jj) = MAX( rzero, zs0c2 (ji,jj)/area(ji,jj) )
247               zs0st (ji,jj) = MAX( rzero, zs0st (ji,jj)/area(ji,jj) )
248
249               ! Recover in situ values.
250               zindb         = MAX( rzero, SIGN( rone, zs0a(ji,jj) - epsi06 ) )
251               zacrith       = 1.0 - ( zindhe * acrit(1) + ( 1.0 - zindhe ) * acrit(2) )
252               zs0a (ji,jj)  = zindb * MIN( zs0a(ji,jj), zacrith )
253               hsnif(ji,jj)  = zindb * ( zs0sn(ji,jj) /MAX( zs0a(ji,jj), epsi16 ) )
254               hicif(ji,jj)  = zindb * ( zs0ice(ji,jj)/MAX( zs0a(ji,jj), epsi16 ) )
255               zindsn        = MAX( rzero, SIGN( rone, hsnif(ji,jj) - epsi06 ) )
256               zindic        = MAX( rzero, SIGN( rone, hicif(ji,jj) - epsi03 ) )
257               zindb         = MAX( zindsn, zindic )
258               zs0a (ji,jj)  = zindb * zs0a(ji,jj)
259               frld (ji,jj)  = 1.0 - zs0a(ji,jj)
260               hsnif(ji,jj)  = zindsn * hsnif(ji,jj)
261               hicif(ji,jj)  = zindic * hicif(ji,jj)
262               zusvosn       = 1.0/MAX( hsnif(ji,jj) * zs0a(ji,jj), epsi16 )
263               zusvoic       = 1.0/MAX( hicif(ji,jj) * zs0a(ji,jj), epsi16 )
264               zignm         = MAX( rzero,  SIGN( rone, hsndif - hsnif(ji,jj) ) )
265               zrtt          = 173.15 * rone 
266               ztsn          =          zignm   * tbif(ji,jj,1)  &
267                              + ( 1.0 - zignm ) * MIN( MAX( zrtt, rt0_snow * zusvosn * zs0c0(ji,jj)) , tfu(ji,jj) ) 
268               ztic1          = MIN( MAX( zrtt, rt0_ice * zusvoic * zs0c1(ji,jj) ) , tfu(ji,jj) )
269               ztic2          = MIN( MAX( zrtt, rt0_ice * zusvoic * zs0c2(ji,jj) ) , tfu(ji,jj) )
270 
271               tbif(ji,jj,1) = zindsn * ztsn  + ( 1.0 - zindsn ) * tfu(ji,jj)               
272               tbif(ji,jj,2) = zindic * ztic1 + ( 1.0 - zindic ) * tfu(ji,jj)
273               tbif(ji,jj,3) = zindic * ztic2 + ( 1.0 - zindic ) * tfu(ji,jj)
274               qstoif(ji,jj) = zindb  * xlic * zs0st(ji,jj) /  MAX( zs0a(ji,jj), epsi16 )
275            END DO
276         END DO
277         
278      ENDIF
279     
280   END SUBROUTINE lim_trp_2
281
282
283   SUBROUTINE lim_trp_init_2
284      !!-------------------------------------------------------------------
285      !!                  ***  ROUTINE lim_trp_init_2  ***
286      !!
287      !! ** Purpose :   initialization of ice advection parameters
288      !!
289      !! ** Method  : Read the namicetrp namelist and check the parameter
290      !!       values called at the first timestep (nit000)
291      !!
292      !! ** input   :   Namelist namicetrp
293      !!
294      !! history :
295      !!   2.0  !  03-08 (C. Ethe)  Original code
296      !!-------------------------------------------------------------------
297      NAMELIST/namicetrp/ bound
298      !!-------------------------------------------------------------------
299
300      ! Read Namelist namicetrp
301      REWIND ( numnam_ice )
302      READ   ( numnam_ice  , namicetrp )
303      IF(lwp) THEN
304         WRITE(numout,*)
305         WRITE(numout,*) 'lim_trp_init_2 : Ice parameters for advection '
306         WRITE(numout,*) '~~~~~~~~~~~~~~'
307         WRITE(numout,*) '   boundary conditions (0. no-slip, 1. free-slip) bound  = ', bound
308      ENDIF
309           
310   END SUBROUTINE lim_trp_init_2
311
312#else
313   !!----------------------------------------------------------------------
314   !!   Default option         Empty Module                No sea-ice model
315   !!----------------------------------------------------------------------
316CONTAINS
317   SUBROUTINE lim_trp_2        ! Empty routine
318   END SUBROUTINE lim_trp_2
319#endif
320
321   !!======================================================================
322END MODULE limtrp_2
Note: See TracBrowser for help on using the repository browser.