New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
mppini.F90 in trunk/NEMO/OPA_SRC – NEMO

source: trunk/NEMO/OPA_SRC/mppini.F90 @ 1344

Last change on this file since 1344 was 1344, checked in by rblod, 15 years ago

Update lib_mpp, see ticket #379
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 18.4 KB
Line 
1MODULE mppini
2   !!==============================================================================
3   !!                       ***  MODULE mppini   ***
4   !! Ocean initialization : distributed memory computing initialization
5   !!==============================================================================
6
7   !!----------------------------------------------------------------------
8   !!   mpp_init       : Lay out the global domain over processors
9   !!   mpp_init2      : Lay out the global domain over processors
10   !!                    with land processor elimination
11   !!   mpp_init_ioispl: IOIPSL initialization in mpp
12   !!----------------------------------------------------------------------
13   !! * Modules used
14   USE dom_oce         ! ocean space and time domain
15   USE in_out_manager  ! I/O Manager
16   USE sol_oce         ! ocean elliptic solver
17   USE lib_mpp         ! distribued memory computing library
18   USE ioipsl
19
20   IMPLICIT NONE
21   PRIVATE
22
23   !! * Routine accessibility
24   PUBLIC mpp_init       ! called by opa.F90
25   PUBLIC mpp_init2      ! called by opa.F90
26
27   !! * Substitutions
28#  include "domzgr_substitute.h90"
29   !!----------------------------------------------------------------------
30   !!   OPA 9.0 , LOCEAN-IPSL (2005)
31   !! $Id$
32   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
33   !!----------------------------------------------------------------------
34
35CONTAINS
36
37#if ! defined key_mpp_mpi   &&   ! defined key_mpp_shmem
38   !!----------------------------------------------------------------------
39   !!   Default option :                            shared memory computing
40   !!----------------------------------------------------------------------
41
42   SUBROUTINE mpp_init
43      !!----------------------------------------------------------------------
44      !!                  ***  ROUTINE mpp_init  ***
45      !!
46      !! ** Purpose :   Lay out the global domain over processors.
47      !!
48      !! ** Method  :   Shared memory computing, set the local processor
49      !!      variables to the value of the global domain
50      !!
51      !! History :
52      !!   9.0  !  04-01  (G. Madec, J.M. Molines)  F90 : free form, north fold jpni >1
53      !!----------------------------------------------------------------------
54
55      ! No mpp computation
56      nimpp  = 1
57      njmpp  = 1
58      nlci   = jpi
59      nlcj   = jpj
60      nldi   = 1
61      nldj   = 1
62      nlei   = jpi
63      nlej   = jpj
64      nperio = jperio
65      nbondi = 2
66      nbondj = 2
67      nidom  = FLIO_DOM_NONE
68      npolj = jperio
69
70      IF(lwp) THEN
71         WRITE(numout,*)
72         WRITE(numout,*) 'mpp_init(2) : NO massively parallel processing'
73         WRITE(numout,*) '~~~~~~~~~~~: '
74         WRITE(numout,*) '         nperio = ', nperio
75         WRITE(numout,*) '         npolj  = ', npolj
76         WRITE(numout,*) '         nimpp  = ', nimpp
77         WRITE(numout,*) '         njmpp  = ', njmpp
78      ENDIF
79
80      IF(  jpni /= 1 .OR. jpnj /= 1 .OR. jpnij /= 1 ) &
81          CALL ctl_stop( 'equality  jpni = jpnj = jpnij = 1 is not satisfied',   &
82          &              'the domain is lay out for distributed memory computing! ' )
83
84   END SUBROUTINE mpp_init
85
86
87   SUBROUTINE mpp_init2 
88      CALL mpp_init                             ! same routine as mpp_init
89   END SUBROUTINE mpp_init2
90
91#else
92   !!----------------------------------------------------------------------
93   !!   'key_mpp_mpi'          OR         MPI massively parallel processing
94   !!   'key_mpp_shmem'                 SHMEM massively parallel processing
95   !!----------------------------------------------------------------------
96
97   SUBROUTINE mpp_init
98      !!----------------------------------------------------------------------
99      !!                  ***  ROUTINE mpp_init  ***
100      !!                   
101      !! ** Purpose :   Lay out the global domain over processors.
102      !!
103      !! ** Method  :   Global domain is distributed in smaller local domains.
104      !!      Periodic condition is a function of the local domain position
105      !!      (global boundary or neighbouring domain) and of the global
106      !!      periodic
107      !!      Type :         jperio global periodic condition
108      !!                     nperio local  periodic condition
109      !!
110      !! ** Action  : - set domain parameters
111      !!                    nimpp     : longitudinal index
112      !!                    njmpp     : latitudinal  index
113      !!                    nperio    : lateral condition type
114      !!                    narea     : number for local area
115      !!                    nlci      : first dimension
116      !!                    nlcj      : second dimension
117      !!                    nbondi    : mark for "east-west local boundary"
118      !!                    nbondj    : mark for "north-south local boundary"
119      !!                    nproc     : number for local processor
120      !!                    noea      : number for local neighboring processor
121      !!                    nowe      : number for local neighboring processor
122      !!                    noso      : number for local neighboring processor
123      !!                    nono      : number for local neighboring processor
124      !!
125      !! History :
126      !!        !  94-11  (M. Guyon)  Original code
127      !!        !  95-04  (J. Escobar, M. Imbard)
128      !!        !  98-02  (M. Guyon)  FETI method
129      !!        !  98-05  (M. Imbard, J. Escobar, L. Colombet )  SHMEM and MPI versions
130      !!   8.5  !  02-08  (G. Madec)  F90 : free form
131      !!----------------------------------------------------------------------
132      !! * Local variables
133      CHARACTER (len=32) ::   clname
134      INTEGER ::   ji, jj, jn               ! dummy loop indices
135      INTEGER ::   &
136         ii, ij, ifreq, il1, il2,        &  ! temporary integers
137         iresti, irestj, ijm1, imil,     &  !    "          "
138         inum                               ! temporary logical unit
139
140      INTEGER, DIMENSION(jpni,jpnj) ::   &
141         iimppt, ijmppt, ilcit, ilcjt       ! temporary workspace
142      REAL(wp) ::   zidom, zjdom            ! temporary scalars
143      !!----------------------------------------------------------------------
144
145#if defined key_mpp_shmem
146      IF(lwp) WRITE(numout,*)
147      IF(lwp) WRITE(numout,*) 'mpp_init : Message Passing PVM T3E + SHMEM'
148      IF(lwp) WRITE(numout,*) '~~~~~~~~'
149
150      CALL mppshmem                           ! Initialisation of shmem array
151
152#endif
153#if defined key_mpp_mpi
154      IF(lwp) WRITE(numout,*)
155      IF(lwp) WRITE(numout,*) 'mpp_init : Message Passing MPI'
156      IF(lwp) WRITE(numout,*) '~~~~~~~~'
157#endif
158
159
160      !  1. Dimension arrays for subdomains
161      ! -----------------------------------
162      !  Computation of local domain sizes ilcit() ilcjt()
163      !  These dimensions depend on global sizes jpni,jpnj and jpiglo,jpjglo
164      !  The subdomains are squares leeser than or equal to the global
165      !  dimensions divided by the number of processors minus the overlap
166      !  array (cf. par_oce.F90).
167     
168      nreci  = 2 * jpreci
169      nrecj  = 2 * jprecj
170      iresti = MOD( jpiglo - nreci , jpni )
171      irestj = MOD( jpjglo - nrecj , jpnj )
172
173      IF(  iresti == 0 )   iresti = jpni
174      DO jj = 1, jpnj
175         DO ji = 1, iresti
176            ilcit(ji,jj) = jpi
177         END DO
178         DO ji = iresti+1, jpni
179            ilcit(ji,jj) = jpi -1
180         END DO
181      END DO
182     
183      IF( irestj == 0 )   irestj = jpnj
184      DO ji = 1, jpni
185         DO jj = 1, irestj
186            ilcjt(ji,jj) = jpj
187         END DO
188         DO jj = irestj+1, jpnj
189            ilcjt(ji,jj) = jpj -1
190         END DO
191      END DO
192     
193      IF(lwp) THEN
194         WRITE(numout,*)
195         WRITE(numout,*) '           defines mpp subdomains'
196         WRITE(numout,*) '           ----------------------'
197         WRITE(numout,*) '           iresti=',iresti,' irestj=',irestj
198         WRITE(numout,*) '           jpni  =',jpni  ,' jpnj  =',jpnj
199         ifreq = 4
200         il1   = 1
201         DO jn = 1, (jpni-1)/ifreq+1
202            il2 = MIN( jpni, il1+ifreq-1 )
203            WRITE(numout,*)
204            WRITE(numout,9200) ('***',ji = il1,il2-1)
205            DO jj = jpnj, 1, -1
206               WRITE(numout,9203) ('   ',ji = il1,il2-1)
207               WRITE(numout,9202) jj, ( ilcit(ji,jj),ilcjt(ji,jj),ji = il1,il2 )
208               WRITE(numout,9203) ('   ',ji = il1,il2-1)
209               WRITE(numout,9200) ('***',ji = il1,il2-1)
210            END DO
211            WRITE(numout,9201) (ji,ji = il1,il2)
212            il1 = il1+ifreq
213         END DO
214 9200    FORMAT('     ***',20('*************',a3))
215 9203    FORMAT('     *     ',20('         *   ',a3))
216 9201    FORMAT('        ',20('   ',i3,'          '))
217 9202    FORMAT(' ',i3,' *  ',20(i3,'  x',i3,'   *   '))
218      ENDIF
219
220      zidom = nreci
221      DO ji = 1, jpni
222         zidom = zidom + ilcit(ji,1) - nreci
223      END DO
224      IF(lwp) WRITE(numout,*)
225      IF(lwp) WRITE(numout,*)' sum ilcit(i,1) = ', zidom, ' jpiglo = ', jpiglo
226     
227      zjdom = nrecj
228      DO jj = 1, jpnj
229         zjdom = zjdom + ilcjt(1,jj) - nrecj
230      END DO
231      IF(lwp) WRITE(numout,*)' sum ilcit(1,j) = ', zjdom, ' jpjglo = ', jpjglo
232      IF(lwp) WRITE(numout,*)
233     
234
235      !  2. Index arrays for subdomains
236      ! -------------------------------
237     
238      iimppt(:,:) = 1
239      ijmppt(:,:) = 1
240     
241      IF( jpni > 1 ) THEN
242         DO jj = 1, jpnj
243            DO ji = 2, jpni
244               iimppt(ji,jj) = iimppt(ji-1,jj) + ilcit(ji-1,jj) - nreci
245            END DO
246         END DO
247      ENDIF
248
249      IF( jpnj > 1 ) THEN
250         DO jj = 2, jpnj
251            DO ji = 1, jpni
252               ijmppt(ji,jj) = ijmppt(ji,jj-1)+ilcjt(ji,jj-1)-nrecj
253            END DO
254         END DO
255      ENDIF
256     
257      ! 3. Subdomain description
258      ! ------------------------
259
260      DO jn = 1, jpnij
261         ii = 1 + MOD( jn-1, jpni )
262         ij = 1 + (jn-1) / jpni
263         nimppt(jn) = iimppt(ii,ij)
264         njmppt(jn) = ijmppt(ii,ij)
265         nlcit (jn) = ilcit (ii,ij)     
266         nlci       = nlcit (jn)     
267         nlcjt (jn) = ilcjt (ii,ij)     
268         nlcj       = nlcjt (jn)
269         nbondj = -1                                   ! general case
270         IF( jn   >  jpni          )   nbondj = 0      ! first row of processor
271         IF( jn   >  (jpnj-1)*jpni )   nbondj = 1      ! last  row of processor
272         IF( jpnj == 1             )   nbondj = 2      ! one processor only in j-direction
273         ibonjt(jn) = nbondj
274         
275         nbondi = 0                                    !
276         IF( MOD( jn, jpni ) == 1 )   nbondi = -1      !
277         IF( MOD( jn, jpni ) == 0 )   nbondi =  1      !
278         IF( jpni            == 1 )   nbondi =  2      ! one processor only in i-direction
279         ibonit(jn) = nbondi
280         
281         nldi =  1   + jpreci
282         nlei = nlci - jpreci
283         IF( nbondi == -1 .OR. nbondi == 2 )   nldi = 1
284         IF( nbondi ==  1 .OR. nbondi == 2 )   nlei = nlci
285         nldj =  1   + jprecj
286         nlej = nlcj - jprecj
287         IF( nbondj == -1 .OR. nbondj == 2 )   nldj = 1
288         IF( nbondj ==  1 .OR. nbondj == 2 )   nlej = nlcj
289         nldit(jn) = nldi
290         nleit(jn) = nlei
291         nldjt(jn) = nldj
292         nlejt(jn) = nlej
293      END DO
294     
295
296      ! 4. From global to local
297      ! -----------------------
298
299      nperio = 0
300      IF( jperio == 2 .AND. nbondj == -1 )   nperio = 2
301
302
303      ! 5. Subdomain neighbours
304      ! ----------------------
305
306      nproc = narea - 1
307      noso  = nproc - jpni
308      nowe  = nproc - 1
309      noea  = nproc + 1
310      nono  = nproc + jpni
311      ! great neighbours
312      npnw = nono - 1
313      npne = nono + 1
314      npsw = noso - 1
315      npse = noso + 1
316      nbsw = 1
317      nbnw = 1
318      IF( MOD( nproc, jpni ) == 0 ) THEN
319         nbsw = 0
320         nbnw = 0
321      ENDIF
322      nbse = 1
323      nbne = 1
324      IF( MOD( nproc, jpni ) == jpni-1 ) THEN
325         nbse = 0
326         nbne = 0
327      ENDIF
328      IF(nproc < jpni) THEN
329         nbsw = 0
330         nbse = 0
331      ENDIF
332      IF( nproc >= (jpnj-1)*jpni ) THEN
333         nbnw = 0
334         nbne = 0
335      ENDIF
336      nlcj = nlcjt(narea) 
337      nlci = nlcit(narea) 
338      nldi = nldit(narea)
339      nlei = nleit(narea)
340      nldj = nldjt(narea)
341      nlej = nlejt(narea)
342      nbondi = ibonit(narea)
343      nbondj = ibonjt(narea)
344      nimpp  = nimppt(narea) 
345      njmpp  = njmppt(narea) 
346
347     ! Save processor layout in layout.dat file
348       IF (lwp) THEN
349        clname = 'layout.dat'
350        CALL ctlopn( inum, clname, 'UNKNOWN', 'FORMATTED', 'SEQUENTIAL',   &
351           &         1, numout, .FALSE., 1 )
352        WRITE(inum,'(a)') '   jpnij     jpi     jpj     jpk  jpiglo  jpjglo'
353        WRITE(inum,'(6i8)') jpnij,jpi,jpj,jpk,jpiglo,jpjglo
354        WRITE(inum,'(a)') 'NAREA nlci nlcj nldi nldj nlei nlej nimpp njmpp'
355
356        DO  jn = 1, jpnij
357         WRITE(inum,'(9i5)') jn, nlcit(jn), nlcjt(jn), &
358                                      nldit(jn), nldjt(jn), &
359                                      nleit(jn), nlejt(jn), &
360                                      nimppt(jn), njmppt(jn)
361        END DO
362        CLOSE(inum)   
363      END IF
364
365
366      ! w a r n i n g  narea (zone) /= nproc (processors)!
367
368      IF( jperio == 1 .OR. jperio == 4 .OR. jperio == 6 ) THEN
369         IF( jpni == 1 )THEN
370            nbondi = 2
371            nperio = 1
372         ELSE
373            nbondi = 0
374         ENDIF
375         IF( MOD( narea, jpni ) == 0 ) THEN
376            noea = nproc-(jpni-1)
377            npne = npne-jpni
378            npse = npse-jpni
379         ENDIF
380         IF( MOD( narea, jpni ) == 1 ) THEN
381            nowe = nproc+(jpni-1)
382            npnw = npnw+jpni
383            npsw = npsw+jpni
384         ENDIF
385         nbsw = 1
386         nbnw = 1
387         nbse = 1
388         nbne = 1
389         IF( nproc < jpni ) THEN
390            nbsw = 0
391            nbse = 0
392         ENDIF
393         IF( nproc >= (jpnj-1)*jpni ) THEN
394            nbnw = 0
395            nbne = 0
396         ENDIF
397      ENDIF
398      npolj = 0
399      IF( jperio == 3 .OR. jperio == 4 ) THEN
400         ijm1 = jpni*(jpnj-1)
401         imil = ijm1+(jpni+1)/2
402         IF( narea > ijm1 ) npolj = 3
403         IF( MOD(jpni,2) == 1 .AND. narea == imil ) npolj = 4
404         IF( npolj == 3 ) nono = jpni*jpnj-narea+ijm1
405      ENDIF
406      IF( jperio == 5 .OR. jperio == 6 ) THEN
407          ijm1 = jpni*(jpnj-1)
408          imil = ijm1+(jpni+1)/2
409          IF( narea > ijm1) npolj = 5
410          IF( MOD(jpni,2) == 1 .AND. narea == imil ) npolj = 6
411          IF( npolj == 5 ) nono = jpni*jpnj-narea+ijm1
412      ENDIF
413
414      ! FETI method
415
416      IF( nperio == 1 .AND. nsolv == 3 ) THEN 
417         
418         ! general case : Earth == infinite tube
419         
420         nbnw = 1
421         npnw = narea
422         nbne = 1
423         npne = narea
424         nbsw = 1
425         npsw = (narea-2)
426         nbse = 1
427         npse = (narea-2)
428         
429         ! REAL boundary condition
430         
431         IF( nbondj == -1 .OR. nbondj == 2 ) THEN
432            nbsw = 0
433            nbse = 0
434         ENDIF
435         
436         IF( nbondj == -1 .OR. nbondj == 2 ) THEN
437            nbsw = 0
438            nbse = 0
439         ENDIF
440         
441         IF( nbondj == 1  .OR. nbondj == 2 ) THEN
442            nbnw = 0
443            nbne = 0
444         ENDIF
445      ENDIF
446
447      ! Periodicity : no corner if nbondi = 2 and nperio != 1
448
449      IF(lwp) THEN
450         WRITE(numout,*) ' nproc  = ', nproc
451         WRITE(numout,*) ' nowe   = ', nowe  , ' noea   =  ', noea
452         WRITE(numout,*) ' nono   = ', nono  , ' noso   =  ', noso
453         WRITE(numout,*) ' nbondi = ', nbondi
454         WRITE(numout,*) ' nbondj = ', nbondj
455         WRITE(numout,*) ' npolj  = ', npolj
456         WRITE(numout,*) ' nperio = ', nperio
457         WRITE(numout,*) ' nlci   = ', nlci
458         WRITE(numout,*) ' nlcj   = ', nlcj
459         WRITE(numout,*) ' nimpp  = ', nimpp
460         WRITE(numout,*) ' njmpp  = ', njmpp
461         WRITE(numout,*) ' nbse   = ', nbse  , ' npse   = ', npse
462         WRITE(numout,*) ' nbsw   = ', nbsw  , ' npsw   = ', npsw
463         WRITE(numout,*) ' nbne   = ', nbne  , ' npne   = ', npne
464         WRITE(numout,*) ' nbnw   = ', nbnw  , ' npnw   = ', npnw
465      ENDIF
466
467      IF( nperio == 1 .AND. jpni /= 1 ) CALL ctl_stop( ' mpp_init: error on cyclicity' )
468
469      ! Prepare mpp north fold
470
471      IF (jperio >= 3 .AND. jperio <= 6 .AND. jpni > 1 ) THEN
472         CALL mpp_ini_north
473      END IF
474
475      ! Prepare NetCDF output file (if necessary)
476      CALL mpp_init_ioipsl
477
478   END SUBROUTINE mpp_init
479
480#  include "mppini_2.h90"
481
482# if defined key_dimgout
483   !!----------------------------------------------------------------------
484   !!   'key_dimgout'                  NO use of NetCDF files
485   !!----------------------------------------------------------------------
486   SUBROUTINE mpp_init_ioipsl       ! Dummy routine
487   END SUBROUTINE mpp_init_ioipsl 
488# else
489   SUBROUTINE mpp_init_ioipsl
490      !!----------------------------------------------------------------------
491      !!                  ***  ROUTINE mpp_init_ioipsl  ***
492      !!
493      !! ** Purpose :   
494      !!
495      !! ** Method  :   
496      !!
497      !! History :
498      !!   9.0  !  04-03  (G. Madec )  MPP-IOIPSL
499      !!   " "  !  08-12  (A. Coward)  addition in case of jpni*jpnj < jpnij
500      !!----------------------------------------------------------------------
501      !! Local declarations
502
503      INTEGER, DIMENSION(2) ::   &
504         iglo, iloc, iabsf, iabsl, ihals, ihale, idid
505      !!----------------------------------------------------------------------
506
507      ! The domain is split only horizontally along i- or/and j- direction
508      ! So we need at the most only 1D arrays with 2 elements.
509      ! Set idompar values equivalent to the jpdom_local_noextra definition
510      ! used in IOM. This works even if jpnij .ne. jpni*jpnj.
511      iglo(1) = jpiglo
512      iglo(2) = jpjglo
513      iloc(1) = nlci
514      iloc(2) = nlcj
515      iabsf(1) = nimppt(narea)
516      iabsf(2) = njmppt(narea)
517      iabsl(:) = iabsf(:) + iloc(:) - 1
518      ihals(1) = nldi - 1
519      ihals(2) = nldj - 1
520      ihale(1) = nlci - nlei
521      ihale(2) = nlcj - nlej
522      idid(1) = 1
523      idid(2) = 2
524
525      IF(lwp) THEN
526          WRITE(numout,*)
527          WRITE(numout,*) 'mpp_init_ioipsl :   iloc  = ', iloc (1), iloc (2)
528          WRITE(numout,*) '~~~~~~~~~~~~~~~     iabsf = ', iabsf(1), iabsf(2)
529          WRITE(numout,*) '                    ihals = ', ihals(1), ihals(2)
530          WRITE(numout,*) '                    ihale = ', ihale(1), ihale(2)
531      ENDIF
532
533      CALL flio_dom_set ( jpnij, nproc, idid, iglo, iloc, iabsf, iabsl, ihals, ihale, 'BOX', nidom)
534
535   END SUBROUTINE mpp_init_ioipsl 
536
537# endif
538#endif
539
540   !!======================================================================
541END MODULE mppini
Note: See TracBrowser for help on using the repository browser.