New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssr.F90 in trunk/NEMO/OPA_SRC/SBC – NEMO

source: trunk/NEMO/OPA_SRC/SBC/sbcssr.F90 @ 1133

Last change on this file since 1133 was 1133, checked in by smasson, 16 years ago

new sbc namelist format, see ticket:1

File size: 9.6 KB
Line 
1MODULE sbcssr
2   !!======================================================================
3   !!                       ***  MODULE  sbcssr  ***
4   !! Surface module :  add to heat and fresh water fluxes a restoring term
5   !!                   toward observed SST/SSS
6   !!======================================================================
7   !! History :  9.0   !  06-06  (G. Madec)  Original code
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_ssr        : add to sbc a restoring term toward SST/SSS climatology
12   !!----------------------------------------------------------------------
13   USE oce             ! ocean dynamics and tracers
14   USE dom_oce         ! ocean space and time domain
15   USE sbc_oce         ! surface boundary condition
16   USE phycst          ! physical constants
17   USE daymod          ! calendar
18   USE sbcrnf          ! surface boundary condition : runoffs
19   USE fldread         ! read input fields
20   USE iom             ! I/O manager
21   USE in_out_manager  ! I/O manager
22   USE lib_mpp         ! distribued memory computing library
23   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   sbc_ssr    ! routine called in sbcmod
29   
30   REAL(wp), ALLOCATABLE, DIMENSION(:)   ::   buffer   ! Temporary buffer for exchange
31
32   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sst   ! structure of input SST (file informations, fields read)
33   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sss   ! structure of input SSS (file informations, fields read)
34
35   REAL(wp), PUBLIC, DIMENSION(jpi,jpj) ::   erp       !: evaporation damping                          [kg/m2/s]
36   REAL(wp), PUBLIC, DIMENSION(jpi,jpj) ::   qrp       !: heat flux damping                            [w/m2]
37
38   !! * Namelist namsbc_ssr
39   INTEGER ::   nn_sstr, nn_sssr   ! SST/SSS indicator
40   REAL(wp) ::  dqdt   , deds      ! restoring term factor
41
42   !! * Substitutions
43#  include "domzgr_substitute.h90"
44   !!----------------------------------------------------------------------
45   !!   OPA 9.0 , LOCEAN-IPSL (2006)
46   !! $ Id: $
47   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49
50CONTAINS
51
52   SUBROUTINE sbc_ssr( kt )
53      !!---------------------------------------------------------------------
54      !!                     ***  ROUTINE sbc_ssr  ***
55      !!
56      !! ** Purpose :   Add to heat and/or freshwater fluxes a damping term
57      !!                toward observed SST and/or SSS.
58      !!
59      !! ** Method  : - Read namelist namsbc_ssr
60      !!              - Read observed SST and/or SSS
61      !!              - at each nscb time step
62      !!                   add a retroaction term on qns    (nn_sstr = 1)
63      !!                   add a damping term on emps       (nn_sssr = 1)
64      !!                   add a damping term on emp & emps (nn_sssr = 2)
65      !!---------------------------------------------------------------------
66      INTEGER, INTENT(in   ) ::   kt   ! ocean time step
67      !!
68      INTEGER  ::   ji, jj   ! dummy loop indices
69      REAL(wp) ::   zerp     ! local scalar for evaporation damping
70      REAL(wp) ::   zqrp     ! local scalar for heat flux damping
71      REAL(wp) ::   zsrp     ! local scalar for unit conversion of deds factor
72      INTEGER  ::   ierror   ! return error code
73      !!
74      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
75      TYPE(FLD_N) ::   sn_sst, sn_sss        ! informations about the fields to be read
76      NAMELIST/namsbc_ssr/ cn_dir, nn_sstr, nn_sssr, dqdt, deds, sn_sst, sn_sss
77      !!----------------------------------------------------------------------
78      !                                               ! -------------------- !
79      IF( kt == nit000 ) THEN                         ! First call kt=nit000 !
80         !                                            ! -------------------- !
81         !                         ! set file information
82         nn_sstr = 0
83         nn_sssr = 0
84         dqdt = -40.e0
85         deds = -27.70
86         cn_dir = './'       ! directory in which the model is executed
87         ! ... default values (NB: frequency positive => hours, negative => months)
88         !            !   file    ! frequency !  variable  ! time intep !  clim   ! 'yearly' or !
89         !            !   name    !  (hours)  !   name     !   (T/F)    !  (T/F)  !  'monthly'  !
90         sn_sst = FLD_N( 'sst'    ,    24.    ,  'sst'     ,  .false.   , .false. ,   'yearly'  )
91         sn_sss = FLD_N( 'sss'    ,    -1.    ,  'sss'     ,  .true.    , .false. ,   'yearly'  )
92
93         REWIND ( numnam )         ! ... read in namlist namflx
94         READ( numnam, namsbc_ssr ) 
95
96         IF(lwp) THEN              ! control print
97            WRITE(numout,*)
98            WRITE(numout,*) 'sbc_ssr : SST and/or SSS damping term '
99            WRITE(numout,*) '~~~~~~~ '
100            WRITE(numout,*) '          SST restoring term (Yes=1)             nn_sstr = ', nn_sstr
101            WRITE(numout,*) '          SSS damping term (Yes=1, salt flux)    nn_sssr = ', nn_sssr
102            WRITE(numout,*) '                           (Yes=2, volume flux) '
103            WRITE(numout,*) '          dQ/dT (restoring magnitude on SST)     dqdt    = ', dqdt, ' W/m2/K'
104            WRITE(numout,*) '          dE/dS (restoring magnitude on SST)     deds    = ', deds, ' mm/day'
105         ENDIF
106
107         IF( nn_sstr == 1 ) THEN      ! set sf_sst structure
108            !
109            ALLOCATE( sf_sst(1), STAT=ierror )
110            IF( ierror > 0 ) THEN
111               CALL ctl_stop( 'sbc_ssr: unable to allocate sf_sst structure' )   ;   RETURN
112            ENDIF
113            ! fill sf_sst with sn_sst and control print
114            CALL fld_fill( sf_sst, (/ sn_sst /), cn_dir, 'sbc_ssr', 'SST restoring term toward SST data', 'namsbc_ssr' )
115
116         ENDIF
117         !
118         IF( nn_sssr == 1 ) THEN      ! set sf_sss structure
119            !
120            ALLOCATE( sf_sss(1), STAT=ierror )
121            IF( ierror > 0 ) THEN
122               CALL ctl_stop( 'sbc_ssr: unable to allocate sf_sss structure' )   ;   RETURN
123            ENDIF
124            ! fill sf_sss with sn_sss and control print
125            CALL fld_fill( sf_sss, (/ sn_sss /), cn_dir, 'sbc_ssr', 'SSS restoring term toward SSS data', 'namsbc_ssr' )
126
127         ENDIF
128         !
129         ! Initialize qrp and erp if no restoring
130         IF( nn_sstr /= 1                   )   qrp(:,:) = 0.e0 
131         IF( nn_sssr /= 1 .OR. nn_sssr /= 2 )   erp(:,:) = 0.e0 
132      ENDIF
133
134      IF( nn_sstr + nn_sssr /= 0 ) THEN
135
136         IF( nn_sstr == 1)   CALL fld_read( kt, nn_fsbc, sf_sst )   ! Read SST data and provides it
137         !                                                          ! at the current time-step
138         IF( nn_sssr == 1)   CALL fld_read( kt, nn_fsbc, sf_sss )   ! Read SSS data and provides it
139         !                                                          ! at the current time-step
140 
141         !                                         ! ========================= !
142         IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN      !    Add restoring term     !
143            !                                      ! ========================= !
144            !
145            IF( nn_sstr == 1 ) THEN                   ! Temperature restoring term
146!CDIR COLLAPSE
147               ! use zqrp scalar to optimize memory access (speedup the loop)
148               DO jj = 1, jpj
149                  DO ji = 1, jpi
150                     zqrp = dqdt * ( sst_m(ji,jj) - sf_sst(1)%fnow(ji,jj) )
151                     qns(ji,jj) = qns(ji,jj) + zqrp
152                     qrp(ji,jj) = zqrp
153                  END DO
154               END DO
155            ENDIF
156            !
157            IF( nn_sssr == 1 ) THEN                   ! Salinity damping term (salt flux, emps only)
158!CDIR COLLAPSE
159               ! use zerp scalar to optimize memory access (speedup the loop)
160               DO jj = 1, jpj
161                  DO ji = 1, jpi
162                     zsrp = deds / rday                               ! from [mm/day] to [kg/m2/s]
163                     zerp = zsrp * ( 1. - 2.*rnfmsk(ji,jj) )   &      ! No damping in vicinity of river mouths
164                        &        * ( sss_m(ji,jj) - sf_sss(1)%fnow(ji,jj) )   &
165                        &        / ( sss_m(ji,jj) + 1.e-20   )
166                     emps(ji,jj) = emps(ji,jj) + zerp
167                     erp( ji,jj) = zerp
168                  END DO
169               END DO
170            ELSEIF( nn_sssr == 2 ) THEN               ! Salinity damping term (volume flux, emp and emps)
171!CDIR COLLAPSE
172               ! use zerp scalar to optimize memory access (speedup the loop)
173               DO jj = 1, jpj
174                  DO ji = 1, jpi                           
175                     zsrp = deds / rday                               ! from [mm/day] to [kg/m2/s]
176                     zerp = zsrp * ( 1. - 2.*rnfmsk(ji,jj) )   &      ! No damping in vicinity of river mouths
177                        &        * ( sss_m(ji,jj) - sf_sss(1)%fnow(ji,jj) )   &
178                        &        / ( sss_m(ji,jj) + 1.e-20   )
179                     emp (ji,jj) = emp (ji,jj) + zerp
180                     emps(ji,jj) = emps(ji,jj) + zerp
181                     erp (ji,jj) = zerp
182                  END DO
183               END DO
184            ENDIF
185            !
186         ENDIF
187         !
188      ENDIF
189
190      !!gm ... to be written                     ! Output sbc fields (using IOM)
191      ! prevoir comment obtenir l info sst sss ssr
192      !
193   END SUBROUTINE sbc_ssr
194     
195   !!======================================================================
196END MODULE sbcssr
Note: See TracBrowser for help on using the repository browser.