New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iom_nf90.F90 in trunk/NEMO/OFF_SRC/IOM – NEMO

source: trunk/NEMO/OFF_SRC/IOM/iom_nf90.F90 @ 1324

Last change on this file since 1324 was 1324, checked in by cetlod, 15 years ago

update IOM and lib_mpp modules, see ticket:348
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 28.5 KB
Line 
1MODULE iom_nf90
2   !!=====================================================================
3   !!                    ***  MODULE  iom_nf90 ***
4   !! Input/Output manager :  Library to read input files with NF90 (only fliocom module)
5   !!====================================================================
6   !! History :  9.0  ! 05 12  (J. Belier) Original code
7   !!            9.0  ! 06 02  (S. Masson) Adaptation to NEMO
8   !!             "   ! 07 07  (D. Storkey) Changes to iom_nf90_gettime
9   !!--------------------------------------------------------------------
10   !!gm  caution add !DIR nec: improved performance to be checked as well as no result changes
11
12   !!--------------------------------------------------------------------
13   !!   iom_open       : open a file read only
14   !!   iom_close      : close a file or all files opened by iom
15   !!   iom_get        : read a field (interfaced to several routines)
16   !!   iom_gettime    : read the time axis kvid in the file
17   !!   iom_varid      : get the id of a variable in a file
18   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
19   !!--------------------------------------------------------------------
20   USE in_out_manager  ! I/O manager
21   USE dom_oce         ! ocean space and time domain
22   USE lbclnk          ! lateal boundary condition / mpp exchanges
23   USE iom_def         ! iom variables definitions
24   USE netcdf          ! NetCDF library
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC iom_nf90_open, iom_nf90_close, iom_nf90_varid, iom_nf90_get, iom_nf90_gettime, iom_nf90_rstput
30
31   INTERFACE iom_nf90_get
32      MODULE PROCEDURE iom_nf90_g0d, iom_nf90_g123d
33   END INTERFACE
34   INTERFACE iom_nf90_rstput
35      MODULE PROCEDURE iom_nf90_rp0123d
36   END INTERFACE
37   !!----------------------------------------------------------------------
38   !!  OPA 9.0 , LOCEAN-IPSL (2006)
39   !! $Id$
40   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42
43CONTAINS
44
45   SUBROUTINE iom_nf90_open( cdname, kiomid, ldwrt, ldok, kdompar )
46      !!---------------------------------------------------------------------
47      !!                   ***  SUBROUTINE  iom_open  ***
48      !!
49      !! ** Purpose : open an input file with NF90
50      !!---------------------------------------------------------------------
51      CHARACTER(len=*)       , INTENT(inout)           ::   cdname    ! File name
52      INTEGER                , INTENT(  out)           ::   kiomid    ! nf90 identifier of the opened file
53      LOGICAL                , INTENT(in   )           ::   ldwrt     ! read or write the file?
54      LOGICAL                , INTENT(in   )           ::   ldok      ! check the existence
55      INTEGER, DIMENSION(2,5), INTENT(in   ), OPTIONAL ::   kdompar   ! domain parameters:
56
57      CHARACTER(LEN=100) ::   clinfo   ! info character
58      CHARACTER(LEN=100) ::   cltmp    ! temporary character
59      INTEGER            ::   iln      ! lengths of character
60      INTEGER            ::   istop    ! temporary storage of nstop
61      INTEGER            ::   if90id   ! nf90 identifier of the opened file
62      INTEGER            ::   idmy     ! dummy variable
63      INTEGER            ::   jl       ! loop variable
64      !---------------------------------------------------------------------
65
66      clinfo = '                    iom_nf90_open ~~~  '
67      istop = nstop   ! store the actual value of nstop
68      !
69      IF( ldok ) THEN      ! Open existing file...
70         !                 ! =============
71         IF( ldwrt ) THEN  ! ... in write mode
72            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in WRITE mode'
73            CALL iom_nf90_check(NF90_OPEN(TRIM(cdname), NF90_WRITE  , if90id), clinfo)
74            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy    ), clinfo)
75         ELSE              ! ... in read mode
76            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode'
77            CALL iom_nf90_check(NF90_OPEN(TRIM(cdname), NF90_NOWRITE, if90id), clinfo)
78         ENDIF
79      ELSE                 ! the file does not exist
80         !                 ! =============
81         iln = INDEX( cdname, '.nc' )
82         IF( ldwrt ) THEN  ! the file should be open in write mode so we create it...
83            IF( jpnij > 1 ) THEN
84               WRITE(cltmp,'(a,a,i4.4,a)') cdname(1:iln-1), '_', narea-1, '.nc'
85               cdname = TRIM(cltmp)
86            ENDIF
87            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//TRIM(cdname)//' in WRITE mode'
88            CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), NF90_NOCLOBBER, if90id ), clinfo)
89            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy          ), clinfo)
90            ! define dimensions
91            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'x', kdompar(1,1)  , idmy ), clinfo)
92            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'y', kdompar(2,1)  , idmy ), clinfo)
93            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'z', jpk           , idmy ), clinfo)
94            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 't', NF90_UNLIMITED, idmy ), clinfo)
95            ! global attributes
96            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number_total'   , jpnij              ), clinfo)
97            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number'         , narea-1            ), clinfo)
98            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_dimensions_ids' , (/1     , 2     /) ), clinfo)
99            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_global'    , (/jpiglo, jpjglo/) ), clinfo)
100            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_local'     , kdompar(:,1)       ), clinfo)
101            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_first' , kdompar(:,2)       ), clinfo)
102            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_last'  , kdompar(:,3)       ), clinfo)
103            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_start', kdompar(:,4)       ), clinfo)
104            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_end'  , kdompar(:,5)       ), clinfo)
105            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_type'           , 'BOX'              ), clinfo)
106         ELSE              ! the file should be open for read mode so it must exist...
107            CALL ctl_stop( TRIM(clinfo), ' should be impossible case...' )
108         ENDIF
109      ENDIF
110      ! start to fill file informations
111      ! =============
112      IF( istop == nstop ) THEN   ! no error within this routine
113!does not work with some compilers         kiomid = MINLOC(iom_file(:)%nfid, dim = 1)
114         kiomid = 0
115         DO jl = jpmax_files, 1, -1
116            IF( iom_file(jl)%nfid == 0 )   kiomid = jl
117         ENDDO
118         iom_file(kiomid)%name   = TRIM(cdname)
119         iom_file(kiomid)%nfid   = if90id
120         iom_file(kiomid)%iolib  = jpnf90
121         iom_file(kiomid)%nvars  = 0
122         iom_file(kiomid)%irec   = -1   ! useless for NetCDF files, used to know if the file is in define mode
123         CALL iom_nf90_check(NF90_Inquire(if90id, unlimitedDimId = iom_file(kiomid)%iduld), clinfo)
124         IF ( iom_file(kiomid)%iduld .GE. 0 ) THEN
125           CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, iom_file(kiomid)%iduld,   &
126        &                                               name = iom_file(kiomid)%uldname), clinfo)
127         ENDIF
128         IF(lwp) WRITE(numout,*) '                   ---> '//TRIM(cdname)//' OK'
129      ELSE
130         kiomid = 0               ! return error flag
131      ENDIF
132      !
133   END SUBROUTINE iom_nf90_open
134
135
136   SUBROUTINE iom_nf90_close( kiomid )
137      !!--------------------------------------------------------------------
138      !!                   ***  SUBROUTINE  iom_nf90_close  ***
139      !!
140      !! ** Purpose : close an input file with NF90
141      !!--------------------------------------------------------------------
142      INTEGER, INTENT(in) ::   kiomid   ! iom identifier of the file to be closed
143      CHARACTER(LEN=100)  ::   clinfo   ! info character
144      !---------------------------------------------------------------------
145      !
146      clinfo = '      iom_nf90_close    , file: '//TRIM(iom_file(kiomid)%name)
147      CALL iom_nf90_check(NF90_CLOSE(iom_file(kiomid)%nfid), clinfo)
148      !   
149   END SUBROUTINE iom_nf90_close
150
151
152   FUNCTION iom_nf90_varid ( kiomid, cdvar, kiv, kdimsz ) 
153      !!-----------------------------------------------------------------------
154      !!                  ***  FUNCTION  iom_varid  ***
155      !!
156      !! ** Purpose : get the id of a variable in a file with NF90
157      !!-----------------------------------------------------------------------
158      INTEGER              , INTENT(in   )           ::   kiomid   ! file Identifier
159      CHARACTER(len=*)     , INTENT(in   )           ::   cdvar    ! name of the variable
160      INTEGER              , INTENT(in   )           ::   kiv   !
161      INTEGER, DIMENSION(:), INTENT(  out), OPTIONAL ::   kdimsz   ! size of the dimensions
162      !
163      INTEGER                        ::   iom_nf90_varid   ! iom variable Id
164      INTEGER                        ::   if90id           ! nf90 file identifier
165      INTEGER                        ::   ji               ! dummy loop index
166      INTEGER                        ::   ivarid           ! NetCDF  variable Id
167      INTEGER                        ::   i_nvd            ! number of dimension of the variable
168      INTEGER, DIMENSION(jpmax_dims) ::   idimid           ! dimension ids of the variable
169      LOGICAL                        ::   llok             ! ok  test
170      CHARACTER(LEN=100)             ::   clinfo           ! info character
171      !!-----------------------------------------------------------------------
172      clinfo = '          iom_nf90_varid, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
173      iom_nf90_varid = 0                    ! default definition
174      IF( PRESENT(kdimsz) ) kdimsz(:) = 0   ! default definition
175      if90id = iom_file(kiomid)%nfid        ! get back NetCDF file id
176      !
177      llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr   ! does the variable exist in the file
178      IF( llok ) THEN
179         iom_nf90_varid = kiv
180         iom_file(kiomid)%nvars       = kiv
181         iom_file(kiomid)%nvid(kiv)   = ivarid
182         iom_file(kiomid)%cn_var(kiv) = TRIM(cdvar)
183         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, ndims = i_nvd), clinfo)   ! number of dimensions
184         iom_file(kiomid)%ndims(kiv)  = i_nvd
185         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, dimids = idimid(1:i_nvd)), clinfo)   ! dimensions ids
186         iom_file(kiomid)%luld(kiv) = .FALSE.   ! default value
187         DO ji = 1, i_nvd                       ! dimensions size
188            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, idimid(ji), len = iom_file(kiomid)%dimsz(ji,kiv)), clinfo)   
189            IF( idimid(ji) == iom_file(kiomid)%iduld ) iom_file(kiomid)%luld(kiv) = .TRUE.   ! unlimited dimension?
190         END DO
191         !---------- Deal with scale_factor and add_offset
192         llok = NF90_Inquire_attribute(if90id, ivarid, 'scale_factor') == nf90_noerr
193         IF( llok) THEN
194            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'scale_factor', iom_file(kiomid)%scf(kiv)), clinfo)
195         ELSE
196            iom_file(kiomid)%scf(kiv) = 1.
197         END IF
198         llok = NF90_Inquire_attribute(if90id, ivarid, 'add_offset') == nf90_noerr
199         IF( llok ) THEN
200            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'add_offset', iom_file(kiomid)%ofs(kiv)), clinfo)
201         ELSE
202            iom_file(kiomid)%ofs(kiv) = 0.
203         END IF
204         ! return the simension size
205         IF( PRESENT(kdimsz) ) THEN
206            IF( i_nvd == SIZE(kdimsz) ) THEN
207               kdimsz(:) = iom_file(kiomid)%dimsz(1:i_nvd,kiv)
208            ELSE
209               WRITE(ctmp1,*) i_nvd, SIZE(kdimsz)
210               CALL ctl_stop( TRIM(clinfo), 'error in kdimsz size'//TRIM(ctmp1) )
211            ENDIF
212         ENDIF
213      ELSE 
214         iom_nf90_varid = -1   !   variable not found, return error code: -1
215      ENDIF
216      !
217   END FUNCTION iom_nf90_varid
218
219
220   SUBROUTINE iom_nf90_g0d( kiomid, kvid, pvar )
221      !!-----------------------------------------------------------------------
222      !!                  ***  ROUTINE  iom_nf90_g0d  ***
223      !!
224      !! ** Purpose : read a scalar with NF90
225      !!-----------------------------------------------------------------------
226      INTEGER , INTENT(in   ) ::   kiomid   ! Identifier of the file
227      INTEGER , INTENT(in   ) ::   kvid     ! variable id
228      REAL(wp), INTENT(  out) ::   pvar     ! read field
229      !
230      CHARACTER(LEN=100)      ::   clinfo   ! info character
231      !---------------------------------------------------------------------
232      clinfo = 'iom_nf90_g0d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
233      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), pvar), clinfo )
234      !
235   END SUBROUTINE iom_nf90_g0d
236
237
238   SUBROUTINE iom_nf90_g123d( kiomid, kvid, knbdim, kstart, kcount, kx1, kx2, ky1, ky2,   &
239         &                    pv_r1d, pv_r2d, pv_r3d )
240      !!-----------------------------------------------------------------------
241      !!                  ***  ROUTINE  iom_nf90_g123d  ***
242      !!
243      !! ** Purpose : read a 1D/2D/3D variable with NF90
244      !!
245      !! ** Method : read ONE record at each CALL
246      !!-----------------------------------------------------------------------
247      INTEGER                    , INTENT(in   )           ::   kiomid    ! iom identifier of the file
248      INTEGER                    , INTENT(in   )           ::   kvid      ! Name of the variable
249      INTEGER                    , INTENT(in   )           ::   knbdim    ! number of dimensions of the variable
250      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kstart    ! start position of the reading in each axis
251      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kcount    ! number of points to be read in each axis
252      INTEGER ,                    INTENT(in   )           ::   kx1, kx2, ky1, ky2   ! subdomain indexes
253      REAL(wp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d    ! read field (1D case)
254      REAL(wp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d    ! read field (2D case)
255      REAL(wp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d    ! read field (3D case)
256      !
257      CHARACTER(LEN=100) ::   clinfo               ! info character
258      INTEGER            ::   if90id               ! nf90 identifier of the opened file
259      INTEGER            ::   ivid                 ! nf90 variable id
260      !---------------------------------------------------------------------
261      clinfo = 'iom_nf90_g123d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
262      if90id = iom_file(kiomid)%nfid         ! get back NetCDF file id
263      ivid   = iom_file(kiomid)%nvid(kvid)   ! get back NetCDF var id
264      !
265      IF(     PRESENT(pv_r1d) ) THEN
266         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r1d(:                ), start = kstart(1:knbdim),   &
267            &                                                                       count = kcount(1:knbdim)), clinfo )
268      ELSEIF( PRESENT(pv_r2d) ) THEN
269         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r2d(kx1:kx2,ky1:ky2  ), start = kstart(1:knbdim),   &
270            &                                                                       count = kcount(1:knbdim)), clinfo )
271      ELSEIF( PRESENT(pv_r3d) ) THEN
272         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r3d(kx1:kx2,ky1:ky2,:), start = kstart(1:knbdim),   &
273            &                                                                       count = kcount(1:knbdim)), clinfo )
274      ENDIF
275      !
276   END SUBROUTINE iom_nf90_g123d
277
278
279   SUBROUTINE iom_nf90_gettime( kiomid, kvid, ptime, cdunits, cdcalendar )
280      !!--------------------------------------------------------------------
281      !!                   ***  SUBROUTINE iom_gettime  ***
282      !!
283      !! ** Purpose : read the time axis kvid in the file with NF90
284      !!--------------------------------------------------------------------
285      INTEGER                   , INTENT(in   ) ::   kiomid     ! file Identifier
286      INTEGER                   , INTENT(in   ) ::   kvid       ! variable id
287      REAL(wp), DIMENSION(:)    , INTENT(  out) ::   ptime      ! the time axis
288      CHARACTER(len=*), OPTIONAL, INTENT(  out) ::   cdunits    ! units attribute
289      CHARACTER(len=*), OPTIONAL, INTENT(  out) ::   cdcalendar ! calendar attribute
290      !
291      CHARACTER(LEN=100) ::   clinfo     ! info character
292      !---------------------------------------------------------------------
293      clinfo = 'iom_nf90_gettime, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
294      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), ptime(:),   &
295            &                           start=(/ 1 /), count=(/ iom_file(kiomid)%dimsz(1, kvid) /)), clinfo)
296      IF ( PRESENT(cdunits) ) THEN
297         CALL iom_nf90_check(NF90_GET_ATT(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), "units", &
298            &                           values=cdunits), clinfo)
299      ENDIF
300      IF ( PRESENT(cdcalendar) ) THEN
301         CALL iom_nf90_check(NF90_GET_ATT(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), "calendar", &
302            &                           values=cdcalendar), clinfo)
303      ENDIF
304      !
305   END SUBROUTINE iom_nf90_gettime
306
307
308   SUBROUTINE iom_nf90_rp0123d( kt, kwrite, kiomid, cdvar , kvid  , ktype,   &
309         &                               pv_r0d, pv_r1d, pv_r2d, pv_r3d )
310      !!--------------------------------------------------------------------
311      !!                   ***  SUBROUTINE  iom_nf90_rstput  ***
312      !!
313      !! ** Purpose : read the time axis cdvar in the file
314      !!--------------------------------------------------------------------
315      INTEGER                     , INTENT(in)           ::   kt       ! ocean time-step
316      INTEGER                     , INTENT(in)           ::   kwrite   ! writing time-step
317      INTEGER                     , INTENT(in)           ::   kiomid   ! Identifier of the file
318      CHARACTER(len=*)            , INTENT(in)           ::   cdvar    ! variable name
319      INTEGER                     , INTENT(in)           ::   kvid     ! variable id
320      INTEGER                     , INTENT(in), OPTIONAL ::   ktype    ! variable type (default R8)
321      REAL(wp)                    , INTENT(in), OPTIONAL ::   pv_r0d   ! written Od field
322      REAL(wp), DIMENSION(      :), INTENT(in), OPTIONAL ::   pv_r1d   ! written 1d field
323      REAL(wp), DIMENSION(:, :   ), INTENT(in), OPTIONAL ::   pv_r2d   ! written 2d field
324      REAL(wp), DIMENSION(:, :, :), INTENT(in), OPTIONAL ::   pv_r3d   ! written 3d field
325      !
326      INTEGER               :: idims                ! number of dimension
327      INTEGER               :: idvar                ! variable id
328      INTEGER               :: jd                   ! dimension loop counter   
329      INTEGER               :: ix1, ix2, iy1, iy2   ! subdomain indexes   
330      INTEGER, DIMENSION(4) :: idimsz               ! dimensions size 
331      INTEGER, DIMENSION(4) :: idimid               ! dimensions id
332      CHARACTER(LEN=100)    :: clinfo               ! info character
333      CHARACTER(LEN= 12), DIMENSION(4) :: cltmp     ! temporary character
334      INTEGER               :: if90id               ! nf90 file identifier
335      INTEGER               :: idmy                 ! dummy variable
336      INTEGER               :: itype                ! variable type
337      !---------------------------------------------------------------------
338      !
339      clinfo = '          iom_nf90_rp0123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
340      if90id = iom_file(kiomid)%nfid
341      !
342      ! define dimension variables if it is not already done
343      ! ==========================
344      IF( iom_file(kiomid)%nvars == 0 ) THEN
345         ! are we in define mode?
346         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
347            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
348         ENDIF
349         ! define the dimension variables if it is not already done
350         cltmp = (/ 'nav_lon     ', 'nav_lat     ', 'nav_lev     ', 'time_counter' /)
351         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(1)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(1) ), clinfo)
352         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(2)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(2) ), clinfo)
353         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(3)), NF90_FLOAT , (/ 3    /), iom_file(kiomid)%nvid(3) ), clinfo)
354         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(4)), NF90_DOUBLE, (/ 4    /), iom_file(kiomid)%nvid(4) ), clinfo)
355         ! update informations structure related the dimension variable we just added...
356         iom_file(kiomid)%nvars       = 4
357         iom_file(kiomid)%luld(1:4)   = (/ .FALSE., .FALSE., .FALSE., .TRUE. /)
358         iom_file(kiomid)%cn_var(1:4) = cltmp
359         iom_file(kiomid)%ndims(1:4)  = (/ 2, 2, 1, 1 /) 
360         ! trick: defined to 0 to say that dimension variables are defined but not yet written
361         iom_file(kiomid)%dimsz(1, 1)  = 0   
362         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' define dimension variables done'
363      ENDIF
364      ! define the data if it is not already done
365      ! ===============
366      IF( kvid <= 0 ) THEN
367         idvar = iom_file(kiomid)%nvars + 1
368         ! are we in define mode?
369         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
370            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
371         ENDIF
372         ! variable definition
373         IF(     PRESENT(pv_r0d) ) THEN   ;   idims = 0
374         ELSEIF( PRESENT(pv_r1d) ) THEN   ;   idims = 2   ;   idimid(1:idims) = (/    3,4/)
375         ELSEIF( PRESENT(pv_r2d) ) THEN   ;   idims = 3   ;   idimid(1:idims) = (/1,2  ,4/)
376         ELSEIF( PRESENT(pv_r3d) ) THEN   ;   idims = 4   ;   idimid(1:idims) = (/1,2,3,4/)
377         ENDIF
378         IF( PRESENT(ktype) ) THEN   ! variable external type
379            SELECT CASE (ktype)
380            CASE (jp_r8)  ;   itype = NF90_DOUBLE
381            CASE (jp_r4)  ;   itype = NF90_FLOAT
382            CASE (jp_i4)  ;   itype = NF90_INT
383            CASE (jp_i2)  ;   itype = NF90_SHORT
384            CASE (jp_i1)  ;   itype = NF90_BYTE
385            CASE DEFAULT   ;   CALL ctl_stop( TRIM(clinfo)//' unknown variable type' )
386            END SELECT
387         ELSE
388            itype = NF90_DOUBLE
389         ENDIF
390         IF( PRESENT(pv_r0d) ) THEN
391            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype,                    &
392                 &                            iom_file(kiomid)%nvid(idvar) ), clinfo)
393         ELSE
394            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype, idimid(1:idims),   &
395                 &                            iom_file(kiomid)%nvid(idvar) ), clinfo)
396         ENDIF
397         ! update informations structure related the new variable we want to add...
398         iom_file(kiomid)%nvars         = idvar
399         iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar)
400         iom_file(kiomid)%scf(idvar)    = 1.
401         iom_file(kiomid)%ofs(idvar)    = 0.
402         iom_file(kiomid)%ndims(idvar)  = idims
403         IF( .NOT. PRESENT(pv_r0d) ) THEN   ;   iom_file(kiomid)%luld(idvar) = .TRUE.
404         ELSE                               ;   iom_file(kiomid)%luld(idvar) = .FALSE.
405         ENDIF
406         DO jd = 1, idims
407            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, idimid(jd), len = iom_file(kiomid)%dimsz(jd,idvar) ), clinfo)
408         END DO
409         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' defined ok'
410      ELSE
411         idvar = kvid
412      ENDIF
413
414      ! time step kwrite : write the variable
415      IF( kt == kwrite ) THEN
416         ! are we in write mode?
417         IF( iom_file(kiomid)%irec == -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
418            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = 0
419         ENDIF
420         ! on what kind of domain must the data be written?
421         IF( PRESENT(pv_r2d) .OR. PRESENT(pv_r3d) ) THEN
422            idimsz(1:2) = iom_file(kiomid)%dimsz(1:2,idvar)
423            IF(     idimsz(1) == (nlei - nldi + 1) .AND. idimsz(2) == (nlej - nldj + 1) ) THEN
424               ix1 = nldi   ;   ix2 = nlei   ;   iy1 = nldj   ;   iy2 = nlej
425            ELSEIF( idimsz(1) == nlci              .AND. idimsz(2) == nlcj              ) THEN
426               ix1 = 1      ;   ix2 = nlci   ;   iy1 = 1      ;   iy2 = nlcj
427            ELSEIF( idimsz(1) == jpi               .AND. idimsz(2) == jpj               ) THEN
428               ix1 = 1      ;   ix2 = jpi    ;   iy1 = 1      ;   iy2 = jpj
429            ELSE
430               CALL ctl_stop( 'iom_nf90_rp0123d: should have been an impossible case...' )
431            ENDIF
432
433            ! write dimension variables if it is not already done
434            ! =============
435            ! trick: is defined to 0 => dimension variable are defined but not yet written
436            IF( iom_file(kiomid)%dimsz(1, 1) == 0 ) THEN
437               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lon'     , idmy ), clinfo)
438               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, glamt(ix1:ix2, iy1:iy2) ), clinfo)
439               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lat'     , idmy ), clinfo)
440               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, gphit(ix1:ix2, iy1:iy2) ), clinfo)
441               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lev'     , idmy ), clinfo)
442               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, gdept_0                 ), clinfo)
443               ! +++ WRONG VALUE: to be improved but not really useful...
444               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'time_counter', idmy ), clinfo)
445               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, kt                      ), clinfo)   
446               ! update the values of the variables dimensions size
447               CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 1, len = iom_file(kiomid)%dimsz(1,1) ), clinfo)
448               CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 2, len = iom_file(kiomid)%dimsz(2,1) ), clinfo)
449               iom_file(kiomid)%dimsz(1:2, 2) = iom_file(kiomid)%dimsz(1:2, 1)
450               CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 3, len = iom_file(kiomid)%dimsz(1,3) ), clinfo)
451               iom_file(kiomid)%dimsz(1  , 4) = 1   ! unlimited dimension
452               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' write dimension variables done'
453            ENDIF
454         ENDIF
455
456         ! write the data
457         ! =============
458         IF(     PRESENT(pv_r0d) ) THEN
459            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r0d                      ), clinfo)
460         ELSEIF( PRESENT(pv_r1d) ) THEN
461            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r1d(                  :) ), clinfo)
462         ELSEIF( PRESENT(pv_r2d) ) THEN
463            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r2d(ix1:ix2, iy1:iy2   ) ), clinfo)
464         ELSEIF( PRESENT(pv_r3d) ) THEN
465            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r3d(ix1:ix2, iy1:iy2, :) ), clinfo)
466         ENDIF
467         ! add 1 to the size of the temporal dimension (not really useful...)
468         IF( iom_file(kiomid)%luld(idvar) )   iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar)    &
469               &                            = iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) + 1
470         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok'
471      ENDIF
472      !     
473   END SUBROUTINE iom_nf90_rp0123d
474
475
476   SUBROUTINE iom_nf90_check( kstatus, cdinfo )
477      !!--------------------------------------------------------------------
478      !!                   ***  SUBROUTINE iom_nf90_check  ***
479      !!
480      !! ** Purpose :   check nf90 errors
481      !!--------------------------------------------------------------------
482      INTEGER,          INTENT(in) :: kstatus
483      CHARACTER(LEN=*), INTENT(in) :: cdinfo
484      !---------------------------------------------------------------------
485      IF(kstatus /= nf90_noerr)   CALL ctl_stop( 'iom_nf90_check : '//TRIM(nf90_strerror(kstatus)), TRIM(cdinfo) )
486   END SUBROUTINE iom_nf90_check
487
488
489   !!======================================================================
490END MODULE iom_nf90
Note: See TracBrowser for help on using the repository browser.