New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcmod.F90 in trunk/NEMO/OPA_SRC/SBC – NEMO

source: trunk/NEMO/OPA_SRC/SBC/sbcmod.F90 @ 1226

Last change on this file since 1226 was 1226, checked in by smasson, 15 years ago

bugfix of the coupling interface (commited during changeset:1218), see ticket:155
  • Property svn:keywords set to Id
File size: 13.9 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0   !  07-2006  (G. Madec)  Original code
7   !!             -    !  08-2008  (S. Masson, E. .... ) coupled interface
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_init       : read namsbc namelist
12   !!   sbc            : surface ocean momentum, heat and freshwater boundary conditions
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and tracers
15   USE dom_oce         ! ocean space and time domain
16   USE daymod          ! calendar
17   USE phycst          ! physical constants
18
19   USE ice_oce         ! sea-ice model : LIM
20   USE sbc_oce         ! Surface boundary condition: ocean fields
21   USE sbcssm          ! surface boundary condition: sea-surface mean variables
22   USE sbcana          ! surface boundary condition: analytical formulation
23   USE sbcflx          ! surface boundary condition: flux formulation
24   USE sbcblk_clio     ! surface boundary condition: bulk formulation : CLIO
25   USE sbcblk_core     ! surface boundary condition: bulk formulation : CORE
26   USE sbcice_if       ! surface boundary condition: ice-if sea-ice model
27   USE sbcice_lim      ! surface boundary condition: LIM 3.0 sea-ice model
28   USE sbcice_lim_2    ! surface boundary condition: LIM 2.0 sea-ice model
29   USE sbccpl          ! surface boundary condition: coupled florulation
30   USE cpl_oasis3, ONLY:lk_cpl      ! are we in coupled mode?
31   USE sbcssr          ! surface boundary condition: sea surface restoring
32   USE sbcrnf          ! surface boundary condition: runoffs
33   USE sbcfwb          ! surface boundary condition: freshwater budget
34   USE closea          ! closed sea
35
36   USE prtctl          ! Print control                    (prt_ctl routine)
37   USE restart         ! ocean restart
38   USE iom
39   USE in_out_manager  ! I/O manager
40
41   IMPLICIT NONE
42   PRIVATE
43
44   PUBLIC   sbc        ! routine called by step.F90
45   
46   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
47     
48   !! * Substitutions
49#  include "domzgr_substitute.h90"
50   !!----------------------------------------------------------------------
51   !! NEMO/OPA 3.0 , LOCEAN-IPSL (2008)
52   !! $Id$
53   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
54   !!----------------------------------------------------------------------
55
56CONTAINS
57
58   SUBROUTINE sbc_init
59      !!---------------------------------------------------------------------
60      !!                    ***  ROUTINE sbc_init ***
61      !!
62      !! ** Purpose :   Initialisation of the ocean surface boundary computation
63      !!
64      !! ** Method  :   Read the namsbc namelist and set derived parameters
65      !!
66      !! ** Action  : - read namsbc parameters
67      !!              - nsbc: type of sbc
68      !!----------------------------------------------------------------------
69      INTEGER ::   icpt      ! temporary integer
70      !!
71      NAMELIST/namsbc/ nn_fsbc, ln_ana, ln_flx, ln_blk_clio, ln_blk_core, ln_cpl,   &
72         &             nn_ice , ln_dm2dc, ln_rnf, ln_ssr, nn_fwb, nn_ico_cpl
73      !!----------------------------------------------------------------------
74
75      IF(lwp) THEN
76         WRITE(numout,*)
77         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
78         WRITE(numout,*) '~~~~~~~~ '
79      ENDIF
80
81      REWIND( numnam )                   ! Read Namelist namsbc
82      READ  ( numnam, namsbc )
83
84      ! overwrite namelist parameter using CPP key information
85!!gm here no overwrite, test all option via namelist change: require more incore memory
86!!gm  IF( lk_sbc_cpl       ) THEN   ;   ln_cpl      = .TRUE.   ;   ELSE   ;   ln_cpl      = .FALSE.   ;   ENDIF
87      IF( lk_lim2 )            nn_ice      = 2
88      IF( lk_lim3 )            nn_ice      = 3
89      IF( cp_cfg == 'gyre' ) THEN
90          ln_ana      = .TRUE.   
91          nn_ice      =   0
92      ENDIF
93     
94      ! Control print
95      IF(lwp) THEN
96         WRITE(numout,*) '        Namelist namsbc (partly overwritten with CPP key setting)'
97         WRITE(numout,*) '           frequency update of sbc (and ice)             nn_fsbc     = ', nn_fsbc
98         WRITE(numout,*) '           Type of sbc : '
99         WRITE(numout,*) '              analytical formulation                     ln_ana      = ', ln_ana
100         WRITE(numout,*) '              flux       formulation                     ln_flx      = ', ln_flx
101         WRITE(numout,*) '              CLIO bulk  formulation                     ln_blk_clio = ', ln_blk_clio
102         WRITE(numout,*) '              CLIO bulk  formulation                     ln_blk_core = ', ln_blk_core
103         WRITE(numout,*) '              coupled    formulation (T if key_sbc_cpl)  ln_cpl      = ', ln_cpl
104         WRITE(numout,*) '           Misc. options of sbc : '
105         WRITE(numout,*) '              ice management in the sbc (=0/1/2/3)       nn_ice      = ', nn_ice 
106         WRITE(numout,*) '              ice-ocean stress computation (=0/1/2)      nn_ico_cpl  = ', nn_ico_cpl
107         WRITE(numout,*) '              daily mean to diurnal cycle qsr            ln_dm2dc    = ', ln_dm2dc 
108         WRITE(numout,*) '              runoff / runoff mouths                     ln_rnf      = ', ln_rnf
109         WRITE(numout,*) '              Sea Surface Restoring on SST and/or SSS    ln_ssr      = ', ln_ssr
110         WRITE(numout,*) '              FreshWater Budget control  (=0/1/2)        nn_fwb      = ', nn_fwb
111         WRITE(numout,*) '              closed sea (=0/1) (set in namdom)          nclosea     = ', nclosea
112      ENDIF
113
114      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
115         ln_rnf_mouth  = .false.                     
116         nkrnf         = 0
117         rnfmsk  (:,:) = 0.e0
118         rnfmsk_z(:)   = 0.e0
119      ENDIF
120      IF( nn_ice == 0  )   fr_i(:,:) = 0.e0        ! no ice in the domain, ice fraction is always zero
121
122      !                                            ! restartability   
123      IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR.   &
124          MOD( nstock             , nn_fsbc) /= 0 ) THEN
125         WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock,   &
126            &           ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
127         CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
128      ENDIF
129      !
130      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
131         &  CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' )
132      !
133      IF( nn_ice == 2 .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. lk_cpl ) )   &
134         &   CALL ctl_stop( 'sea-ice model requires a bulk formulation or coupled configuration' )
135     
136      ! Choice of the Surface Boudary Condition (set nsbc)
137      icpt = 0
138      IF( ln_ana          ) THEN   ;   nsbc =  1   ; icpt = icpt + 1   ;   ENDIF       ! analytical      formulation
139      IF( ln_flx          ) THEN   ;   nsbc =  2   ; icpt = icpt + 1   ;   ENDIF       ! flux            formulation
140      IF( ln_blk_clio     ) THEN   ;   nsbc =  3   ; icpt = icpt + 1   ;   ENDIF       ! CLIO bulk       formulation
141      IF( ln_blk_core     ) THEN   ;   nsbc =  4   ; icpt = icpt + 1   ;   ENDIF       ! CORE bulk       formulation
142      IF( ln_cpl          ) THEN   ;   nsbc =  5   ; icpt = icpt + 1   ;   ENDIF       ! Coupled         formulation
143      IF( cp_cfg == 'gyre') THEN   ;   nsbc =  0                       ;   ENDIF       ! GYRE analytical formulation
144      IF( lk_esopa        )            nsbc = -1                                       ! esopa test, ALL formulations
145
146      IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN
147         WRITE(numout,*)
148         WRITE(numout,*) '           E R R O R in setting the sbc, one and only one namelist/CPP key option '
149         WRITE(numout,*) '                     must be choosen. You choose ', icpt, ' option(s)'
150         WRITE(numout,*) '                     We stop'
151         nstop = nstop + 1
152      ENDIF
153      IF(lwp) THEN
154         WRITE(numout,*)
155         IF( nsbc == -1 )   WRITE(numout,*) '              ESOPA test All surface boundary conditions'
156         IF( nsbc ==  0 )   WRITE(numout,*) '              GYRE analytical formulation'
157         IF( nsbc ==  1 )   WRITE(numout,*) '              analytical formulation'
158         IF( nsbc ==  2 )   WRITE(numout,*) '              flux formulation'
159         IF( nsbc ==  3 )   WRITE(numout,*) '              CLIO bulk formulation'
160         IF( nsbc ==  4 )   WRITE(numout,*) '              CORE bulk formulation'
161         IF( nsbc ==  5 )   WRITE(numout,*) '              coupled formulation'
162      ENDIF
163      !
164   END SUBROUTINE sbc_init
165
166
167   SUBROUTINE sbc( kt )
168      !!---------------------------------------------------------------------
169      !!                    ***  ROUTINE sbc  ***
170      !!             
171      !! ** Purpose :   provide at each time-step the ocean surface boundary
172      !!                condition (momentum, heat and freshwater fluxes)
173      !!
174      !! ** Method  :   blah blah  to be written ?????????
175      !!                CAUTION : never mask the surface stress field (tke sbc)
176      !!
177      !! ** Action  : - set the ocean surface boundary condition, i.e. 
178      !!                utau, vtau, qns, qsr, emp, emps, qrp, erp
179      !!              - updte the ice fraction : fr_i
180      !!----------------------------------------------------------------------
181      INTEGER, INTENT(in) ::   kt       ! ocean time step
182      !!---------------------------------------------------------------------
183
184      IF( kt == nit000 )   CALL sbc_init         ! Read namsbc namelist : surface module
185
186      ! ocean to sbc mean sea surface variables (ss._m)
187      ! ---------------------------------------
188      CALL sbc_ssm( kt )                         ! sea surface mean currents (at U- and V-points),
189      !                                          ! temperature and salinity (at T-point) over nf_sbc time-step
190      !                                          ! (i.e. sst_m, sss_m, ssu_m, ssv_m)
191
192      ! sbc formulation
193      ! ---------------
194         
195      SELECT CASE( nsbc )                        ! Compute ocean surface boundary condition
196      !                                          ! (i.e. utau,vtau, qns, qsr, emp, emps)
197      CASE(  0 )   ;   CALL sbc_gyre    ( kt )                    ! analytical formulation : GYRE configuration
198      CASE(  1 )   ;   CALL sbc_ana     ( kt )                    ! analytical formulation : uniform sbc
199      CASE(  2 )   ;   CALL sbc_flx     ( kt )                    ! flux formulation
200      CASE(  3 )   ;   CALL sbc_blk_clio( kt )                    ! bulk formulation : CLIO for the ocean
201      CASE(  4 )   ;   CALL sbc_blk_core( kt )                    ! bulk formulation : CORE for the ocean
202      CASE(  5 )   ;   CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! coupled formulation
203      CASE( -1 )                               
204                       CALL sbc_ana     ( kt )                    ! ESOPA, test ALL the formulations
205                       CALL sbc_gyre    ( kt )                    !
206                       CALL sbc_flx     ( kt )                    !
207                       CALL sbc_blk_clio( kt )                    !
208                       CALL sbc_blk_core( kt )                    !
209                       CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   !
210      END SELECT
211
212      ! Misc. Options
213      ! -------------
214
215!!gm  IF( ln_dm2dc       )   CALL sbc_dcy( kt )                 ! Daily mean qsr distributed over the Diurnal Cycle
216     
217      SELECT CASE( nn_ice )                                     ! Update heat and freshwater fluxes over sea-ice areas
218      CASE(  1 )   ;       CALL sbc_ice_if   ( kt )                   ! Ice-cover climatology ("Ice-if" model)
219         !                                                     
220      CASE(  2 )   ;       CALL sbc_ice_lim_2( kt, nsbc )             ! LIM 2.0 ice model
221         !                                                     
222      CASE(  3 )   ;       CALL sbc_ice_lim  ( kt, nsbc, nn_ico_cpl)  ! LIM 3.0 ice model
223      END SELECT                                             
224
225      IF( ln_rnf       )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
226 
227      IF( ln_ssr       )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
228
229      IF( nn_fwb  /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
230
231      IF( nclosea == 1 )   CALL sbc_clo( kt )                   ! treatment of closed sea in the model domain
232      !                                                         ! (update freshwater fluxes)
233      !
234      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
235         CALL prt_ctl(tab2d_1=fr_i   , clinfo1=' fr_i - : ', mask1=tmask, ovlap=1 )
236         CALL prt_ctl(tab2d_1=emp    , clinfo1=' emp  - : ', mask1=tmask, ovlap=1 )
237         CALL prt_ctl(tab2d_1=emps   , clinfo1=' emps - : ', mask1=tmask, ovlap=1 )
238         CALL prt_ctl(tab2d_1=qns    , clinfo1=' qns  - : ', mask1=tmask, ovlap=1 )
239         CALL prt_ctl(tab2d_1=qsr    , clinfo1=' qsr  - : ', mask1=tmask, ovlap=1 )
240         CALL prt_ctl(tab3d_1=tmask  , clinfo1=' tmask  : ', mask1=tmask, ovlap=1, kdim=jpk )
241         CALL prt_ctl(tab3d_1=tn     , clinfo1=' sst  - : ', mask1=tmask, ovlap=1, kdim=1   )
242         CALL prt_ctl(tab3d_1=sn     , clinfo1=' sss  - : ', mask1=tmask, ovlap=1, kdim=1   )
243         CALL prt_ctl(tab2d_1=utau   , clinfo1=' utau - : ', mask1=umask,                      &
244            &         tab2d_2=vtau   , clinfo2=' vtau - : ', mask2=vmask, ovlap=1 )
245      ENDIF
246      !
247   END SUBROUTINE sbc
248
249   !!======================================================================
250END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.