New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcice_lim_2.F90 in trunk/NEMO/OPA_SRC/SBC – NEMO

source: trunk/NEMO/OPA_SRC/SBC/sbcice_lim_2.F90 @ 914

Last change on this file since 914 was 914, checked in by ctlod, 16 years ago

move the set to zero of qsr(:,:) (when more than 50% of sea-ice) from sbcblk_clio.F90 into sbcice_lim*, see ticket: #131

File size: 11.1 KB
Line 
1MODULE sbcice_lim_2
2   !!======================================================================
3   !!                       ***  MODULE  sbcice_lim_2  ***
4   !! Surface module :  update surface ocean boundary condition over ice
5   !!                   covered area using LIM sea-ice model
6   !! Sea-Ice model  :  LIM 2.0 Sea ice model time-stepping
7   !!======================================================================
8   !! History :  9.0   !  06-06  (G. Madec)  from icestp_2.F90
9   !!----------------------------------------------------------------------
10#if defined key_lim2
11   !!----------------------------------------------------------------------
12   !!   'key_lim2' :                                  LIM 2.0 sea-ice model
13   !!----------------------------------------------------------------------
14   !!   sbc_ice_lim_2  : sea-ice model time-stepping and
15   !!                    update ocean sbc over ice-covered area
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers
18   USE c1d             ! 1d configuration
19   USE dom_oce         ! ocean space and time domain
20   USE ice_2
21   USE iceini_2
22   USE ice_oce         ! ice variables
23   USE dom_ice_2
24   USE cpl_oce
25
26   USE sbc_oce         ! Surface boundary condition: ocean fields
27   USE sbc_ice         ! Surface boundary condition: ice   fields
28   USE sbcblk_core     ! Surface boundary condition: CORE bulk
29   USE sbcblk_clio     ! Surface boundary condition: CLIO bulk
30   USE albedo
31
32   USE daymod          ! day calendar
33   USE phycst          ! Define parameters for the routines
34   USE eosbn2          ! equation of state
35   USE limdyn_2
36   USE limtrp_2
37   USE limdmp_2
38   USE limthd_2
39   USE limsbc_2        ! sea surface boundary condition
40   USE limdia_2
41   USE limwri_2
42   USE limrst_2
43
44   USE lbclnk
45   USE iom             ! I/O manager library
46   USE in_out_manager  ! I/O manager
47   USE prtctl          ! Print control
48   USE ocfzpt          ! ocean freezing point
49
50   IMPLICIT NONE
51   PRIVATE
52
53   PUBLIC sbc_ice_lim_2 ! routine called by sbcmod.F90
54   
55   CHARACTER(len=1) ::   cl_grid = 'B'     ! type of grid used in ice dynamics
56
57   !! * Substitutions
58#  include "domzgr_substitute.h90"
59#  include "vectopt_loop_substitute.h90"
60   !!----------------------------------------------------------------------
61   !! NEMO/SBC  3.0 , LOCEAN-IPSL (2008)
62   !! $Id: $
63   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
64   !!----------------------------------------------------------------------
65
66CONTAINS
67
68   SUBROUTINE sbc_ice_lim_2( kt, kblk )
69      !!---------------------------------------------------------------------
70      !!                  ***  ROUTINE sbc_ice_lim_2  ***
71      !!                   
72      !! ** Purpose :   update the ocean surface boundary condition via the
73      !!                Louvain la Neuve Sea Ice Model time stepping
74      !!
75      !! ** Method  :   ice model time stepping
76      !!              - call the ice dynamics routine
77      !!              - call the ice advection/diffusion routine
78      !!              - call the ice thermodynamics routine
79      !!              - call the routine that computes mass and
80      !!                heat fluxes at the ice/ocean interface
81      !!              - save the outputs
82      !!              - save the outputs for restart when necessary
83      !!
84      !! ** Action  : - time evolution of the LIM sea-ice model
85      !!              - update all sbc variables below sea-ice:
86      !!                utau, vtau, qns , qsr, emp , emps
87      !!---------------------------------------------------------------------
88      INTEGER, INTENT(in) ::   kt      ! ocean time step
89      INTEGER, INTENT(in) ::   kblk    ! type of bulk (=3 CLIO, =4 CORE)
90      !!
91      INTEGER  ::   ji, jj   ! dummy loop indices
92      REAL(wp) ::   zinda   
93      REAL(wp), DIMENSION(jpi,jpj,1) ::   alb_ice_os   ! albedo of the ice under overcast sky
94      REAL(wp), DIMENSION(jpi,jpj,1) ::   alb_ice_cs   ! albedo of ice under clear sky
95      REAL(wp), DIMENSION(jpi,jpj,1) ::   zsist        ! surface ice temperature (K)
96      REAL(wp), DIMENSION(jpi,jpj,1) ::   zhicif       ! ice thickness
97      REAL(wp), DIMENSION(jpi,jpj,1) ::   zhsnif       ! snow thickness
98      REAL(wp), DIMENSION(jpi,jpj,1) ::   zqns_ice     ! non solar sea-ice heat flux
99      REAL(wp), DIMENSION(jpi,jpj,1) ::   zqsr_ice     !     solar sea-ice heat flux
100      REAL(wp), DIMENSION(jpi,jpj,1) ::   zqla_ice     ! ice latent heat flux
101      REAL(wp), DIMENSION(jpi,jpj,1) ::   zdqns_ice    ! sensitivity ice net heat flux
102      REAL(wp), DIMENSION(jpi,jpj,1) ::   zdqla_ice    ! sensitivity ice latent heat flux
103      !!----------------------------------------------------------------------
104
105      IF( kt == nit000 ) THEN
106         IF(lwp) WRITE(numout,*)
107         IF(lwp) WRITE(numout,*) 'sbc_ice_lim_2 : update ocean surface boudary condition' 
108         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~   via Louvain la Neuve Ice Model (LIM) time stepping'
109
110         CALL ice_init_2
111
112      ENDIF
113
114      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
115         !
116         ! ... mean surface ocean current at ice dynamics point
117         !     B-grid dynamics :  I-point (F-point with sea-ice indexation)
118         DO jj = 2, jpj
119            DO ji = fs_2, jpi   ! vector opt.
120               ui_oce(ji,jj) = 0.5 * ( ssu_m(ji-1,jj  ) + ssu_m(ji-1,jj-1) ) * tmu(ji,jj)
121               vi_oce(ji,jj) = 0.5 * ( ssv_m(ji  ,jj-1) + ssv_m(ji-1,jj-1) ) * tmu(ji,jj)
122            END DO
123         END DO
124         CALL lbc_lnk( ui_oce, 'I', -1. )   ! I-point (i.e. F-point with ice indices)
125         CALL lbc_lnk( vi_oce, 'I', -1. )   ! I-point (i.e. F-point with ice indices)
126
127         ! ... masked sea surface freezing temperature [Kelvin] (set to rt0 over land)
128         tfu(:,:) = tfreez( sss_m ) +  rt0 
129
130         zsist (:,:,1) = sist (:,:)
131         zhicif(:,:,1) = hicif(:,:)   ;   zhsnif(:,:,1) = hsnif(:,:)
132
133         ! ... ice albedo
134         CALL albedo_ice( zsist, zhicif, zhsnif, alb_ice_cs, alb_ice_os )
135
136         ! ... Sea-ice surface boundary conditions output from bulk formulae :
137         !     - utaui_ice  ! surface ice stress i-component (I-point)   [N/m2]
138         !     - vtaui_ice  ! surface ice stress j-component (I-point)   [N/m2]
139         !     - qns_ice    ! non solar heat flux over ice   (T-point)   [W/m2]
140         !     - qsr_ice    !     solar heat flux over ice   (T-point)   [W/m2]
141         !     - qla_ice    ! latent    heat flux over ice   (T-point)   [W/m2]
142         !     - dqns_ice   ! non solar heat sensistivity    (T-point)   [W/m2]
143         !     - dqla_ice   ! latent    heat sensistivity    (T-point)   [W/m2]
144         !     - tprecip    ! total precipitation            (T-point)   [Kg/m2/s]
145         !     - sprecip    ! solid precipitation            (T-point)   [Kg/m2/s]
146         !     - fr1_i0     ! 1sr fraction of qsr penetration in ice     [%]
147         !     - fr2_i0     ! 2nd fraction of qsr penetration in ice     [%]
148         !
149         SELECT CASE( kblk )
150         CASE( 3 )           ! CLIO bulk formulation
151            CALL blk_ice_clio( zsist , ui_ice , vi_ice   , alb_ice_cs , alb_ice_os ,             &
152               &                               utaui_ice , vtaui_ice  , zqns_ice   , zqsr_ice,   &
153               &                               zqla_ice  , zdqns_ice  , zdqla_ice  ,             &
154               &                               tprecip   , sprecip    ,                          &
155               &                               fr1_i0    , fr2_i0     , cl_grid  )
156
157            ! CAUTION: ocean shortwave radiation sets to zero if more than 50% of sea-ice !!gm to be removed
158            DO jj = 1, jpj
159               DO ji = 1, jpi
160                  zinda    = MAX(  0.e0, SIGN(  1.e0, -( -1.5 - freeze(ji,jj) )  )  )
161                  qsr(ji,jj) = zinda * qsr(ji,jj)
162               END DO
163            END DO
164
165         CASE( 4 )           ! CORE bulk formulation
166            CALL blk_ice_core( zsist , ui_ice , vi_ice   , alb_ice_cs ,                         &
167               &                               utaui_ice , vtaui_ice  , zqns_ice  , zqsr_ice,   &
168               &                               zqla_ice  , zdqns_ice  , zdqla_ice ,             &
169               &                               tprecip   , sprecip    ,                         &
170               &                               fr1_i0    , fr2_i0     , cl_grid)
171         END SELECT
172
173         qsr_ice(:,:) = zqsr_ice(:,:,1)
174         qns_ice(:,:) = zqns_ice(:,:,1)   ;   dqns_ice(:,:) = zdqns_ice(:,:,1)
175         qla_ice(:,:) = zqla_ice(:,:,1)   ;   dqla_ice(:,:) = zdqla_ice(:,:,1)
176
177         IF(ln_ctl) THEN         ! print mean trends (used for debugging)
178            CALL prt_ctl_info( 'Ice Forcings ' )
179            CALL prt_ctl( tab2d_1=tprecip  ,clinfo1=' sbc_ice_lim: precip   : ', tab2d_2=sprecip  , clinfo2=' Snow     : ' )
180            CALL prt_ctl( tab2d_1=utaui_ice,clinfo1=' sbc_ice_lim: utaui_ice: ', tab2d_2=vtaui_ice, clinfo2=' vtaui_ice: ' )
181            CALL prt_ctl( tab2d_1=sst_m    ,clinfo1=' sbc_ice_lim: sst      : ', tab2d_2=sss_m    , clinfo2=' sss      : ' )
182            CALL prt_ctl( tab2d_1=ui_oce   ,clinfo1=' sbc_ice_lim: u_io     : ', tab2d_2=vi_oce   , clinfo2=' v_io     : ' )
183            CALL prt_ctl( tab2d_1=hsnif    ,clinfo1=' sbc_ice_lim: hsnif  1 : ', tab2d_2=hicif    , clinfo2=' hicif    : ' )
184            CALL prt_ctl( tab2d_1=frld     ,clinfo1=' sbc_ice_lim: frld   1 : ', tab2d_2=sist     , clinfo2=' sist     : ' )
185         ENDIF
186
187         ! ---------------- !
188         !  Ice model step  !
189         ! ---------------- !
190                                        CALL lim_rst_opn_2  ( kt )      ! Open Ice restart file
191         IF( .NOT. lk_c1d ) THEN                                        ! Ice dynamics & transport (not in 1D case)
192                                        CALL lim_dyn_2      ( kt )           ! Ice dynamics    ( rheology/dynamics )
193                                        CALL lim_trp_2      ( kt )           ! Ice transport   ( Advection/diffusion )
194            IF( ln_limdmp )             CALL lim_dmp_2      ( kt )           ! Ice damping
195         ENDIF
196                                        CALL lim_thd_2      ( kt )      ! Ice thermodynamics
197                                        CALL lim_sbc_2      ( kt )      ! Ice/Ocean Mass & Heat fluxes
198         IF( MOD( kt+nn_fsbc-1, ninfo ) == 0 .OR.   &
199            &  ntmoy == 1 )             CALL lim_dia_2      ( kt )      ! Ice Diagnostics
200                                        CALL lim_wri_2      ( kt )      ! Ice outputs
201         IF( lrst_ice )                 CALL lim_rst_write_2( kt )      ! Ice restart file
202         !
203      ENDIF
204      !
205   END SUBROUTINE sbc_ice_lim_2
206
207#else
208   !!----------------------------------------------------------------------
209   !!   Default option           Dummy module      NO LIM 2.0 sea-ice model
210   !!----------------------------------------------------------------------
211CONTAINS
212   SUBROUTINE sbc_ice_lim_2 ( kt, kblk )     ! Dummy routine
213      WRITE(*,*) 'sbc_ice_lim_2: You should not have seen this print! error?', kt, kblk
214   END SUBROUTINE sbc_ice_lim_2
215#endif
216
217   !!======================================================================
218END MODULE sbcice_lim_2
Note: See TracBrowser for help on using the repository browser.