New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynadv.F90 in trunk/NEMO/OPA_SRC/DYN – NEMO

source: trunk/NEMO/OPA_SRC/DYN/dynadv.F90 @ 1152

Last change on this file since 1152 was 1152, checked in by rblod, 16 years ago

Convert cvs header to svn Id, step II

  • Property svn:eol-style set to native
  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 6.1 KB
Line 
1MODULE dynadv
2   !!==============================================================================
3   !!                       ***  MODULE  dynadv  ***
4   !! Ocean active tracers:  advection scheme control
5   !!==============================================================================
6   !! History :  9.0  !  06-11  (G. Madec)  Original code
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   dyn_adv      : compute the momentum advection trend
11   !!   dyn_adv_ctl  : control the different options of advection scheme
12   !!----------------------------------------------------------------------
13   USE dom_oce         ! ocean space and time domain
14   USE in_out_manager  ! I/O manager
15
16   USE dynadv_cen2     ! centred flux form advection      (dyn_adv_cen2 routine)
17   USE dynadv_ubs      ! UBS flux form advection          (dyn_adv_ubs  routine)
18   USE dynkeg          ! kinetic energy gradient          (dyn_keg      routine)
19   USE dynzad          ! vertical advection               (dyn_zad      routine)
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC dyn_adv     ! routine called by step module
25 
26   LOGICAL, PUBLIC ::   ln_dynadv_vec  = .TRUE.    ! vector form flag
27   LOGICAL, PUBLIC ::   ln_dynadv_cen2 = .FALSE.   ! flux form - 2nd order centered scheme flag
28   LOGICAL, PUBLIC ::   ln_dynadv_ubs  = .FALSE.   ! flux form - 3rd order UBS scheme flag
29   
30   INTEGER ::   nadv   ! choice of the formulation and scheme for the advection
31
32   !! * Substitutions
33#  include "domzgr_substitute.h90"
34#  include "vectopt_loop_substitute.h90"
35   !!----------------------------------------------------------------------
36   !!   OPA 9.0 , LOCEAN-IPSL (2006)
37   !! $Id$
38   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
39   !!----------------------------------------------------------------------
40
41CONTAINS
42
43   SUBROUTINE dyn_adv( kt )
44      !!---------------------------------------------------------------------
45      !!                  ***  ROUTINE dyn_adv  ***
46      !!               
47      !! ** Purpose :   compute the ocean momentum advection trend.
48      !!
49      !! ** Method  : - Update (ua,va) with the advection term following nadv
50      !!      NB: in flux form advection (ln_dynadv_cen2 or ln_dynadv_ubs=T)
51      !!      a metric term is add to the coriolis term while in vector form
52      !!      it is the relative vorticity which is added to coriolis term
53      !!      (see dynvor module).
54      !!----------------------------------------------------------------------
55      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
56      !!----------------------------------------------------------------------
57      !
58      IF( kt == nit000 )   CALL dyn_adv_ctl          ! initialisation & control of options
59
60      SELECT CASE ( nadv )                     ! compute advection trend and add it to general trend
61      CASE ( 0 )     
62                      CALL dyn_keg     ( kt )    ! vector form : horizontal gradient of kinetic energy
63                      CALL dyn_zad     ( kt )    ! vector form : vertical advection
64      CASE ( 1 ) 
65                      CALL dyn_adv_cen2( kt )    ! 2nd order centered scheme
66      CASE ( 2 )   
67                      CALL dyn_adv_ubs ( kt )    ! 3rd order UBS      scheme
68      !
69      CASE (-1 )                                 ! esopa: test all possibility with control print
70                      CALL dyn_keg     ( kt )
71                      CALL dyn_zad     ( kt )
72                      CALL dyn_adv_cen2( kt )
73                      CALL dyn_adv_ubs ( kt )
74      END SELECT
75      !
76   END SUBROUTINE dyn_adv
77
78   
79   SUBROUTINE dyn_adv_ctl
80      !!---------------------------------------------------------------------
81      !!                  ***  ROUTINE dyn_adv_ctl  ***
82      !!               
83      !! ** Purpose :   Control the consistency between namelist options for
84      !!              momentum advection formulation & scheme and set nadv
85      !!----------------------------------------------------------------------
86      INTEGER ::   ioptio
87
88      NAMELIST/nam_dynadv/ ln_dynadv_vec, ln_dynadv_cen2 , ln_dynadv_ubs
89      !!----------------------------------------------------------------------
90
91      REWIND ( numnam )               ! Read Namelist nam_dynadv : momentum advection scheme
92      READ   ( numnam, nam_dynadv )
93
94      IF(lwp) THEN                    ! Namelist print
95         WRITE(numout,*)
96         WRITE(numout,*) 'dyn_adv_ctl : choice/control of the momentum advection scheme'
97         WRITE(numout,*) '~~~~~~~~~~~'
98         WRITE(numout,*) '       Namelist nam_dynadv : chose a advection formulation & scheme for momentum'
99         WRITE(numout,*) '          Vector/flux form (T/F)             ln_dynadv_vec  = ', ln_dynadv_vec
100         WRITE(numout,*) '          2nd order centred advection scheme ln_dynadv_cen2 = ', ln_dynadv_cen2
101         WRITE(numout,*) '          3rd order UBS advection scheme     ln_dynadv_ubs  = ', ln_dynadv_ubs
102      ENDIF
103
104      ioptio = 0                      ! Parameter control
105      IF( ln_dynadv_vec  )   ioptio = ioptio + 1
106      IF( ln_dynadv_cen2 )   ioptio = ioptio + 1
107      IF( ln_dynadv_ubs  )   ioptio = ioptio + 1
108      IF( lk_esopa       )   ioptio =          1
109
110      IF( ioptio /= 1 )   CALL ctl_stop( 'Choose ONE advection scheme in namelist nam_dynadv' )
111
112      !                               ! Set nadv
113      IF( ln_dynadv_vec  )   nadv =  0 
114      IF( ln_dynadv_cen2 )   nadv =  1
115      IF( ln_dynadv_ubs  )   nadv =  2
116      IF( lk_esopa       )   nadv = -1
117
118      IF(lwp) THEN                    ! Print the choice
119         WRITE(numout,*)
120         IF( nadv ==  0 )   WRITE(numout,*) '         vector form : keg + zad + vor is used'
121         IF( nadv ==  1 )   WRITE(numout,*) '         flux form   : 2nd order scheme is used'
122         IF( nadv ==  2 )   WRITE(numout,*) '         flux form   : UBS       scheme is used'
123         IF( nadv == -1 )   WRITE(numout,*) '         esopa test: use all advection formulation'
124      ENDIF
125      !
126   END SUBROUTINE dyn_adv_ctl
127
128  !!======================================================================
129END MODULE dynadv
Note: See TracBrowser for help on using the repository browser.