New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
domvvl.F90 in trunk/NEMO/OPA_SRC/DOM – NEMO

source: trunk/NEMO/OPA_SRC/DOM/domvvl.F90 @ 1694

Last change on this file since 1694 was 1694, checked in by smasson, 14 years ago

avoid out of bounds access, see ticket:576
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 7.5 KB
Line 
1MODULE domvvl
2   !!======================================================================
3   !!                       ***  MODULE domvvl   ***
4   !! Ocean :
5   !!======================================================================
6   !! History :  2.0  !  2006-06  (B. Levier, L. Marie)  original code
7   !!            3.1  !  2009-02  (G. Madec, M. Leclair, R. Benshila)  pure z* coordinate
8   !!----------------------------------------------------------------------
9#if defined key_vvl
10   !!----------------------------------------------------------------------
11   !!   'key_vvl'                              variable volume
12   !!----------------------------------------------------------------------
13   !!   dom_vvl     : defined coefficients to distribute ssh on each layers
14   !!----------------------------------------------------------------------
15   USE oce             ! ocean dynamics and tracers
16   USE dom_oce         ! ocean space and time domain
17   USE sbc_oce         ! surface boundary condition: ocean
18   USE phycst          ! physical constants
19   USE in_out_manager  ! I/O manager
20   USE lib_mpp         ! distributed memory computing library
21   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   dom_vvl    ! called by domain.F90
27
28   REAL(wp), PUBLIC, DIMENSION(jpi,jpj)     ::   ee_t, ee_u, ee_v, ee_f   !: ???
29   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   mut, muu, muv, muf       !: ???
30
31   REAL(wp), DIMENSION(jpk) ::   r2dt   ! vertical profile time-step, = 2 rdttra
32      !                                 ! except at nit000 (=rdttra) if neuler=0
33
34   !! * Substitutions
35#  include "domzgr_substitute.h90"
36#  include "vectopt_loop_substitute.h90"
37   !!----------------------------------------------------------------------
38   !! NEMO/OPA 3.2 , LOCEAN-IPSL (2009)
39   !! $Id$
40   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42
43CONTAINS       
44
45   SUBROUTINE dom_vvl
46      !!----------------------------------------------------------------------
47      !!                ***  ROUTINE dom_vvl  ***
48      !!                   
49      !! ** Purpose :  compute coefficients muX at T-U-V-F points to spread
50      !!               ssh over the whole water column (scale factors)
51      !!----------------------------------------------------------------------
52      INTEGER  ::   ji, jj, jk
53      REAL(wp) ::   zcoefu, zcoefv, zcoeff
54      !!----------------------------------------------------------------------
55
56      IF(lwp)   THEN
57         WRITE(numout,*)
58         WRITE(numout,*) 'dom_vvl : Variable volume activated'
59         WRITE(numout,*) '~~~~~~~~  compute coef. used to spread ssh over each layers'
60      ENDIF
61
62      IF( lk_zco )   CALL ctl_stop( 'dom_vvl : key_zco is incompatible with variable volume option key_vvl')
63
64      fsdept(:,:,:) = gdept (:,:,:)
65      fsdepw(:,:,:) = gdepw (:,:,:)
66      fsde3w(:,:,:) = gdep3w(:,:,:)
67      fse3t (:,:,:) = e3t   (:,:,:)
68      fse3u (:,:,:) = e3u   (:,:,:)
69      fse3v (:,:,:) = e3v   (:,:,:)
70      fse3f (:,:,:) = e3f   (:,:,:)
71      fse3w (:,:,:) = e3w   (:,:,:)
72      fse3uw(:,:,:) = e3uw  (:,:,:)
73      fse3vw(:,:,:) = e3vw  (:,:,:)
74
75      !                                 !==  mu computation  ==!
76      ee_t(:,:) = fse3t_0(:,:,1)                ! Lower bound : thickness of the first model level
77      ee_u(:,:) = fse3u_0(:,:,1)
78      ee_v(:,:) = fse3v_0(:,:,1)
79      ee_f(:,:) = fse3f_0(:,:,1)
80      DO jk = 2, jpkm1                          ! Sum of the masked vertical scale factors
81         ee_t(:,:) = ee_t(:,:) + fse3t_0(:,:,jk) * tmask(:,:,jk)
82         ee_u(:,:) = ee_u(:,:) + fse3u_0(:,:,jk) * umask(:,:,jk)
83         ee_v(:,:) = ee_v(:,:) + fse3v_0(:,:,jk) * vmask(:,:,jk)
84         DO jj = 1, jpjm1                      ! f-point : fmask=shlat at coasts, use the product of umask
85            ee_f(:,jj) = ee_f(:,jj) + fse3f_0(:,jj,jk) *  umask(:,jj,jk) * umask(:,jj+1,jk)
86         END DO
87      END DO 
88      !                                         ! Compute and mask the inverse of the local depth at T, U, V and F points
89      ee_t(:,:) = 1. / ee_t(:,:) * tmask(:,:,1)
90      ee_u(:,:) = 1. / ee_u(:,:) * umask(:,:,1)
91      ee_v(:,:) = 1. / ee_v(:,:) * vmask(:,:,1)
92      DO jj = 1, jpjm1                               ! f-point case fmask cannot be used
93         ee_f(:,jj) = 1. / ee_f(:,jj) * umask(:,jj,1) * umask(:,jj+1,1)
94      END DO
95      CALL lbc_lnk( ee_f, 'F', 1. )                  ! lateral boundary condition on ee_f
96      !
97      DO jk = 1, jpk                            ! mu coefficients
98         mut(:,:,jk) = ee_t(:,:) * tmask(:,:,jk)     ! T-point at T levels
99         muu(:,:,jk) = ee_u(:,:) * umask(:,:,jk)     ! U-point at T levels
100         muv(:,:,jk) = ee_v(:,:) * vmask(:,:,jk)     ! V-point at T levels
101      END DO
102      DO jk = 1, jpk                                 ! F-point : fmask=shlat at coasts, use the product of umask
103         DO jj = 1, jpjm1
104               muf(:,jj,jk) = ee_f(:,jj) * umask(:,jj,jk) * umask(:,jj+1,jk)   ! at T levels
105         END DO
106         muf(:,jpj,jk) = 0.e0
107      END DO
108      CALL lbc_lnk( muf, 'F', 1. )                   ! lateral boundary condition
109
110
111      hu_0(:,:) = 0.e0                          ! Reference ocean depth at U- and V-points
112      hv_0(:,:) = 0.e0
113      DO jk = 1, jpk
114         hu_0(:,:) = hu_0(:,:) + fse3u_0(:,:,jk) * umask(:,:,jk)
115         hv_0(:,:) = hv_0(:,:) + fse3v_0(:,:,jk) * vmask(:,:,jk)
116      END DO
117
118      DO jj = 1, jpjm1                          ! initialise before and now Sea Surface Height at u-, v-, f-points
119         DO ji = 1, jpim1   ! NO vector opt.
120            zcoefu = 0.5  * umask(ji,jj,1) / ( e1u(ji,jj) * e2u(ji,jj) )
121            zcoefv = 0.5  * vmask(ji,jj,1) / ( e1v(ji,jj) * e2v(ji,jj) )
122            zcoeff = 0.25 * umask(ji,jj,1) * umask(ji,jj+1,1)
123            sshu_b(ji,jj) = zcoefu * ( e1t(ji  ,jj) * e2t(ji  ,jj) * sshb(ji  ,jj)     &
124               &                     + e1t(ji+1,jj) * e2t(ji+1,jj) * sshb(ji+1,jj) )   
125            sshv_b(ji,jj) = zcoefv * ( e1t(ji,jj  ) * e2t(ji,jj  ) * sshb(ji,jj  )     &
126               &                     + e1t(ji,jj+1) * e2t(ji,jj+1) * sshb(ji,jj+1) )   
127            sshf_b(ji,jj) = zcoeff * ( sshb(ji  ,jj) + sshb(ji  ,jj+1)                 &
128               &                     + sshb(ji+1,jj) + sshb(ji+1,jj+1) )               
129            sshu_n(ji,jj) = zcoefu * ( e1t(ji  ,jj) * e2t(ji  ,jj) * sshn(ji  ,jj)     &
130               &                     + e1t(ji+1,jj) * e2t(ji+1,jj) * sshn(ji+1,jj) )   
131            sshv_n(ji,jj) = zcoefv * ( e1t(ji,jj  ) * e2t(ji,jj  ) * sshn(ji,jj  )     & 
132               &                     + e1t(ji,jj+1) * e2t(ji,jj+1) * sshn(ji,jj+1) )     
133            sshf_n(ji,jj) = zcoeff * ( sshn(ji  ,jj) + sshn(ji  ,jj+1)                 &
134               &                     + sshn(ji+1,jj) + sshn(ji+1,jj+1) )               
135         END DO
136      END DO
137      CALL lbc_lnk( sshu_b, 'U', 1. )   ;   CALL lbc_lnk( sshu_n, 'U', 1. )      ! lateral boundary conditions
138      CALL lbc_lnk( sshv_b, 'V', 1. )   ;   CALL lbc_lnk( sshv_n, 'V', 1. )
139      CALL lbc_lnk( sshf_b, 'F', 1. )   ;   CALL lbc_lnk( sshf_n, 'F', 1. )
140      !
141   END SUBROUTINE dom_vvl
142
143#else
144   !!----------------------------------------------------------------------
145   !!   Default option :                                      Empty routine
146   !!----------------------------------------------------------------------
147CONTAINS
148   SUBROUTINE dom_vvl
149   END SUBROUTINE dom_vvl
150#endif
151
152   !!======================================================================
153END MODULE domvvl
Note: See TracBrowser for help on using the repository browser.