New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
ldfslp.F90 in trunk/NEMO/OPA_SRC/LDF – NEMO

source: trunk/NEMO/OPA_SRC/LDF/ldfslp.F90 @ 2389

Last change on this file since 2389 was 2389, checked in by smasson, 13 years ago

ticket #435, bug fix on uslpml and vslpml
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 29.9 KB
Line 
1MODULE ldfslp
2   !!======================================================================
3   !!                       ***  MODULE  ldfslp  ***
4   !! Ocean physics: slopes of neutral surfaces
5   !!======================================================================
6   !! History :  OPA  ! 1994-12  (G. Madec, M. Imbard)  Original code
7   !!            8.0  ! 1997-06  (G. Madec)  optimization, lbc
8   !!            8.1  ! 1999-10  (A. Jouzeau)  NEW profile in the mixed layer
9   !!   NEMO     0.5  ! 2002-10  (G. Madec)  Free form, F90
10   !!            1.0  ! 2005-10  (A. Beckmann)  correction for s-coordinates
11   !!            3.2  ! 2010-11  (F. Dupond, G. Madec)  bug correction in slopes just below the ML
12   !!----------------------------------------------------------------------
13#if   defined key_ldfslp   ||   defined key_esopa
14   !!----------------------------------------------------------------------
15   !!   'key_ldfslp'                      Rotation of lateral mixing tensor
16   !!----------------------------------------------------------------------
17   !!   ldf_slp      : compute the slopes of iso-neutral surface
18   !!   ldf_slp_mxl  : compute the slopes of iso-neutral surface just below the Mixed Layer
19   !!   ldf_slp_init : initialization of the slopes computation
20   !!----------------------------------------------------------------------
21   USE oce             ! ocean dynamics and tracers
22   USE dom_oce         ! ocean space and time domain
23   USE ldftra_oce
24   USE ldfdyn_oce
25   USE phycst          ! physical constants
26   USE zdfmxl          ! mixed layer depth
27   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
28   USE in_out_manager  ! I/O manager
29   USE prtctl          ! Print control
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   ldf_slp    ! routine called by step.F90
35
36   LOGICAL , PUBLIC, PARAMETER              ::   lk_ldfslp = .TRUE.   !: slopes flag
37   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   uslp, wslpi          !: i_slope at U- and W-points
38   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   vslp, wslpj          !: j-slope at V- and W-points
39   
40   REAL(wp), DIMENSION(jpi,jpj,jpk) ::   omlmask           ! mask of the surface mixed layer at T-pt
41   REAL(wp), DIMENSION(jpi,jpj)     ::   uslpml, wslpiml   ! i_slope at U- and W-points just below the mixed layer
42   REAL(wp), DIMENSION(jpi,jpj)     ::   vslpml, wslpjml   ! j_slope at V- and W-points just below the mixed layer
43
44   !! * Substitutions
45#  include "domzgr_substitute.h90"
46#  include "vectopt_loop_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.2 , LOCEAN-IPSL (2009)
49   !! $Id$
50   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52
53CONTAINS
54
55   SUBROUTINE ldf_slp( kt, prd, pn2 )
56      !!----------------------------------------------------------------------
57      !!                 ***  ROUTINE ldf_slp  ***
58      !!
59      !! ** Purpose :   Compute the slopes of neutral surface (slope of isopycnal
60      !!              surfaces referenced locally) ('key_traldfiso').
61      !!
62      !! ** Method  :   The slope in the i-direction is computed at U- and
63      !!      W-points (uslp, wslpi) and the slope in the j-direction is
64      !!      computed at V- and W-points (vslp, wslpj).
65      !!      They are bounded by 1/100 over the whole ocean, and within the
66      !!      surface layer they are bounded by the distance to the surface
67      !!      ( slope<= depth/l  where l is the length scale of horizontal
68      !!      diffusion (here, aht=2000m2/s ==> l=20km with a typical velocity
69      !!      of 10cm/s)
70      !!        A horizontal shapiro filter is applied to the slopes
71      !!        ln_sco=T, s-coordinate, add to the previously computed slopes
72      !!      the slope of the model level surface.
73      !!        macro-tasked on horizontal slab (jk-loop)  (2, jpk-1)
74      !!      [slopes already set to zero at level 1, and to zero or the ocean
75      !!      bottom slope (ln_sco=T) at level jpk in inildf]
76      !!
77      !! ** Action : - uslp, wslpi, and vslp, wslpj, the i- and  j-slopes
78      !!               of now neutral surfaces at u-, w- and v- w-points, resp.
79      !!----------------------------------------------------------------------
80      USE oce , zgru  => ua   ! use ua as workspace
81      USE oce , zgrv  => va   ! use va as workspace
82      USE oce , zwy   => ta   ! use ta as workspace
83      USE oce , zwz   => sa   ! use sa as workspace
84      !!
85      INTEGER , INTENT(in)                         ::   kt    ! ocean time-step index
86      REAL(wp), INTENT(in), DIMENSION(jpi,jpj,jpk) ::   prd   ! in situ density
87      REAL(wp), INTENT(in), DIMENSION(jpi,jpj,jpk) ::   pn2   ! Brunt-Vaisala frequency (locally ref.)
88      !!
89      INTEGER  ::   ji , jj , jk    ! dummy loop indices
90      INTEGER  ::   ii0, ii1, iku   ! temporary integer
91      INTEGER  ::   ij0, ij1, ikv   ! temporary integer
92      REAL(wp) ::   zeps, zmg, zm05g, zalpha        ! temporary scalars
93      REAL(wp) ::   zcoef1, zcoef2, zcoef3          !    -         -
94      REAL(wp) ::   zcofu , zcofv , zcofw           !    -         -
95      REAL(wp) ::   zau, zbu, zai, zbi, z1u, z1wu   !    -         -
96      REAL(wp) ::   zav, zbv, zaj, zbj, z1v, z1wv   !
97      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zww     ! 3D workspace
98      !!----------------------------------------------------------------------
99     
100      IF( kt == nit000 )   CALL ldf_slp_init      ! initialization (first time-step only)
101
102      zeps  =  1.e-20                             ! Local constant initialization
103      zmg   = -1.0 / grav
104      zm05g = -0.5 / grav
105      !
106      zww(:,:,:) = 0.e0
107      zwz(:,:,:) = 0.e0
108      !                                           ! horizontal density gradient computation
109      DO jk = 1, jpk
110         DO jj = 1, jpjm1
111            DO ji = 1, fs_jpim1   ! vector opt.
112               zgru(ji,jj,jk) = umask(ji,jj,jk) * ( prd(ji+1,jj  ,jk) - prd(ji,jj,jk) ) 
113               zgrv(ji,jj,jk) = vmask(ji,jj,jk) * ( prd(ji  ,jj+1,jk) - prd(ji,jj,jk) ) 
114            END DO
115         END DO
116      END DO
117      IF( ln_zps ) THEN                           ! partial steps correction at the bottom ocean level
118# if defined key_vectopt_loop 
119         DO jj = 1, 1
120            DO ji = 1, jpij-jpi   ! vector opt. (forced unrolling)
121# else
122         DO jj = 1, jpjm1
123            DO ji = 1, jpim1
124# endif
125               iku = MIN ( mbathy(ji,jj), mbathy(ji+1,jj) ) - 1               ! last ocean level
126               ikv = MIN ( mbathy(ji,jj), mbathy(ji,jj+1) ) - 1
127               zgru(ji,jj,iku) = gru(ji,jj) 
128               zgrv(ji,jj,ikv) = grv(ji,jj)               
129            END DO
130         END DO
131      ENDIF
132     
133
134      !                                           !* Local vertical density gradient evaluated from N^2
135      DO jk = 2, jpkm1                            !  zwy = d/dz(prd)= - ( prd ) / grav * mk(pn2) -- at t point
136         zwy(:,:,jk) = zmg * ( prd(:,:,jk) + 1. ) * (    pn2  (:,:,jk) + pn2  (:,:,jk+1)     )   &
137            &                                     / MAX( tmask(:,:,jk) + tmask(:,:,jk+1), 1. )
138      END DO
139      zwy(:,:,1) = 0.e0                           !  surface value set to zero
140
141     
142      CALL ldf_slp_mxl( prd, pn2 )                !* Slopes of isopycnal surfaces just below the mixed layer
143     
144     
145      ! I.  slopes at u and v point      | uslp = d/di( prd ) / d/dz( prd )
146      ! ===========================      | vslp = d/dj( prd ) / d/dz( prd )
147      !               
148      DO jk = 2, jpkm1                            !* Slopes at u and v points
149         DO jj = 2, jpjm1
150            DO ji = fs_2, fs_jpim1   ! vector opt.
151               ! horizontal and vertical density gradient at u- and v-points
152               zau = 1. / e1u(ji,jj) * zgru(ji,jj,jk)
153               zav = 1. / e2v(ji,jj) * zgrv(ji,jj,jk)
154               zbu = 0.5 * ( zwy(ji,jj,jk) + zwy(ji+1,jj  ,jk) )
155               zbv = 0.5 * ( zwy(ji,jj,jk) + zwy(ji  ,jj+1,jk) )
156               ! bound the slopes: abs(zw.)<= 1/100 and zb..<0
157               !                   kxz max= ah slope max =< e1 e3 /(pi**2 2 dt)
158               zbu = MIN( zbu, -100.*ABS( zau ), -7.e+3/fse3u(ji,jj,jk)*ABS( zau ) )
159               zbv = MIN( zbv, -100.*ABS( zav ), -7.e+3/fse3v(ji,jj,jk)*ABS( zav ) )
160               ! uslp and vslp output in zwz and zww, resp.
161               zalpha = MAX( omlmask(ji,jj,jk), omlmask(ji+1,jj,jk) )
162               zwz (ji,jj,jk) = ( ( 1. - zalpha) * zau / ( zbu - zeps )                                           &
163                  &                    + zalpha  * uslpml(ji,jj)                                                  &
164                  &                              * 0.5 * ( fsdept(ji+1,jj,jk)+fsdept(ji,jj,jk)-fse3u(ji,jj,1) )   &
165                  &                              / MAX( hmlpt(ji,jj), hmlpt(ji+1,jj), 5. ) ) * umask(ji,jj,jk)
166               zalpha = MAX( omlmask(ji,jj,jk), omlmask(ji,jj+1,jk) )
167               zww (ji,jj,jk) = ( ( 1. - zalpha) * zav / ( zbv - zeps )                                           &
168                  &                    + zalpha  * vslpml(ji,jj)                                                  &
169                  &                              * 0.5 * ( fsdept(ji,jj+1,jk)+fsdept(ji,jj,jk)-fse3v(ji,jj,1) )   &
170                  &                              / MAX( hmlpt(ji,jj), hmlpt(ji,jj+1), 5. ) ) * vmask(ji,jj,jk)
171            END DO
172         END DO
173      END DO
174      CALL lbc_lnk( zwz, 'U', -1. )   ;   CALL lbc_lnk( zww, 'V', -1. )      ! lateral boundary conditions
175      !
176      zcofu = 1. / 16.                            !* horizontal Shapiro filter
177      zcofv = 1. / 16.
178      DO jk = 2, jpkm1
179         DO jj = 2, jpjm1, jpj-3                        ! rows jj=2 and =jpjm1 only
180            DO ji = 2, jpim1 
181               uslp(ji,jj,jk) = zcofu * (        zwz(ji-1,jj-1,jk) + zwz(ji+1,jj-1,jk)      &
182                  &                       +      zwz(ji-1,jj+1,jk) + zwz(ji+1,jj+1,jk)      &
183                  &                       + 2.*( zwz(ji  ,jj-1,jk) + zwz(ji-1,jj  ,jk)      &
184                  &                       +      zwz(ji+1,jj  ,jk) + zwz(ji  ,jj+1,jk) )    &
185                  &                       + 4.*  zwz(ji  ,jj  ,jk)                       )
186               vslp(ji,jj,jk) = zcofv * (        zww(ji-1,jj-1,jk) + zww(ji+1,jj-1,jk)      &
187                  &                       +      zww(ji-1,jj+1,jk) + zww(ji+1,jj+1,jk)      &
188                  &                       + 2.*( zww(ji  ,jj-1,jk) + zww(ji-1,jj  ,jk)      &
189                  &                       +      zww(ji+1,jj  ,jk) + zww(ji  ,jj+1,jk) )    &
190                  &                       + 4.*  zww(ji,jj    ,jk)                       )
191            END DO
192         END DO
193         DO jj = 3, jpj-2                               ! other rows
194            DO ji = fs_2, fs_jpim1   ! vector opt.
195               uslp(ji,jj,jk) = zcofu * (        zwz(ji-1,jj-1,jk) + zwz(ji+1,jj-1,jk)      &
196                  &                       +      zwz(ji-1,jj+1,jk) + zwz(ji+1,jj+1,jk)      &
197                  &                       + 2.*( zwz(ji  ,jj-1,jk) + zwz(ji-1,jj  ,jk)      &
198                  &                       +      zwz(ji+1,jj  ,jk) + zwz(ji  ,jj+1,jk) )    &
199                  &                       + 4.*  zwz(ji  ,jj  ,jk)                       )
200               vslp(ji,jj,jk) = zcofv * (        zww(ji-1,jj-1,jk) + zww(ji+1,jj-1,jk)      &
201                  &                       +      zww(ji-1,jj+1,jk) + zww(ji+1,jj+1,jk)      &
202                  &                       + 2.*( zww(ji  ,jj-1,jk) + zww(ji-1,jj  ,jk)      &
203                  &                       +      zww(ji+1,jj  ,jk) + zww(ji  ,jj+1,jk) )    &
204                  &                       + 4.*  zww(ji,jj    ,jk)                       )
205            END DO
206         END DO
207         !                                        !* decrease along coastal boundaries
208         DO jj = 2, jpjm1
209            DO ji = fs_2, fs_jpim1   ! vector opt.
210               z1u  = ( umask(ji,jj+1,jk) + umask(ji,jj-1,jk) )*.5
211               z1v  = ( vmask(ji+1,jj,jk) + vmask(ji-1,jj,jk) )*.5
212               z1wu = ( umask(ji,jj,jk)   + umask(ji,jj,jk+1) )*.5
213               z1wv = ( vmask(ji,jj,jk)   + vmask(ji,jj,jk+1) )*.5
214               uslp(ji,jj,jk) = uslp(ji,jj,jk) * z1u * z1wu
215               vslp(ji,jj,jk) = vslp(ji,jj,jk) * z1v * z1wv
216            END DO
217         END DO
218      END DO
219
220
221      ! II.  slopes at w point           | wslpi = mij( d/di( prd ) / d/dz( prd )
222      ! ===========================      | wslpj = mij( d/dj( prd ) / d/dz( prd )
223      !               
224      !                                           !* Local vertical density gradient evaluated from N^2
225      DO jk = 2, jpkm1                            !  zwy = d/dz(prd)= - mk ( prd ) / grav * pn2 -- at w point
226         DO jj = 1, jpj
227            DO ji = 1, jpi
228               zwy(ji,jj,jk) = zm05g * pn2 (ji,jj,jk) * ( prd (ji,jj,jk) + prd (ji,jj,jk-1) + 2. )
229            END DO
230         END DO
231      END DO
232      DO jk = 2, jpkm1                            !* Slopes at w point
233         DO jj = 2, jpjm1
234            DO ji = fs_2, fs_jpim1   ! vector opt.
235               !                                        ! horizontal density i-gradient at w-points
236               zcoef1 = MAX( zeps, umask(ji-1,jj,jk  )+umask(ji,jj,jk  )    &
237                  &               +umask(ji-1,jj,jk-1)+umask(ji,jj,jk-1) )
238               zcoef1 = 1. / ( zcoef1 * e1t (ji,jj) )
239               zai = zcoef1 * (  zgru(ji  ,jj,jk  ) + zgru(ji  ,jj,jk-1)   &
240                  &            + zgru(ji-1,jj,jk-1) + zgru(ji-1,jj,jk  ) ) * tmask (ji,jj,jk)
241               !                                        ! horizontal density j-gradient at w-points
242               zcoef2 = MAX( zeps, vmask(ji,jj-1,jk  )+vmask(ji,jj,jk-1)   &
243                  &               +vmask(ji,jj-1,jk-1)+vmask(ji,jj,jk  ) )
244               zcoef2 = 1.0 / ( zcoef2 *  e2t (ji,jj) )
245               zaj = zcoef2 * (  zgrv(ji,jj  ,jk  ) + zgrv(ji,jj  ,jk-1)   &
246                  &            + zgrv(ji,jj-1,jk-1) + zgrv(ji,jj-1,jk  ) ) * tmask (ji,jj,jk)
247               !                                        ! bound the slopes: abs(zw.)<= 1/100 and zb..<0.
248               !                                        ! static instability: kxz max= ah slope max =< e1 e3 /(pi**2 2 dt)
249               zbi = MIN( zwy (ji,jj,jk),- 100.*ABS(zai), -7.e+3/fse3w(ji,jj,jk)*ABS(zai) )
250               zbj = MIN( zwy (ji,jj,jk), -100.*ABS(zaj), -7.e+3/fse3w(ji,jj,jk)*ABS(zaj) )
251               !                                        ! wslpi and wslpj output in zwz and zww, resp.
252               zalpha = MAX( omlmask(ji,jj,jk), omlmask(ji,jj,jk-1) )
253               zcoef3 = fsdepw(ji,jj,jk) / MAX( hmlp(ji,jj), 10. )
254               zwz(ji,jj,jk) = (     zai / ( zbi - zeps)  * ( 1. - zalpha )   &
255                  &             + zcoef3 * wslpiml(ji,jj) *        zalpha   ) * tmask (ji,jj,jk)
256               zww(ji,jj,jk) = (     zaj / ( zbj - zeps)  * ( 1. - zalpha )   &
257                  &             + zcoef3 * wslpjml(ji,jj) *        zalpha   ) * tmask (ji,jj,jk)
258            END DO
259         END DO
260      END DO
261      CALL lbc_lnk( zwz, 'T', -1. )   ;    CALL lbc_lnk( zww, 'T', -1. )      ! lateral boundary conditions on zwz and zww
262      !
263      !                                           !* horizontal Shapiro filter
264      DO jk = 2, jpkm1
265         DO jj = 2, jpjm1, jpj-3                        ! rows jj=2 and =jpjm1
266            DO ji = 2, jpim1
267               zcofw = tmask(ji,jj,jk) / 16.
268               wslpi(ji,jj,jk) = (        zwz(ji-1,jj-1,jk) + zwz(ji+1,jj-1,jk)     &
269                  &                +      zwz(ji-1,jj+1,jk) + zwz(ji+1,jj+1,jk)     &
270                  &                + 2.*( zwz(ji  ,jj-1,jk) + zwz(ji-1,jj  ,jk)     &
271                  &                +      zwz(ji+1,jj  ,jk) + zwz(ji  ,jj+1,jk) )   &
272                  &                + 4.*  zwz(ji  ,jj  ,jk)                        ) * zcofw
273
274               wslpj(ji,jj,jk) = (        zww(ji-1,jj-1,jk) + zww(ji+1,jj-1,jk)     &
275                  &                +      zww(ji-1,jj+1,jk) + zww(ji+1,jj+1,jk)     &
276                  &                + 2.*( zww(ji  ,jj-1,jk) + zww(ji-1,jj  ,jk)     &
277                  &                +      zww(ji+1,jj  ,jk) + zww(ji  ,jj+1,jk) )   &
278                  &                + 4.*  zww(ji  ,jj  ,jk)                        ) * zcofw
279            END DO
280         END DO 
281         DO jj = 3, jpj-2                               ! other rows
282            DO ji = fs_2, fs_jpim1   ! vector opt.
283               zcofw = tmask(ji,jj,jk) / 16.
284               wslpi(ji,jj,jk) = (        zwz(ji-1,jj-1,jk) + zwz(ji+1,jj-1,jk)     &
285                  &                +      zwz(ji-1,jj+1,jk) + zwz(ji+1,jj+1,jk)     &
286                  &                + 2.*( zwz(ji  ,jj-1,jk) + zwz(ji-1,jj  ,jk)     &
287                  &                +      zwz(ji+1,jj  ,jk) + zwz(ji  ,jj+1,jk) )   &
288                  &                + 4.*  zwz(ji  ,jj  ,jk)                        ) * zcofw
289
290               wslpj(ji,jj,jk) = (        zww(ji-1,jj-1,jk) + zww(ji+1,jj-1,jk)     &
291                  &                +      zww(ji-1,jj+1,jk) + zww(ji+1,jj+1,jk)     &
292                  &                + 2.*( zww(ji  ,jj-1,jk) + zww(ji-1,jj  ,jk)     &
293                  &                +      zww(ji+1,jj  ,jk) + zww(ji  ,jj+1,jk) )   &
294                  &                + 4.*  zww(ji  ,jj  ,jk)                        ) * zcofw
295            END DO
296         END DO
297         !                                        !* decrease along coastal boundaries
298         DO jj = 2, jpjm1
299            DO ji = fs_2, fs_jpim1   ! vector opt.
300               z1u = ( umask(ji,jj,jk) + umask(ji-1,jj,jk) ) *.5
301               z1v = ( vmask(ji,jj,jk) + vmask(ji,jj-1,jk) ) *.5
302               wslpi(ji,jj,jk) = wslpi(ji,jj,jk) * z1u * z1v
303               wslpj(ji,jj,jk) = wslpj(ji,jj,jk) * z1u * z1v
304            END DO
305         END DO
306      END DO
307         
308
309      ! III.  Specific grid points     
310      ! ===========================
311      !               
312      IF( cp_cfg == "orca" .AND. jp_cfg == 4 ) THEN     !  ORCA_R4 configuration: horizontal diffusion in specific area
313         !                                                    ! Gibraltar Strait
314         ij0 =  50   ;   ij1 =  53
315         ii0 =  69   ;   ii1 =  71   ;   uslp ( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , : ) = 0.e0
316         ij0 =  51   ;   ij1 =  53
317         ii0 =  68   ;   ii1 =  71   ;   vslp ( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , : ) = 0.e0
318         ii0 =  69   ;   ii1 =  71   ;   wslpi( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , : ) = 0.e0
319         ii0 =  69   ;   ii1 =  71   ;   wslpj( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , : ) = 0.e0
320         !
321         !                                                    ! Mediterrannean Sea
322         ij0 =  49   ;   ij1 =  56
323         ii0 =  71   ;   ii1 =  90   ;   uslp ( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , : ) = 0.e0
324         ij0 =  50   ;   ij1 =  56
325         ii0 =  70   ;   ii1 =  90   ;   vslp ( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , : ) = 0.e0
326         ii0 =  71   ;   ii1 =  90   ;   wslpi( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , : ) = 0.e0
327         ii0 =  71   ;   ii1 =  90   ;   wslpj( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , : ) = 0.e0
328      ENDIF
329
330     
331      ! IV. Lateral boundary conditions
332      ! ===============================
333      CALL lbc_lnk( uslp , 'U', -1. )      ;      CALL lbc_lnk( vslp , 'V', -1. )
334      CALL lbc_lnk( wslpi, 'W', -1. )      ;      CALL lbc_lnk( wslpj, 'W', -1. )
335
336
337      IF(ln_ctl) THEN
338         CALL prt_ctl(tab3d_1=uslp , clinfo1=' slp  - u : ', tab3d_2=vslp,  clinfo2=' v : ', kdim=jpk)
339         CALL prt_ctl(tab3d_1=wslpi, clinfo1=' slp  - wi: ', tab3d_2=wslpj, clinfo2=' wj: ', kdim=jpk)
340      ENDIF
341      !
342   END SUBROUTINE ldf_slp
343
344
345   SUBROUTINE ldf_slp_mxl( prd, pn2 )
346      !!----------------------------------------------------------------------
347      !!                  ***  ROUTINE ldf_slp_mxl  ***
348      !!
349      !! ** Purpose :   Compute the slopes of iso-neutral surface just below
350      !!              the mixed layer.
351      !!
352      !! ** Method  :   caution: use zgru, zgrv and zwy computed in ldf_slp
353      !!
354      !! ** Action  :   uslpml, wslpiml :  i- &  j-slopes of neutral surfaces
355      !!                vslpml, wslpjml    just below the mixed layer
356      !!                omlmask         :  mixed layer mask
357      !!----------------------------------------------------------------------
358      USE oce , zgru  => ua   ! zgru, zgrv (ua, va used as workspace) 
359      USE oce , zgrv  => va   ! set to i- & j-density gradient in ldf_slp
360      USE oce , zwy   => ta   ! set to vertical density gradient at T-point in ldfslp
361      !!
362      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in) ::   prd   ! in situ density
363      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in) ::   pn2   ! Brunt-Vaisala frequency (locally ref.)
364      !!
365      INTEGER  ::   ji, jj, jk           ! dummy loop indices
366      INTEGER  ::   ik, ikm1             ! temporary integers
367      REAL(wp) ::   zeps, zmg, zm05g     ! temporary scalars
368      REAL(wp) ::   zcoef1, zcoef2       !    -         -
369      REAL(wp) ::   zau, zbu, zai, zbi   !    -         -
370      REAL(wp) ::   zav, zbv, zaj, zbj   !    -         -
371      REAL(wp) ::        zbw             !    -         -
372      !!----------------------------------------------------------------------
373
374      zeps  =  1.e-20                    ! Local constant initialization
375      zmg   = -1.0 / grav
376      zm05g = -0.5 / grav
377      !
378      uslpml (1,:) = 0.e0      ;      uslpml (jpi,:) = 0.e0
379      vslpml (1,:) = 0.e0      ;      vslpml (jpi,:) = 0.e0
380      wslpiml(1,:) = 0.e0      ;      wslpiml(jpi,:) = 0.e0
381      wslpjml(1,:) = 0.e0      ;      wslpjml(jpi,:) = 0.e0
382
383      !                                  ! surface mixed layer mask
384      DO jk = 1, jpk                          ! =1 inside the mixed layer, =0 otherwise
385# if defined key_vectopt_loop
386         DO jj = 1, 1
387            DO ji = 1, jpij   ! vector opt. (forced unrolling)
388# else
389         DO jj = 1, jpj
390            DO ji = 1, jpi
391# endif
392               ik = nmln(ji,jj) - 1
393               IF( jk <= ik ) THEN   ;   omlmask(ji,jj,jk) = 1.e0
394               ELSE                  ;   omlmask(ji,jj,jk) = 0.e0
395               ENDIF
396            END DO
397         END DO
398      END DO
399
400
401      ! Slopes of isopycnal surfaces just before bottom of mixed layer
402      ! --------------------------------------------------------------
403      ! The slope are computed as in the 3D case.
404      ! A key point here is the definition of the mixed layer at u- and v-points.
405      ! It is assumed to be the maximum of the two neighbouring T-point mixed layer depth.
406      ! Otherwise, a n2 value inside the mixed layer can be involved in the computation
407      ! of the slope, resulting in a too steep diagnosed slope and thus a spurious eddy
408      ! induce velocity field near the base of the mixed layer.
409      !-----------------------------------------------------------------------
410      !
411      !                            !* Slope at u points
412# if defined key_vectopt_loop
413      DO jj = 1, 1
414         DO ji = jpi+2, jpij-jpi-1   ! vector opt. (forced unrolling)
415# else
416      DO jj = 2, jpjm1
417         DO ji = 2, jpim1
418# endif
419            ! horizontal and vertical density gradient at u-points
420            ik = MAX( 1, nmln(ji,jj) , nmln(ji+1,jj) )
421            ik = MIN( ik, jpkm1 )
422            zau = 1./ e1u(ji,jj) * zgru(ji,jj,ik)
423            zbu = 0.5*( zwy(ji,jj,ik) + zwy(ji+1,jj,ik) )
424            ! bound the slopes: abs(zw.)<= 1/100 and zb..<0
425            !                         kxz max= ah slope max =< e1 e3 /(pi**2 2 dt)
426            zbu = MIN( zbu, -100.*ABS(zau), -7.e+3/fse3u(ji,jj,ik)*ABS(zau) )
427            ! uslpml
428            uslpml (ji,jj) = zau / ( zbu - zeps ) * umask (ji,jj,ik)
429         END DO
430      END DO
431      CALL lbc_lnk( uslpml, 'U', -1. )      ! lateral boundary conditions (i-gradient => sign change)
432
433      !                            !* Slope at v points
434# if defined key_vectopt_loop
435      DO jj = 1, 1
436         DO ji = jpi+2, jpij-jpi-1   ! vector opt. (forced unrolling)
437# else
438      DO jj = 2, jpjm1
439         DO ji = 2, jpim1
440# endif
441            ! horizontal and vertical density gradient at v-points
442            ik = MAX( 1, nmln(ji,jj) , nmln(ji,jj+1) )
443            ik = MIN( ik,jpkm1 )
444            zav = 1./ e2v(ji,jj) * zgrv(ji,jj,ik)
445            zbv = 0.5*( zwy(ji,jj,ik) + zwy(ji,jj+1,ik) )
446            ! bound the slopes: abs(zw.)<= 1/100 and zb..<0
447            !                         kxz max= ah slope max =< e1 e3 /(pi**2 2 dt)
448            zbv = MIN( zbv, -100.*ABS(zav), -7.e+3/fse3v(ji,jj,ik)*ABS( zav ) )
449            ! vslpml
450            vslpml (ji,jj) = zav / ( zbv - zeps ) * vmask (ji,jj,ik)
451         END DO
452      END DO
453      CALL lbc_lnk( vslpml, 'V', -1. )      ! lateral boundary conditions (j-gradient => sign change)
454
455      !                            !* Slopes at w points
456# if defined key_vectopt_loop
457      DO jj = 1, 1
458         DO ji = jpi+2, jpij-jpi-1   ! vector opt. (forced unrolling)
459# else
460      DO jj = 2, jpjm1
461         DO ji = 2, jpim1
462# endif
463            ik = nmln(ji,jj) + 1
464            ik = MIN( ik, jpk )
465            ikm1 = MAX ( 1, ik-1 )
466            ! horizontal density i-gradient at w-points
467            zcoef1 = MAX( zeps, umask(ji-1,jj,ik  )+umask(ji,jj,ik  )   &
468               &               +umask(ji-1,jj,ikm1)+umask(ji,jj,ikm1) )
469            zcoef1 = 1. / ( zcoef1 * e1t (ji,jj) )
470            zai = zcoef1 * (  zgru(ji  ,jj,ik  ) + zgru(ji  ,jj,ikm1)   &
471               &            + zgru(ji-1,jj,ikm1) + zgru(ji-1,jj,ik  ) ) * tmask (ji,jj,ik)
472            ! horizontal density j-gradient at w-points
473            zcoef2 = MAX( zeps, vmask(ji,jj-1,ik  )+vmask(ji,jj,ikm1)    &
474               &               +vmask(ji,jj-1,ikm1)+vmask(ji,jj,ik  ) )
475            zcoef2 = 1.0 / ( zcoef2 *  e2t (ji,jj) )
476            zaj = zcoef2 * (  zgrv(ji,jj  ,ik  ) + zgrv(ji,jj  ,ikm1)   &
477               &            + zgrv(ji,jj-1,ikm1) + zgrv(ji,jj-1,ik  ) ) * tmask (ji,jj,ik)
478            ! vertical density gradient at w-point (from N^2)
479            zbw = zm05g * pn2 (ji,jj,ik) * ( prd (ji,jj,ik) + prd (ji,jj,ikm1) + 2. )
480            ! bound the slopes: abs(zw.)<= 1/100 and zb..<0.
481            !                   static instability:
482            !                   kxz max= ah slope max =< e1 e3 /(pi**2 2 dt)
483            zbi = MIN ( zbw,- 100.*ABS(zai), -7.e+3/fse3w(ji,jj,ik)*ABS(zai) )
484            zbj = MIN ( zbw, -100.*ABS(zaj), -7.e+3/fse3w(ji,jj,ik)*ABS(zaj) )
485            ! wslpiml and wslpjml
486            wslpiml (ji,jj) = zai / ( zbi - zeps) * tmask (ji,jj,ik)
487            wslpjml (ji,jj) = zaj / ( zbj - zeps) * tmask (ji,jj,ik)
488         END DO
489      END DO
490      CALL lbc_lnk( wslpiml, 'W', -1. )   ;   CALL lbc_lnk( wslpjml, 'W', -1. )      ! lateral boundary conditions
491      !
492   END SUBROUTINE ldf_slp_mxl
493
494
495   SUBROUTINE ldf_slp_init
496      !!----------------------------------------------------------------------
497      !!                  ***  ROUTINE ldf_slp_init  ***
498      !!
499      !! ** Purpose :   Initialization for the isopycnal slopes computation
500      !!
501      !! ** Method  :   read the nammbf namelist and check the parameter
502      !!      values called by tra_dmp at the first timestep (nit000)
503      !!----------------------------------------------------------------------
504      INTEGER ::   ji, jj, jk   ! dummy loop indices
505      !!----------------------------------------------------------------------
506     
507      IF(lwp) THEN   
508         WRITE(numout,*)
509         WRITE(numout,*) 'ldf_slp : direction of lateral mixing'
510         WRITE(numout,*) '~~~~~~~'
511      ENDIF
512
513      ! Direction of lateral diffusion (tracers and/or momentum)
514      ! ------------------------------
515      ! set the slope to zero (even in s-coordinates)
516
517      uslp (:,:,:) = 0.e0
518      vslp (:,:,:) = 0.e0
519      wslpi(:,:,:) = 0.e0
520      wslpj(:,:,:) = 0.e0
521
522      uslpml (:,:) = 0.e0
523      vslpml (:,:) = 0.e0
524      wslpiml(:,:) = 0.e0
525      wslpjml(:,:) = 0.e0
526
527      IF( (ln_traldf_hor .OR. ln_dynldf_hor) .AND. .NOT. (lk_vvl .AND. ln_rstart) ) THEN
528         IF(lwp) THEN
529            WRITE(numout,*) '          Horizontal mixing in s-coordinate: slope = slope of s-surfaces'
530         ENDIF
531
532         ! geopotential diffusion in s-coordinates on tracers and/or momentum
533         ! The slopes of s-surfaces are computed once (no call to ldfslp in step)
534         ! The slopes for momentum diffusion are i- or j- averaged of those on tracers
535
536         ! set the slope of diffusion to the slope of s-surfaces
537         !      ( c a u t i o n : minus sign as fsdep has positive value )
538         DO jk = 1, jpk
539            DO jj = 2, jpjm1
540               DO ji = fs_2, fs_jpim1   ! vector opt.
541                  uslp (ji,jj,jk) = -1./e1u(ji,jj) * ( fsdept(ji+1,jj,jk) - fsdept(ji ,jj ,jk) ) * umask(ji,jj,jk)
542                  vslp (ji,jj,jk) = -1./e2v(ji,jj) * ( fsdept(ji,jj+1,jk) - fsdept(ji ,jj ,jk) ) * vmask(ji,jj,jk)
543                  wslpi(ji,jj,jk) = -1./e1t(ji,jj) * ( fsdepw(ji+1,jj,jk) - fsdepw(ji-1,jj,jk) ) * tmask(ji,jj,jk) * 0.5
544                  wslpj(ji,jj,jk) = -1./e2t(ji,jj) * ( fsdepw(ji,jj+1,jk) - fsdepw(ji,jj-1,jk) ) * tmask(ji,jj,jk) * 0.5
545               END DO
546            END DO
547         END DO
548         ! Lateral boundary conditions on the slopes
549         CALL lbc_lnk( uslp , 'U', -1. )      ;      CALL lbc_lnk( vslp , 'V', -1. )
550         CALL lbc_lnk( wslpi, 'W', -1. )      ;      CALL lbc_lnk( wslpj, 'W', -1. )
551      ENDIF
552      !
553   END SUBROUTINE ldf_slp_init
554
555#else
556   !!------------------------------------------------------------------------
557   !!   Dummy module :                 NO Rotation of lateral mixing tensor
558   !!------------------------------------------------------------------------
559   LOGICAL, PUBLIC, PARAMETER ::   lk_ldfslp = .FALSE.    !: slopes flag
560CONTAINS
561   SUBROUTINE ldf_slp( kt, prd, pn2 )        ! Dummy routine
562      INTEGER, INTENT(in) :: kt 
563      REAL, DIMENSION(:,:,:), INTENT(in) :: prd, pn2
564      WRITE(*,*) 'ldf_slp: You should not have seen this print! error?', kt, prd(1,1,1), pn2(1,1,1)
565   END SUBROUTINE ldf_slp
566#endif
567
568   !!======================================================================
569END MODULE ldfslp
Note: See TracBrowser for help on using the repository browser.