New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
ldfeiv.F90 in trunk/NEMO/OPA_SRC/LDF – NEMO

source: trunk/NEMO/OPA_SRC/LDF/ldfeiv.F90 @ 412

Last change on this file since 412 was 412, checked in by opalod, 18 years ago

nemo_v1_bugfix_031 : CT : make the computation of ahtu(), ahtv() & ahtw() done in auto-task identical to the one done in mono-processor
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 15.7 KB
Line 
1MODULE ldfeiv
2   !!======================================================================
3   !!                     ***  MODULE  ldfeiv  ***
4   !! Ocean physics:  variable eddy induced velocity coefficients
5   !!======================================================================
6#if   defined key_traldf_eiv   &&   defined key_traldf_c2d
7   !!----------------------------------------------------------------------
8   !!   'key_traldf_eiv'      and                     eddy induced velocity
9   !!   'key_traldf_c2d'                    2D tracer lateral  mixing coef.
10   !!----------------------------------------------------------------------
11   !!   ldf_eiv      : compute the eddy induced velocity coefficients
12   !!                  Same results but not same routine if 'key_autotasking'
13   !!                  is defined or not
14   !!----------------------------------------------------------------------
15   !! * Modules used
16   USE oce             ! ocean dynamics and tracers
17   USE dom_oce         ! ocean space and time domain
18   USE ldftra_oce      ! ocean tracer   lateral physics
19   USE phycst          ! physical constants
20   USE ldfslp          ! iso-neutral slopes
21   USE flxrnf          !
22   USE in_out_manager  ! I/O manager
23   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
24   USE prtctl          ! Print control
25
26   IMPLICIT NONE
27   PRIVATE
28   
29   !! * Routine accessibility
30   PUBLIC ldf_eiv               ! routine called by step.F90
31   !!----------------------------------------------------------------------
32   !!  OPA 9.0 , LOCEAN-IPSL (2005)
33   !! $Header$
34   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
35   !!----------------------------------------------------------------------
36   !! * Substitutions
37#  include "domzgr_substitute.h90"
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40
41CONTAINS
42
43# if defined key_autotasking
44   !!----------------------------------------------------------------------
45   !!   'key_autotasking' :                            autotasking (j-slab)
46   !!----------------------------------------------------------------------
47
48   SUBROUTINE ldf_eiv( kt )
49      !!----------------------------------------------------------------------
50      !!                  ***  ROUTINE ldf_eiv  ***
51      !!
52      !! ** Purpose :   Compute the eddy induced velocity coefficient from the
53      !!      growth rate of baroclinic instability.
54      !!
55      !! ** Method :
56      !!
57      !! ** Action :   uslp(),   : i- and j-slopes of neutral surfaces
58      !!               vslp()      at u- and v-points, resp.
59      !!               wslpi(),  : i- and j-slopes of neutral surfaces
60      !!               wslpj()     at w-points.
61      !!
62      !! History :
63      !!   8.1  !  99-03  (G. Madec, A. Jouzeau)  Original code
64      !!   8.5  !  02-06  (G. Madec)  Free form, F90
65      !!----------------------------------------------------------------------
66      !! * Arguments
67      INTEGER, INTENT( in ) ::   kt     ! ocean time-step inedx
68     
69      !! * Local declarations
70      INTEGER ::   ji, jj, jk           ! dummy loop indices
71      REAL(wp) ::   &
72         zfw, ze3w, zn2, zf20,       &  ! temporary scalars
73         zaht, zaht_min
74      REAL(wp), DIMENSION(jpi,jpj) ::   &
75         zn, zah, zhw, zross            ! workspace
76      !!----------------------------------------------------------------------
77
78      IF( kt == nit000 ) THEN
79         IF(lwp) WRITE(numout,*)
80         IF(lwp) WRITE(numout,*) 'ldf_eiv : eddy induced velocity coefficients'
81         IF(lwp) WRITE(numout,*) '~~~~~~~   key_autotasking'
82      ENDIF
83     
84      !                                                ! ===============
85      DO jj = 2, jpjm1                                 !  Vertical slab
86         !                                             ! ===============
87         
88         ! 0. Local initialization
89         ! -----------------------
90         zn   (:,jj) = 0.e0
91         zhw  (:,jj) = 5.e0
92         zah  (:,jj) = 0.e0
93         zross(:,jj) = 0.e0
94         
95         ! 1. Compute lateral diffusive coefficient
96         ! ----------------------------------------
97
98!CDIR NOVERRCHK
99         DO jk = 1, jpk
100!CDIR NOVERRCHK
101            DO ji = 2, jpim1
102               ! Take the max of N^2 and zero then take the vertical sum
103               ! of the square root of the resulting N^2 ( required to compute
104               ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
105               zn2 = MAX( rn2(ji,jj,jk), 0.e0 )
106               ze3w = fse3w(ji,jj,jk) * tmask(ji,jj,jk)
107               zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * fse3w(ji,jj,jk)
108               ! Compute elements required for the inverse time scale of baroclinic
109               ! eddies using the isopycnal slopes calculated in ldfslp.F :
110               ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
111               zah(ji,jj) = zah(ji,jj) + zn2   &
112                              * ( wslpi(ji,jj,jk) * wslpi(ji,jj,jk)    &
113                                + wslpj(ji,jj,jk) * wslpj(ji,jj,jk) )   &
114                              * ze3w
115               zhw(ji,jj) = zhw(ji,jj) + ze3w
116            END DO
117         END DO 
118 
119!CDIR NOVERRCHK
120         DO ji = 2, jpim1
121            zfw = MAX( ABS( 2. * omega * SIN( rad * gphit(ji,jj) ) ) , 1.e-10 )
122            ! Rossby radius at w-point taken < 40km and  > 2km
123            zross(ji,jj) = MAX( MIN( .4 * zn(ji,jj) / zfw, 40.e3 ), 2.e3 )
124            ! Compute aeiw by multiplying Ro^2 and T^-1
125            aeiw(ji,jj) = zross(ji,jj) * zross(ji,jj) * SQRT( zah(ji,jj) / zhw(ji,jj) ) * tmask(ji,jj,1)
126            ! Take the minimum between aeiw and 1000m^2/s for depth levels
127            ! lower than 20 (21 in w- point)
128            IF( mbathy(ji,jj) <= 21. ) aeiw(ji,jj) = MIN( aeiw(ji,jj), 1000. )
129         END DO
130
131         ! Decrease the coefficient in the tropics (20N-20S)
132         zf20 = 2. * omega * sin( rad * 20. )
133         DO ji = 2, jpim1
134            aeiw(ji,jj) = MIN( 1., ABS( ff(ji,jj) / zf20 ) ) * aeiw(ji,jj)
135         END DO
136 
137         ! ORCA R05: Take the minimum between aeiw  and 1000m2/s
138         IF( cp_cfg == "orca" .AND. jp_cfg == 05 ) THEN   ! ORCA R05
139            DO ji = 2, jpim1
140               aeiw(ji,jj) = MIN( aeiw(ji,jj), 1000. )
141            END DO
142         ENDIF
143         !                                             ! ===============
144      END DO                                           !   End of slab
145      !                                                ! ===============
146
147      !,,,,,,,,,,,,,,,,,,,,,,,,,,,,,synchro,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,
148
149      ! lateral boundary condition on aeiw
150      CALL lbc_lnk( aeiw, 'W', 1. )
151
152      ! Average the diffusive coefficient at u- v- points
153      DO jj = 2, jpjm1
154         DO ji = fs_2, fs_jpim1   ! vector opt.
155            aeiu(ji,jj) = .5 * (aeiw(ji,jj) + aeiw(ji+1,jj  ))
156            aeiv(ji,jj) = .5 * (aeiw(ji,jj) + aeiw(ji  ,jj+1))
157         END DO
158      END DO 
159      !,,,,,,,,,,,,,,,,,,,,,,,,,,,,,synchro,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,
160
161      ! lateral boundary condition on aeiu, aeiv
162      CALL lbc_lnk( aeiu, 'U', 1. )
163      CALL lbc_lnk( aeiv, 'V', 1. )
164
165      IF(ln_ctl)   THEN
166         CALL prt_ctl(tab2d_1=aeiu, clinfo1=' eiv  - u: ', ovlap=1)
167         CALL prt_ctl(tab2d_1=aeiv, clinfo1=' eiv  - v: ', ovlap=1)
168      ENDIF
169     
170      ! ORCA R05: add a space variation on aht (=aeiv except at the equator and river mouth)
171      IF( cp_cfg == "orca" .AND. jp_cfg == 05 ) THEN
172         zf20     = 2. * omega * SIN( rad * 20. )
173         zaht_min = 100.                              ! minimum value for aht
174         DO jj = 1, jpj
175            DO ji = 1, jpi
176               zaht      = ( 1. -  MIN( 1., ABS( ff(ji,jj) / zf20 ) ) ) * ( aht0 - zaht_min )  &
177                  &      + aht0 * upsrnfh(ji,jj)                          ! enhanced near river mouths
178               ahtu(ji,jj) = MAX( MAX( zaht_min, aeiu(ji,jj) ) + zaht, aht0 )
179               ahtv(ji,jj) = MAX( MAX( zaht_min, aeiv(ji,jj) ) + zaht, aht0 )
180               ahtw(ji,jj) = MAX( MAX( zaht_min, aeiw(ji,jj) ) + zaht, aht0 )
181            END DO
182         END DO
183         IF(ln_ctl) THEN
184            CALL prt_ctl(tab2d_1=ahtu, clinfo1=' aht  - u: ', ovlap=1)
185            CALL prt_ctl(tab2d_1=ahtv, clinfo1=' aht  - v: ', ovlap=1)
186            CALL prt_ctl(tab2d_1=ahtw, clinfo1=' aht  - w: ', ovlap=1)
187         ENDIF
188      ENDIF
189
190   END SUBROUTINE ldf_eiv
191
192# else
193   !!----------------------------------------------------------------------
194   !!   Default key                                             k-j-i loops
195   !!----------------------------------------------------------------------
196
197   SUBROUTINE ldf_eiv( kt )
198      !!----------------------------------------------------------------------
199      !!                  ***  ROUTINE ldf_eiv  ***
200      !!
201      !! ** Purpose :   Compute the eddy induced velocity coefficient from the
202      !!      growth rate of baroclinic instability.
203      !!
204      !! ** Method :
205      !!
206      !! ** Action : - uslp(),  : i- and j-slopes of neutral surfaces
207      !!             - vslp()      at u- and v-points, resp.
208      !!             - wslpi(),  : i- and j-slopes of neutral surfaces
209      !!             - wslpj()     at w-points.
210      !!
211      !! History :
212      !!   8.1  !  99-03  (G. Madec, A. Jouzeau)  Original code
213      !!   8.5  !  02-06  (G. Madec)  Free form, F90
214      !!----------------------------------------------------------------------
215      !! * Arguments
216      INTEGER, INTENT( in ) ::   kt     ! ocean time-step inedx
217     
218      !! * Local declarations
219      INTEGER ::   ji, jj, jk           ! dummy loop indices
220      REAL(wp) ::   &
221         zfw, ze3w, zn2, zf20,       &  ! temporary scalars
222         zaht, zaht_min
223      REAL(wp), DIMENSION(jpi,jpj) ::   &
224         zn, zah, zhw, zross            ! workspace
225      !!----------------------------------------------------------------------
226     
227      IF( kt == nit000 ) THEN
228         IF(lwp) WRITE(numout,*)
229         IF(lwp) WRITE(numout,*) 'ldf_eiv : eddy induced velocity coefficients'
230         IF(lwp) WRITE(numout,*) '~~~~~~~'
231      ENDIF
232     
233      ! 0. Local initialization
234      ! -----------------------
235      zn   (:,:) = 0.e0
236      zhw  (:,:) = 5.e0
237      zah  (:,:) = 0.e0
238      zross(:,:) = 0.e0
239
240
241      ! 1. Compute lateral diffusive coefficient
242      ! ----------------------------------------
243
244      DO jk = 1, jpk
245#  if defined key_vectopt_loop  &&  ! defined key_autotasking
246!CDIR NOVERRCHK
247         DO ji = 1, jpij   ! vector opt.
248            ! Take the max of N^2 and zero then take the vertical sum
249            ! of the square root of the resulting N^2 ( required to compute
250            ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
251            zn2 = MAX( rn2(ji,1,jk), 0.e0 )
252            zn(ji,1) = zn(ji,1) + SQRT( zn2 ) * fse3w(ji,1,jk)
253            ! Compute elements required for the inverse time scale of baroclinic
254            ! eddies using the isopycnal slopes calculated in ldfslp.F :
255            ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
256            ze3w = fse3w(ji,1,jk) * tmask(ji,1,jk)
257               zah(ji,1) = zah(ji,1) + zn2   &
258                              * ( wslpi(ji,1,jk) * wslpi(ji,1,jk)    &
259                                + wslpj(ji,1,jk) * wslpj(ji,1,jk) )   &
260                              * ze3w
261            zhw(ji,1) = zhw(ji,1) + ze3w
262         END DO
263#  else
264         DO jj = 2, jpjm1
265!CDIR NOVERRCHK
266            DO ji = 2, jpim1
267               ! Take the max of N^2 and zero then take the vertical sum
268               ! of the square root of the resulting N^2 ( required to compute
269               ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
270               zn2 = MAX( rn2(ji,jj,jk), 0.e0 )
271               zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * fse3w(ji,jj,jk)
272               ! Compute elements required for the inverse time scale of baroclinic
273               ! eddies using the isopycnal slopes calculated in ldfslp.F :
274               ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
275               ze3w = fse3w(ji,jj,jk) * tmask(ji,jj,jk)
276               zah(ji,jj) = zah(ji,jj) + zn2   &
277                              * ( wslpi(ji,jj,jk) * wslpi(ji,jj,jk)    &
278                                + wslpj(ji,jj,jk) * wslpj(ji,jj,jk) )  &
279                              * ze3w
280               zhw(ji,jj) = zhw(ji,jj) + ze3w
281            END DO
282         END DO 
283#  endif
284      END DO
285
286      DO jj = 2, jpjm1
287!CDIR NOVERRCHK
288         DO ji = fs_2, fs_jpim1   ! vector opt.
289            zfw = MAX( ABS( 2. * omega * SIN( rad * gphit(ji,jj) ) ) , 1.e-10 )
290            ! Rossby radius at w-point taken < 40km and  > 2km
291            zross(ji,jj) = MAX( MIN( .4 * zn(ji,jj) / zfw, 40.e3 ), 2.e3 )
292            ! Compute aeiw by multiplying Ro^2 and T^-1
293            aeiw(ji,jj) = zross(ji,jj) * zross(ji,jj) * SQRT( zah(ji,jj) / zhw(ji,jj) ) * tmask(ji,jj,1)
294            ! Take the minimum between aeiw and 1000m^2/s for depth levels
295            ! lower than 20 (21 in w- point)
296            IF( mbathy(ji,jj) <= 21. ) aeiw(ji,jj) = MIN( aeiw(ji,jj), 1000. )
297         END DO
298      END DO
299
300      ! Decrease the coefficient in the tropics (20N-20S)
301         zf20 = 2. * omega * sin( rad * 20. )
302      DO jj = 2, jpjm1
303         DO ji = fs_2, fs_jpim1   ! vector opt.
304            aeiw(ji,jj) = MIN( 1., ABS( ff(ji,jj) / zf20 ) ) * aeiw(ji,jj)
305         END DO
306      END DO
307
308      ! ORCA R05: Take the minimum between aeiw  and 1000m2/s
309      IF( cp_cfg == "orca" .AND. jp_cfg == 05 ) THEN
310         DO jj = 2, jpjm1
311            DO ji = fs_2, fs_jpim1   ! vector opt.
312               aeiw(ji,jj) = MIN( aeiw(ji,jj), aeiv0 )
313            END DO
314         END DO
315      ENDIF
316
317      ! lateral boundary condition on aeiw
318      CALL lbc_lnk( aeiw, 'W', 1. )
319
320      ! Average the diffusive coefficient at u- v- points
321      DO jj = 2, jpjm1
322         DO ji = fs_2, fs_jpim1   ! vector opt.
323            aeiu(ji,jj) = .5 * ( aeiw(ji,jj) + aeiw(ji+1,jj  ) )
324            aeiv(ji,jj) = .5 * ( aeiw(ji,jj) + aeiw(ji  ,jj+1) )
325         END DO
326      END DO 
327
328      ! lateral boundary condition on aeiu, aeiv
329      CALL lbc_lnk( aeiu, 'U', 1. )
330      CALL lbc_lnk( aeiv, 'V', 1. )
331
332      IF(ln_ctl)   THEN
333         CALL prt_ctl(tab2d_1=aeiu, clinfo1=' eiv  - u: ', ovlap=1)
334         CALL prt_ctl(tab2d_1=aeiv, clinfo1=' eiv  - v: ', ovlap=1)
335      ENDIF
336
337      ! ORCA R05: add a space variation on aht (=aeiv except at the equator and river mouth)
338      IF( cp_cfg == "orca" .AND. jp_cfg == 05 ) THEN
339         zf20     = 2. * omega * SIN( rad * 20. )
340         zaht_min = 100.                              ! minimum value for aht
341         DO jj = 1, jpj
342            DO ji = 1, jpi
343               zaht      = ( 1. -  MIN( 1., ABS( ff(ji,jj) / zf20 ) ) ) * ( aht0 - zaht_min )  &
344                  &      + aht0 * upsrnfh(ji,jj)                          ! enhanced near river mouths
345               ahtu(ji,jj) = MAX( MAX( zaht_min, aeiu(ji,jj) ) + zaht, aht0 )
346               ahtv(ji,jj) = MAX( MAX( zaht_min, aeiv(ji,jj) ) + zaht, aht0 )
347               ahtw(ji,jj) = MAX( MAX( zaht_min, aeiw(ji,jj) ) + zaht, aht0 )
348            END DO
349         END DO
350         IF(ln_ctl) THEN
351            CALL prt_ctl(tab2d_1=ahtu, clinfo1=' aht  - u: ', ovlap=1)
352            CALL prt_ctl(tab2d_1=ahtv, clinfo1=' aht  - v: ', ovlap=1)
353            CALL prt_ctl(tab2d_1=ahtw, clinfo1=' aht  - w: ', ovlap=1)
354         ENDIF
355      ENDIF
356
357   END SUBROUTINE ldf_eiv
358
359# endif
360
361#else
362   !!----------------------------------------------------------------------
363   !!   Default option                                         Dummy module
364   !!----------------------------------------------------------------------
365CONTAINS
366   SUBROUTINE ldf_eiv( kt )       ! Empty routine
367      WRITE(*,*) 'ldf_eiv: You should not have seen this print! error?', kt
368   END SUBROUTINE ldf_eiv
369#endif
370
371   !!======================================================================
372END MODULE ldfeiv
Note: See TracBrowser for help on using the repository browser.