New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcflx.F90 in trunk/NEMO/OPA_SRC/SBC – NEMO

source: trunk/NEMO/OPA_SRC/SBC/sbcflx.F90 @ 1275

Last change on this file since 1275 was 1275, checked in by rblod, 15 years ago

First introduction off interpolation off the fly, see ticket #279

  • Property svn:keywords set to Id
File size: 9.5 KB
Line 
1MODULE sbcflx
2   !!======================================================================
3   !!                       ***  MODULE  sbcflx  ***
4   !! Ocean forcing:  momentum, heat and freshwater flux formulation
5   !!=====================================================================
6   !! History :  9.0   !  06-06  (G. Madec)  Original code
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   namflx   : flux formulation namlist
11   !!   sbc_flx  : flux formulation as ocean surface boundary condition
12   !!              (forced mode, fluxes read in NetCDF files)
13   !!----------------------------------------------------------------------
14   !! question diverses
15   !!  *   ajouter un test sur la division entier de freqh et rdttra ???
16   !!  **  ajoute dans namelist: 1 year forcing files
17   !!                         or forcing file starts at the begining of the run
18   !!  *** we assume that the forcing file start and end with the previous
19   !!      year last record and the next year first record (useful for
20   !!      time interpolation, required even if no time interp???)
21   !!  *   ajouter un test sur la division de la frequence en pas de temps
22   !!  ==> daymod ajout de nsec_year = number of second since the begining of the year
23   !!      assumed to be 0 at 0h january the 1st (i.e. 24h december the 31)
24   !!
25   !!  *** regrouper dtatem et dtasal
26   !!----------------------------------------------------------------------
27   USE oce             ! ocean dynamics and tracers
28   USE dom_oce         ! ocean space and time domain
29   USE sbc_oce         ! Surface boundary condition: ocean fields
30   USE phycst          ! physical constants
31   USE daymod          ! calendar
32   USE fldread         ! read input fields
33   USE iom             ! IOM library
34   USE in_out_manager  ! I/O manager
35   USE lib_mpp         ! distribued memory computing library
36   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
37
38   IMPLICIT NONE
39   PRIVATE
40
41   PUBLIC sbc_flx       ! routine called by step.F90
42
43   INTEGER , PARAMETER ::   jpfld   = 5   ! maximum number of files to read
44   INTEGER , PARAMETER ::   jp_utau = 1   ! index of wind stress (i-component) file
45   INTEGER , PARAMETER ::   jp_vtau = 2   ! index of wind stress (j-component) file
46   INTEGER , PARAMETER ::   jp_qtot = 3   ! index of total (non solar+solar) heat file
47   INTEGER , PARAMETER ::   jp_qsr  = 4   ! index of solar heat file
48   INTEGER , PARAMETER ::   jp_emp  = 5   ! index of evaporation-precipation file
49   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf    ! structure of input fields (file informations, fields read)
50
51   !! * Substitutions
52#  include "domzgr_substitute.h90"
53#  include "vectopt_loop_substitute.h90"
54   !!----------------------------------------------------------------------
55   !!   OPA 9.0 , LOCEAN-IPSL (2006)
56   !! $Id$
57   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
58   !!----------------------------------------------------------------------
59
60CONTAINS
61
62   SUBROUTINE sbc_flx( kt )
63      !!---------------------------------------------------------------------
64      !!                    ***  ROUTINE sbc_flx  ***
65      !!                   
66      !! ** Purpose :   provide at each time step the surface ocean fluxes
67      !!                (momentum, heat, freshwater and runoff)
68      !!
69      !! ** Method  : - READ each fluxes in NetCDF files:
70      !!                   i-component of the stress              utau  (N/m2)
71      !!                   j-component of the stress              vtau  (N/m2)
72      !!                   net downward heat flux                 qtot  (watt/m2)
73      !!                   net downward radiative flux            qsr   (watt/m2)
74      !!                   net upward freshwater (evapo - precip) emp   (kg/m2/s)
75      !!                Assumptions made:
76      !!                 - each file content an entire year (read record, not the time axis)
77      !!                 - first and last record are part of the previous and next year
78      !!                   (useful for time interpolation)
79      !!                 - the number of records is 2 + 365*24 / freqh(jf)
80      !!                   or 366 in leap year case
81      !!
82      !!      CAUTION :  - never mask the surface stress fields
83      !!                 - the stress is assumed to be in the mesh referential
84      !!                   i.e. the (i,j) referential
85      !!
86      !! ** Action  :   update at each time-step
87      !!              - utau  & vtau    : stress components in (i,j) referential
88      !!              - qns             : non solar heat flux
89      !!              - qsr             : solar heat flux
90      !!              - emp             : evap - precip (volume flux)
91      !!              - emps            : evap - precip (concentration/dillution)
92      !!----------------------------------------------------------------------
93      INTEGER, INTENT(in) ::   kt   ! ocean time step
94      !!
95      INTEGER  ::   ji, jj, jf   ! dummy indices
96      INTEGER  ::   ierror       ! return error code
97      REAL(wp) ::   zfact        ! temporary scalar
98      !!
99      CHARACTER(len=100) ::  cn_dir                               ! Root directory for location of flx files
100      TYPE(FLD_N), DIMENSION(jpfld) ::   slf_i                    ! array of namelist information structures
101      TYPE(FLD_N) ::   sn_utau, sn_vtau, sn_qtot, sn_qsr, sn_emp  ! informations about the fields to be read
102      NAMELIST/namsbc_flx/ cn_dir, sn_utau, sn_vtau, sn_qtot, sn_qsr, sn_emp
103      !!---------------------------------------------------------------------
104      !                                         ! ====================== !
105      IF( kt == nit000 ) THEN                   !  First call kt=nit000  !
106         !                                      ! ====================== !
107         ! set file information
108         cn_dir = './'        ! directory in which the model is executed
109         ! ... default values (NB: frequency positive => hours, negative => months)
110         !              !   file    ! frequency !  variable  ! time intep !  clim   ! 'yearly' or ! weights  ! rotation   !
111         !              !   name    !  (hours)  !   name     !   (T/F)    !  (T/F)  !  'monthly'  ! filename ! pairs      !
112         sn_utau = FLD_N(   'utau'  ,    24.    ,  'utau'    ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
113         sn_vtau = FLD_N(   'vtau'  ,    24.    ,  'vtau'    ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
114         sn_qtot = FLD_N(   'qtot'  ,    24.    ,  'qtot'    ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
115         sn_qsr  = FLD_N(   'qsr'   ,    24.    ,  'qsr'     ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
116         sn_emp  = FLD_N(   'emp'   ,    24.    ,  'emp'     ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
117
118         REWIND ( numnam )               ! ... read in namlist namflx
119         READ   ( numnam, namsbc_flx ) 
120
121         ! store namelist information in an array
122         slf_i(jp_utau) = sn_utau   ;   slf_i(jp_vtau) = sn_vtau
123         slf_i(jp_qtot) = sn_qtot   ;   slf_i(jp_qsr ) = sn_qsr 
124         slf_i(jp_emp ) = sn_emp
125
126         ! set sf structure
127         ALLOCATE( sf(jpfld), STAT=ierror )
128         IF( ierror > 0 ) THEN   
129            CALL ctl_stop( 'sbc_flx: unable to allocate sf structure' )   ;   RETURN 
130         ENDIF
131         DO ji= 1, jpfld
132            ALLOCATE( sf(ji)%fnow(jpi,jpj) )
133            ALLOCATE( sf(ji)%fdta(jpi,jpj,2) )
134         END DO
135
136
137         ! fill sf with slf_i and control print
138         CALL fld_fill( sf, slf_i, cn_dir, 'sbc_flx', 'flux formulation for ocean surface boundary condition', 'namsbc_flx' )
139         !
140      ENDIF
141
142      CALL fld_read( kt, nn_fsbc, sf )           ! Read input fields and provides the
143      !                                          ! input fields at the current time-step
144
145      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
146         !
147         ! set the ocean fluxes from read fields
148!CDIR COLLAPSE
149         DO jj = 1, jpj
150            DO ji = 1, jpi
151               utau(ji,jj) = sf(jp_utau)%fnow(ji,jj)
152               vtau(ji,jj) = sf(jp_vtau)%fnow(ji,jj)
153               qns (ji,jj) = sf(jp_qtot)%fnow(ji,jj) - sf(jp_qsr)%fnow(ji,jj)
154               qsr (ji,jj) = sf(jp_qsr )%fnow(ji,jj)
155               emp (ji,jj) = sf(jp_emp )%fnow(ji,jj)
156            END DO
157         END DO
158         
159         ! Initialization of emps (when no ice model)
160         emps(:,:) = emp (:,:) 
161         
162         ! Estimation of wind speed as a function of wind stress ( |tau|=rhoa*Cd*|U|^2 )
163         CALL sbc_tau2wnd
164         
165         ! control print (if less than 100 time-step asked)
166         IF( nitend-nit000 <= 100 .AND. lwp ) THEN
167            WRITE(numout,*) 
168            WRITE(numout,*) '        read daily momentum, heat and freshwater fluxes OK'
169            DO jf = 1, jpfld
170               IF( jf == jp_utau .OR. jf == jp_vtau )   zfact =     1.
171               IF( jf == jp_qtot .OR. jf == jp_qsr  )   zfact =     0.1
172               IF( jf == jp_emp                     )   zfact = 86400.
173               WRITE(numout,*) 
174               WRITE(numout,*) ' day: ', ndastp , TRIM(sf(jf)%clvar), ' * ', zfact
175               CALL prihre( sf(jf)%fnow, jpi, jpj, 1, jpi, 20, 1, jpj, 10, zfact, numout )
176            END DO
177            CALL FLUSH(numout)
178         ENDIF
179         !
180      ENDIF
181      !
182   END SUBROUTINE sbc_flx
183
184   !!======================================================================
185END MODULE sbcflx
Note: See TracBrowser for help on using the repository browser.