| 1 | MODULE sbcice_lim_2 |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcice_lim_2 *** |
|---|
| 4 | !! Surface module : update surface ocean boundary condition over ice |
|---|
| 5 | !! covered area using LIM sea-ice model |
|---|
| 6 | !! Sea-Ice model : LIM 2.0 Sea ice model time-stepping |
|---|
| 7 | !!====================================================================== |
|---|
| 8 | !! History : 1.0 ! 06-2006 (G. Madec) from icestp_2.F90 |
|---|
| 9 | !! 3.0 ! 08-2008 (S. Masson, E. .... ) coupled interface |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | #if defined key_lim2 |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | !! 'key_lim2' : LIM 2.0 sea-ice model |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! sbc_ice_lim_2 : sea-ice model time-stepping and |
|---|
| 16 | !! update ocean sbc over ice-covered area |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | USE oce ! ocean dynamics and tracers |
|---|
| 19 | USE c1d ! 1d configuration |
|---|
| 20 | USE dom_oce ! ocean space and time domain |
|---|
| 21 | USE lib_mpp |
|---|
| 22 | USE ice_2 |
|---|
| 23 | USE par_ice_2 |
|---|
| 24 | USE iceini_2 |
|---|
| 25 | USE dom_ice_2 |
|---|
| 26 | |
|---|
| 27 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 28 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 29 | USE sbcblk_core ! Surface boundary condition: CORE bulk |
|---|
| 30 | USE sbcblk_clio ! Surface boundary condition: CLIO bulk |
|---|
| 31 | USE sbccpl ! Surface boundary condition: coupled interface |
|---|
| 32 | USE albedo |
|---|
| 33 | |
|---|
| 34 | USE daymod ! day calendar |
|---|
| 35 | USE phycst ! Define parameters for the routines |
|---|
| 36 | USE eosbn2 ! equation of state |
|---|
| 37 | USE limdyn_2 |
|---|
| 38 | USE limtrp_2 |
|---|
| 39 | USE limdmp_2 |
|---|
| 40 | USE limthd_2 |
|---|
| 41 | USE limsbc_2 ! sea surface boundary condition |
|---|
| 42 | USE limdia_2 |
|---|
| 43 | USE limwri_2 |
|---|
| 44 | USE limrst_2 |
|---|
| 45 | |
|---|
| 46 | USE lbclnk |
|---|
| 47 | USE iom ! I/O manager library |
|---|
| 48 | USE in_out_manager ! I/O manager |
|---|
| 49 | USE prtctl ! Print control |
|---|
| 50 | |
|---|
| 51 | IMPLICIT NONE |
|---|
| 52 | PRIVATE |
|---|
| 53 | |
|---|
| 54 | PUBLIC sbc_ice_lim_2 ! routine called by sbcmod.F90 |
|---|
| 55 | |
|---|
| 56 | CHARACTER(len=1) :: cl_grid = 'B' ! type of grid used in ice dynamics |
|---|
| 57 | |
|---|
| 58 | !! * Substitutions |
|---|
| 59 | # include "domzgr_substitute.h90" |
|---|
| 60 | # include "vectopt_loop_substitute.h90" |
|---|
| 61 | !!---------------------------------------------------------------------- |
|---|
| 62 | !! NEMO/SBC 3.0 , LOCEAN-IPSL (2008) |
|---|
| 63 | !! $Id$ |
|---|
| 64 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
|---|
| 65 | !!---------------------------------------------------------------------- |
|---|
| 66 | |
|---|
| 67 | CONTAINS |
|---|
| 68 | |
|---|
| 69 | SUBROUTINE sbc_ice_lim_2( kt, ksbc ) |
|---|
| 70 | !!--------------------------------------------------------------------- |
|---|
| 71 | !! *** ROUTINE sbc_ice_lim_2 *** |
|---|
| 72 | !! |
|---|
| 73 | !! ** Purpose : update the ocean surface boundary condition via the |
|---|
| 74 | !! Louvain la Neuve Sea Ice Model time stepping |
|---|
| 75 | !! |
|---|
| 76 | !! ** Method : ice model time stepping |
|---|
| 77 | !! - call the ice dynamics routine |
|---|
| 78 | !! - call the ice advection/diffusion routine |
|---|
| 79 | !! - call the ice thermodynamics routine |
|---|
| 80 | !! - call the routine that computes mass and |
|---|
| 81 | !! heat fluxes at the ice/ocean interface |
|---|
| 82 | !! - save the outputs |
|---|
| 83 | !! - save the outputs for restart when necessary |
|---|
| 84 | !! |
|---|
| 85 | !! ** Action : - time evolution of the LIM sea-ice model |
|---|
| 86 | !! - update all sbc variables below sea-ice: |
|---|
| 87 | !! utau, vtau, qns , qsr, emp , emps |
|---|
| 88 | !!--------------------------------------------------------------------- |
|---|
| 89 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 90 | INTEGER, INTENT(in) :: ksbc ! type of sbc ( =3 CLIO bulk ; =4 CORE bulk ; =5 coupled ) |
|---|
| 91 | !! |
|---|
| 92 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 93 | REAL(wp), DIMENSION(jpi,jpj,1) :: zalb_ice_os ! albedo of the ice under overcast sky |
|---|
| 94 | REAL(wp), DIMENSION(jpi,jpj,1) :: zalb_ice_cs ! albedo of ice under clear sky |
|---|
| 95 | REAL(wp), DIMENSION(jpi,jpj,1) :: zsist ! surface ice temperature (K) |
|---|
| 96 | !!---------------------------------------------------------------------- |
|---|
| 97 | |
|---|
| 98 | IF( kt == nit000 ) THEN |
|---|
| 99 | IF(lwp) WRITE(numout,*) |
|---|
| 100 | IF(lwp) WRITE(numout,*) 'sbc_ice_lim_2 : update ocean surface boudary condition' |
|---|
| 101 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~ via Louvain la Neuve Ice Model (LIM) time stepping' |
|---|
| 102 | |
|---|
| 103 | CALL ice_init_2 |
|---|
| 104 | |
|---|
| 105 | ENDIF |
|---|
| 106 | |
|---|
| 107 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN |
|---|
| 108 | ! |
|---|
| 109 | ! ... mean surface ocean current at ice dynamics point |
|---|
| 110 | ! B-grid dynamics : I-point |
|---|
| 111 | DO jj = 2, jpj |
|---|
| 112 | DO ji = 2, jpi ! B grid : no vector opt. |
|---|
| 113 | u_oce(ji,jj) = 0.5 * ( ssu_m(ji-1,jj ) + ssu_m(ji-1,jj-1) ) * tmu(ji,jj) |
|---|
| 114 | v_oce(ji,jj) = 0.5 * ( ssv_m(ji ,jj-1) + ssv_m(ji-1,jj-1) ) * tmu(ji,jj) |
|---|
| 115 | END DO |
|---|
| 116 | END DO |
|---|
| 117 | CALL lbc_lnk( u_oce, 'I', -1. ) ! I-point (i.e. F-point with ice indices) |
|---|
| 118 | CALL lbc_lnk( v_oce, 'I', -1. ) ! I-point (i.e. F-point with ice indices) |
|---|
| 119 | |
|---|
| 120 | ! ... masked sea surface freezing temperature [Kelvin] (set to rt0 over land) |
|---|
| 121 | tfu(:,:) = tfreez( sss_m ) + rt0 |
|---|
| 122 | |
|---|
| 123 | zsist (:,:,1) = sist (:,:) + rt0 * ( 1. - tmask(:,:,1) ) |
|---|
| 124 | |
|---|
| 125 | ! ... ice albedo (clear sky and overcast sky) |
|---|
| 126 | CALL albedo_ice( zsist, reshape( hicif, (/jpi,jpj,1/) ), reshape( hsnif, (/jpi,jpj,1/) ), zalb_ice_cs, zalb_ice_os ) |
|---|
| 127 | |
|---|
| 128 | ! ... Sea-ice surface boundary conditions output from bulk formulae : |
|---|
| 129 | ! - utau_ice ! surface ice stress i-component (I-point) [N/m2] |
|---|
| 130 | ! - vtau_ice ! surface ice stress j-component (I-point) [N/m2] |
|---|
| 131 | ! - qns_ice ! non solar heat flux over ice (T-point) [W/m2] |
|---|
| 132 | ! - qsr_ice ! solar heat flux over ice (T-point) [W/m2] |
|---|
| 133 | ! - qla_ice ! latent heat flux over ice (T-point) [W/m2] |
|---|
| 134 | ! - dqns_ice ! non solar heat sensistivity (T-point) [W/m2] |
|---|
| 135 | ! - dqla_ice ! latent heat sensistivity (T-point) [W/m2] |
|---|
| 136 | ! - tprecip ! total precipitation (T-point) [Kg/m2/s] |
|---|
| 137 | ! - sprecip ! solid precipitation (T-point) [Kg/m2/s] |
|---|
| 138 | ! - fr1_i0 ! 1sr fraction of qsr penetration in ice [%] |
|---|
| 139 | ! - fr2_i0 ! 2nd fraction of qsr penetration in ice [%] |
|---|
| 140 | ! |
|---|
| 141 | SELECT CASE( ksbc ) |
|---|
| 142 | CASE( 3 ) ! CLIO bulk formulation |
|---|
| 143 | CALL blk_ice_clio( zsist, zalb_ice_cs, zalb_ice_os, & |
|---|
| 144 | & utau_ice , vtau_ice , qns_ice , qsr_ice, & |
|---|
| 145 | & qla_ice , dqns_ice , dqla_ice , & |
|---|
| 146 | & tprecip , sprecip , & |
|---|
| 147 | & fr1_i0 , fr2_i0 , cl_grid , jpl ) |
|---|
| 148 | |
|---|
| 149 | CASE( 4 ) ! CORE bulk formulation |
|---|
| 150 | CALL blk_ice_core( zsist, u_ice , v_ice , zalb_ice_cs, & |
|---|
| 151 | & utau_ice , vtau_ice , qns_ice , qsr_ice, & |
|---|
| 152 | & qla_ice , dqns_ice , dqla_ice , & |
|---|
| 153 | & tprecip , sprecip , & |
|---|
| 154 | & fr1_i0 , fr2_i0 , cl_grid , jpl ) |
|---|
| 155 | CASE( 5 ) ! Coupled formulation : atmosphere-ice stress only (fluxes provided after ice dynamics) |
|---|
| 156 | CALL sbc_cpl_ice_tau( utau_ice , vtau_ice ) |
|---|
| 157 | END SELECT |
|---|
| 158 | |
|---|
| 159 | CALL iom_put( 'utau_ice', utau_ice ) ! Wind stress over ice along i-axis at I-point |
|---|
| 160 | CALL iom_put( 'vtau_ice', vtau_ice ) ! Wind stress over ice along j-axis at I-point |
|---|
| 161 | |
|---|
| 162 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 163 | CALL prt_ctl_info( 'Ice Forcings ' ) |
|---|
| 164 | CALL prt_ctl( tab2d_1=tprecip ,clinfo1=' sbc_ice_lim: precip : ', tab2d_2=sprecip , clinfo2=' Snow : ' ) |
|---|
| 165 | CALL prt_ctl( tab2d_1=utau_ice,clinfo1=' sbc_ice_lim: utau_ice: ', tab2d_2=vtau_ice, clinfo2=' vtau_ice: ' ) |
|---|
| 166 | CALL prt_ctl( tab2d_1=sst_m ,clinfo1=' sbc_ice_lim: sst : ', tab2d_2=sss_m , clinfo2=' sss : ' ) |
|---|
| 167 | CALL prt_ctl( tab2d_1=u_oce ,clinfo1=' sbc_ice_lim: u_io : ', tab2d_2=v_oce , clinfo2=' v_io : ' ) |
|---|
| 168 | CALL prt_ctl( tab2d_1=hsnif ,clinfo1=' sbc_ice_lim: hsnif 1: ', tab2d_2=hicif , clinfo2=' hicif : ' ) |
|---|
| 169 | CALL prt_ctl( tab2d_1=frld ,clinfo1=' sbc_ice_lim: frld 1: ', tab2d_2=sist , clinfo2=' sist : ' ) |
|---|
| 170 | ENDIF |
|---|
| 171 | |
|---|
| 172 | ! ---------------- ! |
|---|
| 173 | ! Ice model step ! |
|---|
| 174 | ! ---------------- ! |
|---|
| 175 | |
|---|
| 176 | CALL lim_rst_opn_2 ( kt ) ! Open Ice restart file |
|---|
| 177 | IF( .NOT. lk_c1d ) THEN ! Ice dynamics & transport (not in 1D case) |
|---|
| 178 | CALL lim_dyn_2 ( kt ) ! Ice dynamics ( rheology/dynamics ) |
|---|
| 179 | CALL lim_trp_2 ( kt ) ! Ice transport ( Advection/diffusion ) |
|---|
| 180 | IF( ln_limdmp ) CALL lim_dmp_2 ( kt ) ! Ice damping |
|---|
| 181 | ENDIF |
|---|
| 182 | #if defined key_coupled |
|---|
| 183 | IF( ksbc == 5 ) CALL sbc_cpl_ice_flx( frld , & |
|---|
| 184 | & qns_tot, qns_ice, qsr_tot , qsr_ice, & |
|---|
| 185 | & emp_tot, emp_ice, dqns_ice, sprecip, & |
|---|
| 186 | ! optional arguments, used only in 'mixed oce-ice' case |
|---|
| 187 | & palbi = zalb_ice_cs, psst = sst_m, pist = sist ) |
|---|
| 188 | #endif |
|---|
| 189 | CALL lim_thd_2 ( kt ) ! Ice thermodynamics |
|---|
| 190 | CALL lim_sbc_2 ( kt ) ! Ice/Ocean Mass & Heat fluxes |
|---|
| 191 | |
|---|
| 192 | IF( ( MOD( kt+nn_fsbc-1, ninfo ) == 0 .OR. ntmoy == 1 ) .AND. .NOT. lk_mpp ) & |
|---|
| 193 | & CALL lim_dia_2 ( kt ) ! Ice Diagnostics |
|---|
| 194 | # if ! defined key_iomput |
|---|
| 195 | CALL lim_wri_2 ( kt ) ! Ice outputs |
|---|
| 196 | # endif |
|---|
| 197 | IF( lrst_ice ) CALL lim_rst_write_2( kt ) ! Ice restart file |
|---|
| 198 | ! |
|---|
| 199 | ENDIF |
|---|
| 200 | ! |
|---|
| 201 | END SUBROUTINE sbc_ice_lim_2 |
|---|
| 202 | |
|---|
| 203 | #else |
|---|
| 204 | !!---------------------------------------------------------------------- |
|---|
| 205 | !! Default option Dummy module NO LIM 2.0 sea-ice model |
|---|
| 206 | !!---------------------------------------------------------------------- |
|---|
| 207 | CONTAINS |
|---|
| 208 | SUBROUTINE sbc_ice_lim_2 ( kt, ksbc ) ! Dummy routine |
|---|
| 209 | WRITE(*,*) 'sbc_ice_lim_2: You should not have seen this print! error?', kt, ksbc |
|---|
| 210 | END SUBROUTINE sbc_ice_lim_2 |
|---|
| 211 | #endif |
|---|
| 212 | |
|---|
| 213 | !!====================================================================== |
|---|
| 214 | END MODULE sbcice_lim_2 |
|---|
