New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in trunk/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMO/OPA_SRC/TRA/traldf_iso.F90 @ 789

Last change on this file since 789 was 789, checked in by rblod, 16 years ago

Suppress jki routines and associated key_mpp_omp
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 14.3 KB
Line 
1MODULE traldf_iso
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso  ***
4   !! Ocean active tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :        !  94-08  (G. Madec, M. Imbard)
7   !!                  !  97-05  (G. Madec)  split into traldf and trazdf
8   !!             8.5  !  02-08  (G. Madec)  Free form, F90
9   !!             9.0  !  05-11  (G. Madec)  merge traldf and trazdf :-)
10   !!----------------------------------------------------------------------
11#if   defined key_ldfslp   ||   defined key_esopa
12   !!----------------------------------------------------------------------
13   !!   'key_ldfslp'               slope of the lateral diffusive direction
14   !!----------------------------------------------------------------------
15   !!----------------------------------------------------------------------
16   !!   tra_ldf_iso  : update the tracer trend with the horizontal
17   !!                  component of a iso-neutral laplacian operator
18   !!                  and with the vertical part of
19   !!                  the isopycnal or geopotential s-coord. operator
20   !!----------------------------------------------------------------------
21   USE oce             ! ocean dynamics and active tracers
22   USE dom_oce         ! ocean space and time domain
23   USE ldftra_oce      ! ocean active tracers: lateral physics
24   USE trdmod          ! ocean active tracers trends
25   USE trdmod_oce      ! ocean variables trends
26   USE zdf_oce         ! ocean vertical physics
27   USE in_out_manager  ! I/O manager
28   USE ldfslp          ! iso-neutral slopes
29   USE diaptr          ! poleward transport diagnostics
30   USE prtctl          ! Print control
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   tra_ldf_iso   ! routine called by step.F90
36
37   !! * Substitutions
38#  include "domzgr_substitute.h90"
39#  include "ldftra_substitute.h90"
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !!   OPA 9.0 , LOCEAN-IPSL (2005)
43   !! $Header$
44   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46
47CONTAINS
48
49   SUBROUTINE tra_ldf_iso( kt )
50      !!----------------------------------------------------------------------
51      !!                  ***  ROUTINE tra_ldf_iso  ***
52      !!
53      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
54      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
55      !!      add it to the general trend of tracer equation.
56      !!
57      !! ** Method  :   The horizontal component of the lateral diffusive trends
58      !!      is provided by a 2nd order operator rotated along neural or geopo-
59      !!      tential surfaces to which an eddy induced advection can be added
60      !!      It is computed using before fields (forward in time) and isopyc-
61      !!      nal or geopotential slopes computed in routine ldfslp.
62      !!
63      !!      1st part :  masked horizontal derivative of T & S ( di[ t ] )
64      !!      ========    with partial cell update if ln_zps=T.
65      !!
66      !!      2nd part :  horizontal fluxes of the lateral mixing operator
67      !!      ========   
68      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
69      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
70      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
71      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
72      !!      take the horizontal divergence of the fluxes:
73      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
74      !!      Add this trend to the general trend (ta,sa):
75      !!         ta = ta + difft
76      !!
77      !!      3rd part: vertical trends of the lateral mixing operator
78      !!      ========  (excluding the vertical flux proportional to dk[t] )
79      !!      vertical fluxes associated with the rotated lateral mixing:
80      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
81      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
82      !!      take the horizontal divergence of the fluxes:
83      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
84      !!      Add this trend to the general trend (ta,sa):
85      !!         ta = ta + difft
86      !!
87      !! ** Action :   Update (ta,sa) arrays with the before rotated diffusion
88      !!            trend (except the dk[ dk[.] ] term)
89      !!----------------------------------------------------------------------
90      USE oce           , zftv => ua   ! use ua as workspace
91      USE oce           , zfsv => va   ! use va as workspace
92      !!
93      INTEGER, INTENT( in ) ::   kt    ! ocean time-step index
94      !!
95      INTEGER  ::   ji, jj, jk   ! dummy loop indices
96      INTEGER  ::   iku, ikv     ! temporary integer
97      REAL(wp) ::   zmsku, zabe1, zcof1, zcoef3, zta   ! temporary scalars
98      REAL(wp) ::   zmskv, zabe2, zcof2, zcoef4, zsa   !    "         "
99      REAL(wp) ::   zcoef0, zbtr                       !    "         "
100      REAL(wp), DIMENSION(jpi,jpj)     ::   zdkt , zdk1t, zftu   ! 2D workspace
101      REAL(wp), DIMENSION(jpi,jpj)     ::   zdks , zdk1s, zfsu   !    "           "
102      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdit, zdjt, ztfw     ! 3D workspace
103      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdis, zdjs, zsfw     !  "      "
104      !!----------------------------------------------------------------------
105
106      IF( kt == nit000 ) THEN
107         IF(lwp) WRITE(numout,*)
108         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator'
109         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
110      ENDIF
111
112      !!----------------------------------------------------------------------
113      !!   I - masked horizontal derivative of T & S
114      !!----------------------------------------------------------------------
115!!bug ajout.... why?   ( 1,jpj,:) and (jpi,1,:) should be sufficient....
116      zdit (1,:,:) = 0.e0     ;     zdit (jpi,:,:) = 0.e0
117      zdis (1,:,:) = 0.e0     ;     zdis (jpi,:,:) = 0.e0
118      zdjt (1,:,:) = 0.e0     ;     zdjt (jpi,:,:) = 0.e0
119      zdjs (1,:,:) = 0.e0     ;     zdjs (jpi,:,:) = 0.e0
120!!end
121
122      ! Horizontal temperature and salinity gradient
123      DO jk = 1, jpkm1
124         DO jj = 1, jpjm1
125            DO ji = 1, fs_jpim1   ! vector opt.
126               zdit(ji,jj,jk) = ( tb(ji+1,jj  ,jk) - tb(ji,jj,jk) ) * umask(ji,jj,jk)
127               zdis(ji,jj,jk) = ( sb(ji+1,jj  ,jk) - sb(ji,jj,jk) ) * umask(ji,jj,jk)
128               zdjt(ji,jj,jk) = ( tb(ji  ,jj+1,jk) - tb(ji,jj,jk) ) * vmask(ji,jj,jk)
129               zdjs(ji,jj,jk) = ( sb(ji  ,jj+1,jk) - sb(ji,jj,jk) ) * vmask(ji,jj,jk)
130            END DO
131         END DO
132      END DO
133      IF( ln_zps ) THEN      ! partial steps correction at the last level
134         DO jj = 1, jpjm1
135            DO ji = 1, fs_jpim1   ! vector opt.
136               ! last level
137               iku = MIN( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1
138               ikv = MIN( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1
139               zdit(ji,jj,iku) = gtu(ji,jj) 
140               zdis(ji,jj,iku) = gsu(ji,jj)               
141               zdjt(ji,jj,ikv) = gtv(ji,jj) 
142               zdjs(ji,jj,ikv) = gsv(ji,jj)               
143            END DO
144         END DO
145      ENDIF
146
147      !!----------------------------------------------------------------------
148      !!   II - horizontal trend of T & S (full)
149      !!----------------------------------------------------------------------
150     
151!CDIR PARALLEL DO PRIVATE( zdk1t, zdk1s, zftu, zfsu )
152      !                                                ! ===============
153      DO jk = 1, jpkm1                                 ! Horizontal slab
154         !                                             ! ===============
155         ! 1. Vertical tracer gradient at level jk and jk+1
156         ! ------------------------------------------------
157         ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
158
159         zdk1t(:,:) = ( tb(:,:,jk) - tb(:,:,jk+1) ) * tmask(:,:,jk+1)
160         zdk1s(:,:) = ( sb(:,:,jk) - sb(:,:,jk+1) ) * tmask(:,:,jk+1)
161
162         IF( jk == 1 ) THEN
163            zdkt(:,:) = zdk1t(:,:)
164            zdks(:,:) = zdk1s(:,:)
165         ELSE
166            zdkt(:,:) = ( tb(:,:,jk-1) - tb(:,:,jk) ) * tmask(:,:,jk)
167            zdks(:,:) = ( sb(:,:,jk-1) - sb(:,:,jk) ) * tmask(:,:,jk)
168         ENDIF
169
170
171         ! 2. Horizontal fluxes
172         ! --------------------
173
174         DO jj = 1 , jpjm1
175            DO ji = 1, fs_jpim1   ! vector opt.
176               zabe1 = ( fsahtu(ji,jj,jk) + ahtb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
177               zabe2 = ( fsahtv(ji,jj,jk) + ahtb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
178
179               zmsku = 1. / MAX(  tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
180                  &             + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
181
182               zmskv = 1. / MAX(  tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
183                  &             + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
184
185               zcof1 = -fsahtu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
186               zcof2 = -fsahtv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
187
188               zftu(ji,jj   ) = (  zabe1 * zdit(ji,jj,jk)   &
189                  &              + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
190                  &                         + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  ) * umask(ji,jj,jk)
191               zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
192                  &              + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
193                  &                         + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  ) * vmask(ji,jj,jk)
194               zfsu(ji,jj   ) = (  zabe1 * zdis(ji,jj,jk)   &
195                  &              + zcof1 * (  zdks (ji+1,jj) + zdk1s(ji,jj)      &
196                  &                         + zdk1s(ji+1,jj) + zdks (ji,jj)  )  ) * umask(ji,jj,jk)
197               zfsv(ji,jj,jk) = (  zabe2 * zdjs(ji,jj,jk)   &
198                  &              + zcof2 * (  zdks (ji,jj+1) + zdk1s(ji,jj)      &
199                  &                         + zdk1s(ji,jj+1) + zdks (ji,jj)  )  ) * vmask(ji,jj,jk)
200            END DO
201         END DO
202
203
204         ! II.4 Second derivative (divergence) and add to the general trend
205         ! ----------------------------------------------------------------
206         DO jj = 2 , jpjm1
207            DO ji = fs_2, fs_jpim1   ! vector opt.
208               zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
209               zta = zbtr * ( zftu(ji,jj   ) - zftu(ji-1,jj   ) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
210               zsa = zbtr * ( zfsu(ji,jj   ) - zfsu(ji-1,jj   ) + zfsv(ji,jj,jk) - zfsv(ji,jj-1,jk)  )
211               ta (ji,jj,jk) = ta (ji,jj,jk) + zta
212               sa (ji,jj,jk) = sa (ji,jj,jk) + zsa
213            END DO
214         END DO
215         !                                          ! ===============
216      END DO                                        !   End of slab 
217      !                                             ! ===============
218
219      IF( ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN   ! Poleward diffusive heat and salt transports
220         pht_ldf(:) = ptr_vj( zftv(:,:,:) )
221         pst_ldf(:) = ptr_vj( zfsv(:,:,:) )
222      ENDIF
223
224      !!----------------------------------------------------------------------
225      !!   III - vertical trend of T & S (extra diagonal terms only)
226      !!----------------------------------------------------------------------
227
228      ! Local constant initialization
229      ! -----------------------------
230      ztfw(1,:,:) = 0.e0     ;     ztfw(jpi,:,:) = 0.e0
231      zsfw(1,:,:) = 0.e0     ;     zsfw(jpi,:,:) = 0.e0
232
233
234      ! Vertical fluxes
235      ! ---------------
236
237      ! Surface and bottom vertical fluxes set to zero
238      ztfw(:,:, 1 ) = 0.e0      ;      ztfw(:,:,jpk) = 0.e0
239      zsfw(:,:, 1 ) = 0.e0      ;      zsfw(:,:,jpk) = 0.e0
240
241      ! interior (2=<jk=<jpk-1)
242      DO jk = 2, jpkm1
243         DO jj = 2, jpjm1
244            DO ji = fs_2, fs_jpim1   ! vector opt.
245               zcoef0 = - fsahtw(ji,jj,jk) * tmask(ji,jj,jk)
246
247               zmsku = 1./MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)      &
248                  &            + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk), 1.  )
249
250               zmskv = 1./MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)      &
251                  &            + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk), 1.  )
252
253               zcoef3 = zcoef0 * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk)
254               zcoef4 = zcoef0 * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk)
255
256               ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
257                  &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
258                  &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
259                  &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
260
261               zsfw(ji,jj,jk) = zcoef3 * (   zdis(ji  ,jj  ,jk-1) + zdis(ji-1,jj  ,jk)      &
262                  &                        + zdis(ji-1,jj  ,jk-1) + zdis(ji  ,jj  ,jk)  )   &
263                  &           + zcoef4 * (   zdjs(ji  ,jj  ,jk-1) + zdjs(ji  ,jj-1,jk)      &
264                  &                        + zdjs(ji  ,jj-1,jk-1) + zdjs(ji  ,jj  ,jk)  )
265            END DO
266         END DO
267      END DO
268
269
270      ! I.5 Divergence of vertical fluxes added to the general tracer trend
271      ! -------------------------------------------------------------------
272
273      DO jk = 1, jpkm1
274         DO jj = 2, jpjm1
275            DO ji = fs_2, fs_jpim1   ! vector opt.
276               zbtr =  1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
277               zta  = (  ztfw(ji,jj,jk) - ztfw(ji,jj,jk+1)  ) * zbtr
278               zsa  = (  zsfw(ji,jj,jk) - zsfw(ji,jj,jk+1)  ) * zbtr
279               ta(ji,jj,jk) = ta(ji,jj,jk) + zta
280               sa(ji,jj,jk) = sa(ji,jj,jk) + zsa
281            END DO
282         END DO
283      END DO
284      !
285   END SUBROUTINE tra_ldf_iso
286
287#else
288   !!----------------------------------------------------------------------
289   !!   default option :   Dummy code   NO rotation of the diffusive tensor
290   !!----------------------------------------------------------------------
291CONTAINS
292   SUBROUTINE tra_ldf_iso( kt )               ! Empty routine
293      WRITE(*,*) 'tra_ldf_iso: You should not have seen this print! error?', kt
294   END SUBROUTINE tra_ldf_iso
295#endif
296
297   !!==============================================================================
298END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.