New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in trunk/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMO/OPA_SRC/TRA/traldf_iso.F90 @ 719

Last change on this file since 719 was 719, checked in by ctlod, 16 years ago

get back to the nemo_v2_3 version for trunk

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 14.4 KB
Line 
1MODULE traldf_iso
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso  ***
4   !! Ocean active tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :        !  94-08  (G. Madec, M. Imbard)
7   !!                  !  97-05  (G. Madec)  split into traldf and trazdf
8   !!             8.5  !  02-08  (G. Madec)  Free form, F90
9   !!             9.0  !  05-11  (G. Madec)  merge traldf and trazdf :-)
10   !!----------------------------------------------------------------------
11#if   defined key_ldfslp   ||   defined key_esopa
12   !!----------------------------------------------------------------------
13   !!   'key_ldfslp'               slope of the lateral diffusive direction
14   !!----------------------------------------------------------------------
15   !!----------------------------------------------------------------------
16   !!   tra_ldf_iso  : update the tracer trend with the horizontal
17   !!                  component of a iso-neutral laplacian operator
18   !!                  and with the vertical part of
19   !!                  the isopycnal or geopotential s-coord. operator
20   !!                  vector optimization, use k-j-i loops.
21   !!----------------------------------------------------------------------
22   USE oce             ! ocean dynamics and active tracers
23   USE dom_oce         ! ocean space and time domain
24   USE ldftra_oce      ! ocean active tracers: lateral physics
25   USE trdmod          ! ocean active tracers trends
26   USE trdmod_oce      ! ocean variables trends
27   USE zdf_oce         ! ocean vertical physics
28   USE in_out_manager  ! I/O manager
29   USE ldfslp          ! iso-neutral slopes
30   USE diaptr          ! poleward transport diagnostics
31   USE prtctl          ! Print control
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   tra_ldf_iso   ! routine called by step.F90
37
38   !! * Substitutions
39#  include "domzgr_substitute.h90"
40#  include "ldftra_substitute.h90"
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !!   OPA 9.0 , LOCEAN-IPSL (2005)
44   !! $Header$
45   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47
48CONTAINS
49
50   SUBROUTINE tra_ldf_iso( kt )
51      !!----------------------------------------------------------------------
52      !!                  ***  ROUTINE tra_ldf_iso  ***
53      !!
54      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
55      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
56      !!      add it to the general trend of tracer equation.
57      !!
58      !! ** Method  :   The horizontal component of the lateral diffusive trends
59      !!      is provided by a 2nd order operator rotated along neural or geopo-
60      !!      tential surfaces to which an eddy induced advection can be added
61      !!      It is computed using before fields (forward in time) and isopyc-
62      !!      nal or geopotential slopes computed in routine ldfslp.
63      !!
64      !!      1st part :  masked horizontal derivative of T & S ( di[ t ] )
65      !!      ========    with partial cell update if ln_zps=T.
66      !!
67      !!      2nd part :  horizontal fluxes of the lateral mixing operator
68      !!      ========   
69      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
70      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
71      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
72      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
73      !!      take the horizontal divergence of the fluxes:
74      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
75      !!      Add this trend to the general trend (ta,sa):
76      !!         ta = ta + difft
77      !!
78      !!      3rd part: vertical trends of the lateral mixing operator
79      !!      ========  (excluding the vertical flux proportional to dk[t] )
80      !!      vertical fluxes associated with the rotated lateral mixing:
81      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
82      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
83      !!      take the horizontal divergence of the fluxes:
84      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
85      !!      Add this trend to the general trend (ta,sa):
86      !!         ta = ta + difft
87      !!
88      !! ** Action :   Update (ta,sa) arrays with the before rotated diffusion
89      !!            trend (except the dk[ dk[.] ] term)
90      !!----------------------------------------------------------------------
91      USE oce           , zftv => ua   ! use ua as workspace
92      USE oce           , zfsv => va   ! use va as workspace
93      !!
94      INTEGER, INTENT( in ) ::   kt    ! ocean time-step index
95      !!
96      INTEGER  ::   ji, jj, jk   ! dummy loop indices
97      INTEGER  ::   iku, ikv     ! temporary integer
98      REAL(wp) ::   zmsku, zabe1, zcof1, zcoef3, zta   ! temporary scalars
99      REAL(wp) ::   zmskv, zabe2, zcof2, zcoef4, zsa   !    "         "
100      REAL(wp) ::   zcoef0, zbtr                       !    "         "
101      REAL(wp), DIMENSION(jpi,jpj)     ::   zdkt , zdk1t, zftu   ! 2D workspace
102      REAL(wp), DIMENSION(jpi,jpj)     ::   zdks , zdk1s, zfsu   !    "           "
103      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdit, zdjt, ztfw     ! 3D workspace
104      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdis, zdjs, zsfw     !  "      "
105      !!----------------------------------------------------------------------
106
107      IF( kt == nit000 ) THEN
108         IF(lwp) WRITE(numout,*)
109         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator'
110         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
111      ENDIF
112
113      !!----------------------------------------------------------------------
114      !!   I - masked horizontal derivative of T & S
115      !!----------------------------------------------------------------------
116!!bug ajout.... why?   ( 1,jpj,:) and (jpi,1,:) should be sufficient....
117      zdit (1,:,:) = 0.e0     ;     zdit (jpi,:,:) = 0.e0
118      zdis (1,:,:) = 0.e0     ;     zdis (jpi,:,:) = 0.e0
119      zdjt (1,:,:) = 0.e0     ;     zdjt (jpi,:,:) = 0.e0
120      zdjs (1,:,:) = 0.e0     ;     zdjs (jpi,:,:) = 0.e0
121!!end
122
123      ! Horizontal temperature and salinity gradient
124      DO jk = 1, jpkm1
125         DO jj = 1, jpjm1
126            DO ji = 1, fs_jpim1   ! vector opt.
127               zdit(ji,jj,jk) = ( tb(ji+1,jj  ,jk) - tb(ji,jj,jk) ) * umask(ji,jj,jk)
128               zdis(ji,jj,jk) = ( sb(ji+1,jj  ,jk) - sb(ji,jj,jk) ) * umask(ji,jj,jk)
129               zdjt(ji,jj,jk) = ( tb(ji  ,jj+1,jk) - tb(ji,jj,jk) ) * vmask(ji,jj,jk)
130               zdjs(ji,jj,jk) = ( sb(ji  ,jj+1,jk) - sb(ji,jj,jk) ) * vmask(ji,jj,jk)
131            END DO
132         END DO
133      END DO
134      IF( ln_zps ) THEN      ! partial steps correction at the last level
135         DO jj = 1, jpjm1
136            DO ji = 1, fs_jpim1   ! vector opt.
137               ! last level
138               iku = MIN( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1
139               ikv = MIN( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1
140               zdit(ji,jj,iku) = gtu(ji,jj) 
141               zdis(ji,jj,iku) = gsu(ji,jj)               
142               zdjt(ji,jj,ikv) = gtv(ji,jj) 
143               zdjs(ji,jj,ikv) = gsv(ji,jj)               
144            END DO
145         END DO
146      ENDIF
147
148      !!----------------------------------------------------------------------
149      !!   II - horizontal trend of T & S (full)
150      !!----------------------------------------------------------------------
151     
152!CDIR PARALLEL DO PRIVATE( zdk1t, zdk1s, zftu, zfsu )
153!$OMP PARALLEL DO PRIVATE( zdk1t, zdk1s, zftu, zfsu )
154      !                                                ! ===============
155      DO jk = 1, jpkm1                                 ! Horizontal slab
156         !                                             ! ===============
157         ! 1. Vertical tracer gradient at level jk and jk+1
158         ! ------------------------------------------------
159         ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
160
161         zdk1t(:,:) = ( tb(:,:,jk) - tb(:,:,jk+1) ) * tmask(:,:,jk+1)
162         zdk1s(:,:) = ( sb(:,:,jk) - sb(:,:,jk+1) ) * tmask(:,:,jk+1)
163
164         IF( jk == 1 ) THEN
165            zdkt(:,:) = zdk1t(:,:)
166            zdks(:,:) = zdk1s(:,:)
167         ELSE
168            zdkt(:,:) = ( tb(:,:,jk-1) - tb(:,:,jk) ) * tmask(:,:,jk)
169            zdks(:,:) = ( sb(:,:,jk-1) - sb(:,:,jk) ) * tmask(:,:,jk)
170         ENDIF
171
172
173         ! 2. Horizontal fluxes
174         ! --------------------
175
176         DO jj = 1 , jpjm1
177            DO ji = 1, fs_jpim1   ! vector opt.
178               zabe1 = ( fsahtu(ji,jj,jk) + ahtb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
179               zabe2 = ( fsahtv(ji,jj,jk) + ahtb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
180
181               zmsku = 1. / MAX(  tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
182                  &             + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
183
184               zmskv = 1. / MAX(  tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
185                  &             + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
186
187               zcof1 = -fsahtu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
188               zcof2 = -fsahtv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
189
190               zftu(ji,jj   ) = (  zabe1 * zdit(ji,jj,jk)   &
191                  &              + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
192                  &                         + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  ) * umask(ji,jj,jk)
193               zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
194                  &              + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
195                  &                         + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  ) * vmask(ji,jj,jk)
196               zfsu(ji,jj   ) = (  zabe1 * zdis(ji,jj,jk)   &
197                  &              + zcof1 * (  zdks (ji+1,jj) + zdk1s(ji,jj)      &
198                  &                         + zdk1s(ji+1,jj) + zdks (ji,jj)  )  ) * umask(ji,jj,jk)
199               zfsv(ji,jj,jk) = (  zabe2 * zdjs(ji,jj,jk)   &
200                  &              + zcof2 * (  zdks (ji,jj+1) + zdk1s(ji,jj)      &
201                  &                         + zdk1s(ji,jj+1) + zdks (ji,jj)  )  ) * vmask(ji,jj,jk)
202            END DO
203         END DO
204
205
206         ! II.4 Second derivative (divergence) and add to the general trend
207         ! ----------------------------------------------------------------
208         DO jj = 2 , jpjm1
209            DO ji = fs_2, fs_jpim1   ! vector opt.
210               zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
211               zta = zbtr * ( zftu(ji,jj   ) - zftu(ji-1,jj   ) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
212               zsa = zbtr * ( zfsu(ji,jj   ) - zfsu(ji-1,jj   ) + zfsv(ji,jj,jk) - zfsv(ji,jj-1,jk)  )
213               ta (ji,jj,jk) = ta (ji,jj,jk) + zta
214               sa (ji,jj,jk) = sa (ji,jj,jk) + zsa
215            END DO
216         END DO
217         !                                          ! ===============
218      END DO                                        !   End of slab 
219      !                                             ! ===============
220
221      IF( ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN   ! Poleward diffusive heat and salt transports
222         pht_ldf(:) = ptr_vj( zftv(:,:,:) )
223         pst_ldf(:) = ptr_vj( zfsv(:,:,:) )
224      ENDIF
225
226      !!----------------------------------------------------------------------
227      !!   III - vertical trend of T & S (extra diagonal terms only)
228      !!----------------------------------------------------------------------
229
230      ! Local constant initialization
231      ! -----------------------------
232      ztfw(1,:,:) = 0.e0     ;     ztfw(jpi,:,:) = 0.e0
233      zsfw(1,:,:) = 0.e0     ;     zsfw(jpi,:,:) = 0.e0
234
235
236      ! Vertical fluxes
237      ! ---------------
238
239      ! Surface and bottom vertical fluxes set to zero
240      ztfw(:,:, 1 ) = 0.e0      ;      ztfw(:,:,jpk) = 0.e0
241      zsfw(:,:, 1 ) = 0.e0      ;      zsfw(:,:,jpk) = 0.e0
242
243      ! interior (2=<jk=<jpk-1)
244      DO jk = 2, jpkm1
245         DO jj = 2, jpjm1
246            DO ji = fs_2, fs_jpim1   ! vector opt.
247               zcoef0 = - fsahtw(ji,jj,jk) * tmask(ji,jj,jk)
248
249               zmsku = 1./MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)      &
250                  &            + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk), 1.  )
251
252               zmskv = 1./MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)      &
253                  &            + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk), 1.  )
254
255               zcoef3 = zcoef0 * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk)
256               zcoef4 = zcoef0 * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk)
257
258               ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
259                  &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
260                  &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
261                  &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
262
263               zsfw(ji,jj,jk) = zcoef3 * (   zdis(ji  ,jj  ,jk-1) + zdis(ji-1,jj  ,jk)      &
264                  &                        + zdis(ji-1,jj  ,jk-1) + zdis(ji  ,jj  ,jk)  )   &
265                  &           + zcoef4 * (   zdjs(ji  ,jj  ,jk-1) + zdjs(ji  ,jj-1,jk)      &
266                  &                        + zdjs(ji  ,jj-1,jk-1) + zdjs(ji  ,jj  ,jk)  )
267            END DO
268         END DO
269      END DO
270
271
272      ! I.5 Divergence of vertical fluxes added to the general tracer trend
273      ! -------------------------------------------------------------------
274
275      DO jk = 1, jpkm1
276         DO jj = 2, jpjm1
277            DO ji = fs_2, fs_jpim1   ! vector opt.
278               zbtr =  1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
279               zta  = (  ztfw(ji,jj,jk) - ztfw(ji,jj,jk+1)  ) * zbtr
280               zsa  = (  zsfw(ji,jj,jk) - zsfw(ji,jj,jk+1)  ) * zbtr
281               ta(ji,jj,jk) = ta(ji,jj,jk) + zta
282               sa(ji,jj,jk) = sa(ji,jj,jk) + zsa
283            END DO
284         END DO
285      END DO
286      !
287   END SUBROUTINE tra_ldf_iso
288
289#else
290   !!----------------------------------------------------------------------
291   !!   default option :   Dummy code   NO rotation of the diffusive tensor
292   !!----------------------------------------------------------------------
293CONTAINS
294   SUBROUTINE tra_ldf_iso( kt )               ! Empty routine
295      WRITE(*,*) 'tra_ldf_iso: You should not have seen this print! error?', kt
296   END SUBROUTINE tra_ldf_iso
297#endif
298
299   !!==============================================================================
300END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.