New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iom_nf90.F90 in trunk/NEMO/OPA_SRC/IOM – NEMO

source: trunk/NEMO/OPA_SRC/IOM/iom_nf90.F90 @ 745

Last change on this file since 745 was 745, checked in by smasson, 16 years ago

by default stop if variable doesn't exist, see ticket:21

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 27.7 KB
Line 
1MODULE iom_nf90
2   !!=====================================================================
3   !!                    ***  MODULE  iom_nf90 ***
4   !! Input/Output manager :  Library to read input files with NF90 (only fliocom module)
5   !!====================================================================
6   !! History :  9.0  ! 05 12  (J. Belier) Original code
7   !!            9.0  ! 06 02  (S. Masson) Adaptation to NEMO
8   !!--------------------------------------------------------------------
9   !!gm  caution add !DIR nec: improved performance to be checked as well as no result changes
10
11   !!--------------------------------------------------------------------
12   !!   iom_open       : open a file read only
13   !!   iom_close      : close a file or all files opened by iom
14   !!   iom_get        : read a field (interfaced to several routines)
15   !!   iom_gettime    : read the time axis kvid in the file
16   !!   iom_varid      : get the id of a variable in a file
17   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
18   !!--------------------------------------------------------------------
19   USE in_out_manager  ! I/O manager
20   USE dom_oce         ! ocean space and time domain
21   USE lbclnk          ! lateal boundary condition / mpp exchanges
22   USE iom_def         ! iom variables definitions
23   USE netcdf          ! NetCDF library
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC iom_nf90_open, iom_nf90_close, iom_nf90_varid, iom_nf90_get, iom_nf90_gettime, iom_nf90_rstput
29
30   INTERFACE iom_nf90_get
31      MODULE PROCEDURE iom_nf90_g0d, iom_nf90_g123d
32   END INTERFACE
33   INTERFACE iom_nf90_rstput
34      MODULE PROCEDURE iom_nf90_rp0123d
35   END INTERFACE
36   !!----------------------------------------------------------------------
37   !!  OPA 9.0 , LOCEAN-IPSL (2006)
38   !! $Header: /home/opalod/NEMOCVSROOT/NEMO/OPA_SRC/IOM/iom_nf90.F90,v 1.8 2007/06/29 14:10:50 opalod Exp $
39   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
40   !!----------------------------------------------------------------------
41
42CONTAINS
43
44   SUBROUTINE iom_nf90_open( cdname, kiomid, ldwrt, ldok, kdompar )
45      !!---------------------------------------------------------------------
46      !!                   ***  SUBROUTINE  iom_open  ***
47      !!
48      !! ** Purpose : open an input file with NF90
49      !!---------------------------------------------------------------------
50      CHARACTER(len=*)       , INTENT(inout)           ::   cdname    ! File name
51      INTEGER                , INTENT(  out)           ::   kiomid    ! nf90 identifier of the opened file
52      LOGICAL                , INTENT(in   )           ::   ldwrt     ! read or write the file?
53      LOGICAL                , INTENT(in   )           ::   ldok      ! check the existence
54      INTEGER, DIMENSION(2,5), INTENT(in   ), OPTIONAL ::   kdompar   ! domain parameters:
55
56      CHARACTER(LEN=100) ::   clinfo   ! info character
57      CHARACTER(LEN=100) ::   cltmp    ! temporary character
58      INTEGER            ::   iln      ! lengths of character
59      INTEGER            ::   istop    ! temporary storage of nstop
60      INTEGER            ::   if90id   ! nf90 identifier of the opened file
61      INTEGER            ::   idmy     ! dummy variable
62      INTEGER            ::   jl       ! loop variable
63      !---------------------------------------------------------------------
64
65      clinfo = '                    iom_nf90_open ~~~  '
66      istop = nstop   ! store the actual value of nstop
67      !
68      IF( ldok ) THEN      ! Open existing file...
69         !                 ! =============
70         IF( ldwrt ) THEN  ! ... in write mode
71            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in WRITE mode'
72            CALL iom_nf90_check(NF90_OPEN(TRIM(cdname), NF90_WRITE  , if90id), clinfo)
73            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy    ), clinfo)
74         ELSE              ! ... in read mode
75            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode'
76            CALL iom_nf90_check(NF90_OPEN(TRIM(cdname), NF90_NOWRITE, if90id), clinfo)
77         ENDIF
78      ELSE                 ! the file does not exist
79         !                 ! =============
80         iln = INDEX( cdname, '.nc' )
81         IF( ldwrt ) THEN  ! the file should be open in write mode so we create it...
82            IF( jpnij > 1 ) THEN
83               WRITE(cltmp,'(a,a,i4.4,a)') cdname(1:iln-1), '_', narea-1, '.nc'
84               cdname = TRIM(cltmp)
85            ENDIF
86            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//TRIM(cdname)//' in WRITE mode'
87            CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), NF90_NOCLOBBER, if90id ), clinfo)
88            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy          ), clinfo)
89            ! define dimensions
90            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'x', kdompar(1,1)  , idmy ), clinfo)
91            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'y', kdompar(2,1)  , idmy ), clinfo)
92            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'z', jpk           , idmy ), clinfo)
93            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 't', NF90_UNLIMITED, idmy ), clinfo)
94            ! global attributes
95            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number_total'   , jpnij              ), clinfo)
96            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number'         , narea-1            ), clinfo)
97            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_dimensions_ids' , (/1     , 2     /) ), clinfo)
98            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_global'    , (/jpiglo, jpjglo/) ), clinfo)
99            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_local'     , kdompar(:,1)       ), clinfo)
100            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_first' , kdompar(:,2)       ), clinfo)
101            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_last'  , kdompar(:,3)       ), clinfo)
102            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_start', kdompar(:,4)       ), clinfo)
103            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_end'  , kdompar(:,5)       ), clinfo)
104            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_type'           , 'BOX'              ), clinfo)
105         ELSE              ! the file should be open for read mode so it must exist...
106            CALL ctl_stop( TRIM(clinfo), ' should be impossible case...' )
107         ENDIF
108      ENDIF
109      ! start to fill file informations
110      ! =============
111      IF( istop == nstop ) THEN   ! no error within this routine
112!does not work with some compilers         kiomid = MINLOC(iom_file(:)%nfid, dim = 1)
113         kiomid = 0
114         DO jl = jpmax_files, 1, -1
115            IF( iom_file(jl)%nfid == 0 )   kiomid = jl
116         ENDDO
117         iom_file(kiomid)%name   = TRIM(cdname)
118         iom_file(kiomid)%nfid   = if90id
119         iom_file(kiomid)%iolib  = jpnf90
120         iom_file(kiomid)%nvars  = 0
121         iom_file(kiomid)%irec   = -1   ! useless for NetCDF files, used to know if the file is in define mode
122         CALL iom_nf90_check(NF90_Inquire(if90id, unlimitedDimId = iom_file(kiomid)%iduld), clinfo)
123         IF(lwp) WRITE(numout,*) '                   ---> '//TRIM(cdname)//' OK'
124      ELSE
125         kiomid = 0               ! return error flag
126      ENDIF
127      !
128   END SUBROUTINE iom_nf90_open
129
130
131   SUBROUTINE iom_nf90_close( kiomid )
132      !!--------------------------------------------------------------------
133      !!                   ***  SUBROUTINE  iom_nf90_close  ***
134      !!
135      !! ** Purpose : close an input file with NF90
136      !!--------------------------------------------------------------------
137      INTEGER, INTENT(in) ::   kiomid   ! iom identifier of the file to be closed
138      CHARACTER(LEN=100)  ::   clinfo   ! info character
139      !---------------------------------------------------------------------
140      !
141      clinfo = '      iom_nf90_close    , file: '//TRIM(iom_file(kiomid)%name)
142      CALL iom_nf90_check(NF90_CLOSE(iom_file(kiomid)%nfid), clinfo)
143      !   
144   END SUBROUTINE iom_nf90_close
145
146
147   FUNCTION iom_nf90_varid ( kiomid, cdvar, kiv, kdimsz ) 
148      !!-----------------------------------------------------------------------
149      !!                  ***  FUNCTION  iom_varid  ***
150      !!
151      !! ** Purpose : get the id of a variable in a file with NF90
152      !!-----------------------------------------------------------------------
153      INTEGER              , INTENT(in   )           ::   kiomid   ! file Identifier
154      CHARACTER(len=*)     , INTENT(in   )           ::   cdvar    ! name of the variable
155      INTEGER              , INTENT(in   )           ::   kiv   !
156      INTEGER, DIMENSION(:), INTENT(  out), OPTIONAL ::   kdimsz   ! size of the dimensions
157      !
158      INTEGER                        ::   iom_nf90_varid   ! iom variable Id
159      INTEGER                        ::   if90id           ! nf90 file identifier
160      INTEGER                        ::   ji               ! dummy loop index
161      INTEGER                        ::   ivarid           ! NetCDF  variable Id
162      INTEGER                        ::   i_nvd            ! number of dimension of the variable
163      INTEGER, DIMENSION(jpmax_dims) ::   idimid           ! dimension ids of the variable
164      LOGICAL                        ::   llok             ! ok  test
165      CHARACTER(LEN=100)             ::   clinfo           ! info character
166      !!-----------------------------------------------------------------------
167      clinfo = '          iom_nf90_varid, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
168      iom_nf90_varid = 0                    ! default definition
169      IF( PRESENT(kdimsz) ) kdimsz(:) = 0   ! default definition
170      if90id = iom_file(kiomid)%nfid        ! get back NetCDF file id
171      !
172      llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr   ! does the variable exist in the file
173      IF( llok ) THEN
174         iom_nf90_varid = kiv
175         iom_file(kiomid)%nvars       = kiv
176         iom_file(kiomid)%nvid(kiv)   = ivarid
177         iom_file(kiomid)%cn_var(kiv) = TRIM(cdvar)
178         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, ndims = i_nvd), clinfo)   ! number of dimensions
179         iom_file(kiomid)%ndims(kiv)  = i_nvd
180         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, dimids = idimid(1:i_nvd)), clinfo)   ! dimensions ids
181         iom_file(kiomid)%luld(kiv) = .FALSE.   ! default value
182         DO ji = 1, i_nvd                       ! dimensions size
183            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, idimid(ji), len = iom_file(kiomid)%dimsz(ji,kiv)), clinfo)   
184            IF( idimid(ji) == iom_file(kiomid)%iduld ) iom_file(kiomid)%luld(kiv) = .TRUE.   ! unlimited dimension?
185         END DO
186         !---------- Deal with scale_factor and add_offset
187         llok = NF90_Inquire_attribute(if90id, ivarid, 'scale_factor') == nf90_noerr
188         IF( llok) THEN
189            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'scale_factor', iom_file(kiomid)%scf(kiv)), clinfo)
190         ELSE
191            iom_file(kiomid)%scf(kiv) = 1.
192         END IF
193         llok = NF90_Inquire_attribute(if90id, ivarid, 'add_offset') == nf90_noerr
194         IF( llok ) THEN
195            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'add_offset', iom_file(kiomid)%ofs(kiv)), clinfo)
196         ELSE
197            iom_file(kiomid)%ofs(kiv) = 0.
198         END IF
199         ! return the simension size
200         IF( PRESENT(kdimsz) ) THEN
201            IF( i_nvd == SIZE(kdimsz) ) THEN
202               kdimsz(:) = iom_file(kiomid)%dimsz(1:i_nvd,kiv)
203            ELSE
204               WRITE(ctmp1,*) i_nvd, SIZE(kdimsz)
205               CALL ctl_stop( TRIM(clinfo), 'error in kdimsz size'//TRIM(ctmp1) )
206            ENDIF
207         ENDIF
208      ELSE 
209         iom_nf90_varid = -1   !   variable not found, return error code: -1
210      ENDIF
211      !
212   END FUNCTION iom_nf90_varid
213
214
215   SUBROUTINE iom_nf90_g0d( kiomid, kvid, pvar )
216      !!-----------------------------------------------------------------------
217      !!                  ***  ROUTINE  iom_nf90_g0d  ***
218      !!
219      !! ** Purpose : read a scalar with NF90
220      !!-----------------------------------------------------------------------
221      INTEGER , INTENT(in   ) ::   kiomid   ! Identifier of the file
222      INTEGER , INTENT(in   ) ::   kvid     ! variable id
223      REAL(wp), INTENT(  out) ::   pvar     ! read field
224      !
225      CHARACTER(LEN=100)      ::   clinfo   ! info character
226      !---------------------------------------------------------------------
227      clinfo = 'iom_nf90_g0d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
228      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), pvar), clinfo )
229      !
230   END SUBROUTINE iom_nf90_g0d
231
232
233   SUBROUTINE iom_nf90_g123d( kiomid, kvid, knbdim, kstart, kcount, kx1, kx2, ky1, ky2,   &
234         &                    pv_r1d, pv_r2d, pv_r3d )
235      !!-----------------------------------------------------------------------
236      !!                  ***  ROUTINE  iom_nf90_g123d  ***
237      !!
238      !! ** Purpose : read a 1D/2D/3D variable with NF90
239      !!
240      !! ** Method : read ONE record at each CALL
241      !!-----------------------------------------------------------------------
242      INTEGER                    , INTENT(in   )           ::   kiomid    ! iom identifier of the file
243      INTEGER                    , INTENT(in   )           ::   kvid      ! Name of the variable
244      INTEGER                    , INTENT(in   )           ::   knbdim    ! number of dimensions of the variable
245      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kstart    ! start position of the reading in each axis
246      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kcount    ! number of points to be read in each axis
247      INTEGER ,                    INTENT(in   )           ::   kx1, kx2, ky1, ky2   ! subdomain indexes
248      REAL(wp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d    ! read field (1D case)
249      REAL(wp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d    ! read field (2D case)
250      REAL(wp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d    ! read field (3D case)
251      !
252      CHARACTER(LEN=100) ::   clinfo               ! info character
253      INTEGER            ::   if90id               ! nf90 identifier of the opened file
254      INTEGER            ::   ivid                 ! nf90 variable id
255      !---------------------------------------------------------------------
256      clinfo = 'iom_nf90_g123d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
257      if90id = iom_file(kiomid)%nfid         ! get back NetCDF file id
258      ivid   = iom_file(kiomid)%nvid(kvid)   ! get back NetCDF var id
259      !
260      IF(     PRESENT(pv_r1d) ) THEN
261         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r1d(:                ), start = kstart(1:knbdim),   &
262            &                                                                       count = kcount(1:knbdim)), clinfo )
263      ELSEIF( PRESENT(pv_r2d) ) THEN
264         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r2d(kx1:kx2,ky1:ky2  ), start = kstart(1:knbdim),   &
265            &                                                                       count = kcount(1:knbdim)), clinfo )
266      ELSEIF( PRESENT(pv_r3d) ) THEN
267         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r3d(kx1:kx2,ky1:ky2,:), start = kstart(1:knbdim),   &
268            &                                                                       count = kcount(1:knbdim)), clinfo )
269      ENDIF
270      !
271   END SUBROUTINE iom_nf90_g123d
272
273
274   SUBROUTINE iom_nf90_gettime( kiomid, kvid, ptime )
275      !!--------------------------------------------------------------------
276      !!                   ***  SUBROUTINE iom_gettime  ***
277      !!
278      !! ** Purpose : read the time axis kvid in the file with NF90
279      !!--------------------------------------------------------------------
280      INTEGER               , INTENT(in   ) ::   kiomid   ! file Identifier
281      INTEGER               , INTENT(in   ) ::   kvid     ! variable id
282      REAL(wp), DIMENSION(:), INTENT(  out) ::   ptime    ! the time axis
283      !
284      CHARACTER(LEN=100) ::   clinfo     ! info character
285      !---------------------------------------------------------------------
286      clinfo = 'iom_nf90_gettime, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
287      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), ptime(:),   &
288            &                           start=(/ 1 /), count=(/ iom_file(kiomid)%dimsz(1, kvid) /)), clinfo)
289      !
290   END SUBROUTINE iom_nf90_gettime
291
292
293   SUBROUTINE iom_nf90_rp0123d( kt, kwrite, kiomid, cdvar , kvid  , ktype,   &
294         &                               pv_r0d, pv_r1d, pv_r2d, pv_r3d )
295      !!--------------------------------------------------------------------
296      !!                   ***  SUBROUTINE  iom_nf90_rstput  ***
297      !!
298      !! ** Purpose : read the time axis cdvar in the file
299      !!--------------------------------------------------------------------
300      INTEGER                         , INTENT(in)           ::   kt       ! ocean time-step
301      INTEGER                         , INTENT(in)           ::   kwrite   ! writing time-step
302      INTEGER                         , INTENT(in)           ::   kiomid   ! Identifier of the file
303      CHARACTER(len=*)                , INTENT(in)           ::   cdvar    ! variable name
304      INTEGER                         , INTENT(in)           ::   kvid     ! variable id
305      INTEGER                         , INTENT(in), OPTIONAL ::   ktype    ! variable type (default R8)
306      REAL(wp)                        , INTENT(in), OPTIONAL ::   pv_r0d   ! written Od field
307      REAL(wp), DIMENSION(        jpk), INTENT(in), OPTIONAL ::   pv_r1d   ! written 1d field
308      REAL(wp), DIMENSION(jpi,jpj    ), INTENT(in), OPTIONAL ::   pv_r2d   ! written 2d field
309      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in), OPTIONAL ::   pv_r3d   ! written 3d field
310      !
311      INTEGER               :: idims                ! number of dimension
312      INTEGER               :: idvar                ! variable id
313      INTEGER               :: jd                   ! dimension loop counter   
314      INTEGER               :: ix1, ix2, iy1, iy2   ! subdomain indexes   
315      INTEGER, DIMENSION(4) :: idimsz               ! dimensions size 
316      INTEGER, DIMENSION(4) :: idimid               ! dimensions id
317      CHARACTER(LEN=100)    :: clinfo               ! info character
318      CHARACTER(LEN= 12), DIMENSION(4) :: cltmp     ! temporary character
319      INTEGER               :: if90id               ! nf90 file identifier
320      INTEGER               :: idmy                 ! dummy variable
321      INTEGER               :: itype                ! variable type
322      !---------------------------------------------------------------------
323      !
324      clinfo = '          iom_nf90_rp0123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
325      if90id = iom_file(kiomid)%nfid
326      !
327      ! define dimension variables if it is not already done
328      ! ==========================
329      IF( iom_file(kiomid)%nvars == 0 ) THEN
330         ! are we in define mode?
331         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
332            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
333         ENDIF
334         ! define the dimension variables if it is not already done
335         cltmp = (/ 'nav_lon     ', 'nav_lat     ', 'nav_lev     ', 'time_counter' /)
336         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(1)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(1) ), clinfo)
337         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(2)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(2) ), clinfo)
338         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(3)), NF90_FLOAT , (/ 3    /), iom_file(kiomid)%nvid(3) ), clinfo)
339         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(4)), NF90_DOUBLE, (/ 4    /), iom_file(kiomid)%nvid(4) ), clinfo)
340         ! update informations structure related the dimension variable we just added...
341         iom_file(kiomid)%nvars       = 4
342         iom_file(kiomid)%luld(1:4)   = (/ .FALSE., .FALSE., .FALSE., .TRUE. /)
343         iom_file(kiomid)%cn_var(1:4) = cltmp
344         iom_file(kiomid)%ndims(1:4)  = (/ 2, 2, 1, 1 /) 
345         ! trick: defined to 0 to say that dimension variables are defined but not yet written
346         iom_file(kiomid)%dimsz(1, 1)  = 0   
347         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' define dimension variables done'
348      ENDIF
349      ! define the data if it is not already done
350      ! ===============
351      IF( kvid <= 0 ) THEN
352         idvar = iom_file(kiomid)%nvars + 1
353         ! are we in define mode?
354         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
355            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
356         ENDIF
357         ! variable definition
358         IF(     PRESENT(pv_r0d) ) THEN   ;   idims = 0
359         ELSEIF( PRESENT(pv_r1d) ) THEN   ;   idims = 2   ;   idimid(1:idims) = (/    3,4/)
360         ELSEIF( PRESENT(pv_r2d) ) THEN   ;   idims = 3   ;   idimid(1:idims) = (/1,2  ,4/)
361         ELSEIF( PRESENT(pv_r3d) ) THEN   ;   idims = 4   ;   idimid(1:idims) = (/1,2,3,4/)
362         ENDIF
363         IF( PRESENT(ktype) ) THEN   ! variable external type
364            SELECT CASE (ktype)
365            CASE (jp_r8)  ;   itype = NF90_DOUBLE
366            CASE (jp_r4)  ;   itype = NF90_FLOAT
367            CASE (jp_i4)  ;   itype = NF90_INT
368            CASE (jp_i2)  ;   itype = NF90_SHORT
369            CASE (jp_i1)  ;   itype = NF90_BYTE
370            CASE DEFAULT   ;   CALL ctl_stop( TRIM(clinfo)//' unknown variable type' )
371            END SELECT
372         ELSE
373            itype = NF90_DOUBLE
374         ENDIF
375         IF( PRESENT(pv_r0d) ) THEN
376            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype,                    &
377                 &                            iom_file(kiomid)%nvid(idvar) ), clinfo)
378         ELSE
379            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype, idimid(1:idims),   &
380                 &                            iom_file(kiomid)%nvid(idvar) ), clinfo)
381         ENDIF
382         ! update informations structure related the new variable we want to add...
383         iom_file(kiomid)%nvars         = idvar
384         iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar)
385         iom_file(kiomid)%scf(idvar)    = 1.
386         iom_file(kiomid)%ofs(idvar)    = 0.
387         iom_file(kiomid)%ndims(idvar)  = idims
388         IF( .NOT. PRESENT(pv_r0d) ) THEN   ;   iom_file(kiomid)%luld(idvar) = .TRUE.
389         ELSE                               ;   iom_file(kiomid)%luld(idvar) = .FALSE.
390         ENDIF
391         DO jd = 1, idims
392            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, idimid(jd), len = iom_file(kiomid)%dimsz(jd,idvar) ), clinfo)
393         END DO
394         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' defined ok'
395      ELSE
396         idvar = kvid
397      ENDIF
398
399      ! time step kwrite : write the variable
400      IF( kt == kwrite ) THEN
401         ! are we in write mode?
402         IF( iom_file(kiomid)%irec == -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
403            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = 0
404         ENDIF
405         ! on what kind of domain must the data be written?
406         IF( PRESENT(pv_r2d) .OR. PRESENT(pv_r3d) ) THEN
407            idimsz(1:2) = iom_file(kiomid)%dimsz(1:2,idvar)
408            IF(     idimsz(1) == (nlei - nldi + 1) .AND. idimsz(2) == (nlej - nldj + 1) ) THEN
409               ix1 = nldi   ;   ix2 = nlei   ;   iy1 = nldj   ;   iy2 = nlej
410            ELSEIF( idimsz(1) == nlci              .AND. idimsz(2) == nlcj              ) THEN
411               ix1 = 1      ;   ix2 = nlci   ;   iy1 = 1      ;   iy2 = nlcj
412            ELSEIF( idimsz(1) == jpi               .AND. idimsz(2) == jpj               ) THEN
413               ix1 = 1      ;   ix2 = jpi    ;   iy1 = 1      ;   iy2 = jpj
414            ELSE
415               CALL ctl_stop( 'iom_nf90_rp0123d: should have been an impossible case...' )
416            ENDIF
417
418            ! write dimension variables if it is not already done
419            ! =============
420            ! trick: is defined to 0 => dimension variable are defined but not yet written
421            IF( iom_file(kiomid)%dimsz(1, 1) == 0 ) THEN
422               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lon'     , idmy ), clinfo)
423               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, glamt(ix1:ix2, iy1:iy2) ), clinfo)
424               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lat'     , idmy ), clinfo)
425               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, gphit(ix1:ix2, iy1:iy2) ), clinfo)
426               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lev'     , idmy ), clinfo)
427               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, gdept_0                 ), clinfo)
428               ! +++ WRONG VALUE: to be improved but not really useful...
429               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'time_counter', idmy ), clinfo)
430               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, kt                      ), clinfo)   
431               ! update the values of the variables dimensions size
432               CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 1, len = iom_file(kiomid)%dimsz(1,1) ), clinfo)
433               CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 2, len = iom_file(kiomid)%dimsz(2,1) ), clinfo)
434               iom_file(kiomid)%dimsz(1:2, 2) = iom_file(kiomid)%dimsz(1:2, 1)
435               CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 3, len = iom_file(kiomid)%dimsz(1,3) ), clinfo)
436               iom_file(kiomid)%dimsz(1  , 4) = 1   ! unlimited dimension
437               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' write dimension variables done'
438            ENDIF
439         ENDIF
440
441         ! write the data
442         ! =============
443         IF(     PRESENT(pv_r0d) ) THEN
444            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r0d                      ), clinfo)
445         ELSEIF( PRESENT(pv_r1d) ) THEN
446            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r1d(                  :) ), clinfo)
447         ELSEIF( PRESENT(pv_r2d) ) THEN
448            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r2d(ix1:ix2, iy1:iy2   ) ), clinfo)
449         ELSEIF( PRESENT(pv_r3d) ) THEN
450            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r3d(ix1:ix2, iy1:iy2, :) ), clinfo)
451         ENDIF
452         ! add 1 to the size of the temporal dimension (not really useful...)
453         IF( iom_file(kiomid)%luld(idvar) )   iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar)    &
454               &                            = iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) + 1
455         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok'
456      ENDIF
457      !     
458   END SUBROUTINE iom_nf90_rp0123d
459
460
461   SUBROUTINE iom_nf90_check( kstatus, cdinfo )
462      !!--------------------------------------------------------------------
463      !!                   ***  SUBROUTINE iom_nf90_check  ***
464      !!
465      !! ** Purpose :   check nf90 errors
466      !!--------------------------------------------------------------------
467      INTEGER,          INTENT(in) :: kstatus
468      CHARACTER(LEN=*), INTENT(in) :: cdinfo
469      !---------------------------------------------------------------------
470      IF(kstatus /= nf90_noerr)   CALL ctl_stop( 'iom_nf90_check : '//TRIM(nf90_strerror(kstatus)), TRIM(cdinfo) )
471   END SUBROUTINE iom_nf90_check
472
473
474   !!======================================================================
475END MODULE iom_nf90
Note: See TracBrowser for help on using the repository browser.