| 1 | MODULE sbcice_lim |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcice_lim *** |
|---|
| 4 | !! Surface module : update the ocean surface boundary condition over ice |
|---|
| 5 | !! & covered area using LIM sea-ice model |
|---|
| 6 | !! Sea-Ice model : LIM 3.0 Sea ice model time-stepping |
|---|
| 7 | !!====================================================================== |
|---|
| 8 | !! History : 2.0 ! 2006-12 (M. Vancoppenolle) Original code |
|---|
| 9 | !! 3.0 ! 2008-02 (C. Talandier) Surface module from icestp.F90 |
|---|
| 10 | !! 9.0 ! 2008-04 (G. Madec) sltyle and lim_ctl routine |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | #if defined key_lim3 |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! 'key_lim3' : LIM 3.0 sea-ice model |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! sbc_ice_lim : sea-ice model time-stepping and update ocean sbc over ice-covered area |
|---|
| 17 | !! lim_ctl : alerts in case of ice model crash |
|---|
| 18 | !! lim_prt_state : ice control print at a given grid point |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | USE oce ! ocean dynamics and tracers |
|---|
| 21 | USE c1d ! 1d configuration |
|---|
| 22 | USE dom_oce ! ocean space and time domain |
|---|
| 23 | USE lib_mpp |
|---|
| 24 | USE par_ice ! sea-ice parameters |
|---|
| 25 | USE ice |
|---|
| 26 | USE iceini |
|---|
| 27 | USE dom_ice |
|---|
| 28 | |
|---|
| 29 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 30 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 31 | USE sbcblk_core ! Surface boundary condition: CORE bulk |
|---|
| 32 | USE sbcblk_clio ! Surface boundary condition: CLIO bulk |
|---|
| 33 | USE albedo |
|---|
| 34 | |
|---|
| 35 | USE daymod ! day calendar |
|---|
| 36 | USE phycst ! Define parameters for the routines |
|---|
| 37 | USE eosbn2 ! equation of state |
|---|
| 38 | USE limdyn ! Ice dynamics |
|---|
| 39 | USE limtrp ! Ice transport |
|---|
| 40 | USE limthd ! Ice thermodynamics |
|---|
| 41 | USE limitd_th ! Thermodynamics on ice thickness distribution |
|---|
| 42 | USE limitd_me ! Mechanics on ice thickness distribution |
|---|
| 43 | USE limsbc ! sea surface boundary condition |
|---|
| 44 | USE limdia ! Ice diagnostics |
|---|
| 45 | USE limwri ! Ice outputs |
|---|
| 46 | USE limrst ! Ice restarts |
|---|
| 47 | USE limupdate ! update of global variables |
|---|
| 48 | USE limvar ! Ice variables switch |
|---|
| 49 | |
|---|
| 50 | USE lbclnk |
|---|
| 51 | USE iom ! I/O manager library |
|---|
| 52 | USE in_out_manager ! I/O manager |
|---|
| 53 | USE prtctl ! Print control |
|---|
| 54 | |
|---|
| 55 | IMPLICIT NONE |
|---|
| 56 | PRIVATE |
|---|
| 57 | |
|---|
| 58 | PUBLIC sbc_ice_lim ! routine called by sbcmod.F90 |
|---|
| 59 | |
|---|
| 60 | CHARACTER(len=1) :: cl_grid = 'C' ! type of grid used in ice dynamics |
|---|
| 61 | |
|---|
| 62 | !! * Substitutions |
|---|
| 63 | # include "domzgr_substitute.h90" |
|---|
| 64 | # include "vectopt_loop_substitute.h90" |
|---|
| 65 | !!---------------------------------------------------------------------- |
|---|
| 66 | !! NEMO/LIM 3.0 , UCL-LOCEAN-IPSL (2008) |
|---|
| 67 | !! $Id$ |
|---|
| 68 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
|---|
| 69 | !!---------------------------------------------------------------------- |
|---|
| 70 | |
|---|
| 71 | CONTAINS |
|---|
| 72 | |
|---|
| 73 | SUBROUTINE sbc_ice_lim( kt, kblk, kico ) |
|---|
| 74 | !!--------------------------------------------------------------------- |
|---|
| 75 | !! *** ROUTINE sbc_ice_lim *** |
|---|
| 76 | !! |
|---|
| 77 | !! ** Purpose : update the ocean surface boundary condition via the |
|---|
| 78 | !! Louvain la Neuve Sea Ice Model time stepping |
|---|
| 79 | !! |
|---|
| 80 | !! ** Method : ice model time stepping |
|---|
| 81 | !! - call the ice dynamics routine |
|---|
| 82 | !! - call the ice advection/diffusion routine |
|---|
| 83 | !! - call the ice thermodynamics routine |
|---|
| 84 | !! - call the routine that computes mass and |
|---|
| 85 | !! heat fluxes at the ice/ocean interface |
|---|
| 86 | !! - save the outputs |
|---|
| 87 | !! - save the outputs for restart when necessary |
|---|
| 88 | !! |
|---|
| 89 | !! ** Action : - time evolution of the LIM sea-ice model |
|---|
| 90 | !! - update all sbc variables below sea-ice: |
|---|
| 91 | !! utau, vtau, qns , qsr, emp , emps |
|---|
| 92 | !!--------------------------------------------------------------------- |
|---|
| 93 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 94 | INTEGER, INTENT(in) :: kblk ! type of bulk (=3 CLIO, =4 CORE) |
|---|
| 95 | INTEGER, INTENT(in) :: kico ! ice-ocean stress treatment |
|---|
| 96 | !! |
|---|
| 97 | INTEGER :: jl ! loop index |
|---|
| 98 | REAL(wp) :: zcoef ! temporary scalar |
|---|
| 99 | REAL(wp), DIMENSION(jpi,jpj,jpl) :: alb_ice_os ! albedo of the ice under overcast sky |
|---|
| 100 | REAL(wp), DIMENSION(jpi,jpj,jpl) :: alb_ice_cs ! albedo of ice under clear sky |
|---|
| 101 | !!---------------------------------------------------------------------- |
|---|
| 102 | |
|---|
| 103 | IF( kt == nit000 ) THEN |
|---|
| 104 | IF(lwp) WRITE(numout,*) |
|---|
| 105 | IF(lwp) WRITE(numout,*) 'sbc_ice_lim : update ocean surface boudary condition' |
|---|
| 106 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ via Louvain la Neuve Ice Model (LIM-3) time stepping' |
|---|
| 107 | ! |
|---|
| 108 | CALL ice_init |
|---|
| 109 | ! |
|---|
| 110 | IF( ln_nicep ) THEN ! control print at a given point |
|---|
| 111 | jiindx = 44 ; jjindx = 140 |
|---|
| 112 | WRITE(numout,*) ' The debugging point is : jiindx : ',jiindx, ' jjindx : ',jjindx |
|---|
| 113 | ENDIF |
|---|
| 114 | ENDIF |
|---|
| 115 | |
|---|
| 116 | ! !----------------------! |
|---|
| 117 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN ! Ice time-step only ! |
|---|
| 118 | ! !----------------------! |
|---|
| 119 | ! ! Bulk Formulea ! |
|---|
| 120 | ! !----------------! |
|---|
| 121 | ! |
|---|
| 122 | u_oce(:,:) = ssu_m(:,:) ! mean surface ocean current at ice velocity point |
|---|
| 123 | v_oce(:,:) = ssv_m(:,:) ! (C-grid dynamics : U- & V-points as the ocean) |
|---|
| 124 | ! |
|---|
| 125 | t_bo(:,:) = tfreez( sss_m ) + rt0 ! masked sea surface freezing temperature [Kelvin] |
|---|
| 126 | ! ! (set to rt0 over land) |
|---|
| 127 | CALL albedo_ice( t_su, ht_i, ht_s, alb_ice_cs, alb_ice_os ) ! ... ice albedo |
|---|
| 128 | |
|---|
| 129 | DO jl = 1, jpl |
|---|
| 130 | t_su(:,:,jl) = t_su(:,:,jl) + rt0 * ( 1. - tmask(:,:,1) ) |
|---|
| 131 | END DO |
|---|
| 132 | ! Bulk formulea - provides the following fields: |
|---|
| 133 | ! utau_ice, vtau_ice : surface ice stress (U- & V-points) [N/m2] |
|---|
| 134 | ! qsr_ice , qns_ice : solar & non solar heat flux over ice (T-point) [W/m2] |
|---|
| 135 | ! qla_ice : latent heat flux over ice (T-point) [W/m2] |
|---|
| 136 | ! dqns_ice, dqla_ice : non solar & latent heat sensistivity (T-point) [W/m2] |
|---|
| 137 | ! tprecip , sprecip : total & solid precipitation (T-point) [Kg/m2/s] |
|---|
| 138 | ! fr1_i0 , fr2_i0 : 1sr & 2nd fraction of qsr penetration in ice [%] |
|---|
| 139 | ! |
|---|
| 140 | SELECT CASE( kblk ) |
|---|
| 141 | CASE( 3 ) ! CLIO bulk formulation |
|---|
| 142 | CALL blk_ice_clio( t_su , alb_ice_cs, alb_ice_os, & |
|---|
| 143 | & utau_ice , vtau_ice , qns_ice , qsr_ice , & |
|---|
| 144 | & qla_ice , dqns_ice , dqla_ice , & |
|---|
| 145 | & tprecip , sprecip , & |
|---|
| 146 | & fr1_i0 , fr2_i0 , cl_grid, jpl ) |
|---|
| 147 | ! |
|---|
| 148 | CASE( 4 ) ! CORE bulk formulation |
|---|
| 149 | CALL blk_ice_core( t_su , u_ice , v_ice , alb_ice_cs, & |
|---|
| 150 | & utau_ice , vtau_ice , qns_ice , qsr_ice , & |
|---|
| 151 | & qla_ice , dqns_ice , dqla_ice , & |
|---|
| 152 | & tprecip , sprecip , & |
|---|
| 153 | & fr1_i0 , fr2_i0 , cl_grid, jpl ) |
|---|
| 154 | END SELECT |
|---|
| 155 | |
|---|
| 156 | ! !----------------------! |
|---|
| 157 | ! ! LIM-3 time-stepping ! |
|---|
| 158 | ! !----------------------! |
|---|
| 159 | ! |
|---|
| 160 | numit = numit + nn_fsbc ! Ice model time step |
|---|
| 161 | ! |
|---|
| 162 | ! ! Store previous ice values |
|---|
| 163 | !!gm : remark old_... should becomes ...b as tn versus tb |
|---|
| 164 | old_a_i(:,:,:) = a_i(:,:,:) ! ice area |
|---|
| 165 | old_e_i(:,:,:,:) = e_i(:,:,:,:) ! ice thermal energy |
|---|
| 166 | old_v_i(:,:,:) = v_i(:,:,:) ! ice volume |
|---|
| 167 | old_v_s(:,:,:) = v_s(:,:,:) ! snow volume |
|---|
| 168 | old_e_s(:,:,:,:) = e_s(:,:,:,:) ! snow thermal energy |
|---|
| 169 | old_smv_i(:,:,:) = smv_i(:,:,:) ! salt content |
|---|
| 170 | old_oa_i(:,:,:) = oa_i(:,:,:) ! areal age content |
|---|
| 171 | |
|---|
| 172 | ! ! intialisation to zero !!gm is it truly necessary ??? |
|---|
| 173 | d_a_i_thd(:,:,:) = 0.e0 ; d_a_i_trp(:,:,:) = 0.e0 |
|---|
| 174 | d_v_i_thd(:,:,:) = 0.e0 ; d_v_i_trp(:,:,:) = 0.e0 |
|---|
| 175 | d_e_i_thd(:,:,:,:) = 0.e0 ; d_e_i_trp(:,:,:,:) = 0.e0 |
|---|
| 176 | d_v_s_thd(:,:,:) = 0.e0 ; d_v_s_trp(:,:,:) = 0.e0 |
|---|
| 177 | d_e_s_thd(:,:,:,:) = 0.e0 ; d_e_s_trp(:,:,:,:) = 0.e0 |
|---|
| 178 | d_smv_i_thd(:,:,:) = 0.e0 ; d_smv_i_trp(:,:,:) = 0.e0 |
|---|
| 179 | d_oa_i_thd(:,:,:) = 0.e0 ; d_oa_i_trp(:,:,:) = 0.e0 |
|---|
| 180 | ! |
|---|
| 181 | fseqv(:,:) = 0.e0 |
|---|
| 182 | fsbri(:,:) = 0.e0 ; fsalt_res(:,:) = 0.e0 |
|---|
| 183 | fsalt_rpo(:,:) = 0.e0 |
|---|
| 184 | fhmec(:,:) = 0.e0 ; fhbri(:,:) = 0.e0 |
|---|
| 185 | fmmec(:,:) = 0.e0 ; fheat_res(:,:) = 0.e0 |
|---|
| 186 | fheat_rpo(:,:) = 0.e0 ; focea2D(:,:) = 0.e0 |
|---|
| 187 | fsup2D(:,:) = 0.e0 |
|---|
| 188 | ! |
|---|
| 189 | diag_sni_gr(:,:) = 0.e0 ; diag_lat_gr(:,:) = 0.e0 |
|---|
| 190 | diag_bot_gr(:,:) = 0.e0 ; diag_dyn_gr(:,:) = 0.e0 |
|---|
| 191 | diag_bot_me(:,:) = 0.e0 ; diag_sur_me(:,:) = 0.e0 |
|---|
| 192 | ! dynamical invariants |
|---|
| 193 | delta_i(:,:) = 0.e0 ; divu_i (:,:) = 0.e0 ; shear_i(:,:) = 0.e0 |
|---|
| 194 | |
|---|
| 195 | CALL lim_rst_opn( kt ) ! Open Ice restart file |
|---|
| 196 | ! |
|---|
| 197 | IF( ln_nicep ) CALL lim_prt_state( jiindx, jjindx, 1, ' - Beginning the time step - ' ) ! control print |
|---|
| 198 | ! |
|---|
| 199 | IF( .NOT. lk_c1d ) THEN ! Ice dynamics & transport (not in 1D case) |
|---|
| 200 | CALL lim_dyn( kt ) ! Ice dynamics ( rheology/dynamics ) |
|---|
| 201 | CALL lim_trp( kt ) ! Ice transport ( Advection/diffusion ) |
|---|
| 202 | CALL lim_var_agg(1) ! aggregate categories, requested |
|---|
| 203 | CALL lim_var_glo2eqv ! equivalent variables, requested for rafting |
|---|
| 204 | IF( ln_nicep ) CALL lim_prt_state( jiindx, jjindx,-1, ' - ice dyn & trp - ' ) ! control print |
|---|
| 205 | CALL lim_itd_me ! Mechanical redistribution ! (ridging/rafting) |
|---|
| 206 | ENDIF |
|---|
| 207 | ! |
|---|
| 208 | ! ! Ice thermodynamics |
|---|
| 209 | CALL lim_var_glo2eqv ! equivalent variables |
|---|
| 210 | CALL lim_var_agg(1) ! aggregate ice categories |
|---|
| 211 | CALL lim_var_bv ! bulk brine volume (diag) |
|---|
| 212 | CALL lim_thd( kt ) ! Ice thermodynamics |
|---|
| 213 | zcoef = rdt_ice / 86400.e0 ! Ice natural aging |
|---|
| 214 | oa_i(:,:,:) = oa_i(:,:,:) + a_i(:,:,:) * zcoef |
|---|
| 215 | CALL lim_var_glo2eqv ! this CALL is maybe not necessary (Martin) |
|---|
| 216 | IF( ln_nicep ) CALL lim_prt_state( jiindx, jjindx, 1, ' - ice thermodyn. - ' ) ! control print |
|---|
| 217 | CALL lim_itd_th( kt ) ! Remap ice categories, lateral accretion ! |
|---|
| 218 | ! |
|---|
| 219 | ! ! Global variables update | |
|---|
| 220 | CALL lim_var_agg( 1 ) ! requested by limupdate |
|---|
| 221 | CALL lim_update ! Global variables update |
|---|
| 222 | CALL lim_var_glo2eqv ! equivalent variables (outputs) |
|---|
| 223 | CALL lim_var_agg(2) ! aggregate ice thickness categories |
|---|
| 224 | IF( ln_nicep ) CALL lim_prt_state( jiindx, jjindx, 2, ' - Final state - ' ) ! control print |
|---|
| 225 | ! |
|---|
| 226 | ! ! Fluxes of mass and heat to the ocean | |
|---|
| 227 | CALL lim_sbc_flx( kt ) ! Ice/Ocean heat freshwater/salt fluxes |
|---|
| 228 | IF( ln_limdyn .AND. kico == 0 ) & ! Ice/Ocean stresses (only in ice-dynamic case) |
|---|
| 229 | & CALL lim_sbc_tau( kt, kico ) ! otherwise the atm.-ocean stresses are used everywhere |
|---|
| 230 | ! |
|---|
| 231 | IF( ln_nicep ) CALL lim_prt_state( jiindx, jjindx, 3, ' - Final state lim_sbc - ' ) ! control print |
|---|
| 232 | ! |
|---|
| 233 | ! ! Diagnostics and outputs |
|---|
| 234 | IF( ( MOD( kt+nn_fsbc-1, ninfo ) == 0 .OR. ntmoy == 1 ) .AND. .NOT. lk_mpp ) & |
|---|
| 235 | & CALL lim_dia |
|---|
| 236 | CALL lim_wri( 1 ) ! Ice outputs |
|---|
| 237 | IF( lrst_ice ) CALL lim_rst_write( kt ) ! Ice restart file |
|---|
| 238 | CALL lim_var_glo2eqv ! ??? |
|---|
| 239 | ! |
|---|
| 240 | IF( ln_nicep ) CALL lim_ctl ! alerts in case of model crash |
|---|
| 241 | ! |
|---|
| 242 | ENDIF ! End sea-ice time step only |
|---|
| 243 | |
|---|
| 244 | ! !--------------------------! |
|---|
| 245 | ! Ice/Ocean stresses (nn_ico_cpl=1 or 2 cases) ! at all ocean time step ! |
|---|
| 246 | ! !--------------------------! |
|---|
| 247 | IF( ln_limdyn .AND. kico /= 0 ) & |
|---|
| 248 | & CALL lim_sbc_tau( kt, kico ) |
|---|
| 249 | !!gm remark, in this case the ocean-ice stress is not saved in diag call above ..... find a solution!!! |
|---|
| 250 | ! |
|---|
| 251 | END SUBROUTINE sbc_ice_lim |
|---|
| 252 | |
|---|
| 253 | |
|---|
| 254 | SUBROUTINE lim_ctl |
|---|
| 255 | !!----------------------------------------------------------------------- |
|---|
| 256 | !! *** ROUTINE lim_ctl *** |
|---|
| 257 | !! |
|---|
| 258 | !! ** Purpose : Alerts in case of model crash |
|---|
| 259 | !!------------------------------------------------------------------- |
|---|
| 260 | INTEGER :: ji, jj, jk, jl ! dummy loop indices |
|---|
| 261 | INTEGER :: inb_altests ! number of alert tests (max 20) |
|---|
| 262 | INTEGER :: ialert_id ! number of the current alert |
|---|
| 263 | REAL(wp) :: ztmelts ! ice layer melting point |
|---|
| 264 | CHARACTER (len=30), DIMENSION(20) :: cl_alname ! name of alert |
|---|
| 265 | INTEGER , DIMENSION(20) :: inb_alp ! number of alerts positive |
|---|
| 266 | !!------------------------------------------------------------------- |
|---|
| 267 | |
|---|
| 268 | inb_altests = 10 |
|---|
| 269 | inb_alp(:) = 0 |
|---|
| 270 | |
|---|
| 271 | ! Alert if incompatible volume and concentration |
|---|
| 272 | ialert_id = 2 ! reference number of this alert |
|---|
| 273 | cl_alname(ialert_id) = ' Incompat vol and con ' ! name of the alert |
|---|
| 274 | |
|---|
| 275 | DO jl = 1, jpl |
|---|
| 276 | DO jj = 1, jpj |
|---|
| 277 | DO ji = 1, jpi |
|---|
| 278 | IF( v_i(ji,jj,jl) /= 0.e0 .AND. a_i(ji,jj,jl) == 0.e0 ) THEN |
|---|
| 279 | WRITE(numout,*) ' ALERTE 2 : Incompatible volume and concentration ' |
|---|
| 280 | WRITE(numout,*) ' at_i ', at_i(ji,jj) |
|---|
| 281 | WRITE(numout,*) ' Point - category', ji, jj, jl |
|---|
| 282 | WRITE(numout,*) ' a_i *** a_i_old ', a_i (ji,jj,jl), old_a_i (ji,jj,jl) |
|---|
| 283 | WRITE(numout,*) ' v_i *** v_i_old ', v_i (ji,jj,jl), old_v_i (ji,jj,jl) |
|---|
| 284 | WRITE(numout,*) ' d_a_i_thd/trp ', d_a_i_thd(ji,jj,jl), d_a_i_trp(ji,jj,jl) |
|---|
| 285 | WRITE(numout,*) ' d_v_i_thd/trp ', d_v_i_thd(ji,jj,jl), d_v_i_trp(ji,jj,jl) |
|---|
| 286 | inb_alp(ialert_id) = inb_alp(ialert_id) + 1 |
|---|
| 287 | ENDIF |
|---|
| 288 | END DO |
|---|
| 289 | END DO |
|---|
| 290 | END DO |
|---|
| 291 | |
|---|
| 292 | ! Alerte if very thick ice |
|---|
| 293 | ialert_id = 3 ! reference number of this alert |
|---|
| 294 | cl_alname(ialert_id) = ' Very thick ice ' ! name of the alert |
|---|
| 295 | jl = jpl |
|---|
| 296 | DO jj = 1, jpj |
|---|
| 297 | DO ji = 1, jpi |
|---|
| 298 | IF( ht_i(ji,jj,jl) .GT. 50.0 ) THEN |
|---|
| 299 | CALL lim_prt_state( ji, jj, 2, ' ALERTE 3 : Very thick ice ' ) |
|---|
| 300 | inb_alp(ialert_id) = inb_alp(ialert_id) + 1 |
|---|
| 301 | ENDIF |
|---|
| 302 | END DO |
|---|
| 303 | END DO |
|---|
| 304 | |
|---|
| 305 | ! Alert if very fast ice |
|---|
| 306 | ialert_id = 4 ! reference number of this alert |
|---|
| 307 | cl_alname(ialert_id) = ' Very fast ice ' ! name of the alert |
|---|
| 308 | DO jj = 1, jpj |
|---|
| 309 | DO ji = 1, jpi |
|---|
| 310 | IF( MAX( ABS( u_ice(ji,jj) ), ABS( v_ice(ji,jj) ) ) .GT. 0.5 .AND. & |
|---|
| 311 | & at_i(ji,jj) .GT. 0.e0 ) THEN |
|---|
| 312 | CALL lim_prt_state( ji, jj, 1, ' ALERTE 4 : Very fast ice ' ) |
|---|
| 313 | WRITE(numout,*) ' ice strength : ', strength(ji,jj) |
|---|
| 314 | WRITE(numout,*) ' oceanic stress utau : ', utau(ji,jj) |
|---|
| 315 | WRITE(numout,*) ' oceanic stress vtau : ', vtau(ji,jj) |
|---|
| 316 | WRITE(numout,*) ' sea-ice stress utau_ice : ', utau_ice(ji,jj) |
|---|
| 317 | WRITE(numout,*) ' sea-ice stress vtau_ice : ', vtau_ice(ji,jj) |
|---|
| 318 | WRITE(numout,*) ' oceanic speed u : ', u_oce(ji,jj) |
|---|
| 319 | WRITE(numout,*) ' oceanic speed v : ', v_oce(ji,jj) |
|---|
| 320 | WRITE(numout,*) ' sst : ', sst_m(ji,jj) |
|---|
| 321 | WRITE(numout,*) ' sss : ', sss_m(ji,jj) |
|---|
| 322 | WRITE(numout,*) |
|---|
| 323 | inb_alp(ialert_id) = inb_alp(ialert_id) + 1 |
|---|
| 324 | ENDIF |
|---|
| 325 | END DO |
|---|
| 326 | END DO |
|---|
| 327 | |
|---|
| 328 | ! Alert if there is ice on continents |
|---|
| 329 | ialert_id = 6 ! reference number of this alert |
|---|
| 330 | cl_alname(ialert_id) = ' Ice on continents ' ! name of the alert |
|---|
| 331 | DO jj = 1, jpj |
|---|
| 332 | DO ji = 1, jpi |
|---|
| 333 | IF( tms(ji,jj) .LE. 0.0 .AND. at_i(ji,jj) .GT. 0.e0 ) THEN |
|---|
| 334 | CALL lim_prt_state( ji, jj, 1, ' ALERTE 6 : Ice on continents ' ) |
|---|
| 335 | WRITE(numout,*) ' masks s, u, v : ', tms(ji,jj), tmu(ji,jj), tmv(ji,jj) |
|---|
| 336 | WRITE(numout,*) ' sst : ', sst_m(ji,jj) |
|---|
| 337 | WRITE(numout,*) ' sss : ', sss_m(ji,jj) |
|---|
| 338 | WRITE(numout,*) ' at_i(ji,jj) : ', at_i(ji,jj) |
|---|
| 339 | WRITE(numout,*) ' v_ice(ji,jj) : ', v_ice(ji,jj) |
|---|
| 340 | WRITE(numout,*) ' v_ice(ji,jj-1) : ', v_ice(ji,jj-1) |
|---|
| 341 | WRITE(numout,*) ' u_ice(ji-1,jj) : ', u_ice(ji-1,jj) |
|---|
| 342 | WRITE(numout,*) ' u_ice(ji,jj) : ', v_ice(ji,jj) |
|---|
| 343 | ! |
|---|
| 344 | inb_alp(ialert_id) = inb_alp(ialert_id) + 1 |
|---|
| 345 | ENDIF |
|---|
| 346 | END DO |
|---|
| 347 | END DO |
|---|
| 348 | |
|---|
| 349 | ! |
|---|
| 350 | ! ! Alert if very fresh ice |
|---|
| 351 | ialert_id = 7 ! reference number of this alert |
|---|
| 352 | cl_alname(ialert_id) = ' Very fresh ice ' ! name of the alert |
|---|
| 353 | DO jl = 1, jpl |
|---|
| 354 | DO jj = 1, jpj |
|---|
| 355 | DO ji = 1, jpi |
|---|
| 356 | !!gm test twice sm_i ... ???? bug? |
|---|
| 357 | IF( ( ( ABS( sm_i(ji,jj,jl) ) .LT. 0.50) .OR. & |
|---|
| 358 | ( ABS( sm_i(ji,jj,jl) ) .LT. 0.50) ) .AND. & |
|---|
| 359 | ( a_i(ji,jj,jl) .GT. 0.e0 ) ) THEN |
|---|
| 360 | ! CALL lim_prt_state(ji,jj,1, ' ALERTE 7 : Very fresh ice ' ) |
|---|
| 361 | ! WRITE(numout,*) ' sst : ', sst_m(ji,jj) |
|---|
| 362 | ! WRITE(numout,*) ' sss : ', sss_m(ji,jj) |
|---|
| 363 | ! WRITE(numout,*) ' s_i_newice : ', s_i_newice(ji,jj,1:jpl) |
|---|
| 364 | ! WRITE(numout,*) |
|---|
| 365 | inb_alp(ialert_id) = inb_alp(ialert_id) + 1 |
|---|
| 366 | ENDIF |
|---|
| 367 | END DO |
|---|
| 368 | END DO |
|---|
| 369 | END DO |
|---|
| 370 | ! |
|---|
| 371 | |
|---|
| 372 | ! ! Alert if too old ice |
|---|
| 373 | ialert_id = 9 ! reference number of this alert |
|---|
| 374 | cl_alname(ialert_id) = ' Very old ice ' ! name of the alert |
|---|
| 375 | DO jl = 1, jpl |
|---|
| 376 | DO jj = 1, jpj |
|---|
| 377 | DO ji = 1, jpi |
|---|
| 378 | IF ( ( ( ABS( o_i(ji,jj,jl) ) .GT. rdt_ice ) .OR. & |
|---|
| 379 | ( ABS( o_i(ji,jj,jl) ) .LT. 0.00) ) .AND. & |
|---|
| 380 | ( a_i(ji,jj,jl) .GT. 0.0 ) ) THEN |
|---|
| 381 | CALL lim_prt_state( ji, jj, 1, ' ALERTE 9 : Wrong ice age ') |
|---|
| 382 | inb_alp(ialert_id) = inb_alp(ialert_id) + 1 |
|---|
| 383 | ENDIF |
|---|
| 384 | END DO |
|---|
| 385 | END DO |
|---|
| 386 | END DO |
|---|
| 387 | |
|---|
| 388 | ! Alert on salt flux |
|---|
| 389 | ialert_id = 5 ! reference number of this alert |
|---|
| 390 | cl_alname(ialert_id) = ' High salt flux ' ! name of the alert |
|---|
| 391 | DO jj = 1, jpj |
|---|
| 392 | DO ji = 1, jpi |
|---|
| 393 | IF( ABS( emps(ji,jj) ) .GT. 1.0e-2 ) THEN |
|---|
| 394 | CALL lim_prt_state( ji, jj, 3, ' ALERTE 5 : High salt flux ' ) |
|---|
| 395 | DO jl = 1, jpl |
|---|
| 396 | WRITE(numout,*) ' Category no: ', jl |
|---|
| 397 | WRITE(numout,*) ' a_i : ', a_i (ji,jj,jl) , ' old_a_i : ', old_a_i (ji,jj,jl) |
|---|
| 398 | WRITE(numout,*) ' d_a_i_trp : ', d_a_i_trp(ji,jj,jl) , ' d_a_i_thd : ', d_a_i_thd(ji,jj,jl) |
|---|
| 399 | WRITE(numout,*) ' v_i : ', v_i (ji,jj,jl) , ' old_v_i : ', old_v_i (ji,jj,jl) |
|---|
| 400 | WRITE(numout,*) ' d_v_i_trp : ', d_v_i_trp(ji,jj,jl) , ' d_v_i_thd : ', d_v_i_thd(ji,jj,jl) |
|---|
| 401 | WRITE(numout,*) ' ' |
|---|
| 402 | END DO |
|---|
| 403 | inb_alp(ialert_id) = inb_alp(ialert_id) + 1 |
|---|
| 404 | ENDIF |
|---|
| 405 | END DO |
|---|
| 406 | END DO |
|---|
| 407 | |
|---|
| 408 | ! Alert if qns very big |
|---|
| 409 | ialert_id = 8 ! reference number of this alert |
|---|
| 410 | cl_alname(ialert_id) = ' fnsolar very big ' ! name of the alert |
|---|
| 411 | DO jj = 1, jpj |
|---|
| 412 | DO ji = 1, jpi |
|---|
| 413 | IF( ABS( qns(ji,jj) ) .GT. 1500.0 .AND. ( at_i(ji,jj) .GT. 0.0 ) ) THEN |
|---|
| 414 | ! |
|---|
| 415 | WRITE(numout,*) ' ALERTE 8 : Very high non-solar heat flux' |
|---|
| 416 | WRITE(numout,*) ' ji, jj : ', ji, jj |
|---|
| 417 | WRITE(numout,*) ' qns : ', qns(ji,jj) |
|---|
| 418 | WRITE(numout,*) ' sst : ', sst_m(ji,jj) |
|---|
| 419 | WRITE(numout,*) ' sss : ', sss_m(ji,jj) |
|---|
| 420 | WRITE(numout,*) ' qcmif : ', qcmif(ji,jj) |
|---|
| 421 | WRITE(numout,*) ' qldif : ', qldif(ji,jj) |
|---|
| 422 | WRITE(numout,*) ' qcmif : ', qcmif(ji,jj) / rdt_ice |
|---|
| 423 | WRITE(numout,*) ' qldif : ', qldif(ji,jj) / rdt_ice |
|---|
| 424 | WRITE(numout,*) ' qfvbq : ', qfvbq(ji,jj) |
|---|
| 425 | WRITE(numout,*) ' qdtcn : ', qdtcn(ji,jj) |
|---|
| 426 | WRITE(numout,*) ' qfvbq / dt: ', qfvbq(ji,jj) / rdt_ice |
|---|
| 427 | WRITE(numout,*) ' qdtcn / dt: ', qdtcn(ji,jj) / rdt_ice |
|---|
| 428 | WRITE(numout,*) ' fdtcn : ', fdtcn(ji,jj) |
|---|
| 429 | WRITE(numout,*) ' fhmec : ', fhmec(ji,jj) |
|---|
| 430 | WRITE(numout,*) ' fheat_rpo : ', fheat_rpo(ji,jj) |
|---|
| 431 | WRITE(numout,*) ' fheat_res : ', fheat_res(ji,jj) |
|---|
| 432 | WRITE(numout,*) ' fhbri : ', fhbri(ji,jj) |
|---|
| 433 | ! |
|---|
| 434 | CALL lim_prt_state( ji, jj, 2, ' ') |
|---|
| 435 | inb_alp(ialert_id) = inb_alp(ialert_id) + 1 |
|---|
| 436 | ! |
|---|
| 437 | ENDIF |
|---|
| 438 | END DO |
|---|
| 439 | END DO |
|---|
| 440 | !+++++ |
|---|
| 441 | |
|---|
| 442 | ! Alert if very warm ice |
|---|
| 443 | ialert_id = 10 ! reference number of this alert |
|---|
| 444 | cl_alname(ialert_id) = ' Very warm ice ' ! name of the alert |
|---|
| 445 | inb_alp(ialert_id) = 0 |
|---|
| 446 | DO jl = 1, jpl |
|---|
| 447 | DO jk = 1, nlay_i |
|---|
| 448 | DO jj = 1, jpj |
|---|
| 449 | DO ji = 1, jpi |
|---|
| 450 | ztmelts = -tmut * s_i(ji,jj,jk,jl) + rtt |
|---|
| 451 | IF( t_i(ji,jj,jk,jl) .GE. ztmelts .AND. v_i(ji,jj,jl) .GT. 1.e-6 & |
|---|
| 452 | & .AND. a_i(ji,jj,jl) .GT. 0.e0 ) THEN |
|---|
| 453 | WRITE(numout,*) ' ALERTE 10 : Very warm ice' |
|---|
| 454 | WRITE(numout,*) ' ji, jj, jk, jl : ', ji, jj, jk, jl |
|---|
| 455 | WRITE(numout,*) ' t_i : ', t_i(ji,jj,jk,jl) |
|---|
| 456 | WRITE(numout,*) ' e_i : ', e_i(ji,jj,jk,jl) |
|---|
| 457 | WRITE(numout,*) ' s_i : ', s_i(ji,jj,jk,jl) |
|---|
| 458 | WRITE(numout,*) ' ztmelts : ', ztmelts |
|---|
| 459 | inb_alp(ialert_id) = inb_alp(ialert_id) + 1 |
|---|
| 460 | ENDIF |
|---|
| 461 | END DO |
|---|
| 462 | END DO |
|---|
| 463 | END DO |
|---|
| 464 | END DO |
|---|
| 465 | |
|---|
| 466 | ialert_id = 1 ! reference number of this alert |
|---|
| 467 | cl_alname(ialert_id) = ' NO alerte 1 ' ! name of the alert |
|---|
| 468 | WRITE(numout,*) |
|---|
| 469 | WRITE(numout,*) ' All alerts at the end of ice model ' |
|---|
| 470 | DO ialert_id = 1, inb_altests |
|---|
| 471 | WRITE(numout,*) ialert_id, cl_alname(ialert_id)//' : ', inb_alp(ialert_id), ' times ! ' |
|---|
| 472 | END DO |
|---|
| 473 | ! |
|---|
| 474 | END SUBROUTINE lim_ctl |
|---|
| 475 | |
|---|
| 476 | |
|---|
| 477 | SUBROUTINE lim_prt_state( ki, kj, kn, cd1 ) |
|---|
| 478 | !!----------------------------------------------------------------------- |
|---|
| 479 | !! *** ROUTINE lim_prt_state *** |
|---|
| 480 | !! |
|---|
| 481 | !! ** Purpose : Writes global ice state on the (i,j) point |
|---|
| 482 | !! in ocean.ouput |
|---|
| 483 | !! 3 possibilities exist |
|---|
| 484 | !! n = 1/-1 -> simple ice state (plus Mechanical Check if -1) |
|---|
| 485 | !! n = 2 -> exhaustive state |
|---|
| 486 | !! n = 3 -> ice/ocean salt fluxes |
|---|
| 487 | !! |
|---|
| 488 | !! ** input : point coordinates (i,j) |
|---|
| 489 | !! n : number of the option |
|---|
| 490 | !!------------------------------------------------------------------- |
|---|
| 491 | INTEGER , INTENT(in) :: ki, kj, kn ! ocean gridpoint indices |
|---|
| 492 | CHARACTER(len=*), INTENT(in) :: cd1 ! |
|---|
| 493 | !! |
|---|
| 494 | INTEGER :: jl |
|---|
| 495 | !!------------------------------------------------------------------- |
|---|
| 496 | |
|---|
| 497 | WRITE(numout,*) cd1 ! print title |
|---|
| 498 | |
|---|
| 499 | !---------------- |
|---|
| 500 | ! Simple state |
|---|
| 501 | !---------------- |
|---|
| 502 | |
|---|
| 503 | IF ( kn == 1 .OR. kn == -1 ) THEN |
|---|
| 504 | WRITE(numout,*) ' lim_prt_state - Point : ',ki,kj |
|---|
| 505 | WRITE(numout,*) ' ~~~~~~~~~~~~~~ ' |
|---|
| 506 | WRITE(numout,*) ' Simple state ' |
|---|
| 507 | WRITE(numout,*) ' masks s,u,v : ', tms(ki,kj), tmu(ki,kj), tmv(ki,kj) |
|---|
| 508 | WRITE(numout,*) ' lat - long : ', gphit(ki,kj), glamt(ki,kj) |
|---|
| 509 | WRITE(numout,*) ' Time step : ', numit |
|---|
| 510 | WRITE(numout,*) ' - Ice drift ' |
|---|
| 511 | WRITE(numout,*) ' ~~~~~~~~~~~ ' |
|---|
| 512 | WRITE(numout,*) ' u_ice(i-1,j) : ', u_ice(ki-1,kj) |
|---|
| 513 | WRITE(numout,*) ' u_ice(i ,j) : ', u_ice(ki,kj) |
|---|
| 514 | WRITE(numout,*) ' v_ice(i ,j-1): ', v_ice(ki,kj-1) |
|---|
| 515 | WRITE(numout,*) ' v_ice(i ,j) : ', v_ice(ki,kj) |
|---|
| 516 | WRITE(numout,*) ' strength : ', strength(ki,kj) |
|---|
| 517 | WRITE(numout,*) |
|---|
| 518 | WRITE(numout,*) ' - Cell values ' |
|---|
| 519 | WRITE(numout,*) ' ~~~~~~~~~~~ ' |
|---|
| 520 | WRITE(numout,*) ' cell area : ', area(ki,kj) |
|---|
| 521 | WRITE(numout,*) ' at_i : ', at_i(ki,kj) |
|---|
| 522 | WRITE(numout,*) ' vt_i : ', vt_i(ki,kj) |
|---|
| 523 | WRITE(numout,*) ' vt_s : ', vt_s(ki,kj) |
|---|
| 524 | DO jl = 1, jpl |
|---|
| 525 | WRITE(numout,*) ' - Category (', jl,')' |
|---|
| 526 | WRITE(numout,*) ' a_i : ', a_i(ki,kj,jl) |
|---|
| 527 | WRITE(numout,*) ' ht_i : ', ht_i(ki,kj,jl) |
|---|
| 528 | WRITE(numout,*) ' ht_s : ', ht_s(ki,kj,jl) |
|---|
| 529 | WRITE(numout,*) ' v_i : ', v_i(ki,kj,jl) |
|---|
| 530 | WRITE(numout,*) ' v_s : ', v_s(ki,kj,jl) |
|---|
| 531 | WRITE(numout,*) ' e_s : ', e_s(ki,kj,1,jl)/1.0e9 |
|---|
| 532 | WRITE(numout,*) ' e_i : ', e_i(ki,kj,1:nlay_i,jl)/1.0e9 |
|---|
| 533 | WRITE(numout,*) ' t_su : ', t_su(ki,kj,jl) |
|---|
| 534 | WRITE(numout,*) ' t_snow : ', t_s(ki,kj,1,jl) |
|---|
| 535 | WRITE(numout,*) ' t_i : ', t_i(ki,kj,1:nlay_i,jl) |
|---|
| 536 | WRITE(numout,*) ' sm_i : ', sm_i(ki,kj,jl) |
|---|
| 537 | WRITE(numout,*) ' smv_i : ', smv_i(ki,kj,jl) |
|---|
| 538 | WRITE(numout,*) |
|---|
| 539 | WRITE(numout,*) ' Pathological case : ', patho_case(ki,kj,jl) |
|---|
| 540 | END DO |
|---|
| 541 | ENDIF |
|---|
| 542 | IF( kn == -1 ) THEN |
|---|
| 543 | WRITE(numout,*) ' Mechanical Check ************** ' |
|---|
| 544 | WRITE(numout,*) ' Check what means ice divergence ' |
|---|
| 545 | WRITE(numout,*) ' Total ice concentration ', at_i (ki,kj) |
|---|
| 546 | WRITE(numout,*) ' Total lead fraction ', ato_i(ki,kj) |
|---|
| 547 | WRITE(numout,*) ' Sum of both ', ato_i(ki,kj) + at_i(ki,kj) |
|---|
| 548 | WRITE(numout,*) ' Sum of both minus 1 ', ato_i(ki,kj) + at_i(ki,kj) - 1.00 |
|---|
| 549 | ENDIF |
|---|
| 550 | |
|---|
| 551 | |
|---|
| 552 | !-------------------- |
|---|
| 553 | ! Exhaustive state |
|---|
| 554 | !-------------------- |
|---|
| 555 | |
|---|
| 556 | IF ( kn .EQ. 2 ) THEN |
|---|
| 557 | WRITE(numout,*) ' lim_prt_state - Point : ',ki,kj |
|---|
| 558 | WRITE(numout,*) ' ~~~~~~~~~~~~~~ ' |
|---|
| 559 | WRITE(numout,*) ' Exhaustive state ' |
|---|
| 560 | WRITE(numout,*) ' lat - long ', gphit(ki,kj), glamt(ki,kj) |
|---|
| 561 | WRITE(numout,*) ' Time step ', numit |
|---|
| 562 | WRITE(numout,*) |
|---|
| 563 | WRITE(numout,*) ' - Cell values ' |
|---|
| 564 | WRITE(numout,*) ' ~~~~~~~~~~~ ' |
|---|
| 565 | WRITE(numout,*) ' cell area : ', area(ki,kj) |
|---|
| 566 | WRITE(numout,*) ' at_i : ', at_i(ki,kj) |
|---|
| 567 | WRITE(numout,*) ' vt_i : ', vt_i(ki,kj) |
|---|
| 568 | WRITE(numout,*) ' vt_s : ', vt_s(ki,kj) |
|---|
| 569 | WRITE(numout,*) ' u_ice(i-1,j) : ', u_ice(ki-1,kj) |
|---|
| 570 | WRITE(numout,*) ' u_ice(i ,j) : ', u_ice(ki,kj) |
|---|
| 571 | WRITE(numout,*) ' v_ice(i ,j-1): ', v_ice(ki,kj-1) |
|---|
| 572 | WRITE(numout,*) ' v_ice(i ,j) : ', v_ice(ki,kj) |
|---|
| 573 | WRITE(numout,*) ' strength : ', strength(ki,kj) |
|---|
| 574 | WRITE(numout,*) ' d_u_ice_dyn : ', d_u_ice_dyn(ki,kj), ' d_v_ice_dyn : ', d_v_ice_dyn(ki,kj) |
|---|
| 575 | WRITE(numout,*) ' old_u_ice : ', old_u_ice(ki,kj) , ' old_v_ice : ', old_v_ice(ki,kj) |
|---|
| 576 | WRITE(numout,*) |
|---|
| 577 | |
|---|
| 578 | DO jl = 1, jpl |
|---|
| 579 | WRITE(numout,*) ' - Category (',jl,')' |
|---|
| 580 | WRITE(numout,*) ' ~~~~~~~~ ' |
|---|
| 581 | WRITE(numout,*) ' ht_i : ', ht_i(ki,kj,jl) , ' ht_s : ', ht_s(ki,kj,jl) |
|---|
| 582 | WRITE(numout,*) ' t_i : ', t_i(ki,kj,1:nlay_i,jl) |
|---|
| 583 | WRITE(numout,*) ' t_su : ', t_su(ki,kj,jl) , ' t_s : ', t_s(ki,kj,1,jl) |
|---|
| 584 | WRITE(numout,*) ' sm_i : ', sm_i(ki,kj,jl) , ' o_i : ', o_i(ki,kj,jl) |
|---|
| 585 | WRITE(numout,*) ' a_i : ', a_i(ki,kj,jl) , ' old_a_i : ', old_a_i(ki,kj,jl) |
|---|
| 586 | WRITE(numout,*) ' d_a_i_trp : ', d_a_i_trp(ki,kj,jl) , ' d_a_i_thd : ', d_a_i_thd(ki,kj,jl) |
|---|
| 587 | WRITE(numout,*) ' v_i : ', v_i(ki,kj,jl) , ' old_v_i : ', old_v_i(ki,kj,jl) |
|---|
| 588 | WRITE(numout,*) ' d_v_i_trp : ', d_v_i_trp(ki,kj,jl) , ' d_v_i_thd : ', d_v_i_thd(ki,kj,jl) |
|---|
| 589 | WRITE(numout,*) ' v_s : ', v_s(ki,kj,jl) , ' old_v_s : ', old_v_s(ki,kj,jl) |
|---|
| 590 | WRITE(numout,*) ' d_v_s_trp : ', d_v_s_trp(ki,kj,jl) , ' d_v_s_thd : ', d_v_s_thd(ki,kj,jl) |
|---|
| 591 | WRITE(numout,*) ' e_i1 : ', e_i(ki,kj,1,jl)/1.0e9 , ' old_ei1 : ', old_e_i(ki,kj,1,jl)/1.0e9 |
|---|
| 592 | WRITE(numout,*) ' de_i1_trp : ', d_e_i_trp(ki,kj,1,jl)/1.0e9, ' de_i1_thd : ', d_e_i_thd(ki,kj,1,jl)/1.0e9 |
|---|
| 593 | WRITE(numout,*) ' e_i2 : ', e_i(ki,kj,2,jl)/1.0e9 , ' old_ei2 : ', old_e_i(ki,kj,2,jl)/1.0e9 |
|---|
| 594 | WRITE(numout,*) ' de_i2_trp : ', d_e_i_trp(ki,kj,2,jl)/1.0e9, ' de_i2_thd : ', d_e_i_thd(ki,kj,2,jl)/1.0e9 |
|---|
| 595 | WRITE(numout,*) ' e_snow : ', e_s(ki,kj,1,jl) , ' old_e_snow : ', old_e_s(ki,kj,1,jl) |
|---|
| 596 | WRITE(numout,*) ' d_e_s_trp : ', d_e_s_trp(ki,kj,1,jl) , ' d_e_s_thd : ', d_e_s_thd(ki,kj,1,jl) |
|---|
| 597 | WRITE(numout,*) ' smv_i : ', smv_i(ki,kj,jl) , ' old_smv_i : ', old_smv_i(ki,kj,jl) |
|---|
| 598 | WRITE(numout,*) ' d_smv_i_trp: ', d_smv_i_trp(ki,kj,jl) , ' d_smv_i_thd: ', d_smv_i_thd(ki,kj,jl) |
|---|
| 599 | WRITE(numout,*) ' oa_i : ', oa_i(ki,kj,jl) , ' old_oa_i : ', old_oa_i(ki,kj,jl) |
|---|
| 600 | WRITE(numout,*) ' d_oa_i_trp : ', d_oa_i_trp(ki,kj,jl) , ' d_oa_i_thd : ', d_oa_i_thd(ki,kj,jl) |
|---|
| 601 | WRITE(numout,*) ' Path. case : ', patho_case(ki,kj,jl) |
|---|
| 602 | END DO !jl |
|---|
| 603 | |
|---|
| 604 | WRITE(numout,*) |
|---|
| 605 | WRITE(numout,*) ' - Heat / FW fluxes ' |
|---|
| 606 | WRITE(numout,*) ' ~~~~~~~~~~~~~~~~ ' |
|---|
| 607 | ! WRITE(numout,*) ' fsbri : ', fsbri(ki,kj) |
|---|
| 608 | ! WRITE(numout,*) ' fseqv : ', fseqv(ki,kj) |
|---|
| 609 | ! WRITE(numout,*) ' fsalt_res : ', fsalt_res(ki,kj) |
|---|
| 610 | WRITE(numout,*) ' fmmec : ', fmmec(ki,kj) |
|---|
| 611 | WRITE(numout,*) ' fhmec : ', fhmec(ki,kj) |
|---|
| 612 | WRITE(numout,*) ' fhbri : ', fhbri(ki,kj) |
|---|
| 613 | WRITE(numout,*) ' fheat_rpo : ', fheat_rpo(ki,kj) |
|---|
| 614 | WRITE(numout,*) |
|---|
| 615 | WRITE(numout,*) ' sst : ', sst_m(ki,kj) |
|---|
| 616 | WRITE(numout,*) ' sss : ', sss_m(ki,kj) |
|---|
| 617 | WRITE(numout,*) |
|---|
| 618 | WRITE(numout,*) ' - Stresses ' |
|---|
| 619 | WRITE(numout,*) ' ~~~~~~~~ ' |
|---|
| 620 | WRITE(numout,*) ' utau_ice : ', utau_ice(ki,kj) |
|---|
| 621 | WRITE(numout,*) ' vtau_ice : ', vtau_ice(ki,kj) |
|---|
| 622 | WRITE(numout,*) ' utau : ', utau(ki,kj) |
|---|
| 623 | WRITE(numout,*) ' vtau : ', vtau(ki,kj) |
|---|
| 624 | WRITE(numout,*) ' oc. vel. u : ', u_oce(ki,kj) |
|---|
| 625 | WRITE(numout,*) ' oc. vel. v : ', v_oce(ki,kj) |
|---|
| 626 | ENDIF |
|---|
| 627 | |
|---|
| 628 | !--------------------- |
|---|
| 629 | ! Salt / heat fluxes |
|---|
| 630 | !--------------------- |
|---|
| 631 | |
|---|
| 632 | IF ( kn .EQ. 3 ) THEN |
|---|
| 633 | WRITE(numout,*) ' lim_prt_state - Point : ',ki,kj |
|---|
| 634 | WRITE(numout,*) ' ~~~~~~~~~~~~~~ ' |
|---|
| 635 | WRITE(numout,*) ' - Salt / Heat Fluxes ' |
|---|
| 636 | WRITE(numout,*) ' ~~~~~~~~~~~~~~~~ ' |
|---|
| 637 | WRITE(numout,*) ' lat - long ', gphit(ki,kj), glamt(ki,kj) |
|---|
| 638 | WRITE(numout,*) ' Time step ', numit |
|---|
| 639 | WRITE(numout,*) |
|---|
| 640 | WRITE(numout,*) ' - Heat fluxes at bottom interface ***' |
|---|
| 641 | WRITE(numout,*) ' qsr : ', qsr(ki,kj) |
|---|
| 642 | WRITE(numout,*) ' qns : ', qns(ki,kj) |
|---|
| 643 | WRITE(numout,*) |
|---|
| 644 | WRITE(numout,*) ' - Salt fluxes at bottom interface ***' |
|---|
| 645 | WRITE(numout,*) ' emps : ', emps(ki,kj) |
|---|
| 646 | WRITE(numout,*) ' emp : ', emp(ki,kj) |
|---|
| 647 | WRITE(numout,*) ' fsbri : ', fsbri(ki,kj) |
|---|
| 648 | WRITE(numout,*) ' fseqv : ', fseqv(ki,kj) |
|---|
| 649 | WRITE(numout,*) ' fsalt_res : ', fsalt_res(ki,kj) |
|---|
| 650 | WRITE(numout,*) ' fsalt_rpo : ', fsalt_rpo(ki,kj) |
|---|
| 651 | WRITE(numout,*) ' - Heat fluxes at bottom interface ***' |
|---|
| 652 | WRITE(numout,*) ' fheat_res : ', fheat_res(ki,kj) |
|---|
| 653 | WRITE(numout,*) |
|---|
| 654 | WRITE(numout,*) ' - Momentum fluxes ' |
|---|
| 655 | WRITE(numout,*) ' utau : ', utau(ki,kj) |
|---|
| 656 | WRITE(numout,*) ' vtau : ', vtau(ki,kj) |
|---|
| 657 | ENDIF |
|---|
| 658 | WRITE(numout,*) ' ' |
|---|
| 659 | ! |
|---|
| 660 | END SUBROUTINE lim_prt_state |
|---|
| 661 | |
|---|
| 662 | #else |
|---|
| 663 | !!---------------------------------------------------------------------- |
|---|
| 664 | !! Default option Dummy module NO LIM 3.0 sea-ice model |
|---|
| 665 | !!---------------------------------------------------------------------- |
|---|
| 666 | CONTAINS |
|---|
| 667 | SUBROUTINE sbc_ice_lim ( kt, kblk, kico ) ! Dummy routine |
|---|
| 668 | WRITE(*,*) 'sbc_ice_lim: You should not have seen this print! error?', kt, kblk, kico |
|---|
| 669 | END SUBROUTINE sbc_ice_lim |
|---|
| 670 | #endif |
|---|
| 671 | |
|---|
| 672 | !!====================================================================== |
|---|
| 673 | END MODULE sbcice_lim |
|---|
