New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diagap.F90 in trunk/NEMO/OPA_SRC/DIA – NEMO

source: trunk/NEMO/OPA_SRC/DIA/diagap.F90 @ 1152

Last change on this file since 1152 was 1152, checked in by rblod, 16 years ago

Convert cvs header to svn Id, step II
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 10.5 KB
Line 
1MODULE diagap
2   !!======================================================================
3   !!                       ***  MODULE  diagap  ***
4   !! Ocean diagnostics : computation of model-data tracer gap
5   !!======================================================================
6#if defined key_diagap
7   !!----------------------------------------------------------------------
8   !!   'key_diagap' :                           model-data gap diagnostics
9   !!----------------------------------------------------------------------
10   !!   dia_gap      : model and data level mean temperature and salinity
11   !!----------------------------------------------------------------------
12   !! * Modules used
13   USE oce             ! ocean dynamics and tracers
14   USE dom_oce         ! ocean space and time domain
15   USE in_out_manager  ! I/O manager
16   USE dtatem          ! ???
17   USE dtasal          ! ???
18   USE daymod          ! calendar
19   USE dianam          ! build name of file (routine)
20   USE lib_mpp         ! distributed memory computing library
21
22   IMPLICIT NONE
23   PRIVATE
24
25   !! * Routine accessibility
26   PUBLIC dia_gap     ! called in step.F90 module
27
28   !! * Shared module variables
29   LOGICAL, PUBLIC, PARAMETER ::   lk_diagap = .TRUE.   !: model-data diagnostics flag
30
31   !! * Module variables
32   INTEGER ::                 &
33      ngap  ,                 &  ! time step frequency
34      nprg                       ! switch for control print
35   ! netcdf files and index common
36   INTEGER ::   &
37      nhoridg, ndepidg,             &
38      ndex(1)
39   REAL(wp) ::     &
40      vol                        ! total ocean volume
41   REAL(wp), DIMENSION(jpk) ::   &
42      volk , volkr,           &  ! level ocean volume and its inverse
43      tdtag, sdtag,           &  ! level mean data temperature & salinity
44      tmodg, smodg               ! level mean model temperature & salinity
45
46   !! * Substitutions
47#  include "domzgr_substitute.h90"
48   !!----------------------------------------------------------------------
49   !!   OPA 9.0 , LOCEAN-IPSL (2005)
50   !! $Id$
51   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
52   !!----------------------------------------------------------------------
53
54CONTAINS
55
56   SUBROUTINE dia_gap( kt )
57      !!----------------------------------------------------------------------
58      !!                ***  ROUTINE dia_gap  ***
59      !!
60      !! ** Purpose :   Compute model and data level mean T and S profiles
61      !!      and output it in numgap (NetCDF or direct access file)
62      !!
63      !! ** Method :
64      !!         tracers (model) : tn, sn
65      !!         tracers (data)  : t_dta, s_dta
66      !!         difference between model and data tracers
67      !!         variance between model and data tracers
68      !!
69      !! ** Action  :   output in file numgap
70      !!
71      !! History :
72      !!   6.0  !  91-10  (G. Madec)  Original code
73      !!   7.0  !  92-07  (M. Imbard)  Add variance and mpp staff
74      !!   8.5  !  02-07  (G. Madec)  Free form, F90
75      !!----------------------------------------------------------------------
76      !! * Modules used
77      USE ioipsl
78
79      !! * Arguments
80      INTEGER, INTENT(in) ::   kt           ! ocean time-step index
81
82      !! * local declarations
83      INTEGER ::   ji, jj, jk   ! dummy loop indices
84      INTEGER ::   it
85      CHARACTER (len=40) ::   clhstnam
86      CHARACTER (len=40) ::   clop
87      REAL(wp) ::   zbt, zdt    ! temporary scalar
88      REAL(wp) ::   zsto, zout, zmax, zjulian
89      REAL(wp), DIMENSION(jpi) ::   zfoo
90      REAL(wp), DIMENSION(jpj) ::   zloo
91
92      NAMELIST/namgap/ ngap, nprg
93      !!----------------------------------------------------------------------
94
95
96      ! 0. initialization
97      ! -----------------
98
99      zdt = rdt
100      IF( nacc == 1 )   zdt = rdtmin
101
102      IF( kt == nit000 ) THEN
103
104         IF(lwp) WRITE(numout,*)
105         IF(lwp) WRITE(numout,*) 'dia_gap : level mean model-data gap'
106         IF(lwp) WRITE(numout,*) '~~~~~~~'
107
108         ! Read diagap parameters in namelist namgap
109         ngap = 15
110         nprg = 15
111
112         REWIND( numnam )
113         READ( numnam, namgap )
114
115         IF(lwp) WRITE(numout,*) '          time step frequency for gap     ngap  = ',ngap
116         IF(lwp) WRITE(numout,*) '          switch for control print gap    nprg  = ',nprg
117
118         ! horizontal slab volume (tmask_i to take into account only interior ocean domain)
119         volk(:) = 0.e0
120         DO jk = 1, jpkm1
121            DO jj = 1, jpj
122               DO ji = 1, jpi
123                  zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) * tmask_i(ji,jj)
124                  volk(jk) = volk(jk) + tmask(ji,jj,jk) * zbt
125               END DO
126            END DO
127         END DO
128         IF( lk_mpp )   CALL mpp_sum( volk, jpk )   ! sum over the global domain
129
130         volkr(:) = 0.e0
131         DO jk = 1, jpk
132            IF( volk(jk) /= 0.e0 )   volkr(jk) = 1.e0 / volk(jk)
133         END DO
134         IF(lwp) THEN
135            WRITE(numout,*)
136            WRITE(numout,*) '     volume of each horizontal slab (km3) :'
137            DO jk = 1, jpkm1
138               WRITE(numout,9010) jk, volk(jk) * 1.e-9
139            END DO
140         ENDIF
1419010     FORMAT( 9X, 'level ', i3, f15.3 )
142
143         ! basin volume
144         vol = 0.e0
145         DO jk = 1, jpkm1
146            vol = vol + volk(jk)
147         END DO
148         IF(lwp) WRITE(numout,*)
149         IF(lwp) WRITE(numout,*) '     basin volume : ',vol*1.e-9, '  km3'
150
151         ! OPEN netcdf file
152
153         ! Define frequency of output and means
154         zsto = ngap * zdt
155         clop = "ave(x)"
156         zout = ngap * zdt
157         zmax = FLOAT( nitend - nit000 + 1 ) * zdt
158         zfoo(1:jpi) = 0.e0
159         zloo(1:jpj) = 0.e0
160
161         ! Compute julian date from starting date of the run
162
163         CALL ymds2ju( nyear, nmonth, nday, 0.e0, zjulian )
164
165         CALL dia_nam( clhstnam, ngap, 'diagap' )
166         IF(lwp) WRITE(numout,*) 'Name of diagap NETCDF file ', clhstnam
167         ! Horizontal grid : zphi()
168         CALL histbeg( clhstnam, 1, zfoo, 1, zloo,   &
169                       1, 1, 1, 1, 0, zjulian, zdt, nhoridg, numgap, domain_id=nidom )
170         ! Vertical grids : gdept, gdepw
171         CALL histvert( numgap, "deptht", "Vertical T levels",   &
172                         "m", jpk, gdept_0, ndepidg )
173
174         ! define fields to be stored
175         ! mo(temp/sali)(da/mo/va): mean ocean temperature/salinity data/model/differences
176
177          CALL histdef( numgap, "motempda", "Mean Data Temperature","C",   &
178                        1, 1, nhoridg, jpk, 1, jpk, ndepidg, 32, clop,   &
179                        zsto,zout )
180          CALL histdef(numgap, "mosalida", "Mean Data Salinity","PSU",   &
181                        1, 1, nhoridg, jpk, 1, jpk, ndepidg, 32, clop,   &
182                        zsto,zout )
183          CALL histdef(numgap, "motempmo", "Mean Model Temperature","C",   &
184                        1, 1, nhoridg, jpk, 1, jpk, ndepidg, 32, clop,   &
185                        zsto,zout )
186          CALL histdef(numgap, "mosalimo", "Mean Model Salinity","PSU",   &
187                        1, 1, nhoridg, jpk, 1, jpk, ndepidg, 32, clop,   &
188                        zsto,zout )
189          CALL histend( numgap )
190          ndex(1) = 0
191      ENDIF
192
193
194      ! 1. horizontal averaged
195      ! ----------------------
196
197      IF( MOD( kt, ngap ) == 0 ) THEN
198
199         ! initialization
200         tdtag(:) = 0.e0
201         sdtag(:) = 0.e0
202         tmodg(:) = 0.e0
203         smodg(:) = 0.e0
204         
205         !  c a u t i o n  : use of tmask_i : average over the interior domain only
206         
207         ! sum
208         DO jk = 1, jpkm1
209            DO jj = 1, jpj
210              DO ji = 1, jpi
211                zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) * tmask_i(ji,jj)
212                tdtag(jk) = tdtag(jk) + zbt * t_dta(ji,jj,jk) * volkr(jk)
213                sdtag(jk) = sdtag(jk) + zbt * s_dta(ji,jj,jk) * volkr(jk)
214                tmodg(jk) = tmodg(jk) + zbt * tn  (ji,jj,jk) * volkr(jk)
215                smodg(jk) = smodg(jk) + zbt * sn  (ji,jj,jk) * volkr(jk)
216              END DO 
217            END DO 
218         END DO
219
220
221         ! 2. Basin averaged
222         ! -----------------
223         
224         DO jk = 1, jpkm1
225            tdtag(jpk) = tdtag(jpk) + tdtag(jk) * volk(jk) / vol
226            sdtag(jpk) = sdtag(jpk) + sdtag(jk) * volk(jk) / vol
227            tmodg(jpk) = tmodg(jpk) + tmodg(jk) * volk(jk) / vol
228            smodg(jpk) = smodg(jpk) + smodg(jk) * volk(jk) / vol
229         END DO 
230          IF( lk_mpp)   CALL mpp_sum( tdtag, jpk )   ! sum over the global domain
231          IF( lk_mpp)   CALL mpp_sum( sdtag, jpk )
232          IF( lk_mpp)   CALL mpp_sum( tmodg, jpk )
233          IF( lk_mpp)   CALL mpp_sum( smodg, jpk )
234
235          ! 3.  Averaged output in file numgap
236          ! ----------------------------======
237
238          IF( MOD( kt, nprg ) == 0 ) THEN
239              IF(lwp) THEN
240                  WRITE(numout,*) 'dia_gap: time step = ', kt, 'model - data'
241                  WRITE(numout,9300)
242
243                  DO jk = 1, jpk
244                    WRITE(numout,9310) tdtag(jk), tmodg(jk), tdtag(jk) - tmodg(jk), jk, fsdept(1,1,jk),   &
245                                       sdtag(jk), smodg(jk), sdtag(jk) - smodg(jk)
246                  END DO 
247              ENDIF
248          ENDIF
249
250 9300     FORMAT('  T-data  T-model    diff.   level  depth    S-data  S-model    diff.' )
251 9310     FORMAT( 3(f8.3,1x),i5,f9.0,2x,3(f8.3,1x) )
252
253          ! Output in file numgap
254
255          ! Netcdf write
256
257          IF (lwp ) THEN   ! Ok even in mpp after the call to mpp_sum
258             it = kt - nit000 + 1       ! define time axis
259             CALL histwrite( numgap, "motempda", it, tdtag, jpk, ndex )
260             CALL histwrite( numgap, "mosalida", it, sdtag, jpk, ndex )
261             CALL histwrite( numgap, "motempmo", it, tmodg, jpk, ndex )
262             CALL histwrite( numgap, "mosalimo", it, smodg, jpk, ndex )
263          END IF
264      ENDIF
265
266      ! Closing numgap file
267
268      IF( kt == nitend ) THEN
269         CALL histclo( numgap )      !   Netcdf file
270      ENDIF
271
272   END SUBROUTINE dia_gap
273
274#else
275   !!----------------------------------------------------------------------
276   !!   Default option :                                       Dummy module
277   !!----------------------------------------------------------------------
278   LOGICAL, PUBLIC, PARAMETER ::   lk_diagap = .FALSE.    !: diagap flag
279CONTAINS
280   SUBROUTINE dia_gap( kt )           ! Dummy routine
281      WRITE(*,*) 'dia_gap: You should not have seen this print! error?', kt
282   END SUBROUTINE dia_gap
283#endif
284
285   !!======================================================================
286END MODULE diagap
Note: See TracBrowser for help on using the repository browser.