New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
daymod.F90 in trunk/NEMO/OPA_SRC – NEMO

source: trunk/NEMO/OPA_SRC/daymod.F90 @ 1191

Last change on this file since 1191 was 1191, checked in by smasson, 16 years ago

improve control print for debugging ticket #252

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 16.5 KB
Line 
1MODULE daymod
2   !!======================================================================
3   !!                       ***  MODULE  daymod  ***
4   !! Ocean        :  calendar
5   !!=====================================================================
6   !! History :        !  94-09  (M. Pontaud M. Imbard)  Original code
7   !!                  !  97-03  (O. Marti)
8   !!                  !  97-05  (G. Madec)
9   !!                  !  97-08  (M. Imbard)
10   !!             9.0  !  03-09  (G. Madec)  F90 + nyear, nmonth, nday
11   !!                  !  04-01  (A.M. Treguier) new calculation based on adatrj
12   !!                  !  06-08  (G. Madec)  surface module major update
13   !!----------------------------------------------------------------------     
14
15   !!----------------------------------------------------------------------
16   !!   day        : calendar
17   !! 
18   !!           -------------------------------
19   !!           ----------- WARNING -----------
20   !!
21   !!   we suppose that the time step is deviding the number of second of in a day
22   !!             ---> MOD( rday, rdttra(1) ) == 0
23   !!
24   !!           ----------- WARNING -----------
25   !!           -------------------------------
26   !! 
27   !!----------------------------------------------------------------------
28   USE dom_oce         ! ocean space and time domain
29   USE phycst          ! physical constants
30   USE in_out_manager  ! I/O manager
31   USE iom             !
32   USE prtctl          ! Print control
33   USE restart         !
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC day        ! called by step.F90
39   PUBLIC day_init   ! called by istate.F90
40
41   INTEGER , PUBLIC ::   nyear       !: current year
42   INTEGER , PUBLIC ::   nmonth      !: current month
43   INTEGER , PUBLIC ::   nday        !: current day of the month
44   INTEGER , PUBLIC ::   ndastp      !: time step date in yyyymmdd format
45   INTEGER , PUBLIC ::   nday_year   !: current day counted from jan 1st of the current year
46   REAL(wp), PUBLIC ::   rsec_year   !: current time step counted in second since 00h jan 1st of the current year
47   REAL(wp), PUBLIC ::   rsec_month  !: current time step counted in second since 00h 1st day of the current month
48   REAL(wp), PUBLIC ::   rsec_day    !: current time step counted in second since 00h of the current day
49
50   REAL(wp), PUBLIC ::   adatrj      !: number of elapsed days since the begining of the run
51   !                                 !: it is the accumulated duration of previous runs
52   !                                 !: that may have been run with different time steps.
53   INTEGER , PUBLIC, DIMENSION(0:1)  ::   nyear_len    !: length in days of the previous/current year
54   INTEGER , PUBLIC, DIMENSION(0:13) ::   nmonth_len   !: length in days of the months of the current year
55   REAL(wp), PUBLIC, DIMENSION(0:13) ::   rmonth_half  !: second since the beginning of the year and the halft of the months
56   REAL(wp), PUBLIC, DIMENSION(0:13) ::   rmonth_end   !: second since the beginning of the year and the end of the months
57   REAL(wp), PUBLIC                  ::   sec1jan000   !: second since Jan. 1st 00h of nit000 year
58
59   ! this two variables are wrong DO NOT USE THEM !!!
60   INTEGER, PUBLIC, DIMENSION(12) ::   nbiss = (/ 31, 29, 31, 30, 31, 30,    &  !: number of days per month
61      &                                           31, 31, 30, 31, 30, 31 /)     !: (leap-year)
62   INTEGER, PUBLIC, DIMENSION(12) ::   nobis = (/ 31, 28, 31, 30, 31, 30,    &  !: number of days per month
63      &                                           31, 31, 30, 31, 30, 31 /)     !: (365 days a year)
64
65
66   !!----------------------------------------------------------------------
67   !!  OPA 9.0 , LOCEAN-IPSL (2006)
68   !! $Id$
69   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
70   !!----------------------------------------------------------------------
71
72CONTAINS
73
74   SUBROUTINE day_init
75      !!----------------------------------------------------------------------
76      !!                   ***  ROUTINE day_init  ***
77      !!
78      !! ** Purpose :   Initialization of the calendar values to their values 1 time step before nit000
79      !!                because day will be called at the beginning of step
80      !!
81      !! ** Action  : - nyear        : current year
82      !!              - nmonth       : current month of the year nyear
83      !!              - nday         : current day of the month nmonth
84      !!              - nday_year    : current day of the year nyear
85      !!              - rsec_year    : current time step counted in second since 00h jan 1st of the current year
86      !!              - rsec_month   : current time step counted in second since 00h 1st day of the current month
87      !!              - rsec_day     : current time step counted in second since 00h of the current day
88      !!              - sec1jan000   : second since Jan. 1st 00h of nit000 year
89      !!              - nmonth_len, nyear_len, rmonth_half, rmonth_end through day_mth
90      !!----------------------------------------------------------------------
91
92      ! all calendar staff is based on the fact that MOD( rday, rdttra(1) ) == 0
93      IF( MOD( rday, rdttra(1) ) /= 0 )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
94
95      CALL day_rst( nit000, 'READ' ) 
96
97      ! set the calandar from ndastp (read in restart file and namelist)
98
99      nyear   =   ndastp / 10000
100      nmonth  = ( ndastp - (nyear * 10000) ) / 100
101      nday    =   ndastp - (nyear * 10000) - ( nmonth * 100 ) 
102
103      sec1jan000 = 0.e0
104      CALL day_mth
105     
106      IF ( nday == 0 ) THEN     !   for ex if ndastp = ndate0 - 1
107         nmonth = nmonth - 1 
108         nday = nmonth_len(nmonth)
109      ENDIF
110      IF ( nmonth == 0 ) THEN   ! go at the end of previous year
111         nmonth = 12
112         nyear = nyear - 1
113         sec1jan000 = sec1jan000 - rday * REAL( nyear_len(0), wp )
114         IF( nleapy == 1 )   CALL day_mth
115      ENDIF
116     
117      ! day since january 1st
118      nday_year = nday + SUM( nmonth_len(1:nmonth - 1) )
119     
120      ! number of seconds since the beginning of current year/month at the middle of the time-step
121      rsec_year  = REAL( nday_year, wp ) * rday - 0.5 * rdttra(1)   ! 1 time step before the middle of the first time step
122      rsec_month = REAL( nday     , wp ) * rday - 0.5 * rdttra(1)   ! because day will be called at the beginning of step
123      rsec_day   =                         rday - 0.5 * rdttra(1)
124
125      ! control print
126      IF(lwp) WRITE(numout,*)' ==============>> 1/2 time step before the start of the run DATE Y/M/D = ',   &
127           &                   nyear, '/', nmonth, '/', nday, '  rsec_day:', rsec_day
128     
129   END SUBROUTINE day_init
130
131
132   SUBROUTINE day_mth
133      !!----------------------------------------------------------------------
134      !!                   ***  ROUTINE day_init  ***
135      !!
136      !! ** Purpose :   calendar values related to the months
137      !!
138      !! ** Action  : - nmonth_len    : length in days of the months of the current year
139      !!              - nyear_len     : length in days of the previous/current year
140      !!              - rmonth_half   : second since the beginning of the year and the halft of the months
141      !!              - rmonth_end    : second since the beginning of the year and the end of the months
142      !!----------------------------------------------------------------------
143      INTEGER  ::   jm               ! dummy loop indice
144      !!----------------------------------------------------------------------
145
146      ! length of the month of the current year (from nleapy, read in namelist)
147      IF ( nleapy < 2 ) THEN
148         nmonth_len(:) = (/ 31, 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31, 31 /)
149         nyear_len(:) = 365
150         IF ( nleapy == 1 ) THEN   ! we are using calandar with leap years
151            IF ( MOD(nyear-1, 4) == 0 .AND. ( MOD(nyear-1, 400) == 0 .OR. MOD(nyear-1, 100) /= 0 ) ) THEN
152               nyear_len(0) = 366
153            ENDIF
154            IF ( MOD(nyear, 4) == 0 .AND. ( MOD(nyear, 400) == 0 .OR. MOD(nyear, 100) /= 0 ) ) THEN
155               nmonth_len(2) = 29
156               nyear_len(1) = 366
157            ENDIF
158         ENDIF
159      ELSE
160         nmonth_len(:) = nleapy   ! all months with nleapy days per year
161         nyear_len(:) = 12 * nleapy
162      ENDIF
163
164      ! half month in second since the begining of the year:
165      ! time since Jan 1st   0     1     2    ...    11    12    13
166      !          ---------*--|--*--|--*--| ... |--*--|--*--|--*--|--------------------------------------
167      !                 <---> <---> <--->  ...  <---> <---> <--->       
168      ! month number      0     1     2    ...    11    12    13
169      !
170      ! rmonth_half(jm) = rday * REAL( 0.5 * nmonth_len(jm) + SUM(nmonth_len(1:jm-1)) )
171      rmonth_half(0) = - 0.5 * rday * REAL( nmonth_len(0), wp )
172      DO jm = 1, 13
173         rmonth_half(jm) = rmonth_half(jm-1) + 0.5 * rday * REAL( nmonth_len(jm-1) + nmonth_len(jm), wp )
174      END DO
175      rmonth_half(:) = rmonth_half(:) + sec1jan000
176
177      rmonth_end(0) = 0.
178      DO jm = 1, 13
179         rmonth_end(jm) = rmonth_end(jm-1) + rday * REAL( nmonth_len(jm), wp )
180      END DO
181                 
182   END SUBROUTINE
183
184
185   SUBROUTINE day( kt )
186      !!----------------------------------------------------------------------
187      !!                      ***  ROUTINE day  ***
188      !!
189      !! ** Purpose :   Compute the date with a day iteration IF necessary.
190      !!
191      !! ** Method  : - ???
192      !!
193      !! ** Action  : - nyear     : current year
194      !!              - nmonth    : current month of the year nyear
195      !!              - nday      : current day of the month nmonth
196      !!              - nday_year : current day of the year nyear
197      !!              - ndastp    : = nyear*10000 + nmonth*100 + nday
198      !!              - adatrj    : date in days since the beginning of the run
199      !!              - rsec_year : current time of the year (in second since 00h, jan 1st)
200      !!----------------------------------------------------------------------     
201      INTEGER, INTENT(in) ::   kt        ! ocean time-step indices
202      !
203      CHARACTER (len=25) ::   charout
204      !!----------------------------------------------------------------------
205
206      !                                                 ! New time-step
207      rsec_year  = rsec_year  + rdttra(1) 
208      rsec_month = rsec_month + rdttra(1)                 
209      rsec_day   = rsec_day   + rdttra(1)                 
210      adatrj = adatrj + rdttra(1) / rday
211     
212      IF( rsec_day > rday ) THEN                        ! NEW day
213         !
214         nday      = nday + 1
215         nday_year = nday_year + 1
216         rsec_day  = 0.5 * rdttra(1)                 
217         !
218         IF( nday == nmonth_len(nmonth) + 1 ) THEN      ! NEW month
219            nday   = 1
220            nmonth = nmonth + 1
221            rsec_month = 0.5 * rdttra(1)
222            IF( nmonth == 13 ) THEN                     ! NEW year
223               nyear     = nyear + 1
224               nmonth    = 1
225               nday_year = 1
226               rsec_year = 0.5 * rdttra(1)
227               sec1jan000 = sec1jan000 + rday * REAL( nyear_len(1), wp )
228               IF( nleapy == 1 )   CALL day_mth
229            ENDIF
230         ENDIF
231         !
232         ndastp = nyear * 10000 + nmonth * 100 + nday   ! NEW date
233         !
234         IF(lwp) WRITE(numout,'(a,i8,a,i4.4,a,i2.2,a,i2.2,a,i3.3)') '======>> time-step =', kt,   &
235              &   '      New day, DATE Y/M/D = ', nyear, '/', nmonth, '/', nday, '      nday_year = ', nday_year
236         IF(lwp) WRITE(numout,'(a,F9.0,a,F9.0,a,F9.0)') '         rsec_year = ', rsec_year,   &
237              &   '   rsec_month = ', rsec_month, '   rsec_day = ', rsec_day
238      ENDIF
239     
240      IF(ln_ctl) THEN
241         WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
242         CALL prt_ctl_info(charout)
243      ENDIF
244
245      IF( lrst_oce )   CALL day_rst( kt, 'WRITE' )
246      !
247   END SUBROUTINE day
248
249
250   SUBROUTINE day_rst( kt, cdrw )
251      !!---------------------------------------------------------------------
252      !!                   ***  ROUTINE ts_rst  ***
253      !!
254      !!  ** Purpose : Read or write calendar in restart file:
255      !!
256      !!  WRITE(READ) mode:
257      !!       kt        : number of time step since the begining of the experiment at the
258      !!                   end of the current(previous) run
259      !!       adatrj(0) : number of elapsed days since the begining of the experiment at the
260      !!                   end of the current(previous) run (REAL -> keep fractions of day)
261      !!       ndastp    : date at the end of the current(previous) run (coded as yyyymmdd integer)
262      !!
263      !!   According to namelist parameter nrstdt,
264      !!       nrstdt = 0  no control on the date (nit000 is  arbitrary).
265      !!       nrstdt = 1  we verify that nit000 is equal to the last
266      !!                   time step of previous run + 1.
267      !!       In both those options, the  exact duration of the experiment
268      !!       since the beginning (cumulated duration of all previous restart runs)
269      !!       is not stored in the restart and is assumed to be (nit000-1)*rdt.
270      !!       This is valid is the time step has remained constant.
271      !!
272      !!       nrstdt = 2  the duration of the experiment in days (adatrj)
273      !!                    has been stored in the restart file.
274      !!----------------------------------------------------------------------
275      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
276      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
277      !
278      REAL(wp) ::   zkt, zndastp
279      !!----------------------------------------------------------------------
280     
281      IF( TRIM(cdrw) == 'READ' ) THEN
282
283         IF( iom_varid( numror, 'kt', ldstop = .FALSE. ) > 0 ) THEN
284            ! Get Calendar informations
285            CALL iom_get( numror, 'kt', zkt )   ! last time-step of previous run
286            IF(lwp) THEN
287               WRITE(numout,*) ' *** Info read in restart : '
288               WRITE(numout,*) '   previous time-step                               : ', NINT( zkt )
289               WRITE(numout,*) ' *** restart option'
290               SELECT CASE ( nrstdt )
291               CASE ( 0 )   ;   WRITE(numout,*) ' nrstdt = 0 : no control of nit000'
292               CASE ( 1 )   ;   WRITE(numout,*) ' nrstdt = 1 : no control the date at nit000 (use ndate0 read in the namelist)'
293               CASE ( 2 )   ;   WRITE(numout,*) ' nrstdt = 2 : calendar parameters read in restart'
294               END SELECT
295               WRITE(numout,*)
296            ENDIF
297            ! Control of date
298            IF( nit000 - NINT( zkt ) /= 1 .AND. nrstdt /= 0 )                                         & 
299                 &   CALL ctl_stop( ' ===>>>> : problem with nit000 for the restart',                 & 
300                 &                  ' verify the restart file or rerun with nrstdt = 0 (namelist)' )
301            ! define ndastp and adatrj
302            IF ( nrstdt == 2 ) THEN
303               CALL iom_get( numror, 'ndastp', zndastp )
304               ndastp = NINT( zndastp )
305               CALL iom_get( numror, 'adatrj', adatrj  )
306            ELSE
307               ndastp = ndate0 - 1     ! ndate0 read in the namelist in dom_nam
308               adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday 
309               ! note this is wrong if time step has changed during run
310            ENDIF
311         ELSE
312            ndastp = ndate0 - 1        ! ndate0 read in the namelist in dom_nam
313            adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday 
314         ENDIF
315         !
316         IF(lwp) THEN
317            WRITE(numout,*) ' *** Info used values : '
318            WRITE(numout,*) '   date ndastp                                      : ', ndastp
319            WRITE(numout,*) '   number of elapsed days since the begining of run : ', adatrj
320            WRITE(numout,*)
321         ENDIF
322         !
323      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
324         !
325         IF( kt == nitrst ) THEN
326            IF(lwp) WRITE(numout,*)
327            IF(lwp) WRITE(numout,*) 'rst_write : write oce restart file  kt =', kt
328            IF(lwp) WRITE(numout,*) '~~~~~~~'         
329         ENDIF
330         ! calendar control
331         CALL iom_rstput( kt, nitrst, numrow, 'kt'     , REAL( kt    , wp) )   ! time-step
332         CALL iom_rstput( kt, nitrst, numrow, 'ndastp' , REAL( ndastp, wp) )   ! date
333         CALL iom_rstput( kt, nitrst, numrow, 'adatrj' , adatrj            )   ! number of elapsed days since
334         !                                                                     ! the begining of the run [s]
335      ENDIF
336      !
337   END SUBROUTINE day_rst
338
339   !!======================================================================
340END MODULE daymod
Note: See TracBrowser for help on using the repository browser.