New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcice_lim_2.F90 in trunk/NEMO/OPA_SRC/SBC – NEMO

source: trunk/NEMO/OPA_SRC/SBC/sbcice_lim_2.F90 @ 1226

Last change on this file since 1226 was 1226, checked in by smasson, 15 years ago

bugfix of the coupling interface (commited during changeset:1218), see ticket:155

  • Property svn:keywords set to Id
File size: 11.5 KB
Line 
1MODULE sbcice_lim_2
2   !!======================================================================
3   !!                       ***  MODULE  sbcice_lim_2  ***
4   !! Surface module :  update surface ocean boundary condition over ice
5   !!                   covered area using LIM sea-ice model
6   !! Sea-Ice model  :  LIM 2.0 Sea ice model time-stepping
7   !!======================================================================
8   !! History :  1.0   !  06-2006  (G. Madec)  from icestp_2.F90
9   !!            3.0   !  08-2008  (S. Masson, E. .... ) coupled interface
10   !!----------------------------------------------------------------------
11#if defined key_lim2
12   !!----------------------------------------------------------------------
13   !!   'key_lim2' :                                  LIM 2.0 sea-ice model
14   !!----------------------------------------------------------------------
15   !!   sbc_ice_lim_2  : sea-ice model time-stepping and
16   !!                    update ocean sbc over ice-covered area
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers
19   USE c1d             ! 1d configuration
20   USE dom_oce         ! ocean space and time domain
21   USE lib_mpp
22   USE ice_2
23   USE iceini_2
24   USE ice_oce         ! ice variables
25   USE dom_ice_2
26
27   USE sbc_oce         ! Surface boundary condition: ocean fields
28   USE sbc_ice         ! Surface boundary condition: ice   fields
29   USE sbcblk_core     ! Surface boundary condition: CORE bulk
30   USE sbcblk_clio     ! Surface boundary condition: CLIO bulk
31   USE sbccpl          ! Surface boundary condition: coupled interface
32   USE albedo
33
34   USE daymod          ! day calendar
35   USE phycst          ! Define parameters for the routines
36   USE eosbn2          ! equation of state
37   USE limdyn_2
38   USE limtrp_2
39   USE limdmp_2
40   USE limthd_2
41   USE limsbc_2        ! sea surface boundary condition
42   USE limdia_2
43   USE limwri_2
44   USE limrst_2
45
46   USE lbclnk
47   USE iom             ! I/O manager library
48   USE in_out_manager  ! I/O manager
49   USE prtctl          ! Print control
50
51   IMPLICIT NONE
52   PRIVATE
53
54   PUBLIC sbc_ice_lim_2 ! routine called by sbcmod.F90
55   
56   CHARACTER(len=1) ::   cl_grid = 'B'     ! type of grid used in ice dynamics
57
58   !! * Substitutions
59#  include "domzgr_substitute.h90"
60#  include "vectopt_loop_substitute.h90"
61   !!----------------------------------------------------------------------
62   !! NEMO/SBC  3.0 , LOCEAN-IPSL (2008)
63   !! $Id$
64   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
65   !!----------------------------------------------------------------------
66
67CONTAINS
68
69   SUBROUTINE sbc_ice_lim_2( kt, ksbc )
70      !!---------------------------------------------------------------------
71      !!                  ***  ROUTINE sbc_ice_lim_2  ***
72      !!                   
73      !! ** Purpose :   update the ocean surface boundary condition via the
74      !!                Louvain la Neuve Sea Ice Model time stepping
75      !!
76      !! ** Method  :   ice model time stepping
77      !!              - call the ice dynamics routine
78      !!              - call the ice advection/diffusion routine
79      !!              - call the ice thermodynamics routine
80      !!              - call the routine that computes mass and
81      !!                heat fluxes at the ice/ocean interface
82      !!              - save the outputs
83      !!              - save the outputs for restart when necessary
84      !!
85      !! ** Action  : - time evolution of the LIM sea-ice model
86      !!              - update all sbc variables below sea-ice:
87      !!                utau, vtau, qns , qsr, emp , emps
88      !!---------------------------------------------------------------------
89      INTEGER, INTENT(in) ::   kt      ! ocean time step
90      INTEGER, INTENT(in) ::   ksbc    ! type of sbc ( =3 CLIO bulk ; =4 CORE bulk ; =5 coupled )
91      !!
92      INTEGER  ::   ji, jj   ! dummy loop indices
93      REAL(wp), DIMENSION(jpi,jpj,1) ::   alb_ice_os   ! albedo of the ice under overcast sky
94      REAL(wp), DIMENSION(jpi,jpj,1) ::   alb_ice_cs   ! albedo of ice under clear sky
95      REAL(wp), DIMENSION(jpi,jpj,1) ::   zsist        ! surface ice temperature (K)
96      REAL(wp), DIMENSION(jpi,jpj,1) ::   zhicif       ! ice thickness
97      REAL(wp), DIMENSION(jpi,jpj,1) ::   zhsnif       ! snow thickness
98      REAL(wp), DIMENSION(jpi,jpj,1) ::   zqns_ice     ! non solar sea-ice heat flux
99      REAL(wp), DIMENSION(jpi,jpj,1) ::   zqsr_ice     !     solar sea-ice heat flux
100      REAL(wp), DIMENSION(jpi,jpj,1) ::   zqla_ice     ! ice latent heat flux
101      REAL(wp), DIMENSION(jpi,jpj,1) ::   zdqns_ice    ! sensitivity ice net heat flux
102      REAL(wp), DIMENSION(jpi,jpj,1) ::   zdqla_ice    ! sensitivity ice latent heat flux
103      !!----------------------------------------------------------------------
104
105      IF( kt == nit000 ) THEN
106         IF(lwp) WRITE(numout,*)
107         IF(lwp) WRITE(numout,*) 'sbc_ice_lim_2 : update ocean surface boudary condition' 
108         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~   via Louvain la Neuve Ice Model (LIM) time stepping'
109
110         CALL ice_init_2
111
112      ENDIF
113
114      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
115         !
116         ! ... mean surface ocean current at ice dynamics point
117         !     B-grid dynamics :  I-point (F-point with sea-ice indexation)
118         DO jj = 2, jpj
119            DO ji = fs_2, jpi   ! vector opt.
120               ui_oce(ji,jj) = 0.5 * ( ssu_m(ji-1,jj  ) + ssu_m(ji-1,jj-1) ) * tmu(ji,jj)
121               vi_oce(ji,jj) = 0.5 * ( ssv_m(ji  ,jj-1) + ssv_m(ji-1,jj-1) ) * tmu(ji,jj)
122            END DO
123         END DO
124         CALL lbc_lnk( ui_oce, 'I', -1. )   ! I-point (i.e. F-point with ice indices)
125         CALL lbc_lnk( vi_oce, 'I', -1. )   ! I-point (i.e. F-point with ice indices)
126
127         ! ... masked sea surface freezing temperature [Kelvin] (set to rt0 over land)
128         tfu(:,:) = tfreez( sss_m ) +  rt0 
129
130         zsist (:,:,1) = sist (:,:) + rt0 * ( 1. - tmask(:,:,1) )
131         zhicif(:,:,1) = hicif(:,:)
132         zhsnif(:,:,1) = hsnif(:,:)
133
134         ! ... ice albedo (clear sky and overcast sky)
135         CALL albedo_ice( zsist, zhicif, zhsnif, alb_ice_cs, alb_ice_os )
136
137         ! ... Sea-ice surface boundary conditions output from bulk formulae :
138         !     - utaui_ice  ! surface ice stress i-component (I-point)   [N/m2]
139         !     - vtaui_ice  ! surface ice stress j-component (I-point)   [N/m2]
140         !     - qns_ice    ! non solar heat flux over ice   (T-point)   [W/m2]
141         !     - qsr_ice    !     solar heat flux over ice   (T-point)   [W/m2]
142         !     - qla_ice    ! latent    heat flux over ice   (T-point)   [W/m2]
143         !     - dqns_ice   ! non solar heat sensistivity    (T-point)   [W/m2]
144         !     - dqla_ice   ! latent    heat sensistivity    (T-point)   [W/m2]
145         !     - tprecip    ! total precipitation            (T-point)   [Kg/m2/s]
146         !     - sprecip    ! solid precipitation            (T-point)   [Kg/m2/s]
147         !     - fr1_i0     ! 1sr fraction of qsr penetration in ice     [%]
148         !     - fr2_i0     ! 2nd fraction of qsr penetration in ice     [%]
149         !
150         SELECT CASE( ksbc )
151         CASE( 3 )           ! CLIO bulk formulation
152            CALL blk_ice_clio( zsist, alb_ice_cs, alb_ice_os ,                         &
153               &                      utaui_ice , vtaui_ice  , zqns_ice  , zqsr_ice,   &
154               &                      zqla_ice  , zdqns_ice  , zdqla_ice ,             &
155               &                      tprecip   , sprecip    ,                         &
156               &                      fr1_i0    , fr2_i0     , cl_grid  )
157
158         CASE( 4 )           ! CORE bulk formulation
159            CALL blk_ice_core( zsist, ui_ice    , vi_ice     , alb_ice_cs,             &
160               &                      utaui_ice , vtaui_ice  , zqns_ice  , zqsr_ice,   &
161               &                      zqla_ice  , zdqns_ice  , zdqla_ice ,             &
162               &                      tprecip   , sprecip    ,                         &
163               &                      fr1_i0    , fr2_i0     , cl_grid  )
164         CASE( 5 )           ! Coupled formulation : atmosphere-ice stress only (fluxes provided after ice dynamics)
165            CALL sbc_cpl_ice_tau( utaui_ice , vtaui_ice )
166         END SELECT
167
168         qsr_ice(:,:) = zqsr_ice(:,:,1)
169         qns_ice(:,:) = zqns_ice(:,:,1)   ;   dqns_ice(:,:) = zdqns_ice(:,:,1)
170         qla_ice(:,:) = zqla_ice(:,:,1)   ;   dqla_ice(:,:) = zdqla_ice(:,:,1)
171
172         IF(ln_ctl) THEN         ! print mean trends (used for debugging)
173            CALL prt_ctl_info( 'Ice Forcings ' )
174            CALL prt_ctl( tab2d_1=tprecip  ,clinfo1=' sbc_ice_lim: precip   : ', tab2d_2=sprecip  , clinfo2=' Snow     : ' )
175            CALL prt_ctl( tab2d_1=utaui_ice,clinfo1=' sbc_ice_lim: utaui_ice: ', tab2d_2=vtaui_ice, clinfo2=' vtaui_ice: ' )
176            CALL prt_ctl( tab2d_1=sst_m    ,clinfo1=' sbc_ice_lim: sst      : ', tab2d_2=sss_m    , clinfo2=' sss      : ' )
177            CALL prt_ctl( tab2d_1=ui_oce   ,clinfo1=' sbc_ice_lim: u_io     : ', tab2d_2=vi_oce   , clinfo2=' v_io     : ' )
178            CALL prt_ctl( tab2d_1=hsnif    ,clinfo1=' sbc_ice_lim: hsnif  1 : ', tab2d_2=hicif    , clinfo2=' hicif    : ' )
179            CALL prt_ctl( tab2d_1=frld     ,clinfo1=' sbc_ice_lim: frld   1 : ', tab2d_2=sist     , clinfo2=' sist     : ' )
180         ENDIF
181
182         ! ---------------- !
183         !  Ice model step  !
184         ! ---------------- !
185                                        CALL lim_rst_opn_2  ( kt )      ! Open Ice restart file
186         IF( .NOT. lk_c1d ) THEN                                        ! Ice dynamics & transport (not in 1D case)
187                                        CALL lim_dyn_2      ( kt )           ! Ice dynamics    ( rheology/dynamics )
188                                        CALL lim_trp_2      ( kt )           ! Ice transport   ( Advection/diffusion )
189            IF( ln_limdmp )             CALL lim_dmp_2      ( kt )           ! Ice damping
190         ENDIF
191#if defined key_coupled
192         IF( ksbc == 5    )             CALL sbc_cpl_ice_flx( frld, alb_ice_cs , sst_m, sist,   &
193      &                                                             qns_tot, qns_ice,   &
194      &                                                             qsr_tot, qsr_ice,   &
195      &                                                             emp_tot, emp_ice, dqns_ice, sprecip )
196#endif
197                                        CALL lim_thd_2      ( kt )      ! Ice thermodynamics
198                                        CALL lim_sbc_2      ( kt )      ! Ice/Ocean Mass & Heat fluxes
199         IF( ( MOD( kt+nn_fsbc-1, ninfo ) == 0 .OR. ntmoy == 1 ) .AND. .NOT. lk_mpp )   &
200            &                           CALL lim_dia_2      ( kt )      ! Ice Diagnostics
201                                        CALL lim_wri_2      ( kt )      ! Ice outputs
202         IF( lrst_ice )                 CALL lim_rst_write_2( kt )      ! Ice restart file
203         !
204      ENDIF
205      !
206   END SUBROUTINE sbc_ice_lim_2
207
208#else
209   !!----------------------------------------------------------------------
210   !!   Default option           Dummy module      NO LIM 2.0 sea-ice model
211   !!----------------------------------------------------------------------
212CONTAINS
213   SUBROUTINE sbc_ice_lim_2 ( kt, ksbc )     ! Dummy routine
214      WRITE(*,*) 'sbc_ice_lim_2: You should not have seen this print! error?', kt, ksbc
215   END SUBROUTINE sbc_ice_lim_2
216#endif
217
218   !!======================================================================
219END MODULE sbcice_lim_2
Note: See TracBrowser for help on using the repository browser.