New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_muscl.F90 in trunk/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMO/OPA_SRC/TRA/traadv_muscl.F90 @ 719

Last change on this file since 719 was 719, checked in by ctlod, 17 years ago

get back to the nemo_v2_3 version for trunk
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 18.8 KB
Line 
1MODULE traadv_muscl
2   !!======================================================================
3   !!                       ***  MODULE  traadv_muscl  ***
4   !! Ocean active tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  06-00  (A.Estublier)  for passive tracers
7   !!                 !  01-08  (E.Durand, G.Madec)  adapted for T & S
8   !!            8.5  !  02-06  (G. Madec)  F90: Free form and module
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   tra_adv_muscl : update the tracer trend with the horizontal
13   !!                   and vertical advection trends using MUSCL scheme
14   !!----------------------------------------------------------------------
15   USE oce             ! ocean dynamics and active tracers
16   USE dom_oce         ! ocean space and time domain
17   USE trdmod          ! ocean active tracers trends
18   USE trdmod_oce      ! ocean variables trends
19   USE in_out_manager  ! I/O manager
20   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
21   USE trabbl          ! tracers: bottom boundary layer
22   USE lib_mpp         ! distribued memory computing
23   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
24   USE diaptr          ! poleward transport diagnostics
25   USE prtctl          ! Print control
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   tra_adv_muscl  ! routine called by step.F90
31
32   !! * Substitutions
33#  include "domzgr_substitute.h90"
34#  include "vectopt_loop_substitute.h90"
35   !!----------------------------------------------------------------------
36   !!   OPA 9.0 , LOCEAN-IPSL (2006)
37   !! $Header$
38   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
39   !!----------------------------------------------------------------------
40
41CONTAINS
42
43   SUBROUTINE tra_adv_muscl( kt, pun, pvn, pwn )
44      !!----------------------------------------------------------------------
45      !!                    ***  ROUTINE tra_adv_muscl  ***
46      !!
47      !! ** Purpose :   Compute the now trend due to total advection of T and
48      !!      S using a MUSCL scheme (Monotone Upstream-centered Scheme for
49      !!      Conservation Laws) and add it to the general tracer trend.
50      !!
51      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
52      !!
53      !! ** Action  : - update (ta,sa) with the now advective tracer trends
54      !!              - save trends in (ztrdt,ztrds) ('key_trdtra')
55      !!
56      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
57      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
58      !!----------------------------------------------------------------------
59      USE oce, ONLY :   ztrdt => ua   ! use ua as workspace
60      USE oce, ONLY :   ztrds => va   ! use va as workspace
61      !!
62      INTEGER , INTENT(in)                         ::   kt    ! ocean time-step index
63      REAL(wp), INTENT(in), DIMENSION(jpi,jpj,jpk) ::   pun   ! ocean velocity u-component
64      REAL(wp), INTENT(in), DIMENSION(jpi,jpj,jpk) ::   pvn   ! ocean velocity v-component
65      REAL(wp), INTENT(in), DIMENSION(jpi,jpj,jpk) ::   pwn   ! ocean velocity w-component
66      !!
67      INTEGER ::   ji, jj, jk   ! dummy loop indices
68      REAL(wp) ::   &
69         zu, zv, zw, zeu, zev,           & 
70         zew, zbtr, zstep,               &
71         z0u, z0v, z0w,                  &
72         zzt1, zzt2, zalpha,             &
73         zzs1, zzs2, z2,                 &
74         zta, zsa,                       &
75        z_hdivn_x, z_hdivn_y, z_hdivn
76      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zt1, zt2, ztp1, ztp2   ! 3D workspace
77      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zs1, zs2, zsp1, zsp2   !  "      "
78      !!----------------------------------------------------------------------
79
80      IF( kt == nit000 .AND. lwp ) THEN
81         WRITE(numout,*)
82         WRITE(numout,*) 'tra_adv : MUSCL advection scheme'
83         WRITE(numout,*) '~~~~~~~'
84      ENDIF
85
86      IF( neuler == 0 .AND. kt == nit000 ) THEN   ;    z2 = 1.
87      ELSE                                        ;    z2 = 2.
88      ENDIF
89
90      ! I. Horizontal advective fluxes
91      ! ------------------------------
92      ! first guess of the slopes
93      ! interior values
94      DO jk = 1, jpkm1
95         DO jj = 1, jpjm1     
96            DO ji = 1, fs_jpim1   ! vector opt.
97               zt1(ji,jj,jk) = umask(ji,jj,jk) * ( tb(ji+1,jj,jk) - tb(ji,jj,jk) )
98               zs1(ji,jj,jk) = umask(ji,jj,jk) * ( sb(ji+1,jj,jk) - sb(ji,jj,jk) )
99               zt2(ji,jj,jk) = vmask(ji,jj,jk) * ( tb(ji,jj+1,jk) - tb(ji,jj,jk) )
100               zs2(ji,jj,jk) = vmask(ji,jj,jk) * ( sb(ji,jj+1,jk) - sb(ji,jj,jk) )
101            END DO
102         END DO
103      END DO
104      ! bottom values
105      zt1(:,:,jpk) = 0.e0    ;    zt2(:,:,jpk) = 0.e0
106      zs1(:,:,jpk) = 0.e0    ;    zs2(:,:,jpk) = 0.e0
107
108      ! lateral boundary conditions on zt1, zt2 ; zs1, zs2   (changed sign)
109      CALL lbc_lnk( zt1, 'U', -1. )   ;   CALL lbc_lnk( zs1, 'U', -1. )
110      CALL lbc_lnk( zt2, 'V', -1. )   ;   CALL lbc_lnk( zs2, 'V', -1. )
111
112      ! Slopes
113      ! interior values
114      DO jk = 1, jpkm1
115         DO jj = 2, jpj
116            DO ji = fs_2, jpi   ! vector opt.
117               ztp1(ji,jj,jk) =                    ( zt1(ji,jj,jk) + zt1(ji-1,jj  ,jk) )   &
118                  &           * ( 0.25 + SIGN( 0.25, zt1(ji,jj,jk) * zt1(ji-1,jj  ,jk) ) )
119               zsp1(ji,jj,jk) =                    ( zs1(ji,jj,jk) + zs1(ji-1,jj  ,jk) )   &
120                  &           * ( 0.25 + SIGN( 0.25, zs1(ji,jj,jk) * zs1(ji-1,jj  ,jk) ) )
121               ztp2(ji,jj,jk) =                    ( zt2(ji,jj,jk) + zt2(ji  ,jj-1,jk) )   &
122                  &           * ( 0.25 + SIGN( 0.25, zt2(ji,jj,jk) * zt2(ji  ,jj-1,jk) ) )
123               zsp2(ji,jj,jk) =                    ( zs2(ji,jj,jk) + zs2(ji  ,jj-1,jk) )   &
124                  &           * ( 0.25 + SIGN( 0.25, zs2(ji,jj,jk) * zs2(ji  ,jj-1,jk) ) )
125            END DO
126         END DO
127      END DO
128      ! bottom values
129      ztp1(:,:,jpk) = 0.e0    ;    ztp2(:,:,jpk) = 0.e0
130      zsp1(:,:,jpk) = 0.e0    ;    zsp2(:,:,jpk) = 0.e0
131
132      ! Slopes limitation
133      DO jk = 1, jpkm1
134         DO jj = 2, jpj
135            DO ji = fs_2, jpi   ! vector opt.
136               ztp1(ji,jj,jk) = SIGN( 1., ztp1(ji,jj,jk) )   &
137                  &           * MIN(    ABS( ztp1(ji  ,jj,jk) ),   &
138                  &                  2.*ABS( zt1 (ji-1,jj,jk) ),   &
139                  &                  2.*ABS( zt1 (ji  ,jj,jk) ) )
140               zsp1(ji,jj,jk) = SIGN( 1., zsp1(ji,jj,jk) )   &
141                  &           * MIN(    ABS( zsp1(ji  ,jj,jk) ),   &
142                  &                  2.*ABS( zs1 (ji-1,jj,jk) ),   &
143                  &                  2.*ABS( zs1 (ji  ,jj,jk) ) )
144               ztp2(ji,jj,jk) = SIGN( 1., ztp2(ji,jj,jk) )   &
145                  &           * MIN(    ABS( ztp2(ji,jj  ,jk) ),   &
146                  &                  2.*ABS( zt2 (ji,jj-1,jk) ),   &
147                  &                  2.*ABS( zt2 (ji,jj  ,jk) ) )
148               zsp2(ji,jj,jk) = SIGN( 1., zsp2(ji,jj,jk) )   &
149                  &           * MIN(    ABS( zsp2(ji,jj  ,jk) ),   &
150                  &                  2.*ABS( zs2 (ji,jj-1,jk) ),   &
151                  &                  2.*ABS( zs2 (ji,jj  ,jk) ) )
152            END DO
153         END DO
154      END DO       
155
156      ! Advection terms
157      ! interior values
158      DO jk = 1, jpkm1
159         zstep  = z2 * rdttra(jk)
160         DO jj = 2, jpjm1     
161            DO ji = fs_2, fs_jpim1   ! vector opt.
162               ! volume fluxes
163#if defined key_zco
164               zeu = e2u(ji,jj)                   * pun(ji,jj,jk)
165               zev = e1v(ji,jj)                   * pvn(ji,jj,jk)
166#else
167               zeu = e2u(ji,jj) * fse3u(ji,jj,jk) * pun(ji,jj,jk)
168               zev = e1v(ji,jj) * fse3v(ji,jj,jk) * pvn(ji,jj,jk)
169#endif
170               ! MUSCL fluxes
171               z0u = SIGN( 0.5, pun(ji,jj,jk) )           
172               zalpha = 0.5 - z0u
173               zu  = z0u - 0.5 * pun(ji,jj,jk) * zstep / e1u(ji,jj)
174               zzt1 = tb(ji+1,jj,jk) + zu*ztp1(ji+1,jj,jk)
175               zzt2 = tb(ji  ,jj,jk) + zu*ztp1(ji  ,jj,jk)
176               zzs1 = sb(ji+1,jj,jk) + zu*zsp1(ji+1,jj,jk)
177               zzs2 = sb(ji  ,jj,jk) + zu*zsp1(ji  ,jj,jk)
178               zt1(ji,jj,jk) = zeu * ( zalpha * zzt1 + (1.-zalpha) * zzt2 )
179               zs1(ji,jj,jk) = zeu * ( zalpha * zzs1 + (1.-zalpha) * zzs2 )
180               !
181               z0v = SIGN( 0.5, pvn(ji,jj,jk) )           
182               zalpha = 0.5 - z0v
183               zv  = z0v - 0.5 * pvn(ji,jj,jk) * zstep / e2v(ji,jj)
184               zzt1 = tb(ji,jj+1,jk) + zv*ztp2(ji,jj+1,jk)
185               zzt2 = tb(ji,jj  ,jk) + zv*ztp2(ji,jj  ,jk)
186               zzs1 = sb(ji,jj+1,jk) + zv*zsp2(ji,jj+1,jk)
187               zzs2 = sb(ji,jj  ,jk) + zv*zsp2(ji,jj  ,jk)
188               zt2(ji,jj,jk) = zev * ( zalpha * zzt1 + (1.-zalpha) * zzt2 )
189               zs2(ji,jj,jk) = zev * ( zalpha * zzs1 + (1.-zalpha) * zzs2 )
190            END DO
191         END DO
192      END DO
193
194      ! lateral boundary conditions on zt1, zt2 ; zs1, zs2   (changed sign)
195      CALL lbc_lnk( zt1, 'U', -1. )   ;   CALL lbc_lnk( zs1, 'U', -1. ) 
196      CALL lbc_lnk( zt2, 'V', -1. )   ;   CALL lbc_lnk( zs2, 'V', -1. )
197
198      ! Tracer flux divergence at t-point added to the general trend
199      DO jk = 1, jpkm1
200         DO jj = 2, jpjm1     
201            DO ji = fs_2, fs_jpim1   ! vector opt.
202#if defined key_zco
203               zbtr = 1. / ( e1t(ji,jj)*e2t(ji,jj) )
204#else
205               zbtr = 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
206#endif
207               ! horizontal advective trends
208               zta = - zbtr * ( zt1(ji,jj,jk) - zt1(ji-1,jj  ,jk  )   &
209                  &           + zt2(ji,jj,jk) - zt2(ji  ,jj-1,jk  ) )
210               zsa = - zbtr * ( zs1(ji,jj,jk) - zs1(ji-1,jj  ,jk  )   &
211                  &           + zs2(ji,jj,jk) - zs2(ji  ,jj-1,jk  ) ) 
212               ! add it to the general tracer trends
213               ta(ji,jj,jk) = ta(ji,jj,jk) + zta
214               sa(ji,jj,jk) = sa(ji,jj,jk) + zsa
215            END DO
216        END DO
217      END DO       
218
219      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ta, clinfo1=' muscl had  - Ta: ', mask1=tmask ,  &
220         &                       tab3d_2=sa, clinfo2=             ' Sa: ', mask2=tmask, clinfo3='tra' )
221
222      ! Save the horizontal advective trends for diagnostics
223      IF( l_trdtra ) THEN
224         ztrdt(:,:,:) = 0.e0   ;   ztrds(:,:,:) = 0.e0
225         !
226         ! T/S ZONAL advection trends
227         DO jk = 1, jpkm1
228            DO jj = 2, jpjm1
229               DO ji = fs_2, fs_jpim1   ! vector opt.
230                  !-- Compute zonal divergence by splitting hdivn (see divcur.F90)
231                  !   N.B. This computation is not valid along OBCs (if any)
232#if defined key_zco
233                  zbtr      = 1. / ( e1t(ji,jj) * e2t(ji,jj) )
234                  z_hdivn_x = (  e2u(ji  ,jj) * pun(ji  ,jj,jk)                              &
235                     &         - e2u(ji-1,jj) * pun(ji-1,jj,jk) ) * zbtr
236#else
237                  zbtr      = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
238                  z_hdivn_x = (  e2u(ji  ,jj) * fse3u(ji  ,jj,jk) * pun(ji  ,jj,jk)          &
239                     &         - e2u(ji-1,jj) * fse3u(ji-1,jj,jk) * pun(ji-1,jj,jk) ) * zbtr
240#endif
241                  ztrdt(ji,jj,jk) = - zbtr * ( zt1(ji,jj,jk) - zt1(ji-1,jj,jk) ) + tn(ji,jj,jk) * z_hdivn_x
242                  ztrds(ji,jj,jk) = - zbtr * ( zs1(ji,jj,jk) - zs1(ji-1,jj,jk) ) + sn(ji,jj,jk) * z_hdivn_x
243               END DO
244            END DO
245         END DO
246         CALL trd_mod(ztrdt, ztrds, jptra_trd_xad, 'TRA', kt)
247
248         ! T/S MERIDIONAL advection trends
249         DO jk = 1, jpkm1
250            DO jj = 2, jpjm1
251               DO ji = fs_2, fs_jpim1   ! vector opt.
252                  !-- Compute merid. divergence by splitting hdivn (see divcur.F90)
253                  !   N.B. This computation is not valid along OBCs (if any)
254#if defined key_zco
255                  zbtr      = 1. / ( e1t(ji,jj) * e2t(ji,jj) )
256                  z_hdivn_y = (  e1v(ji,jj  ) * pvn(ji,jj  ,jk)                              &
257                     &         - e1v(ji,jj-1) * pvn(ji,jj-1,jk) ) * zbtr
258#else
259                  zbtr      = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
260                  z_hdivn_y = (  e1v(ji,  jj) * fse3v(ji,jj  ,jk) * pvn(ji,jj  ,jk)          &
261                     &         - e1v(ji,jj-1) * fse3v(ji,jj-1,jk) * pvn(ji,jj-1,jk) ) * zbtr
262#endif
263                  ztrdt(ji,jj,jk) = - zbtr * ( zt2(ji,jj,jk) - zt2(ji,jj-1,jk) ) + tn(ji,jj,jk) * z_hdivn_y         
264                  ztrds(ji,jj,jk) = - zbtr * ( zs2(ji,jj,jk) - zs2(ji,jj-1,jk) ) + sn(ji,jj,jk) * z_hdivn_y
265               END DO
266            END DO
267         END DO
268         CALL trd_mod(ztrdt, ztrds, jptra_trd_yad, 'TRA', kt)
269
270         ! Save the up-to-date ta and sa trends
271         ztrdt(:,:,:) = ta(:,:,:) 
272         ztrds(:,:,:) = sa(:,:,:) 
273         !
274      ENDIF
275
276      ! "zonal" mean advective heat and salt transport
277      IF( ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN
278         IF( lk_zco ) THEN
279            DO jk = 1, jpkm1
280               DO jj = 2, jpjm1
281                  DO ji = fs_2, fs_jpim1   ! vector opt.
282                    zt2(ji,jj,jk) = zt2(ji,jj,jk) * fse3v(ji,jj,jk)
283                    zs2(ji,jj,jk) = zs2(ji,jj,jk) * fse3v(ji,jj,jk)
284                  END DO
285               END DO
286            END DO
287         ENDIF
288         pht_adv(:) = ptr_vj( zt2(:,:,:) )
289         pst_adv(:) = ptr_vj( zs2(:,:,:) )
290      ENDIF
291
292      ! II. Vertical advective fluxes
293      ! -----------------------------
294     
295      ! First guess of the slope
296      ! interior values
297      DO jk = 2, jpkm1
298         zt1(:,:,jk) = tmask(:,:,jk) * ( tb(:,:,jk-1) - tb(:,:,jk) )
299         zs1(:,:,jk) = tmask(:,:,jk) * ( sb(:,:,jk-1) - sb(:,:,jk) )
300      END DO
301      ! surface & bottom boundary conditions
302      zt1 (:,:, 1 ) = 0.e0    ;    zt1 (:,:,jpk) = 0.e0
303      zs1 (:,:, 1 ) = 0.e0    ;    zs1 (:,:,jpk) = 0.e0
304
305      ! Slopes
306      DO jk = 2, jpkm1
307         DO jj = 1, jpj
308            DO ji = 1, jpi
309               ztp1(ji,jj,jk) =                    ( zt1(ji,jj,jk) + zt1(ji,jj,jk+1) )   &
310                  &           * ( 0.25 + SIGN( 0.25, zt1(ji,jj,jk) * zt1(ji,jj,jk+1) ) )
311               zsp1(ji,jj,jk) =                    ( zs1(ji,jj,jk) + zs1(ji,jj,jk+1) )   &
312                  &           * ( 0.25 + SIGN( 0.25, zs1(ji,jj,jk) * zs1(ji,jj,jk+1) ) )
313            END DO
314         END DO
315      END DO
316
317      ! Slopes limitation
318      ! interior values
319      DO jk = 2, jpkm1
320         DO jj = 1, jpj
321            DO ji = 1, jpi
322               ztp1(ji,jj,jk) = SIGN( 1., ztp1(ji,jj,jk) )   &
323                  &           * MIN(    ABS( ztp1(ji,jj,jk  ) ),   &
324                  &                  2.*ABS( zt1 (ji,jj,jk+1) ),   &
325                  &                  2.*ABS( zt1 (ji,jj,jk  ) ) )
326               zsp1(ji,jj,jk) = SIGN( 1., zsp1(ji,jj,jk) )   &
327                  &           * MIN(    ABS( zsp1(ji,jj,jk  ) ),   &
328                  &                  2.*ABS( zs1 (ji,jj,jk+1) ),   &
329                  &                  2.*ABS( zs1 (ji,jj,jk  ) ) )
330            END DO
331         END DO
332      END DO
333      ! surface values
334      ztp1(:,:,1) = 0.e0
335      zsp1(:,:,1) = 0.e0
336
337      ! vertical advective flux
338      ! interior values
339      DO jk = 1, jpkm1
340         zstep  = z2 * rdttra(jk)
341         DO jj = 2, jpjm1     
342            DO ji = fs_2, fs_jpim1   ! vector opt.
343               zew = pwn(ji,jj,jk+1)
344               z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
345               zalpha = 0.5 + z0w
346               zw  = z0w - 0.5 * pwn(ji,jj,jk+1)*zstep / fse3w(ji,jj,jk+1)
347               zzt1 = tb(ji,jj,jk+1) + zw*ztp1(ji,jj,jk+1)
348               zzt2 = tb(ji,jj,jk  ) + zw*ztp1(ji,jj,jk  )
349               zzs1 = sb(ji,jj,jk+1) + zw*zsp1(ji,jj,jk+1)
350               zzs2 = sb(ji,jj,jk  ) + zw*zsp1(ji,jj,jk  )
351               zt1(ji,jj,jk+1) = zew * ( zalpha * zzt1 + (1.-zalpha)*zzt2 )
352               zs1(ji,jj,jk+1) = zew * ( zalpha * zzs1 + (1.-zalpha)*zzs2 )
353            END DO
354         END DO
355      END DO
356      ! surface values
357      IF( lk_dynspg_rl .OR. lk_vvl) THEN                ! rigid lid or variable volume: flux set to zero
358         zt1(:,:, 1 ) = 0.e0
359         zs1(:,:, 1 ) = 0.e0
360      ELSE                                              ! free surface
361         zt1(:,:, 1 ) = pwn(:,:,1) * tb(:,:,1)
362         zs1(:,:, 1 ) = pwn(:,:,1) * sb(:,:,1)
363      ENDIF
364
365      ! bottom values
366      zt1(:,:,jpk) = 0.e0
367      zs1(:,:,jpk) = 0.e0
368
369
370      ! Compute & add the vertical advective trend
371
372      DO jk = 1, jpkm1
373         DO jj = 2, jpjm1     
374            DO ji = fs_2, fs_jpim1   ! vector opt.
375               zbtr = 1. / fse3t(ji,jj,jk)
376               ! horizontal advective trends
377               zta = - zbtr * ( zt1(ji,jj,jk) - zt1(ji,jj,jk+1) )
378               zsa = - zbtr * ( zs1(ji,jj,jk) - zs1(ji,jj,jk+1) )
379               ! add it to the general tracer trends
380               ta(ji,jj,jk) =  ta(ji,jj,jk) + zta
381               sa(ji,jj,jk) =  sa(ji,jj,jk) + zsa
382            END DO
383         END DO
384      END DO
385
386      ! Save the vertical advective trends for diagnostic
387      ! -------------------------------------------------
388      IF( l_trdtra )   THEN
389         ! Recompute the vertical advection zta & zsa trends computed
390         ! at the step 2. above in making the difference between the new
391         ! trends and the previous one: ta()/sa - ztrdt()/ztrds() and substract
392         ! the term tn()/sn()*hdivn() to recover the W gradz(T/S) trends
393
394         DO jk = 1, jpkm1
395            DO jj = 2, jpjm1
396               DO ji = fs_2, fs_jpim1   ! vector opt.
397#if defined key_zco
398                  zbtr      = 1. / ( e1t(ji,jj) * e2t(ji,jj) )
399                  z_hdivn_x = e2u(ji,jj)*pun(ji,jj,jk) - e2u(ji-1,jj)*pun(ji-1,jj,jk)
400                  z_hdivn_y = e1v(ji,jj)*pvn(ji,jj,jk) - e1v(ji,jj-1)*pvn(ji,jj-1,jk)
401#else
402                  zbtr      = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
403                  z_hdivn_x = e2u(ji,jj)*fse3u(ji,jj,jk)*pun(ji,jj,jk) - e2u(ji-1,jj)*fse3u(ji-1,jj,jk)*pun(ji-1,jj,jk)
404                  z_hdivn_y = e1v(ji,jj)*fse3v(ji,jj,jk)*pvn(ji,jj,jk) - e1v(ji,jj-1)*fse3v(ji,jj-1,jk)*pvn(ji,jj-1,jk)
405#endif
406                  z_hdivn   = (z_hdivn_x + z_hdivn_y) * zbtr
407                  ztrdt(ji,jj,jk) = ta(ji,jj,jk) - ztrdt(ji,jj,jk) - tn(ji,jj,jk) * z_hdivn 
408                  ztrds(ji,jj,jk) = sa(ji,jj,jk) - ztrds(ji,jj,jk) - sn(ji,jj,jk) * z_hdivn
409               END DO
410            END DO
411         END DO
412         CALL trd_mod(ztrdt, ztrds, jptra_trd_zad, 'TRA', kt)
413         !
414      ENDIF
415
416      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ta, clinfo1=' muscl zad  - Ta: ', mask1=tmask ,   &
417         &                       tab3d_2=sa, clinfo2=             ' Sa: ', mask2=tmask, clinfo3='tra' )
418      !
419   END SUBROUTINE tra_adv_muscl
420
421   !!======================================================================
422END MODULE traadv_muscl
Note: See TracBrowser for help on using the repository browser.